IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                 },
  23 }
  24
  25 sub preprocess (@) {
  26         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  27         my %params=@_;
  28
  29         if (exists $imgdefaults{$params{page}}) {
  30                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  31                         if (! exists $params{$key}) {
  32                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  33                         }
  34                 }
  35         }
  36
  37         if (! exists $params{size}) {
  38                 $params{size}='full';
  39         }
  40
  41         if ($image eq 'defaults') {
  42                 $imgdefaults{$params{page}} = \%params;
  43                 return '';
  44         }
  45
  46         add_link($params{page}, $image);
  47         add_depends($params{page}, $image);
  48
  49         # optimisation: detect scan mode, and avoid generating the image
  50         if (! defined wantarray) {
  51                 return;
  52         }
  53
  54         my $file = bestlink($params{page}, $image);
  55         my $srcfile = srcfile($file, 1);
  56         if (! length $file || ! defined $srcfile) {
  57                 return htmllink($params{page}, $params{destpage}, $image);
  58         }
  59
  60         my $dir = $params{page};
  61         my $base = IkiWiki::basename($file);
  62
  63         eval q{use Image::Magick};
  64         error gettext("Image::Magick is not installed") if $@;
  65         my $im = Image::Magick->new;
  66         my $imglink;
  67         my $r = $im->Read($srcfile);
  68         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
  69
  70         my ($dwidth, $dheight);
  71
  72         if ($params{size} ne 'full') {
  73                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
  74                 error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
  75                         unless (defined $w && defined $h &&
  76                                 (length $w || length $h));
  77
  78                 if ((length $w && $w > $im->Get("width")) ||
  79                     (length $h && $h > $im->Get("height"))) {
  80                         # resizing larger
  81                         $imglink = $file;
  82
  83                         # don't generate larger image, just set display size
  84                         if (length $w && length $h) {
  85                                 ($dwidth, $dheight)=($w, $h);
  86                         }
  87                         # avoid division by zero on 0x0 image
  88                         elsif ($im->Get("width") == 0 || $im->Get("height") == 0) {
  89                                 ($dwidth, $dheight)=(0, 0);
  90                         }
  91                         # calculate unspecified size from the other one, preserving
  92                         # aspect ratio
  93                         elsif (length $w) {
  94                                 $dwidth=$w;
  95                                 $dheight=$w / $im->Get("width") * $im->Get("height");
  96                         }
  97                         elsif (length $h) {
  98                                 $dheight=$h;
  99                                 $dwidth=$h / $im->Get("height") * $im->Get("width");
 100                         }
 101                 }
 102                 else {
 103                         # resizing smaller
 104                         my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
 105                         $imglink = "$dir/${w}x${h}-$base";
 106
 107                         will_render($params{page}, $imglink);
 108
 109                         if (-e $outfile && (-M $srcfile >= -M $outfile)) {
 110                                 $im = Image::Magick->new;
 111                                 $r = $im->Read($outfile);
 112                                 error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
 113
 114                                 $dwidth = $im->Get("width");
 115                                 $dheight = $im->Get("height");
 116                         }
 117                         else {
 118                                 ($dwidth, $dheight)=($w, $h);
 119                                 $r = $im->Resize(geometry => "${w}x${h}");
 120                                 error sprintf(gettext("failed to resize: %s"), $r) if $r;
 121
 122                                 # don't actually write file in preview mode
 123                                 if (! $params{preview}) {
 124                                         my @blob = $im->ImageToBlob();
 125                                         writefile($imglink, $config{destdir}, $blob[0], 1);
 126                                 }
 127                                 else {
 128                                         $imglink = $file;
 129                                 }
 130                         }
 131                 }
 132         }
 133         else {
 134                 $imglink = $file;
 135                 $dwidth = $im->Get("width");
 136                 $dheight = $im->Get("height");
 137         }
 138
 139         if (! defined($dwidth) || ! defined($dheight)) {
 140                 error sprintf(gettext("failed to determine size of image %s"), $file)
 141         }
 142
 143         my ($fileurl, $imgurl);
 144         if (! $params{preview}) {
 145                 $fileurl=urlto($file, $params{destpage});
 146                 $imgurl=urlto($imglink, $params{destpage});
 147         }
 148         else {
 149                 $fileurl="$config{url}/$file";
 150                 $imgurl="$config{url}/$imglink";
 151         }
 152
 153         my $imgtag='<img src="'.$imgurl.
 154                 '" width="'.$dwidth.
 155                 '" height="'.$dheight.'"'.
 156                 (exists $params{alt} ? ' alt="'.$params{alt}.'"' : '').
 157                 (exists $params{title} ? ' title="'.$params{title}.'"' : '').
 158                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 159                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 160                 ' />';
 161
 162         my $alignclass=exists $params{align} ? "align-$params{align}" : "";
 163
 164         my $link;
 165         if (! defined $params{link}) {
 166                 $link=$fileurl;
 167         }
 168         elsif ($params{link} =~ /^\w+:\/\//) {
 169                 $link=$params{link};
 170         }
 171
 172         if (defined $link) {
 173                 $imgtag='<a href="'.$link.'"'.
 174                         (!exists $params{caption} && $alignclass ? ' class="'.$alignclass.'"' : '').
 175                         '>'.$imgtag.'</a>';
 176         }
 177         else {
 178                 my $b = bestlink($params{page}, $params{link});
 179
 180                 if (length $b) {
 181                         add_depends($params{page}, $b, deptype("presence"));
 182                         $imgtag=htmllink($params{page}, $params{destpage},
 183                                 $params{link}, linktext => $imgtag,
 184                                 noimageinline => 1,
 185                                 (!exists $params{caption} && $alignclass) ?
 186                                         (class => $alignclass) : (),
 187                         );
 188                 }
 189         }
 190
 191         if (exists $params{caption}) {
 192                 return '<table class="img'.
 193                         ($alignclass ? ' '.$alignclass : '').
 194                         '">'.
 195                         '<caption>'.$params{caption}.'</caption>'.
 196                         '<tr><td>'.$imgtag.'</td></tr>'.
 197                         '</table>';
 198         }
 199         else {
 200                 return $imgtag;
 201         }
 202 }
 203
 204 1