IkiWiki/Plugin/comments.pm

   1 #!/usr/bin/perl
   2 # Copyright © 2006-2008 Joey Hess <joey@ikiwiki.info>
   3 # Copyright © 2008 Simon McVittie <http://smcv.pseudorandom.co.uk/>
   4 # Licensed under the GNU GPL, version 2, or any later version published by the
   5 # Free Software Foundation
   6 package IkiWiki::Plugin::comments;
   7
   8 use warnings;
   9 use strict;
  10 use IkiWiki 3.00;
  11 use Encode;
  12
  13 use constant PREVIEW => "Preview";
  14 use constant POST_COMMENT => "Post comment";
  15 use constant CANCEL => "Cancel";
  16
  17 my $postcomment;
  18 my %commentstate;
  19
  20 sub import {
  21         hook(type => "checkconfig", id => 'comments',  call => \&checkconfig);
  22         hook(type => "getsetup", id => 'comments',  call => \&getsetup);
  23         hook(type => "preprocess", id => 'comment', call => \&preprocess,
  24                 scan => 1);
  25         hook(type => "preprocess", id => 'commentmoderation', call => \&preprocess_moderation);
  26         # here for backwards compatability with old comments
  27         hook(type => "preprocess", id => '_comment', call => \&preprocess);
  28         hook(type => "sessioncgi", id => 'comment', call => \&sessioncgi);
  29         hook(type => "htmlize", id => "_comment", call => \&htmlize);
  30         hook(type => "htmlize", id => "_comment_pending",
  31                 call => \&htmlize_pending);
  32         hook(type => "pagetemplate", id => "comments", call => \&pagetemplate);
  33         hook(type => "formbuilder_setup", id => "comments",
  34                 call => \&formbuilder_setup);
  35         # Load goto to fix up user page links for logged-in commenters
  36         IkiWiki::loadplugin("goto");
  37         IkiWiki::loadplugin("inline");
  38         IkiWiki::loadplugin("transient");
  39 }
  40
  41 sub getsetup () {
  42         return
  43                 plugin => {
  44                         safe => 1,
  45                         rebuild => 1,
  46                         section => "web",
  47                 },
  48                 comments_pagespec => {
  49                         type => 'pagespec',
  50                         example => 'blog/* and !*/Discussion',
  51                         description => 'PageSpec of pages where comments are allowed',
  52                         link => 'ikiwiki/PageSpec',
  53                         safe => 1,
  54                         rebuild => 1,
  55                 },
  56                 comments_closed_pagespec => {
  57                         type => 'pagespec',
  58                         example => 'blog/controversial or blog/flamewar',
  59                         description => 'PageSpec of pages where posting new comments is not allowed',
  60                         link => 'ikiwiki/PageSpec',
  61                         safe => 1,
  62                         rebuild => 1,
  63                 },
  64                 comments_pagename => {
  65                         type => 'string',
  66                         default => 'comment_',
  67                         description => 'Base name for comments, e.g. "comment_" for pages like "sandbox/comment_12"',
  68                         safe => 0, # manual page moving required
  69                         rebuild => undef,
  70                 },
  71                 comments_allowdirectives => {
  72                         type => 'boolean',
  73                         example => 0,
  74                         description => 'Interpret directives in comments?',
  75                         safe => 1,
  76                         rebuild => 0,
  77                 },
  78                 comments_allowauthor => {
  79                         type => 'boolean',
  80                         example => 0,
  81                         description => 'Allow anonymous commenters to set an author name?',
  82                         safe => 1,
  83                         rebuild => 0,
  84                 },
  85                 comments_commit => {
  86                         type => 'boolean',
  87                         example => 1,
  88                         description => 'commit comments to the VCS',
  89                         # old uncommitted comments are likely to cause
  90                         # confusion if this is changed
  91                         safe => 0,
  92                         rebuild => 0,
  93                 },
  94                 comments_allowformats => {
  95                         type => 'string',
  96                         default => '',
  97                         example => 'mdwn txt',
  98                         description => 'Restrict formats for comments to (no restriction if empty)',
  99                         safe => 1,
 100                         rebuild => 0,
 101                 },
 102
 103 }
 104
 105 sub checkconfig () {
 106         $config{comments_commit} = 1
 107                 unless defined $config{comments_commit};
 108         if (! $config{comments_commit}) {
 109                 $config{only_committed_changes}=0;
 110         }
 111         $config{comments_pagespec} = ''
 112                 unless defined $config{comments_pagespec};
 113         $config{comments_closed_pagespec} = ''
 114                 unless defined $config{comments_closed_pagespec};
 115         $config{comments_pagename} = 'comment_'
 116                 unless defined $config{comments_pagename};
 117         $config{comments_allowformats} = ''
 118                 unless defined $config{comments_allowformats};
 119 }
 120
 121 sub htmlize {
 122         my %params = @_;
 123         return $params{content};
 124 }
 125
 126 sub htmlize_pending {
 127         my %params = @_;
 128         return sprintf(gettext("this comment needs %s"),
 129                 '<a href="'.
 130                 IkiWiki::cgiurl(do => "commentmoderation").'">'.
 131                 gettext("moderation").'</a>');
 132 }
 133
 134 # FIXME: copied verbatim from meta
 135 sub safeurl ($) {
 136         my $url=shift;
 137         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
 138             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
 139                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
 140         }
 141         else {
 142                 return 1;
 143         }
 144 }
 145
 146 sub isallowed ($) {
 147     my $format = shift;
 148     return ! $config{comments_allowformats} || $config{comments_allowformats} =~ /\b$format\b/;
 149 }
 150
 151 sub preprocess {
 152         my %params = @_;
 153         my $page = $params{page};
 154
 155         my $format = $params{format};
 156         if (defined $format && (! exists $IkiWiki::hooks{htmlize}{$format} ||
 157                                 ! isallowed($format))) {
 158                 error(sprintf(gettext("unsupported page format %s"), $format));
 159         }
 160
 161         my $content = $params{content};
 162         if (! defined $content) {
 163                 error(gettext("comment must have content"));
 164         }
 165         $content =~ s/\\"/"/g;
 166
 167         if (defined wantarray) {
 168                 if ($config{comments_allowdirectives}) {
 169                         $content = IkiWiki::preprocess($page, $params{destpage},
 170                                 $content);
 171                 }
 172
 173                 # no need to bother with htmlize if it's just HTML
 174                 $content = IkiWiki::htmlize($page, $params{destpage}, $format, $content)
 175                         if defined $format;
 176
 177                 IkiWiki::run_hooks(sanitize => sub {
 178                         $content = shift->(
 179                                 page => $page,
 180                                 destpage => $params{destpage},
 181                                 content => $content,
 182                         );
 183                 });
 184         }
 185         else {
 186                 IkiWiki::preprocess($page, $params{destpage}, $content, 1);
 187         }
 188
 189         # set metadata, possibly overriding [[!meta]] directives from the
 190         # comment itself
 191
 192         my $commentuser;
 193         my $commentip;
 194         my $commentauthor;
 195         my $commentauthorurl;
 196         my $commentopenid;
 197         if (defined $params{username}) {
 198                 $commentuser = $params{username};
 199
 200                 my $oiduser = eval { IkiWiki::openiduser($commentuser) };
 201                 if (defined $oiduser) {
 202                         # looks like an OpenID
 203                         $commentauthorurl = $commentuser;
 204                         $commentauthor = (defined $params{nickname} && length $params{nickname}) ? $params{nickname} : $oiduser;
 205                         $commentopenid = $commentuser;
 206                 }
 207                 else {
 208                         my $emailuser = IkiWiki::emailuser($commentuser);
 209                         if (defined $emailuser) {
 210                                 $commentuser=$emailuser;
 211                         }
 212
 213                         if (length $config{cgiurl}) {
 214                                 $commentauthorurl = IkiWiki::cgiurl(
 215                                         do => 'goto',
 216                                         page => IkiWiki::userpage($commentuser)
 217                                 );
 218                         }
 219
 220                         $commentauthor = $commentuser;
 221                 }
 222         }
 223         else {
 224                 if (defined $params{ip}) {
 225                         $commentip = $params{ip};
 226                 }
 227                 $commentauthor = gettext("Anonymous");
 228         }
 229
 230         if ($config{comments_allowauthor}) {
 231                 if (defined $params{claimedauthor}) {
 232                         $commentauthor = $params{claimedauthor};
 233                 }
 234
 235                 if (defined $params{url}) {
 236                         my $url=$params{url};
 237
 238                         eval q{use URI::Heuristic};
 239                         if (! $@) {
 240                                 $url=URI::Heuristic::uf_uristr($url);
 241                         }
 242
 243                         if (safeurl($url)) {
 244                                 $commentauthorurl = $url;
 245                         }
 246                 }
 247         }
 248
 249         $commentstate{$page}{commentuser} = $commentuser;
 250         $commentstate{$page}{commentopenid} = $commentopenid;
 251         $commentstate{$page}{commentip} = $commentip;
 252         $commentstate{$page}{commentauthor} = $commentauthor;
 253         $commentstate{$page}{commentauthorurl} = $commentauthorurl;
 254         $commentstate{$page}{commentauthoravatar} = $params{avatar};
 255         if (! defined $pagestate{$page}{meta}{author}) {
 256                 $pagestate{$page}{meta}{author} = $commentauthor;
 257         }
 258         if (! defined $pagestate{$page}{meta}{authorurl}) {
 259                 $pagestate{$page}{meta}{authorurl} = $commentauthorurl;
 260         }
 261
 262         if (defined $params{subject}) {
 263                 # decode title the same way meta does
 264                 eval q{use HTML::Entities};
 265                 $pagestate{$page}{meta}{title} = decode_entities($params{subject});
 266         }
 267
 268         if ($params{page} =~ m/\/\Q$config{comments_pagename}\E\d+_/) {
 269                 $pagestate{$page}{meta}{permalink} = urlto(IkiWiki::dirname($params{page})).
 270                         "#".page_to_id($params{page});
 271         }
 272
 273         eval q{use Date::Parse};
 274         if (! $@) {
 275                 my $time = str2time($params{date});
 276                 $IkiWiki::pagectime{$page} = $time if defined $time;
 277         }
 278
 279         return $content;
 280 }
 281
 282 sub preprocess_moderation {
 283         my %params = @_;
 284
 285         $params{desc}=gettext("Comment Moderation")
 286                 unless defined $params{desc};
 287
 288         if (length $config{cgiurl}) {
 289                 return '<a href="'.
 290                         IkiWiki::cgiurl(do => 'commentmoderation').
 291                         '">'.$params{desc}.'</a>';
 292         }
 293         else {
 294                 return $params{desc};
 295         }
 296 }
 297
 298 sub sessioncgi ($$) {
 299         my $cgi=shift;
 300         my $session=shift;
 301
 302         my $do = $cgi->param('do');
 303         if ($do eq 'comment') {
 304                 editcomment($cgi, $session);
 305         }
 306         elsif ($do eq 'commentmoderation') {
 307                 commentmoderation($cgi, $session);
 308         }
 309         elsif ($do eq 'commentsignin') {
 310                 IkiWiki::cgi_signin($cgi, $session);
 311                 exit;
 312         }
 313 }
 314
 315 # Mostly cargo-culted from IkiWiki::plugin::editpage
 316 sub editcomment ($$) {
 317         my $cgi=shift;
 318         my $session=shift;
 319
 320         IkiWiki::decode_cgi_utf8($cgi);
 321
 322         eval q{use CGI::FormBuilder};
 323         error($@) if $@;
 324
 325         my @buttons = (POST_COMMENT, PREVIEW, CANCEL);
 326         my $form = CGI::FormBuilder->new(
 327                 fields => [qw{do sid page subject editcontent type author
 328                         email url subscribe anonsubscribe}],
 329                 charset => 'utf-8',
 330                 method => 'POST',
 331                 required => [qw{editcontent}],
 332                 javascript => 0,
 333                 params => $cgi,
 334                 action => IkiWiki::cgiurl(),
 335                 header => 0,
 336                 table => 0,
 337                 template => { template('editcomment.tmpl') },
 338         );
 339
 340         IkiWiki::decode_form_utf8($form);
 341         IkiWiki::run_hooks(formbuilder_setup => sub {
 342                         shift->(title => "comment", form => $form, cgi => $cgi,
 343                                 session => $session, buttons => \@buttons);
 344                 });
 345         IkiWiki::decode_form_utf8($form);
 346
 347         my $type = $form->param('type');
 348         if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 349                 $type = IkiWiki::possibly_foolish_untaint($type);
 350         }
 351         else {
 352                 $type = $config{default_pageext};
 353         }
 354
 355
 356         my @page_types;
 357         if (exists $IkiWiki::hooks{htmlize}) {
 358                 foreach my $key (grep { !/^_/ && isallowed($_) } keys %{$IkiWiki::hooks{htmlize}}) {
 359                         push @page_types, [$key, $IkiWiki::hooks{htmlize}{$key}{longname} || $key]
 360                                 unless $IkiWiki::hooks{htmlize}{$key}{nocreate};
 361                 }
 362         }
 363         @page_types=sort @page_types;
 364
 365         $form->field(name => 'do', type => 'hidden');
 366         $form->field(name => 'sid', type => 'hidden', value => $session->id,
 367                 force => 1);
 368         $form->field(name => 'page', type => 'hidden');
 369         $form->field(name => 'subject', type => 'text', size => 72);
 370         $form->field(name => 'editcontent', type => 'textarea', rows => 10);
 371         $form->field(name => "type", value => $type, force => 1,
 372                 type => 'select', options => \@page_types);
 373
 374         my $username=$session->param('name');
 375         $form->tmpl_param(username => $username);
 376
 377         $form->field(name => "subscribe", type => 'hidden');
 378         $form->field(name => "anonsubscribe", type => 'hidden');
 379         if (IkiWiki::Plugin::notifyemail->can("subscribe")) {
 380                 if (defined $username) {
 381                         $form->field(name => "subscribe", type => "checkbox",
 382                                 options => [gettext("email replies to me")]);
 383                 }
 384                 elsif (IkiWiki::Plugin::passwordauth->can("anonuser")) {
 385                         $form->field(name => "anonsubscribe", type => "checkbox",
 386                                 options => [gettext("email replies to me")]);
 387                 }
 388         }
 389
 390         if ($config{comments_allowauthor} and
 391             ! defined $session->param('name')) {
 392                 $form->tmpl_param(allowauthor => 1);
 393                 $form->field(name => 'author', type => 'text', size => '40');
 394                 $form->field(name => 'email', type => 'text', size => '40');
 395                 $form->field(name => 'url', type => 'text', size => '40');
 396         }
 397         else {
 398                 $form->tmpl_param(allowauthor => 0);
 399                 $form->field(name => 'author', type => 'hidden', value => '',
 400                         force => 1);
 401                 $form->field(name => 'email', type => 'hidden', value => '',
 402                         force => 1);
 403                 $form->field(name => 'url', type => 'hidden', value => '',
 404                         force => 1);
 405         }
 406
 407         if (! defined $session->param('name')) {
 408                 # Make signinurl work and return here.
 409                 $form->tmpl_param(signinurl => IkiWiki::cgiurl(do => 'commentsignin'));
 410                 $session->param(postsignin => $ENV{QUERY_STRING});
 411                 IkiWiki::cgi_savesession($session);
 412         }
 413
 414         # The untaint is OK (as in editpage) because we're about to pass
 415         # it to file_pruned and wiki_file_regexp anyway.
 416         my ($page) = $form->field('page')=~/$config{wiki_file_regexp}/;
 417         $page = IkiWiki::possibly_foolish_untaint($page);
 418         if (! defined $page || ! length $page ||
 419                 IkiWiki::file_pruned($page)) {
 420                 error(gettext("bad page name"));
 421         }
 422
 423         $form->title(sprintf(gettext("commenting on %s"),
 424                         IkiWiki::pagetitle(IkiWiki::basename($page))));
 425
 426         $form->tmpl_param('helponformattinglink',
 427                 htmllink($page, $page, 'ikiwiki/formatting',
 428                         noimageinline => 1,
 429                         linktext => 'FormattingHelp'),
 430                         allowdirectives => $config{allow_directives});
 431
 432         if ($form->submitted eq CANCEL) {
 433                 # bounce back to the page they wanted to comment on, and exit.
 434                 IkiWiki::redirect($cgi, urlto($page));
 435                 exit;
 436         }
 437
 438         if (not exists $pagesources{$page}) {
 439                 error(sprintf(gettext(
 440                         "page '%s' doesn't exist, so you can't comment"),
 441                         $page));
 442         }
 443
 444         # There's no UI to get here, but someone might construct the URL,
 445         # leading to a comment that exists in the repository but isn't
 446         # shown
 447         if (!pagespec_match($page, $config{comments_pagespec},
 448                 location => $page)) {
 449                 error(sprintf(gettext(
 450                         "comments on page '%s' are not allowed"),
 451                         $page));
 452         }
 453
 454         if (pagespec_match($page, $config{comments_closed_pagespec},
 455                 location => $page)) {
 456                 error(sprintf(gettext(
 457                         "comments on page '%s' are closed"),
 458                         $page));
 459         }
 460
 461         # Set a flag to indicate that we're posting a comment,
 462         # so that postcomment() can tell it should match.
 463         $postcomment=1;
 464         IkiWiki::check_canedit($page, $cgi, $session);
 465         $postcomment=0;
 466
 467         my $content = "[[!comment format=$type\n";
 468
 469         if (defined $session->param('name')) {
 470                 my $username = IkiWiki::cloak($session->param('name'));
 471                 $username =~ s/"/&quot;/g;
 472                 $content .= " username=\"$username\"\n";
 473         }
 474
 475         if (defined $session->param('nickname')) {
 476                 my $nickname = $session->param('nickname');
 477                 $nickname =~ s/"/&quot;/g;
 478                 $content .= " nickname=\"$nickname\"\n";
 479         }
 480
 481         if (!(defined $session->param('name') || defined $session->param('nickname')) &&
 482                 defined $session->remote_addr()) {
 483                 $content .= " ip=\"".IkiWiki::cloak($session->remote_addr())."\"\n";
 484         }
 485
 486         if ($config{comments_allowauthor}) {
 487                 my $author = $form->field('author');
 488                 if (defined $author && length $author) {
 489                         $author =~ s/"/&quot;/g;
 490                         $content .= " claimedauthor=\"$author\"\n";
 491                 }
 492                 my $url = $form->field('url');
 493                 if (defined $url && length $url) {
 494                         $url =~ s/"/&quot;/g;
 495                         $content .= " url=\"$url\"\n";
 496                 }
 497         }
 498
 499         my $avatar=getavatar($session->param('name'));
 500         if (defined $avatar && length $avatar) {
 501                 $avatar =~ s/"/&quot;/g;
 502                 $content .= " avatar=\"$avatar\"\n";
 503         }
 504
 505         my $subject = $form->field('subject');
 506         if (defined $subject && length $subject) {
 507                 $subject =~ s/"/&quot;/g;
 508         }
 509         else {
 510                 $subject = "comment ".(num_comments($page, $config{srcdir}) + 1);
 511         }
 512         $content .= " subject=\"$subject\"\n";
 513         $content .= " date=\"" . commentdate() . "\"\n";
 514
 515         my $editcontent = $form->field('editcontent');
 516         $editcontent="" if ! defined $editcontent;
 517         $editcontent =~ s/\r\n/\n/g;
 518         $editcontent =~ s/\r/\n/g;
 519         $editcontent =~ s/"/\\"/g;
 520         $content .= " content=\"\"\"\n$editcontent\n\"\"\"]]\n";
 521
 522         my $location=unique_comment_location($page, $content, $config{srcdir});
 523
 524         # This is essentially a simplified version of editpage:
 525         # - the user does not control the page that's created, only the parent
 526         # - it's always a create operation, never an edit
 527         # - this means that conflicts should never happen
 528         # - this means that if they do, rocks fall and everyone dies
 529
 530         if ($form->submitted eq PREVIEW) {
 531                 my $preview=previewcomment($content, $location, $page, time);
 532                 IkiWiki::run_hooks(format => sub {
 533                         $preview = shift->(page => $page,
 534                                 content => $preview);
 535                 });
 536                 $form->tmpl_param(page_preview => $preview);
 537         }
 538         else {
 539                 $form->tmpl_param(page_preview => "");
 540         }
 541
 542         if ($form->submitted eq POST_COMMENT && $form->validate) {
 543                 IkiWiki::checksessionexpiry($cgi, $session);
 544
 545                 if (IkiWiki::Plugin::notifyemail->can("subscribe")) {
 546                         my $subspec="comment($page)";
 547                         if (defined $username &&
 548                             length $form->field("subscribe")) {
 549                                 IkiWiki::Plugin::notifyemail::subscribe(
 550                                         $username, $subspec);
 551                         }
 552                         elsif (length $form->field("email") &&
 553                                length $form->field("anonsubscribe")) {
 554                                 IkiWiki::Plugin::notifyemail::anonsubscribe(
 555                                         $form->field("email"), $subspec);
 556                         }
 557                 }
 558
 559                 $postcomment=1;
 560                 my $ok=IkiWiki::check_content(content => $form->field('editcontent'),
 561                         subject => $form->field('subject'),
 562                         $config{comments_allowauthor} ? (
 563                                 author => $form->field('author'),
 564                                 url => $form->field('url'),
 565                         ) : (),
 566                         page => $location,
 567                         cgi => $cgi,
 568                         session => $session,
 569                         nonfatal => 1,
 570                 );
 571                 $postcomment=0;
 572
 573                 if (! $ok) {
 574                         $location=unique_comment_location($page, $content, $IkiWiki::Plugin::transient::transientdir, "._comment_pending");
 575                         writefile("$location._comment_pending", $IkiWiki::Plugin::transient::transientdir, $content);
 576
 577                         # Refresh so anything that deals with pending
 578                         # comments can be updated.
 579                         require IkiWiki::Render;
 580                         IkiWiki::refresh();
 581                         IkiWiki::saveindex();
 582
 583                         IkiWiki::printheader($session);
 584                         print IkiWiki::cgitemplate($cgi, gettext(gettext("comment stored for moderation")),
 585                                 "<p>".
 586                                 gettext("Your comment will be posted after moderator review").
 587                                 "</p>");
 588                         exit;
 589                 }
 590
 591                 # FIXME: could probably do some sort of graceful retry
 592                 # on error? Would require significant unwinding though
 593                 my $file = "$location._comment";
 594                 writefile($file, $config{srcdir}, $content);
 595
 596                 my $conflict;
 597
 598                 if ($config{rcs} and $config{comments_commit}) {
 599                         my $message = gettext("Added a comment");
 600                         if (defined $form->field('subject') &&
 601                                 length $form->field('subject')) {
 602                                 $message = sprintf(
 603                                         gettext("Added a comment: %s"),
 604                                         $form->field('subject'));
 605                         }
 606
 607                         IkiWiki::rcs_add($file);
 608                         IkiWiki::disable_commit_hook();
 609                         $conflict = IkiWiki::rcs_commit_staged(
 610                                 message => $message,
 611                                 session => $session,
 612                         );
 613                         IkiWiki::enable_commit_hook();
 614                         IkiWiki::rcs_update();
 615                 }
 616
 617                 # Now we need a refresh
 618                 require IkiWiki::Render;
 619                 IkiWiki::refresh();
 620                 IkiWiki::saveindex();
 621
 622                 # this should never happen, unless a committer deliberately
 623                 # breaks it or something
 624                 error($conflict) if defined $conflict;
 625
 626                 # Jump to the new comment on the page.
 627                 # The trailing question mark tries to avoid broken
 628                 # caches and get the most recent version of the page.
 629                 IkiWiki::redirect($cgi, urlto($page).
 630                         "?updated#".page_to_id($location));
 631
 632         }
 633         else {
 634                 IkiWiki::showform($form, \@buttons, $session, $cgi,
 635                         page => $page);
 636         }
 637
 638         exit;
 639 }
 640
 641 sub commentdate () {
 642         strftime_utf8('%Y-%m-%dT%H:%M:%SZ', gmtime);
 643 }
 644
 645 sub getavatar ($) {
 646         my $user=shift;
 647         return undef unless defined $user;
 648
 649         my $avatar;
 650         eval q{use Libravatar::URL};
 651         if (! $@) {
 652                 my $oiduser = eval { IkiWiki::openiduser($user) };
 653                 my $https=defined $config{url} && $config{url}=~/^https:/;
 654
 655                 if (defined $oiduser) {
 656                         eval {
 657                                 $avatar = libravatar_url(openid => $user, https => $https);
 658                         }
 659                 }
 660                 if (! defined $avatar &&
 661                     (my $email = IkiWiki::userinfo_get($user, 'email'))) {
 662                         eval {
 663                                 $avatar = libravatar_url(email => $email, https => $https);
 664                         }
 665                 }
 666         }
 667         return $avatar;
 668 }
 669
 670
 671 sub commentmoderation ($$) {
 672         my $cgi=shift;
 673         my $session=shift;
 674
 675         IkiWiki::needsignin($cgi, $session);
 676         if (! IkiWiki::is_admin($session->param("name"))) {
 677                 error(gettext("you are not logged in as an admin"));
 678         }
 679
 680         IkiWiki::decode_cgi_utf8($cgi);
 681
 682         if (defined $cgi->param('sid')) {
 683                 IkiWiki::checksessionexpiry($cgi, $session);
 684
 685                 my $rejectalldefer=$cgi->param('rejectalldefer');
 686
 687                 my %vars=$cgi->Vars;
 688                 my $added=0;
 689                 foreach my $id (keys %vars) {
 690                         if ($id =~ /(.*)\._comment(?:_pending)?$/) {
 691                                 $id=decode_utf8($id);
 692                                 my $action=$cgi->param($id);
 693                                 next if $action eq 'Defer' && ! $rejectalldefer;
 694
 695                                 # Make sure that the id is of a legal
 696                                 # pending comment.
 697                                 my ($f) = $id =~ /$config{wiki_file_regexp}/;
 698                                 if (! defined $f || ! length $f ||
 699                                     IkiWiki::file_pruned($f)) {
 700                                         error("illegal file");
 701                                 }
 702
 703                                 my $page=IkiWiki::dirname($f);
 704                                 my $filedir=$IkiWiki::Plugin::transient::transientdir;
 705                                 my $file="$filedir/$f";
 706                                 if (! -e $file) {
 707                                         # old location
 708                                         $file="$config{srcdir}/$f";
 709                                         $filedir=$config{srcdir};
 710                                         if (! -e $file) {
 711                                                 # older location
 712                                                 $file="$config{wikistatedir}/comments_pending/".$f;
 713                                                 $filedir="$config{wikistatedir}/comments_pending";
 714                                         }
 715                                 }
 716
 717                                 if ($action eq 'Accept') {
 718                                         my $content=eval { readfile($file) };
 719                                         next if $@; # file vanished since form was displayed
 720                                         my $dest=unique_comment_location($page, $content, $config{srcdir})."._comment";
 721                                         writefile($dest, $config{srcdir}, $content);
 722                                         if ($config{rcs} and $config{comments_commit}) {
 723                                                 IkiWiki::rcs_add($dest);
 724                                         }
 725                                         $added++;
 726                                 }
 727
 728                                 require IkiWiki::Render;
 729                                 IkiWiki::prune($file, $filedir);
 730                         }
 731                 }
 732
 733                 if ($added) {
 734                         my $conflict;
 735                         if ($config{rcs} and $config{comments_commit}) {
 736                                 my $message = gettext("Comment moderation");
 737                                 IkiWiki::disable_commit_hook();
 738                                 $conflict=IkiWiki::rcs_commit_staged(
 739                                         message => $message,
 740                                         session => $session,
 741                                 );
 742                                 IkiWiki::enable_commit_hook();
 743                                 IkiWiki::rcs_update();
 744                         }
 745
 746                         # Now we need a refresh
 747                         require IkiWiki::Render;
 748                         IkiWiki::refresh();
 749                         IkiWiki::saveindex();
 750
 751                         error($conflict) if defined $conflict;
 752                 }
 753         }
 754
 755         my @comments=map {
 756                 my ($id, $dir, $ctime)=@{$_};
 757                 my $content=readfile("$dir/$id");
 758                 my $preview=previewcomment($content, $id,
 759                         $id, $ctime);
 760                 {
 761                         id => $id,
 762                         view => $preview,
 763                 }
 764         } sort { $b->[2] <=> $a->[2] } comments_pending();
 765
 766         my $template=template("commentmoderation.tmpl");
 767         $template->param(
 768                 sid => $session->id,
 769                 comments => \@comments,
 770                 cgiurl => IkiWiki::cgiurl(),
 771         );
 772         IkiWiki::printheader($session);
 773         my $out=$template->output;
 774         IkiWiki::run_hooks(format => sub {
 775                 $out = shift->(page => "", content => $out);
 776         });
 777         print IkiWiki::cgitemplate($cgi, gettext("comment moderation"), $out);
 778         exit;
 779 }
 780
 781 sub formbuilder_setup (@) {
 782         my %params=@_;
 783
 784         my $form=$params{form};
 785         if ($form->title eq "preferences" &&
 786             IkiWiki::is_admin($params{session}->param("name"))) {
 787                 push @{$params{buttons}}, "Comment Moderation";
 788                 if ($form->submitted && $form->submitted eq "Comment Moderation") {
 789                         commentmoderation($params{cgi}, $params{session});
 790                 }
 791         }
 792 }
 793
 794 sub comments_pending () {
 795         my @ret;
 796
 797         eval q{use File::Find};
 798         error($@) if $@;
 799         eval q{use Cwd};
 800         error($@) if $@;
 801         my $origdir=getcwd();
 802
 803         my $find_comments=sub {
 804                 my $dir=shift;
 805                 my $extension=shift;
 806                 return unless -d $dir;
 807
 808                 chdir($dir) || die "chdir $dir: $!";
 809
 810                 find({
 811                         no_chdir => 1,
 812                         wanted => sub {
 813                                 my $file=decode_utf8($_);
 814                                 $file=~s/^\.\///;
 815                                 return if ! length $file || IkiWiki::file_pruned($file)
 816                                         || -l $_ || -d _ || $file !~ /\Q$extension\E$/;
 817                                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 818                                 if (defined $f) {
 819                                         my $ctime=(stat($_))[10];
 820                                         push @ret, [$f, $dir, $ctime];
 821                                 }
 822                         }
 823                 }, ".");
 824
 825                 chdir($origdir) || die "chdir $origdir: $!";
 826         };
 827
 828         $find_comments->($IkiWiki::Plugin::transient::transientdir, "._comment_pending");
 829         # old location
 830         $find_comments->($config{srcdir}, "._comment_pending");
 831         # old location
 832         $find_comments->("$config{wikistatedir}/comments_pending/",
 833                 "._comment");
 834
 835         return @ret;
 836 }
 837
 838 sub previewcomment ($$$) {
 839         my $content=shift;
 840         my $location=shift;
 841         my $page=shift;
 842         my $time=shift;
 843
 844         # Previewing a comment should implicitly enable comment posting mode.
 845         my $oldpostcomment=$postcomment;
 846         $postcomment=1;
 847
 848         my $preview = IkiWiki::htmlize($location, $page, '_comment',
 849                         IkiWiki::linkify($location, $page,
 850                         IkiWiki::preprocess($location, $page,
 851                         IkiWiki::filter($location, $page, $content), 0, 1)));
 852
 853         my $template = template("comment.tmpl");
 854         $template->param(content => $preview);
 855         $template->param(ctime => displaytime($time, undef, 1));
 856         $template->param(html5 => $config{html5});
 857
 858         IkiWiki::run_hooks(pagetemplate => sub {
 859                 shift->(page => $location,
 860                         destpage => $page,
 861                         template => $template);
 862         });
 863
 864         $template->param(have_actions => 0);
 865
 866         $postcomment=$oldpostcomment;
 867
 868         return $template->output;
 869 }
 870
 871 sub commentsshown ($) {
 872         my $page=shift;
 873
 874         return pagespec_match($page, $config{comments_pagespec},
 875                 location => $page);
 876 }
 877
 878 sub commentsopen ($) {
 879         my $page = shift;
 880
 881         return length $config{cgiurl} > 0 &&
 882                (! length $config{comments_closed_pagespec} ||
 883                 ! pagespec_match($page, $config{comments_closed_pagespec},
 884                                  location => $page));
 885 }
 886
 887 sub pagetemplate (@) {
 888         my %params = @_;
 889
 890         my $page = $params{page};
 891         my $template = $params{template};
 892         my $shown = ($template->query(name => 'commentslink') ||
 893                      $template->query(name => 'commentsurl') ||
 894                      $template->query(name => 'atomcommentsurl') ||
 895                      $template->query(name => 'comments')) &&
 896                     commentsshown($page);
 897
 898         if ($template->query(name => 'comments')) {
 899                 my $comments = undef;
 900                 if ($shown) {
 901                         $comments = IkiWiki::preprocess_inline(
 902                                 pages => "comment($page) and !comment($page/*)",
 903                                 template => 'comment',
 904                                 show => 0,
 905                                 reverse => 'yes',
 906                                 page => $page,
 907                                 destpage => $params{destpage},
 908                                 feedfile => 'comments',
 909                                 emptyfeeds => 'no',
 910                         );
 911                 }
 912
 913                 if (defined $comments && length $comments) {
 914                         $template->param(comments => $comments);
 915                 }
 916
 917                 if ($shown && commentsopen($page)) {
 918                         $template->param(addcommenturl => addcommenturl($page));
 919                 }
 920         }
 921
 922         if ($shown) {
 923                 my $absolute = $template->param('wants_absolute_urls');
 924
 925                 if ($template->query(name => 'commentsurl')) {
 926                         $template->param(commentsurl =>
 927                                 urlto($page, undef, $absolute).'#comments');
 928                 }
 929
 930                 if ($template->query(name => 'atomcommentsurl') && $config{usedirs}) {
 931                         # This will 404 until there are some comments, but I
 932                         # think that's probably OK...
 933                         $template->param(atomcommentsurl =>
 934                                 urlto($page, undef, $absolute).'comments.atom');
 935                 }
 936
 937                 if ($template->query(name => 'commentslink')) {
 938                         my $num=num_comments($page, $config{srcdir});
 939                         my $link;
 940                         if ($num > 0) {
 941                                 $link = htmllink($page, $params{destpage}, $page,
 942                                         linktext => sprintf(ngettext("%i comment", "%i comments", $num), $num),
 943                                         anchor => "comments",
 944                                         noimageinline => 1
 945                                 );
 946                         }
 947                         elsif (commentsopen($page)) {
 948                                 $link = "<a href=\"".addcommenturl($page)."\">".
 949                                         #translators: Here "Comment" is a verb;
 950                                         #translators: the user clicks on it to
 951                                         #translators: post a comment.
 952                                         gettext("Comment").
 953                                         "</a>";
 954                         }
 955                         $template->param(commentslink => $link)
 956                                 if defined $link;
 957                 }
 958         }
 959
 960         # everything below this point is only relevant to the comments
 961         # themselves
 962         if (!exists $commentstate{$page}) {
 963                 return;
 964         }
 965
 966         if ($template->query(name => 'commentid')) {
 967                 $template->param(commentid => page_to_id($page));
 968         }
 969
 970         if ($template->query(name => 'commentuser')) {
 971                 $template->param(commentuser =>
 972                         $commentstate{$page}{commentuser});
 973         }
 974
 975         if ($template->query(name => 'commentopenid')) {
 976                 $template->param(commentopenid =>
 977                         $commentstate{$page}{commentopenid});
 978         }
 979
 980         if ($template->query(name => 'commentip')) {
 981                 $template->param(commentip =>
 982                         $commentstate{$page}{commentip});
 983         }
 984
 985         if ($template->query(name => 'commentauthor')) {
 986                 $template->param(commentauthor =>
 987                         $commentstate{$page}{commentauthor});
 988         }
 989
 990         if ($template->query(name => 'commentauthorurl')) {
 991                 $template->param(commentauthorurl =>
 992                         $commentstate{$page}{commentauthorurl});
 993         }
 994
 995         if ($template->query(name => 'commentauthoravatar')) {
 996                 $template->param(commentauthoravatar =>
 997                         $commentstate{$page}{commentauthoravatar});
 998         }
 999
1000         if ($template->query(name => 'removeurl') &&
1001             IkiWiki::Plugin::remove->can("check_canremove") &&
1002             length $config{cgiurl}) {
1003                 $template->param(removeurl => IkiWiki::cgiurl(do => 'remove',
1004                         page => $page));
1005                 $template->param(have_actions => 1);
1006         }
1007 }
1008
1009 sub addcommenturl ($) {
1010         my $page=shift;
1011
1012         return IkiWiki::cgiurl(do => 'comment', page => $page);
1013 }
1014
1015 sub num_comments ($$) {
1016         my $page=shift;
1017         my $dir=shift;
1018
1019         my @comments=glob("$dir/$page/$config{comments_pagename}*._comment");
1020         return int @comments;
1021 }
1022
1023 sub unique_comment_location ($$$;$) {
1024         my $page=shift;
1025         eval q{use Digest::MD5 'md5_hex'};
1026         error($@) if $@;
1027         my $content_md5=md5_hex(Encode::encode_utf8(shift));
1028         my $dir=shift;
1029         my $ext=shift || "._comment";
1030
1031         my $location;
1032         my $i = num_comments($page, $dir);
1033         do {
1034                 $i++;
1035                 $location = "$page/$config{comments_pagename}${i}_${content_md5}";
1036         } while (-e "$dir/$location$ext");
1037
1038         return $location;
1039 }
1040
1041 sub page_to_id ($) {
1042         # Converts a comment page name into a unique, legal html id
1043         # attribute value, that can be used as an anchor to link to the
1044         # comment.
1045         my $page=shift;
1046
1047         eval q{use Digest::MD5 'md5_hex'};
1048         error($@) if $@;
1049
1050         return "comment-".md5_hex(Encode::encode_utf8(($page)));
1051 }
1052
1053 package IkiWiki::PageSpec;
1054
1055 sub match_postcomment ($$;@) {
1056         my $page = shift;
1057         my $glob = shift;
1058
1059         if (! $postcomment) {
1060                 return IkiWiki::FailReason->new("not posting a comment");
1061         }
1062         return match_glob($page, $glob, @_);
1063 }
1064
1065 sub match_comment ($$;@) {
1066         my $page = shift;
1067         my $glob = shift;
1068
1069         if (! $postcomment) {
1070                 # To see if it's a comment, check the source file type.
1071                 # Deal with comments that were just deleted.
1072                 my $source=exists $IkiWiki::pagesources{$page} ?
1073                         $IkiWiki::pagesources{$page} :
1074                         $IkiWiki::delpagesources{$page};
1075                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
1076                 if (! defined $type || $type ne "_comment") {
1077                         return IkiWiki::FailReason->new("$page is not a comment");
1078                 }
1079         }
1080
1081         return match_glob($page, "$glob/*", internal => 1, @_);
1082 }
1083
1084 sub match_comment_pending ($$;@) {
1085         my $page = shift;
1086         my $glob = shift;
1087
1088         my $source=exists $IkiWiki::pagesources{$page} ?
1089                 $IkiWiki::pagesources{$page} :
1090                 $IkiWiki::delpagesources{$page};
1091         my $type=defined $source ? IkiWiki::pagetype($source) : undef;
1092         if (! defined $type || $type ne "_comment_pending") {
1093                 return IkiWiki::FailReason->new("$page is not a pending comment");
1094         }
1095
1096         return match_glob($page, "$glob/*", internal => 1, @_);
1097 }
1098
1099 1