IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX;
  10 use open qw{:utf8 :std};
  11
  12 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  13             %renderedfiles %oldrenderedfiles %pagesources %destsources
  14             %depends %hooks %forcerebuild $gettext_obj};
  15
  16 use Exporter q{import};
  17 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  18                  bestlink htmllink readfile writefile pagetype srcfile pagename
  19                  displaytime will_render gettext urlto targetpage
  20                  add_underlay
  21                  %config %links %renderedfiles %pagesources %destsources);
  22 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  23 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  24 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  25
  26 # Optimisation.
  27 use Memoize;
  28 memoize("abs2rel");
  29 memoize("pagespec_translate");
  30 memoize("file_pruned");
  31
  32 sub defaultconfig () { #{{{
  33         return
  34         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./,
  35                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  36                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
  37                 qr/(^|\/)_MTN\//,
  38                 qr/\.dpkg-tmp$/],
  39         wiki_link_regexp => qr{
  40                 \[\[                    # beginning of link
  41                 (?:
  42                         ([^\]\|\n]+)    # 1: link text
  43                         \|              # followed by '|'
  44                 )?                      # optional
  45
  46                 ([^\s\]#]+)             # 2: page to link to
  47                 (?:
  48                         \#              # '#', beginning of anchor
  49                         ([^\s\]]+)      # 3: anchor text
  50                 )?                      # optional
  51
  52                 \]\]                    # end of link
  53         }x,
  54         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  55         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  56         verbose => 0,
  57         syslog => 0,
  58         wikiname => "wiki",
  59         default_pageext => "mdwn",
  60         htmlext => "html",
  61         cgi => 0,
  62         post_commit => 0,
  63         rcs => '',
  64         notify => 0,
  65         url => '',
  66         cgiurl => '',
  67         historyurl => '',
  68         diffurl => '',
  69         rss => 0,
  70         atom => 0,
  71         discussion => 1,
  72         rebuild => 0,
  73         refresh => 0,
  74         getctime => 0,
  75         w3mmode => 0,
  76         wrapper => undef,
  77         wrappermode => undef,
  78         svnrepo => undef,
  79         svnpath => "trunk",
  80         gitorigin_branch => "origin",
  81         gitmaster_branch => "master",
  82         srcdir => undef,
  83         destdir => undef,
  84         pingurl => [],
  85         templatedir => "$installdir/share/ikiwiki/templates",
  86         underlaydir => "$installdir/share/ikiwiki/basewiki",
  87         underlaydirs => [],
  88         setup => undef,
  89         adminuser => undef,
  90         adminemail => undef,
  91         plugin => [qw{mdwn inline htmlscrubber passwordauth openid signinedit
  92                       lockedit conditional}],
  93         libdir => undef,
  94         timeformat => '%c',
  95         locale => undef,
  96         sslcookie => 0,
  97         httpauth => 0,
  98         userdir => "",
  99         usedirs => 1,
 100         numbacklinks => 10,
 101         account_creation_password => "",
 102 } #}}}
 103
 104 sub checkconfig () { #{{{
 105         # locale stuff; avoid LC_ALL since it overrides everything
 106         if (defined $ENV{LC_ALL}) {
 107                 $ENV{LANG} = $ENV{LC_ALL};
 108                 delete $ENV{LC_ALL};
 109         }
 110         if (defined $config{locale}) {
 111                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 112                         $ENV{LANG}=$config{locale};
 113                         $gettext_obj=undef;
 114                 }
 115         }
 116
 117         if ($config{w3mmode}) {
 118                 eval q{use Cwd q{abs_path}};
 119                 error($@) if $@;
 120                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 121                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 122                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 123                         unless $config{cgiurl} =~ m!file:///!;
 124                 $config{url}="file://".$config{destdir};
 125         }
 126
 127         if ($config{cgi} && ! length $config{url}) {
 128                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 129         }
 130
 131         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 132                 unless exists $config{wikistatedir};
 133
 134         if ($config{rcs}) {
 135                 eval qq{use IkiWiki::Rcs::$config{rcs}};
 136                 if ($@) {
 137                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 138                 }
 139         }
 140         else {
 141                 require IkiWiki::Rcs::Stub;
 142         }
 143
 144         run_hooks(checkconfig => sub { shift->() });
 145
 146         return 1;
 147 } #}}}
 148
 149 sub loadplugins () { #{{{
 150         if (defined $config{libdir}) {
 151                 unshift @INC, possibly_foolish_untaint($config{libdir});
 152         }
 153
 154         loadplugin($_) foreach @{$config{plugin}};
 155
 156         run_hooks(getopt => sub { shift->() });
 157         if (grep /^-/, @ARGV) {
 158                 print STDERR "Unknown option: $_\n"
 159                         foreach grep /^-/, @ARGV;
 160                 usage();
 161         }
 162
 163         return 1;
 164 } #}}}
 165
 166 sub loadplugin ($) { #{{{
 167         my $plugin=shift;
 168
 169         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 170
 171         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 172                          "$installdir/lib/ikiwiki") {
 173                 if (defined $dir && -x "$dir/plugins/$plugin") {
 174                         require IkiWiki::Plugin::external;
 175                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 176                         return 1;
 177                 }
 178         }
 179
 180         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 181         eval qq{use $mod};
 182         if ($@) {
 183                 error("Failed to load plugin $mod: $@");
 184         }
 185         return 1;
 186 } #}}}
 187
 188 sub error ($;$) { #{{{
 189         my $message=shift;
 190         my $cleaner=shift;
 191         if ($config{cgi}) {
 192                 print "Content-type: text/html\n\n";
 193                 print misctemplate(gettext("Error"),
 194                         "<p>".gettext("Error").": $message</p>");
 195         }
 196         log_message('err' => $message) if $config{syslog};
 197         if (defined $cleaner) {
 198                 $cleaner->();
 199         }
 200         die $message."\n";
 201 } #}}}
 202
 203 sub debug ($) { #{{{
 204         return unless $config{verbose};
 205         return log_message(debug => @_);
 206 } #}}}
 207
 208 my $log_open=0;
 209 sub log_message ($$) { #{{{
 210         my $type=shift;
 211
 212         if ($config{syslog}) {
 213                 require Sys::Syslog;
 214                 if (! $log_open) {
 215                         Sys::Syslog::setlogsock('unix');
 216                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 217                         $log_open=1;
 218                 }
 219                 return eval {
 220                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 221                 };
 222         }
 223         elsif (! $config{cgi}) {
 224                 return print "@_\n";
 225         }
 226         else {
 227                 return print STDERR "@_\n";
 228         }
 229 } #}}}
 230
 231 sub possibly_foolish_untaint ($) { #{{{
 232         my $tainted=shift;
 233         my ($untainted)=$tainted=~/(.*)/s;
 234         return $untainted;
 235 } #}}}
 236
 237 sub basename ($) { #{{{
 238         my $file=shift;
 239
 240         $file=~s!.*/+!!;
 241         return $file;
 242 } #}}}
 243
 244 sub dirname ($) { #{{{
 245         my $file=shift;
 246
 247         $file=~s!/*[^/]+$!!;
 248         return $file;
 249 } #}}}
 250
 251 sub pagetype ($) { #{{{
 252         my $page=shift;
 253
 254         if ($page =~ /\.([^.]+)$/) {
 255                 return $1 if exists $hooks{htmlize}{$1};
 256         }
 257         return;
 258 } #}}}
 259
 260 sub pagename ($) { #{{{
 261         my $file=shift;
 262
 263         my $type=pagetype($file);
 264         my $page=$file;
 265         $page=~s/\Q.$type\E*$// if defined $type;
 266         return $page;
 267 } #}}}
 268
 269 sub targetpage ($$) { #{{{
 270         my $page=shift;
 271         my $ext=shift;
 272
 273         if (! $config{usedirs} || $page =~ /^index$/ ) {
 274                 return $page.".".$ext;
 275         } else {
 276                 return $page."/index.".$ext;
 277         }
 278 } #}}}
 279
 280 sub htmlpage ($) { #{{{
 281         my $page=shift;
 282
 283         return targetpage($page, $config{htmlext});
 284 } #}}}
 285
 286 sub srcfile ($) { #{{{
 287         my $file=shift;
 288
 289         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 290         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 291                 return "$dir/$file" if -e "$dir/$file";
 292         }
 293         error("internal error: $file cannot be found in $config{srcdir} or underlay");
 294         return;
 295 } #}}}
 296
 297 sub add_underlay ($) { #{{{
 298         my $dir=shift;
 299
 300         if ($dir=~/^\//) {
 301                 unshift @{$config{underlaydirs}}, $dir;
 302         }
 303         else {
 304                 unshift @{$config{underlaydirs}}, "$config{underlaydir}/../$dir";
 305         }
 306
 307         return 1;
 308 } #}}}
 309
 310 sub readfile ($;$$) { #{{{
 311         my $file=shift;
 312         my $binary=shift;
 313         my $wantfd=shift;
 314
 315         if (-l $file) {
 316                 error("cannot read a symlink ($file)");
 317         }
 318
 319         local $/=undef;
 320         open (my $in, "<", $file) || error("failed to read $file: $!");
 321         binmode($in) if ($binary);
 322         return \*$in if $wantfd;
 323         my $ret=<$in>;
 324         close $in || error("failed to read $file: $!");
 325         return $ret;
 326 } #}}}
 327
 328 sub writefile ($$$;$$) { #{{{
 329         my $file=shift; # can include subdirs
 330         my $destdir=shift; # directory to put file in
 331         my $content=shift;
 332         my $binary=shift;
 333         my $writer=shift;
 334
 335         my $test=$file;
 336         while (length $test) {
 337                 if (-l "$destdir/$test") {
 338                         error("cannot write to a symlink ($test)");
 339                 }
 340                 $test=dirname($test);
 341         }
 342         my $newfile="$destdir/$file.ikiwiki-new";
 343         if (-l $newfile) {
 344                 error("cannot write to a symlink ($newfile)");
 345         }
 346
 347         my $dir=dirname($newfile);
 348         if (! -d $dir) {
 349                 my $d="";
 350                 foreach my $s (split(m!/+!, $dir)) {
 351                         $d.="$s/";
 352                         if (! -d $d) {
 353                                 mkdir($d) || error("failed to create directory $d: $!");
 354                         }
 355                 }
 356         }
 357
 358         my $cleanup = sub { unlink($newfile) };
 359         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 360         binmode($out) if ($binary);
 361         if ($writer) {
 362                 $writer->(\*$out, $cleanup);
 363         }
 364         else {
 365                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 366         }
 367         close $out || error("failed saving $newfile: $!", $cleanup);
 368         rename($newfile, "$destdir/$file") ||
 369                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 370
 371         return 1;
 372 } #}}}
 373
 374 my %cleared;
 375 sub will_render ($$;$) { #{{{
 376         my $page=shift;
 377         my $dest=shift;
 378         my $clear=shift;
 379
 380         # Important security check.
 381         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 382             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 383                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 384         }
 385
 386         if (! $clear || $cleared{$page}) {
 387                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 388         }
 389         else {
 390                 foreach my $old (@{$renderedfiles{$page}}) {
 391                         delete $destsources{$old};
 392                 }
 393                 $renderedfiles{$page}=[$dest];
 394                 $cleared{$page}=1;
 395         }
 396         $destsources{$dest}=$page;
 397
 398         return 1;
 399 } #}}}
 400
 401 sub bestlink ($$) { #{{{
 402         my $page=shift;
 403         my $link=shift;
 404
 405         my $cwd=$page;
 406         if ($link=~s/^\/+//) {
 407                 # absolute links
 408                 $cwd="";
 409         }
 410
 411         do {
 412                 my $l=$cwd;
 413                 $l.="/" if length $l;
 414                 $l.=$link;
 415
 416                 if (exists $links{$l}) {
 417                         return $l;
 418                 }
 419                 elsif (exists $pagecase{lc $l}) {
 420                         return $pagecase{lc $l};
 421                 }
 422         } while $cwd=~s!/?[^/]+$!!;
 423
 424         if (length $config{userdir}) {
 425                 my $l = "$config{userdir}/".lc($link);
 426                 if (exists $links{$l}) {
 427                         return $l;
 428                 }
 429                 elsif (exists $pagecase{lc $l}) {
 430                         return $pagecase{lc $l};
 431                 }
 432         }
 433
 434         #print STDERR "warning: page $page, broken link: $link\n";
 435         return "";
 436 } #}}}
 437
 438 sub isinlinableimage ($) { #{{{
 439         my $file=shift;
 440
 441         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 442 } #}}}
 443
 444 sub pagetitle ($;$) { #{{{
 445         my $page=shift;
 446         my $unescaped=shift;
 447
 448         if ($unescaped) {
 449                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 450         }
 451         else {
 452                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 453         }
 454
 455         return $page;
 456 } #}}}
 457
 458 sub titlepage ($) { #{{{
 459         my $title=shift;
 460         $title=~s/([^-[:alnum:]:+\/.])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 461         return $title;
 462 } #}}}
 463
 464 sub linkpage ($) { #{{{
 465         my $link=shift;
 466         $link=~s/([^-[:alnum:]:+\/._])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 467         return $link;
 468 } #}}}
 469
 470 sub cgiurl (@) { #{{{
 471         my %params=@_;
 472
 473         return $config{cgiurl}."?".
 474                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 475 } #}}}
 476
 477 sub baseurl (;$) { #{{{
 478         my $page=shift;
 479
 480         return "$config{url}/" if ! defined $page;
 481
 482         $page=htmlpage($page);
 483         $page=~s/[^\/]+$//;
 484         $page=~s/[^\/]+\//..\//g;
 485         return $page;
 486 } #}}}
 487
 488 sub abs2rel ($$) { #{{{
 489         # Work around very innefficient behavior in File::Spec if abs2rel
 490         # is passed two relative paths. It's much faster if paths are
 491         # absolute! (Debian bug #376658; fixed in debian unstable now)
 492         my $path="/".shift;
 493         my $base="/".shift;
 494
 495         require File::Spec;
 496         my $ret=File::Spec->abs2rel($path, $base);
 497         $ret=~s/^// if defined $ret;
 498         return $ret;
 499 } #}}}
 500
 501 sub displaytime ($) { #{{{
 502         my $time=shift;
 503
 504         # strftime doesn't know about encodings, so make sure
 505         # its output is properly treated as utf8
 506         return decode_utf8(POSIX::strftime(
 507                         $config{timeformat}, localtime($time)));
 508 } #}}}
 509
 510 sub beautify_url ($) { #{{{
 511         my $url=shift;
 512
 513         $url =~ s!/index.$config{htmlext}$!/!;
 514         $url =~ s!^$!./!; # Browsers don't like empty links...
 515
 516         return $url;
 517 } #}}}
 518
 519 sub urlto ($$) { #{{{
 520         my $to=shift;
 521         my $from=shift;
 522
 523         if (! length $to) {
 524                 return beautify_url(baseurl($from));
 525         }
 526
 527         if (! $destsources{$to}) {
 528                 $to=htmlpage($to);
 529         }
 530
 531         my $link = abs2rel($to, dirname(htmlpage($from)));
 532
 533         return beautify_url($link);
 534 } #}}}
 535
 536 sub htmllink ($$$;@) { #{{{
 537         my $lpage=shift; # the page doing the linking
 538         my $page=shift; # the page that will contain the link (different for inline)
 539         my $link=shift;
 540         my %opts=@_;
 541
 542         my $bestlink;
 543         if (! $opts{forcesubpage}) {
 544                 $bestlink=bestlink($lpage, $link);
 545         }
 546         else {
 547                 $bestlink="$lpage/".lc($link);
 548         }
 549
 550         my $linktext;
 551         if (defined $opts{linktext}) {
 552                 $linktext=$opts{linktext};
 553         }
 554         else {
 555                 $linktext=pagetitle(basename($link));
 556         }
 557
 558         return "<span class=\"selflink\">$linktext</span>"
 559                 if length $bestlink && $page eq $bestlink;
 560
 561         if (! $destsources{$bestlink}) {
 562                 $bestlink=htmlpage($bestlink);
 563
 564                 if (! $destsources{$bestlink}) {
 565                         return $linktext unless length $config{cgiurl};
 566                         return "<span><a href=\"".
 567                                 cgiurl(
 568                                         do => "create",
 569                                         page => pagetitle(lc($link), 1),
 570                                         from => $lpage
 571                                 ).
 572                                 "\">?</a>$linktext</span>"
 573                 }
 574         }
 575
 576         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
 577         $bestlink=beautify_url($bestlink);
 578
 579         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
 580                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 581         }
 582
 583         if (defined $opts{anchor}) {
 584                 $bestlink.="#".$opts{anchor};
 585         }
 586
 587         my @attrs;
 588         if (defined $opts{rel}) {
 589                 push @attrs, ' rel="'.$opts{rel}.'"';
 590         }
 591
 592         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
 593 } #}}}
 594
 595 sub htmlize ($$$) { #{{{
 596         my $page=shift;
 597         my $type=shift;
 598         my $content=shift;
 599
 600         if (exists $hooks{htmlize}{$type}) {
 601                 $content=$hooks{htmlize}{$type}{call}->(
 602                         page => $page,
 603                         content => $content,
 604                 );
 605         }
 606         else {
 607                 error("htmlization of $type not supported");
 608         }
 609
 610         run_hooks(sanitize => sub {
 611                 $content=shift->(
 612                         page => $page,
 613                         content => $content,
 614                 );
 615         });
 616
 617         return $content;
 618 } #}}}
 619
 620 sub linkify ($$$) { #{{{
 621         my $lpage=shift; # the page containing the links
 622         my $page=shift; # the page the link will end up on (different for inline)
 623         my $content=shift;
 624
 625         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 626                 defined $2
 627                         ? ( $1
 628                                 ? "[[$2|$3".($4 ? "#$4" : "")."]]"
 629                                 : htmllink($lpage, $page, linkpage($3),
 630                                         anchor => $4, linktext => pagetitle($2)))
 631                         : ( $1
 632                                 ? "[[$3".($4 ? "#$4" : "")."]]"
 633                                 : htmllink($lpage, $page, linkpage($3),
 634                                         anchor => $4))
 635         }eg;
 636
 637         return $content;
 638 } #}}}
 639
 640 my %preprocessing;
 641 our $preprocess_preview=0;
 642 sub preprocess ($$$;$$) { #{{{
 643         my $page=shift; # the page the data comes from
 644         my $destpage=shift; # the page the data will appear in (different for inline)
 645         my $content=shift;
 646         my $scan=shift;
 647         my $preview=shift;
 648
 649         # Using local because it needs to be set within any nested calls
 650         # of this function.
 651         local $preprocess_preview=$preview if defined $preview;
 652
 653         my $handle=sub {
 654                 my $escape=shift;
 655                 my $command=shift;
 656                 my $params=shift;
 657                 if (length $escape) {
 658                         return "[[$command $params]]";
 659                 }
 660                 elsif (exists $hooks{preprocess}{$command}) {
 661                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 662                         # Note: preserve order of params, some plugins may
 663                         # consider it significant.
 664                         my @params;
 665                         while ($params =~ m{
 666                                 (?:(\w+)=)?             # 1: named parameter key?
 667                                 (?:
 668                                         """(.*?)"""     # 2: triple-quoted value
 669                                 |
 670                                         "([^"]+)"       # 3: single-quoted value
 671                                 |
 672                                         (\S+)           # 4: unquoted value
 673                                 )
 674                                 (?:\s+|$)               # delimiter to next param
 675                         }sgx) {
 676                                 my $key=$1;
 677                                 my $val;
 678                                 if (defined $2) {
 679                                         $val=$2;
 680                                         $val=~s/\r\n/\n/mg;
 681                                         $val=~s/^\n+//g;
 682                                         $val=~s/\n+$//g;
 683                                 }
 684                                 elsif (defined $3) {
 685                                         $val=$3;
 686                                 }
 687                                 elsif (defined $4) {
 688                                         $val=$4;
 689                                 }
 690
 691                                 if (defined $key) {
 692                                         push @params, $key, $val;
 693                                 }
 694                                 else {
 695                                         push @params, $val, '';
 696                                 }
 697                         }
 698                         if ($preprocessing{$page}++ > 3) {
 699                                 # Avoid loops of preprocessed pages preprocessing
 700                                 # other pages that preprocess them, etc.
 701                                 #translators: The first parameter is a
 702                                 #translators: preprocessor directive name,
 703                                 #translators: the second a page name, the
 704                                 #translators: third a number.
 705                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 706                                         $command, $page, $preprocessing{$page}).
 707                                 "]]";
 708                         }
 709                         my $ret=$hooks{preprocess}{$command}{call}->(
 710                                 @params,
 711                                 page => $page,
 712                                 destpage => $destpage,
 713                                 preview => $preprocess_preview,
 714                         );
 715                         $preprocessing{$page}--;
 716                         return $ret;
 717                 }
 718                 else {
 719                         return "[[$command $params]]";
 720                 }
 721         };
 722
 723         $content =~ s{
 724                 (\\?)           # 1: escape?
 725                 \[\[            # directive open
 726                 (\w+)           # 2: command
 727                 \s+
 728                 (               # 3: the parameters..
 729                         (?:
 730                                 (?:\w+=)?               # named parameter key?
 731                                 (?:
 732                                         """.*?"""       # triple-quoted value
 733                                         |
 734                                         "[^"]+"         # single-quoted value
 735                                         |
 736                                         [^\s\]]+        # unquoted value
 737                                 )
 738                                 \s*                     # whitespace or end
 739                                                         # of directive
 740                         )
 741                 *)              # 0 or more parameters
 742                 \]\]            # directive closed
 743         }{$handle->($1, $2, $3)}sexg;
 744         return $content;
 745 } #}}}
 746
 747 sub filter ($$$) { #{{{
 748         my $page=shift;
 749         my $destpage=shift;
 750         my $content=shift;
 751
 752         run_hooks(filter => sub {
 753                 $content=shift->(page => $page, destpage => $destpage,
 754                         content => $content);
 755         });
 756
 757         return $content;
 758 } #}}}
 759
 760 sub indexlink () { #{{{
 761         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 762 } #}}}
 763
 764 my $wikilock;
 765
 766 sub lockwiki (;$) { #{{{
 767         my $wait=@_ ? shift : 1;
 768         # Take an exclusive lock on the wiki to prevent multiple concurrent
 769         # run issues. The lock will be dropped on program exit.
 770         if (! -d $config{wikistatedir}) {
 771                 mkdir($config{wikistatedir});
 772         }
 773         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
 774                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 775         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
 776                 if ($wait) {
 777                         debug("wiki seems to be locked, waiting for lock");
 778                         my $wait=600; # arbitrary, but don't hang forever to
 779                                       # prevent process pileup
 780                         for (1..$wait) {
 781                                 return if flock($wikilock, 2 | 4);
 782                                 sleep 1;
 783                         }
 784                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 785                 }
 786                 else {
 787                         return 0;
 788                 }
 789         }
 790         return 1;
 791 } #}}}
 792
 793 sub unlockwiki () { #{{{
 794         return close($wikilock) if $wikilock;
 795         return;
 796 } #}}}
 797
 798 my $commitlock;
 799
 800 sub commit_hook_enabled () { #{{{
 801         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
 802                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 803         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
 804                 close($commitlock) || error("failed closing commitlock: $!");
 805                 return 0;
 806         }
 807         close($commitlock) || error("failed closing commitlock: $!");
 808         return 1;
 809 } #}}}
 810
 811 sub disable_commit_hook () { #{{{
 812         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
 813                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 814         if (! flock($commitlock, 2)) { # LOCK_EX
 815                 error("failed to get commit lock");
 816         }
 817         return 1;
 818 } #}}}
 819
 820 sub enable_commit_hook () { #{{{
 821         return close($commitlock) if $commitlock;
 822         return;
 823 } #}}}
 824
 825 sub loadindex () { #{{{
 826         open (my $in, "<", "$config{wikistatedir}/index") || return;
 827         while (<$in>) {
 828                 $_=possibly_foolish_untaint($_);
 829                 chomp;
 830                 my %items;
 831                 $items{link}=[];
 832                 $items{dest}=[];
 833                 foreach my $i (split(/ /, $_)) {
 834                         my ($item, $val)=split(/=/, $i, 2);
 835                         push @{$items{$item}}, decode_entities($val);
 836                 }
 837
 838                 next unless exists $items{src}; # skip bad lines for now
 839
 840                 my $page=pagename($items{src}[0]);
 841                 if (! $config{rebuild}) {
 842                         $pagesources{$page}=$items{src}[0];
 843                         $pagemtime{$page}=$items{mtime}[0];
 844                         $oldlinks{$page}=[@{$items{link}}];
 845                         $links{$page}=[@{$items{link}}];
 846                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 847                         $destsources{$_}=$page foreach @{$items{dest}};
 848                         $renderedfiles{$page}=[@{$items{dest}}];
 849                         $pagecase{lc $page}=$page;
 850                 }
 851                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 852                 $pagectime{$page}=$items{ctime}[0];
 853         }
 854         return close($in);
 855 } #}}}
 856
 857 sub saveindex () { #{{{
 858         run_hooks(savestate => sub { shift->() });
 859
 860         if (! -d $config{wikistatedir}) {
 861                 mkdir($config{wikistatedir});
 862         }
 863         my $newfile="$config{wikistatedir}/index.new";
 864         my $cleanup = sub { unlink($newfile) };
 865         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
 866         foreach my $page (keys %pagemtime) {
 867                 next unless $pagemtime{$page};
 868                 my $line="mtime=$pagemtime{$page} ".
 869                         "ctime=$pagectime{$page} ".
 870                         "src=$pagesources{$page}";
 871                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 872                 my %count;
 873                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 874                 if (exists $depends{$page}) {
 875                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 876                 }
 877                 print $out $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 878         }
 879         close $out || error("failed saving to $newfile: $!", $cleanup);
 880         rename($newfile, "$config{wikistatedir}/index") ||
 881                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 882
 883         return 1;
 884 } #}}}
 885
 886 sub template_file ($) { #{{{
 887         my $template=shift;
 888
 889         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 890                 return "$dir/$template" if -e "$dir/$template";
 891         }
 892         return;
 893 } #}}}
 894
 895 sub template_params (@) { #{{{
 896         my $filename=template_file(shift);
 897
 898         if (! defined $filename) {
 899                 return if wantarray;
 900                 return "";
 901         }
 902
 903         my @ret=(
 904                 filter => sub {
 905                         my $text_ref = shift;
 906                         ${$text_ref} = decode_utf8(${$text_ref});
 907                 },
 908                 filename => $filename,
 909                 loop_context_vars => 1,
 910                 die_on_bad_params => 0,
 911                 @_
 912         );
 913         return wantarray ? @ret : {@ret};
 914 } #}}}
 915
 916 sub template ($;@) { #{{{
 917         require HTML::Template;
 918         return HTML::Template->new(template_params(@_));
 919 } #}}}
 920
 921 sub misctemplate ($$;@) { #{{{
 922         my $title=shift;
 923         my $pagebody=shift;
 924
 925         my $template=template("misc.tmpl");
 926         $template->param(
 927                 title => $title,
 928                 indexlink => indexlink(),
 929                 wikiname => $config{wikiname},
 930                 pagebody => $pagebody,
 931                 baseurl => baseurl(),
 932                 @_,
 933         );
 934         run_hooks(pagetemplate => sub {
 935                 shift->(page => "", destpage => "", template => $template);
 936         });
 937         return $template->output;
 938 }#}}}
 939
 940 sub hook (@) { # {{{
 941         my %param=@_;
 942
 943         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 944                 error 'hook requires type, call, and id parameters';
 945         }
 946
 947         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 948
 949         $hooks{$param{type}}{$param{id}}=\%param;
 950         return 1;
 951 } # }}}
 952
 953 sub run_hooks ($$) { # {{{
 954         # Calls the given sub for each hook of the given type,
 955         # passing it the hook function to call.
 956         my $type=shift;
 957         my $sub=shift;
 958
 959         if (exists $hooks{$type}) {
 960                 my @deferred;
 961                 foreach my $id (keys %{$hooks{$type}}) {
 962                         if ($hooks{$type}{$id}{last}) {
 963                                 push @deferred, $id;
 964                                 next;
 965                         }
 966                         $sub->($hooks{$type}{$id}{call});
 967                 }
 968                 foreach my $id (@deferred) {
 969                         $sub->($hooks{$type}{$id}{call});
 970                 }
 971         }
 972
 973         return 1;
 974 } #}}}
 975
 976 sub globlist_to_pagespec ($) { #{{{
 977         my @globlist=split(' ', shift);
 978
 979         my (@spec, @skip);
 980         foreach my $glob (@globlist) {
 981                 if ($glob=~/^!(.*)/) {
 982                         push @skip, $glob;
 983                 }
 984                 else {
 985                         push @spec, $glob;
 986                 }
 987         }
 988
 989         my $spec=join(' or ', @spec);
 990         if (@skip) {
 991                 my $skip=join(' and ', @skip);
 992                 if (length $spec) {
 993                         $spec="$skip and ($spec)";
 994                 }
 995                 else {
 996                         $spec=$skip;
 997                 }
 998         }
 999         return $spec;
1000 } #}}}
1001
1002 sub is_globlist ($) { #{{{
1003         my $s=shift;
1004         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
1005 } #}}}
1006
1007 sub safequote ($) { #{{{
1008         my $s=shift;
1009         $s=~s/[{}]//g;
1010         return "q{$s}";
1011 } #}}}
1012
1013 sub add_depends ($$) { #{{{
1014         my $page=shift;
1015         my $pagespec=shift;
1016
1017         if (! exists $depends{$page}) {
1018                 $depends{$page}=$pagespec;
1019         }
1020         else {
1021                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1022         }
1023
1024         return 1;
1025 } # }}}
1026
1027 sub file_pruned ($$) { #{{{
1028         require File::Spec;
1029         my $file=File::Spec->canonpath(shift);
1030         my $base=File::Spec->canonpath(shift);
1031         $file =~ s#^\Q$base\E/*##;
1032
1033         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1034         return $file =~ m/$regexp/;
1035 } #}}}
1036
1037 sub gettext { #{{{
1038         # Only use gettext in the rare cases it's needed.
1039         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1040             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1041             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1042                 if (! $gettext_obj) {
1043                         $gettext_obj=eval q{
1044                                 use Locale::gettext q{textdomain};
1045                                 Locale::gettext->domain('ikiwiki')
1046                         };
1047                         if ($@) {
1048                                 print STDERR "$@";
1049                                 $gettext_obj=undef;
1050                                 return shift;
1051                         }
1052                 }
1053                 return $gettext_obj->get(shift);
1054         }
1055         else {
1056                 return shift;
1057         }
1058 } #}}}
1059
1060 sub pagespec_merge ($$) { #{{{
1061         my $a=shift;
1062         my $b=shift;
1063
1064         return $a if $a eq $b;
1065
1066         # Support for old-style GlobLists.
1067         if (is_globlist($a)) {
1068                 $a=globlist_to_pagespec($a);
1069         }
1070         if (is_globlist($b)) {
1071                 $b=globlist_to_pagespec($b);
1072         }
1073
1074         return "($a) or ($b)";
1075 } #}}}
1076
1077 sub pagespec_translate ($) { #{{{
1078         # This assumes that $page is in scope in the function
1079         # that evalulates the translated pagespec code.
1080         my $spec=shift;
1081
1082         # Support for old-style GlobLists.
1083         if (is_globlist($spec)) {
1084                 $spec=globlist_to_pagespec($spec);
1085         }
1086
1087         # Convert spec to perl code.
1088         my $code="";
1089         while ($spec=~m{
1090                 \s*             # ignore whitespace
1091                 (               # 1: match a single word
1092                         \!              # !
1093                 |
1094                         \(              # (
1095                 |
1096                         \)              # )
1097                 |
1098                         \w+\([^\)]*\)   # command(params)
1099                 |
1100                         [^\s()]+        # any other text
1101                 )
1102                 \s*             # ignore whitespace
1103         }igx) {
1104                 my $word=$1;
1105                 if (lc $word eq 'and') {
1106                         $code.=' &&';
1107                 }
1108                 elsif (lc $word eq 'or') {
1109                         $code.=' ||';
1110                 }
1111                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1112                         $code.=' '.$word;
1113                 }
1114                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1115                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1116                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@params)";
1117                         }
1118                         else {
1119                                 $code.=' 0';
1120                         }
1121                 }
1122                 else {
1123                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@params)";
1124                 }
1125         }
1126
1127         return $code;
1128 } #}}}
1129
1130 sub pagespec_match ($$;@) { #{{{
1131         my $page=shift;
1132         my $spec=shift;
1133         my @params=@_;
1134
1135         # Backwards compatability with old calling convention.
1136         if (@params == 1) {
1137                 unshift @params, 'location';
1138         }
1139
1140         my $ret=eval pagespec_translate($spec);
1141         return IkiWiki::FailReason->new('syntax error') if $@;
1142         return $ret;
1143 } #}}}
1144
1145 package IkiWiki::FailReason;
1146
1147 use overload ( #{{{
1148         '""'    => sub { ${$_[0]} },
1149         '0+'    => sub { 0 },
1150         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1151         fallback => 1,
1152 ); #}}}
1153
1154 sub new { #{{{
1155         return bless \$_[1], $_[0];
1156 } #}}}
1157
1158 package IkiWiki::SuccessReason;
1159
1160 use overload ( #{{{
1161         '""'    => sub { ${$_[0]} },
1162         '0+'    => sub { 1 },
1163         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1164         fallback => 1,
1165 ); #}}}
1166
1167 sub new { #{{{
1168         return bless \$_[1], $_[0];
1169 }; #}}}
1170
1171 package IkiWiki::PageSpec;
1172
1173 sub match_glob ($$;@) { #{{{
1174         my $page=shift;
1175         my $glob=shift;
1176         my %params=@_;
1177
1178         my $from=exists $params{location} ? $params{location} : '';
1179
1180         # relative matching
1181         if ($glob =~ m!^\./!) {
1182                 $from=~s#/?[^/]+$##;
1183                 $glob=~s#^\./##;
1184                 $glob="$from/$glob" if length $from;
1185         }
1186
1187         # turn glob into safe regexp
1188         $glob=quotemeta($glob);
1189         $glob=~s/\\\*/.*/g;
1190         $glob=~s/\\\?/./g;
1191
1192         if ($page=~/^$glob$/i) {
1193                 return IkiWiki::SuccessReason->new("$glob matches $page");
1194         }
1195         else {
1196                 return IkiWiki::FailReason->new("$glob does not match $page");
1197         }
1198 } #}}}
1199
1200 sub match_link ($$;@) { #{{{
1201         my $page=shift;
1202         my $link=lc(shift);
1203         my %params=@_;
1204
1205         my $from=exists $params{location} ? $params{location} : '';
1206
1207         # relative matching
1208         if ($link =~ m!^\.! && defined $from) {
1209                 $from=~s#/?[^/]+$##;
1210                 $link=~s#^\./##;
1211                 $link="$from/$link" if length $from;
1212         }
1213
1214         my $links = $IkiWiki::links{$page};
1215         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1216         my $bestlink = IkiWiki::bestlink($from, $link);
1217         foreach my $p (@{$links}) {
1218                 if (length $bestlink) {
1219                         return IkiWiki::SuccessReason->new("$page links to $link")
1220                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1221                 }
1222                 else {
1223                         return IkiWiki::SuccessReason->new("$page links to page matching $link")
1224                                 if match_glob($p, $link, %params);
1225                 }
1226         }
1227         return IkiWiki::FailReason->new("$page does not link to $link");
1228 } #}}}
1229
1230 sub match_backlink ($$;@) { #{{{
1231         return match_link($_[1], $_[0], @_);
1232 } #}}}
1233
1234 sub match_created_before ($$;@) { #{{{
1235         my $page=shift;
1236         my $testpage=shift;
1237
1238         if (exists $IkiWiki::pagectime{$testpage}) {
1239                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1240                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1241                 }
1242                 else {
1243                         return IkiWiki::FailReason->new("$page not created before $testpage");
1244                 }
1245         }
1246         else {
1247                 return IkiWiki::FailReason->new("$testpage has no ctime");
1248         }
1249 } #}}}
1250
1251 sub match_created_after ($$;@) { #{{{
1252         my $page=shift;
1253         my $testpage=shift;
1254
1255         if (exists $IkiWiki::pagectime{$testpage}) {
1256                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1257                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1258                 }
1259                 else {
1260                         return IkiWiki::FailReason->new("$page not created after $testpage");
1261                 }
1262         }
1263         else {
1264                 return IkiWiki::FailReason->new("$testpage has no ctime");
1265         }
1266 } #}}}
1267
1268 sub match_creation_day ($$;@) { #{{{
1269         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1270                 return IkiWiki::SuccessReason->new('creation_day matched');
1271         }
1272         else {
1273                 return IkiWiki::FailReason->new('creation_day did not match');
1274         }
1275 } #}}}
1276
1277 sub match_creation_month ($$;@) { #{{{
1278         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1279                 return IkiWiki::SuccessReason->new('creation_month matched');
1280         }
1281         else {
1282                 return IkiWiki::FailReason->new('creation_month did not match');
1283         }
1284 } #}}}
1285
1286 sub match_creation_year ($$;@) { #{{{
1287         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1288                 return IkiWiki::SuccessReason->new('creation_year matched');
1289         }
1290         else {
1291                 return IkiWiki::FailReason->new('creation_year did not match');
1292         }
1293 } #}}}
1294
1295 sub match_user ($$;@) { #{{{
1296         shift;
1297         my $user=shift;
1298         my %params=@_;
1299
1300         return IkiWiki::FailReason->new('cannot match user')
1301                 unless exists $params{user};
1302         if ($user eq $params{user}) {
1303                 return IkiWiki::SuccessReason->new("user is $user")
1304         }
1305         else {
1306                 return IkiWiki::FailReason->new("user is not $user");
1307         }
1308 } #}}}
1309
1310 1