IkiWiki/Plugin/tag.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki tag plugin.
   3 package IkiWiki::Plugin::tag;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 my %tags;
  10
  11 sub import {
  12         hook(type => "getopt", id => "tag", call => \&getopt);
  13         hook(type => "getsetup", id => "tag", call => \&getsetup);
  14         hook(type => "preprocess", id => "tag", call => \&preprocess_tag, scan => 1);
  15         hook(type => "preprocess", id => "taglink", call => \&preprocess_taglink, scan => 1);
  16         hook(type => "pagetemplate", id => "tag", call => \&pagetemplate);
  17 }
  18
  19 sub getopt () {
  20         eval q{use Getopt::Long};
  21         error($@) if $@;
  22         Getopt::Long::Configure('pass_through');
  23         GetOptions("tagbase=s" => \$config{tagbase});
  24 }
  25
  26 sub getsetup () {
  27         return
  28                 plugin => {
  29                         safe => 1,
  30                         rebuild => undef,
  31                 },
  32                 tagbase => {
  33                         type => "string",
  34                         example => "tag",
  35                         description => "parent page tags are located under",
  36                         safe => 1,
  37                         rebuild => 1,
  38                 },
  39                 tag_autocreate => {
  40                         type => "boolean",
  41                         example => 0,
  42                         description => "Autocreate new tag pages",
  43                         safe => 1,
  44                         rebuild => 1,
  45                 },
  46 }
  47
  48 sub tagpage ($) {
  49         my $tag=shift;
  50
  51         if ($tag !~ m{^\.?/} &&
  52             defined $config{tagbase}) {
  53                 $tag="/".$config{tagbase}."/".$tag;
  54                 $tag=~y#/#/#s; # squash dups
  55         }
  56
  57         return $tag;
  58 }
  59
  60 sub taglink ($$$;@) {
  61         my $page=shift;
  62         my $destpage=shift;
  63         my $tag=shift;
  64         my %opts=@_;
  65
  66         return htmllink($page, $destpage, tagpage($tag), %opts);
  67 }
  68
  69 sub gentag ($) {
  70         my $tag=shift;
  71         if (defined $config{tag_autocreate} && $config{tag_autocreate}) {
  72                 my $tagfile = newpagefile(tagpage($tag), $config{default_pageext});
  73                 $tagfile=~s/^\///;
  74                 return if (srcfile($tagfile,1));
  75
  76                 debug(sprintf(gettext("creating tag page %s"), $tag));
  77
  78                 my $template=template("autotag.tmpl");
  79                 $template->param(tag => $tag);
  80                 writefile($tagfile, $config{srcdir}, $template->output);
  81         }
  82 }
  83
  84 sub preprocess_tag (@) {
  85         if (! @_) {
  86                 return "";
  87         }
  88         my %params=@_;
  89         my $page = $params{page};
  90         delete $params{page};
  91         delete $params{destpage};
  92         delete $params{preview};
  93
  94         foreach my $tag (keys %params) {
  95                 $tag=linkpage($tag);
  96                 $tags{$page}{$tag}=1;
  97
  98                 # add tagpage if necessary
  99                 gentag($tag);
 100
 101                 # hidden WikiLink
 102                 add_link($page, tagpage($tag));
 103         }
 104
 105         return "";
 106 }
 107
 108 sub preprocess_taglink (@) {
 109         if (! @_) {
 110                 return "";
 111         }
 112         my %params=@_;
 113         return join(" ", map {
 114                 if (/(.*)\|(.*)/) {
 115                         my $tag=linkpage($2);
 116                         $tags{$params{page}}{$tag}=1;
 117                         add_link($params{page}, tagpage($tag));
 118                         return taglink($params{page}, $params{destpage}, $tag,
 119                                 linktext => pagetitle($1));
 120                 }
 121                 else {
 122                         my $tag=linkpage($_);
 123                         $tags{$params{page}}{$tag}=1;
 124                         add_link($params{page}, tagpage($tag));
 125                         return taglink($params{page}, $params{destpage}, $tag);
 126                 }
 127         }
 128         grep {
 129                 $_ ne 'page' && $_ ne 'destpage' && $_ ne 'preview'
 130         } keys %params);
 131 }
 132
 133 sub pagetemplate (@) {
 134         my %params=@_;
 135         my $page=$params{page};
 136         my $destpage=$params{destpage};
 137         my $template=$params{template};
 138
 139         $template->param(tags => [
 140                 map {
 141                         link => taglink($page, $destpage, $_, rel => "tag")
 142                 }, sort keys %{$tags{$page}}
 143         ]) if exists $tags{$page} && %{$tags{$page}} && $template->query(name => "tags");
 144
 145         if ($template->query(name => "categories")) {
 146                 # It's an rss/atom template. Add any categories.
 147                 if (exists $tags{$page} && %{$tags{$page}}) {
 148                         $template->param(categories => [map { category => $_ },
 149                                 sort keys %{$tags{$page}}]);
 150                 }
 151         }
 152 }
 153
 154 package IkiWiki::PageSpec;
 155
 156 sub match_tagged ($$;@) {
 157         my $page = shift;
 158         my $glob = shift;
 159         return match_link($page, IkiWiki::Plugin::tag::tagpage($glob));
 160 }
 161
 162 1