IkiWiki/Plugin/attachment.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::attachment;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         add_underlay("attachment");
  10         add_underlay("javascript");
  11         add_underlay("jquery");
  12         hook(type => "getsetup", id => "attachment", call => \&getsetup);
  13         hook(type => "checkconfig", id => "attachment", call => \&checkconfig);
  14         hook(type => "formbuilder_setup", id => "attachment", call => \&formbuilder_setup);
  15         hook(type => "formbuilder", id => "attachment", call => \&formbuilder, last => 1);
  16         IkiWiki::loadplugin("filecheck");
  17 }
  18
  19 sub getsetup () {
  20         return
  21                 plugin => {
  22                         safe => 1,
  23                         rebuild => 0,
  24                         section => "web",
  25                 },
  26                 allowed_attachments => {
  27                         type => "pagespec",
  28                         example => "virusfree() and mimetype(image/*) and maxsize(50kb)",
  29                         description => "enhanced PageSpec specifying what attachments are allowed",
  30                         link => "ikiwiki/PageSpec/attachment",
  31                         safe => 1,
  32                         rebuild => 0,
  33                 },
  34                 virus_checker => {
  35                         type => "string",
  36                         example => "clamdscan -",
  37                         description => "virus checker program (reads STDIN, returns nonzero if virus found)",
  38                         safe => 0, # executed
  39                         rebuild => 0,
  40                 },
  41 }
  42
  43 sub check_canattach ($$;$) {
  44         my $session=shift;
  45         my $dest=shift; # where it's going to be put, under the srcdir
  46         my $file=shift; # the path to the attachment currently
  47
  48         # Don't allow an attachment to be uploaded with the same name as an
  49         # existing page.
  50         if (exists $IkiWiki::pagesources{$dest} &&
  51             $IkiWiki::pagesources{$dest} ne $dest) {
  52                 error(sprintf(gettext("there is already a page named %s"), $dest));
  53         }
  54
  55         # Use a special pagespec to test that the attachment is valid.
  56         my $allowed=1;
  57         if (defined $config{allowed_attachments} &&
  58             length $config{allowed_attachments}) {
  59                 $allowed=pagespec_match($dest,
  60                         $config{allowed_attachments},
  61                         file => $file,
  62                         user => $session->param("name"),
  63                         ip => $session->remote_addr(),
  64                 );
  65         }
  66
  67         if (! $allowed) {
  68                 error(gettext("prohibited by allowed_attachments")." ($allowed)");
  69         }
  70         else {
  71                 return 1;
  72         }
  73 }
  74
  75 sub checkconfig () {
  76         $config{cgi_disable_uploads}=0;
  77 }
  78
  79 sub formbuilder_setup (@) {
  80         my %params=@_;
  81         my $form=$params{form};
  82         my $q=$params{cgi};
  83
  84         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  85             $form->field("do") eq "create")) {
  86                 # Add attachment field, set type to multipart.
  87                 $form->enctype(&CGI::MULTIPART);
  88                 $form->field(name => 'attachment', type => 'file');
  89                 # These buttons are not put in the usual place, so
  90                 # are not added to the normal formbuilder button list.
  91                 $form->tmpl_param("field-upload" => '<input name="_submit" type="submit" value="Upload Attachment" />');
  92                 $form->tmpl_param("field-link" => '<input name="_submit" type="submit" value="Insert Links" />');
  93
  94                 # Add all the javascript used by the attachments interface.
  95                 require IkiWiki::Plugin::toggle;
  96                 my $js=IkiWiki::Plugin::toggle::include_javascript($params{page});
  97                 $js.='<link rel="stylesheet" href="'.urlto("ikiwiki/jquery-ui.css", $params{page}).' id="theme">\n';
  98                 my @jsfiles=qw{jquery.min jquery-ui.min
  99                         jquery.tmpl.min jquery.iframe-transport
 100                         jquery.fileupload jquery.fileupload-ui
 101                 };
 102                 foreach my $file (@jsfiles) {
 103                         $js.='<script src="'.urlto("ikiwiki/$file.js", $params{page}).
 104                              '" type="text/javascript" charset="utf-8"></script>'."\n";
 105                 }
 106                 $form->tmpl_param("javascript" => $js);
 107
 108                 # Start with the attachments interface toggled invisible,
 109                 # but if it was used, keep it open.
 110                 if ($form->submitted ne "Upload Attachment" &&
 111                     (! defined $q->param("attachment_select") ||
 112                     ! length $q->param("attachment_select"))) {
 113                         $form->tmpl_param("attachments-class" => "toggleable");
 114                 }
 115                 else {
 116                         $form->tmpl_param("attachments-class" => "toggleable-open");
 117                 }
 118
 119                 # Save attachments in holding area before previewing so
 120                 # they can be seen in the preview.
 121                 if ($form->submitted eq "Preview") {
 122                         attachments_save($form, $params{session});
 123                 }
 124         }
 125 }
 126
 127 sub formbuilder (@) {
 128         my %params=@_;
 129         my $form=$params{form};
 130         my $q=$params{cgi};
 131
 132         return if ! defined $form->field("do") || ($form->field("do") ne "edit" && $form->field("do") ne "create") ;
 133
 134         my $filename=Encode::decode_utf8($q->param('attachment'));
 135         if (defined $filename && length $filename) {
 136                 attachment_store($filename, $form, $q, $params{session});
 137         }
 138
 139         if ($form->submitted eq "Save Page") {
 140                 attachments_save($form, $params{session});
 141         }
 142
 143         if ($form->submitted eq "Insert Links") {
 144                 my $page=quotemeta(Encode::decode_utf8($q->param("page")));
 145                 my $add="";
 146                 foreach my $f ($q->param("attachment_select")) {
 147                         $f=Encode::decode_utf8($f);
 148                         $f=~s/^$page\///;
 149                         if (IkiWiki::isinlinableimage($f) &&
 150                             UNIVERSAL::can("IkiWiki::Plugin::img", "import")) {
 151                                 $add.='[[!img '.$f.' align="right" size="" alt=""]]';
 152                         }
 153                         else {
 154                                 $add.="[[$f]]";
 155                         }
 156                         $add.="\n";
 157                 }
 158                 $form->field(name => 'editcontent',
 159                         value => $form->field('editcontent')."\n\n".$add,
 160                         force => 1) if length $add;
 161         }
 162
 163         # Generate the attachment list only after having added any new
 164         # attachments.
 165         $form->tmpl_param("attachment_list" => [attachment_list($form->field('page'))]);
 166 }
 167
 168 sub attachment_holding_location {
 169         my $page=attachment_location(shift);
 170
 171         my $dir=$config{wikistatedir}."/attachments/".
 172                 IkiWiki::possibly_foolish_untaint(linkpage($page));
 173         $dir=~s/\/$//;
 174         return $dir;
 175 }
 176
 177 sub is_held_attachment {
 178         my $attachment=shift;
 179
 180         my $f=attachment_holding_location($attachment);
 181         if (-f $f) {
 182                 return $f
 183         }
 184         else {
 185                 return undef;
 186         }
 187 }
 188
 189 # Stores the attachment in a holding area, not yet in the wiki proper.
 190 sub attachment_store {
 191         my $filename=shift;
 192         my $form=shift;
 193         my $q=shift;
 194         my $session=shift;
 195
 196         # This is an (apparently undocumented) way to get the name
 197         # of the temp file that CGI writes the upload to.
 198         my $tempfile=$q->tmpFileName($filename);
 199         if (! defined $tempfile || ! length $tempfile) {
 200                 # perl 5.8 needs an alternative, awful method
 201                 if ($q =~ /HASH/ && exists $q->{'.tmpfiles'}) {
 202                         foreach my $key (keys(%{$q->{'.tmpfiles'}})) {
 203                                 $tempfile=$q->tmpFileName(\$key);
 204                                 last if defined $tempfile && length $tempfile;
 205                         }
 206                 }
 207                 if (! defined $tempfile || ! length $tempfile) {
 208                         error("CGI::tmpFileName failed to return the uploaded file name");
 209                 }
 210         }
 211
 212         $filename=IkiWiki::basename($filename);
 213         $filename=~s/.*\\+(.+)/$1/; # hello, windows
 214         $filename=IkiWiki::possibly_foolish_untaint(linkpage($filename));
 215
 216         # Check that the user is allowed to edit the attachment.
 217         my $final_filename=
 218                 linkpage(IkiWiki::possibly_foolish_untaint(
 219                         attachment_location($form->field('page')))).
 220                 $filename;
 221         if (IkiWiki::file_pruned($final_filename)) {
 222                 error(gettext("bad attachment filename"));
 223         }
 224         IkiWiki::check_canedit($final_filename, $q, $session);
 225         # And that the attachment itself is acceptable.
 226         check_canattach($session, $final_filename, $tempfile);
 227
 228         # Move the attachment into holding directory.
 229         # Try to use a fast rename; fall back to copying.
 230         my $dest=attachment_holding_location($form->field('page'));
 231         IkiWiki::prep_writefile($filename, $dest);
 232         unlink($dest."/".$filename);
 233         if (rename($tempfile, $dest."/".$filename)) {
 234                 # The temp file has tight permissions; loosen up.
 235                 chmod(0666 & ~umask, $dest."/".$filename);
 236         }
 237         else {
 238                 my $fh=$q->upload('attachment');
 239                 if (! defined $fh || ! ref $fh) {
 240                         # needed by old CGI versions
 241                         $fh=$q->param('attachment');
 242                         if (! defined $fh || ! ref $fh) {
 243                                 # even that doesn't always work,
 244                                 # fall back to opening the tempfile
 245                                 $fh=undef;
 246                                 open($fh, "<", $tempfile) || error("failed to open \"$tempfile\": $!");
 247                         }
 248                 }
 249                 binmode($fh);
 250                 require IkiWiki::Render;
 251                 writefile($filename, $dest, undef, 1, sub {
 252                         IkiWiki::fast_file_copy($tempfile, $filename, $fh, @_);
 253                 });
 254         }
 255
 256         # Return JSON response for the jquery file upload widget.
 257         eval q{use JSON};
 258         error $@ if $@;
 259         print "Content-type: application/json\n\n";
 260         my $size=-s $dest."/".$filename;
 261         print to_json([
 262                 {
 263                         name => $filename,
 264                         size => $size,
 265                         humansize => IkiWiki::Plugin::filecheck::humansize($size),
 266                         stored_msg => stored_msg(),
 267
 268                 }
 269         ]);
 270         exit 0;
 271 }
 272
 273 # Save all stored attachments for a page.
 274 sub attachments_save {
 275         my $form=shift;
 276         my $session=shift;
 277
 278         # Move attachments out of holding directory.
 279         my @attachments;
 280         my $dir=attachment_holding_location($form->field('page'));
 281         foreach my $filename (glob("$dir/*")) {
 282                 next unless -f $filename;
 283                 my $dest=$config{srcdir}."/".
 284                         linkpage(IkiWiki::possibly_foolish_untaint(
 285                                 attachment_location($form->field('page')))).
 286                         IkiWiki::basename($filename);
 287                 unlink($dest);
 288                 rename($filename, $dest);
 289                 push @attachments, $dest;
 290         }
 291         return unless @attachments;
 292         require IkiWiki::Render;
 293         IkiWiki::prune($dir);
 294
 295         # Check the attachments in and trigger a wiki refresh.
 296         if ($config{rcs}) {
 297                 IkiWiki::rcs_add($_) foreach @attachments;
 298                 IkiWiki::disable_commit_hook();
 299                 IkiWiki::rcs_commit_staged(
 300                         message => gettext("attachment upload"),
 301                         session => $session,
 302                 );
 303                 IkiWiki::enable_commit_hook();
 304                 IkiWiki::rcs_update();
 305         }
 306         IkiWiki::refresh();
 307         IkiWiki::saveindex();
 308 }
 309
 310 sub attachment_location ($) {
 311         my $page=shift;
 312
 313         # Put the attachment in a subdir of the page it's attached
 314         # to, unless that page is an "index" page.
 315         $page=~s/(^|\/)index//;
 316         $page.="/" if length $page;
 317
 318         return $page;
 319 }
 320
 321 sub attachment_list ($) {
 322         my $page=shift;
 323         my $loc=attachment_location($page);
 324
 325         my $std=sub {
 326                 my $file=shift;
 327                 my $mtime=shift;
 328                 my $date=shift;
 329                 my $size=shift;
 330
 331                 name => $file,
 332                 size => IkiWiki::Plugin::filecheck::humansize($size),
 333                 mtime => $date,
 334                 mtime_raw => $mtime,
 335         };
 336
 337         # attachments already in the wiki
 338         my %attachments;
 339         foreach my $f (values %pagesources) {
 340                 if (! defined pagetype($f) &&
 341                     $f=~m/^\Q$loc\E[^\/]+$/) {
 342                         $attachments{$f}={
 343                                 $std->($f, $IkiWiki::pagemtime{$f}, displaytime($IkiWiki::pagemtime{$f}), (stat($f))[7]),
 344                                 link => htmllink($page, $page, $f, noimageinline => 1),
 345                         };
 346                 }
 347         }
 348
 349         # attachments in holding directory
 350         my $dir=attachment_holding_location($page);
 351         my $heldmsg=gettext("this attachment is not yet saved");
 352         foreach my $file (glob("$dir/*")) {
 353                 next unless -f $file;
 354                 my $base=IkiWiki::basename($file);
 355                 my $f=$loc.$base;
 356                 $attachments{$f}={
 357                         $std->($f, (stat($file))[9], stored_msg(), (stat(_))[7]),
 358                         link => $base,
 359                 }
 360         }
 361
 362         # Sort newer attachments to the end of the list.
 363         return sort { $a->{mtime_raw} <=> $b->{mtime_raw} || $a->{link} cmp $b->{link} }
 364                 values %attachments;
 365 }
 366
 367 sub stored_msg {
 368         gettext("just uploaded");
 369 }
 370
 371 1