IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my %backlinks;
  11 my $backlinks_calculated=0;
  12
  13 sub calculate_backlinks () { #{{{
  14         return if $backlinks_calculated;
  15         %backlinks=();
  16         foreach my $page (keys %links) {
  17                 foreach my $link (@{$links{$page}}) {
  18                         my $bestlink=bestlink($page, $link);
  19                         if (length $bestlink && $bestlink ne $page) {
  20                                 $backlinks{$bestlink}{$page}=1;
  21                         }
  22                 }
  23         }
  24         $backlinks_calculated=1;
  25 } #}}}
  26
  27 sub backlinks ($) { #{{{
  28         my $page=shift;
  29
  30         calculate_backlinks();
  31
  32         my @links;
  33         foreach my $p (keys %{$backlinks{$page}}) {
  34                 my $href=urlto($p, $page);
  35
  36                 # Trim common dir prefixes from both pages.
  37                 my $p_trimmed=$p;
  38                 my $page_trimmed=$page;
  39                 my $dir;
  40                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  41                         defined $dir &&
  42                         $p_trimmed=~s/^\Q$dir\E// &&
  43                         $page_trimmed=~s/^\Q$dir\E//;
  44
  45                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  46         }
  47         return @links;
  48 } #}}}
  49
  50 sub parentlinks ($) { #{{{
  51         my $page=shift;
  52
  53         my @ret;
  54         my $pagelink="";
  55         my $path="";
  56         my $title=$config{wikiname};
  57
  58         foreach my $dir (split("/", $page)) {
  59                 next if $dir eq 'index';
  60                 push @ret, { url => urlto($path, $page), page => $title };
  61                 $path.="/".$dir;
  62                 $title=pagetitle($dir);
  63         }
  64         return @ret;
  65 } #}}}
  66
  67 sub genpage ($$) { #{{{
  68         my $page=shift;
  69         my $content=shift;
  70
  71         my $templatefile;
  72         run_hooks(templatefile => sub {
  73                 return if defined $templatefile;
  74                 my $file=shift->(page => $page);
  75                 if (defined $file && defined template_file($file)) {
  76                         $templatefile=$file;
  77                 }
  78         });
  79         my $template=template(defined $templatefile ? $templatefile : 'page.tmpl', blind_cache => 1);
  80         my $actions=0;
  81
  82         if (length $config{cgiurl}) {
  83                 $template->param(editurl => cgiurl(do => "edit", page => pagetitle($page, 1)));
  84                 $template->param(prefsurl => cgiurl(do => "prefs"));
  85                 $actions++;
  86         }
  87
  88         if ($config{rcs}) {
  89                 $template->param(recentchangesurl => urlto("recentchanges", $page));
  90                 $actions++;
  91         }
  92
  93         if (length $config{historyurl}) {
  94                 my $u=$config{historyurl};
  95                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  96                 $template->param(historyurl => $u);
  97                 $actions++;
  98         }
  99         if ($config{discussion}) {
 100                 my $discussionlink=gettext("discussion");
 101                 if ($page !~ /.*\/\Q$discussionlink\E$/ &&
 102                    (length $config{cgiurl} ||
 103                     exists $links{$page."/".$discussionlink})) {
 104                         $template->param(discussionlink => htmllink($page, $page, gettext("Discussion"), noimageinline => 1, forcesubpage => 1));
 105                         $actions++;
 106                 }
 107         }
 108
 109         if ($actions) {
 110                 $template->param(have_actions => 1);
 111         }
 112
 113         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 114         my ($backlinks, $more_backlinks);
 115         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 116                 $backlinks=\@backlinks;
 117                 $more_backlinks=[];
 118         }
 119         else {
 120                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 121                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 122         }
 123
 124         $template->param(
 125                 title => $page eq 'index'
 126                         ? $config{wikiname}
 127                         : pagetitle(basename($page)),
 128                 wikiname => $config{wikiname},
 129                 parentlinks => [parentlinks($page)],
 130                 content => $content,
 131                 backlinks => $backlinks,
 132                 more_backlinks => $more_backlinks,
 133                 mtime => displaytime($pagemtime{$page}),
 134                 baseurl => baseurl($page),
 135         );
 136
 137         run_hooks(pagetemplate => sub {
 138                 shift->(page => $page, destpage => $page, template => $template);
 139         });
 140
 141         $content=$template->output;
 142
 143         run_hooks(format => sub {
 144                 $content=shift->(
 145                         page => $page,
 146                         content => $content,
 147                 );
 148         });
 149
 150         return $content;
 151 } #}}}
 152
 153 sub mtime ($) { #{{{
 154         my $file=shift;
 155
 156         return (stat($file))[9];
 157 } #}}}
 158
 159 sub scan ($) { #{{{
 160         my $file=shift;
 161
 162         my $type=pagetype($file);
 163         if (defined $type) {
 164                 my $srcfile=srcfile($file);
 165                 my $content=readfile($srcfile);
 166                 my $page=pagename($file);
 167                 will_render($page, htmlpage($page), 1);
 168
 169                 # Always needs to be done, since filters might add links
 170                 # to the content.
 171                 $content=filter($page, $page, $content);
 172
 173                 my @links;
 174                 while ($content =~ /(?<!\\)$config{wiki_link_regexp}/g) {
 175                         push @links, linkpage($2);
 176                 }
 177                 if ($config{discussion}) {
 178                         # Discussion links are a special case since they're
 179                         # not in the text of the page, but on its template.
 180                         push @links, $page."/".gettext("discussion");
 181                 }
 182                 $links{$page}=\@links;
 183
 184                 # Preprocess in scan-only mode.
 185                 preprocess($page, $page, $content, 1);
 186         }
 187         else {
 188                 will_render($file, $file, 1);
 189         }
 190 } #}}}
 191
 192 sub render ($) { #{{{
 193         my $file=shift;
 194
 195         my $type=pagetype($file);
 196         my $srcfile=srcfile($file);
 197         if (defined $type) {
 198                 my $page=pagename($file);
 199                 delete $depends{$page};
 200                 will_render($page, htmlpage($page), 1);
 201                 return if $type=~/^_/;
 202
 203                 my $content=htmlize($page, $type,
 204                         linkify($page, $page,
 205                         preprocess($page, $page,
 206                         filter($page, $page,
 207                         readfile($srcfile)))));
 208
 209                 my $output=htmlpage($page);
 210                 writefile($output, $config{destdir}, genpage($page, $content));
 211                 utime($pagemtime{$page}, $pagemtime{$page}, $config{destdir}."/".$output);
 212         }
 213         else {
 214                 my $srcfd=readfile($srcfile, 1, 1);
 215                 delete $depends{$file};
 216                 will_render($file, $file, 1);
 217                 writefile($file, $config{destdir}, undef, 1, sub {
 218                         my $destfd=shift;
 219                         my $cleanup=shift;
 220
 221                         my $blksize = 16384;
 222                         my ($len, $buf, $written);
 223                         while ($len = sysread $srcfd, $buf, $blksize) {
 224                                 if (! defined $len) {
 225                                         next if $! =~ /^Interrupted/;
 226                                         error("failed to read $srcfile: $!", $cleanup);
 227                                 }
 228                                 my $offset = 0;
 229                                 while ($len) {
 230                                         defined($written = syswrite $destfd, $buf, $len, $offset)
 231                                                 or error("failed to write $file: $!", $cleanup);
 232                                         $len -= $written;
 233                                         $offset += $written;
 234                                 }
 235                         }
 236                 });
 237                 utime($pagemtime{$file}, $pagemtime{$file}, $config{destdir}."/".$file);
 238         }
 239 } #}}}
 240
 241 sub prune ($) { #{{{
 242         my $file=shift;
 243
 244         unlink($file);
 245         my $dir=dirname($file);
 246         while (rmdir($dir)) {
 247                 $dir=dirname($dir);
 248         }
 249 } #}}}
 250
 251 sub refresh () { #{{{
 252         # security check, avoid following symlinks in the srcdir path
 253         my $test=$config{srcdir};
 254         while (length $test) {
 255                 if (-l $test) {
 256                         error("symlink found in srcdir path ($test)");
 257                 }
 258                 unless ($test=~s/\/+$//) {
 259                         $test=dirname($test);
 260                 }
 261         }
 262
 263         run_hooks(refresh => sub { shift->() });
 264
 265         # find existing pages
 266         my %exists;
 267         my @files;
 268         eval q{use File::Find};
 269         error($@) if $@;
 270         find({
 271                 no_chdir => 1,
 272                 wanted => sub {
 273                         $_=decode_utf8($_);
 274                         if (file_pruned($_, $config{srcdir})) {
 275                                 $File::Find::prune=1;
 276                         }
 277                         elsif (! -d $_ && ! -l $_) {
 278                                 my ($f)=/$config{wiki_file_regexp}/; # untaint
 279                                 if (! defined $f) {
 280                                         warn(sprintf(gettext("skipping bad filename %s"), $_)."\n");
 281                                 }
 282                                 else {
 283                                         $f=~s/^\Q$config{srcdir}\E\/?//;
 284                                         push @files, $f;
 285                                         $exists{pagename($f)}=1;
 286                                 }
 287                         }
 288                 },
 289         }, $config{srcdir});
 290         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 291                 find({
 292                         no_chdir => 1,
 293                         wanted => sub {
 294                                 $_=decode_utf8($_);
 295                                 if (file_pruned($_, $dir)) {
 296                                         $File::Find::prune=1;
 297                                 }
 298                                 elsif (! -d $_ && ! -l $_) {
 299                                         my ($f)=/$config{wiki_file_regexp}/; # untaint
 300                                         if (! defined $f) {
 301                                                 warn(sprintf(gettext("skipping bad filename %s"), $_)."\n");
 302                                         }
 303                                         else {
 304                                                 $f=~s/^\Q$dir\E\/?//;
 305                                                 # avoid underlaydir
 306                                                 # override attacks; see
 307                                                 # security.mdwn
 308                                                 if (! -e "$config{srcdir}/$f" &&
 309                                                     ! -l "$config{srcdir}/$f") {
 310                                                         my $page=pagename($f);
 311                                                         if (! $exists{$page}) {
 312                                                                 push @files, $f;
 313                                                                 $exists{$page}=1;
 314                                                         }
 315                                                 }
 316                                         }
 317                                 }
 318                         },
 319                 }, $dir);
 320         };
 321
 322         my %rendered;
 323
 324         # check for added or removed pages
 325         my @add;
 326         foreach my $file (@files) {
 327                 my $page=pagename($file);
 328                 $pagesources{$page}=$file;
 329                 if (! $pagemtime{$page}) {
 330                         push @add, $file;
 331                         $pagecase{lc $page}=$page;
 332                         if ($config{getctime} && -e "$config{srcdir}/$file") {
 333                                 $pagectime{$page}=rcs_getctime("$config{srcdir}/$file");
 334                         }
 335                         elsif (! exists $pagectime{$page}) {
 336                                 $pagectime{$page}=mtime(srcfile($file));
 337                         }
 338                 }
 339         }
 340         my @del;
 341         foreach my $page (keys %pagemtime) {
 342                 if (! $exists{$page}) {
 343                         debug(sprintf(gettext("removing old page %s"), $page));
 344                         push @del, $pagesources{$page};
 345                         $links{$page}=[];
 346                         $renderedfiles{$page}=[];
 347                         $pagemtime{$page}=0;
 348                         prune($config{destdir}."/".$_)
 349                                 foreach @{$oldrenderedfiles{$page}};
 350                         delete $pagesources{$page};
 351                         foreach (keys %destsources) {
 352                                 if ($destsources{$_} eq $page) {
 353                                         delete $destsources{$_};
 354                                 }
 355                         }
 356                 }
 357         }
 358
 359         # find changed and new files
 360         my @needsbuild;
 361         foreach my $file (@files) {
 362                 my $page=pagename($file);
 363
 364                 my $mtime=mtime(srcfile($file));
 365                 if (! exists $pagemtime{$page} ||
 366                     $mtime > $pagemtime{$page} ||
 367                     $forcerebuild{$page}) {
 368                         $pagemtime{$page}=$mtime;
 369                         push @needsbuild, $file;
 370                 }
 371         }
 372         run_hooks(needsbuild => sub { shift->(\@needsbuild) });
 373
 374         # scan and render files
 375         foreach my $file (@needsbuild) {
 376                 debug(sprintf(gettext("scanning %s"), $file));
 377                 scan($file);
 378         }
 379         calculate_backlinks();
 380         foreach my $file (@needsbuild) {
 381                 debug(sprintf(gettext("rendering %s"), $file));
 382                 render($file);
 383                 $rendered{$file}=1;
 384         }
 385
 386         # rebuild pages that link to added or removed pages
 387         if (@add || @del) {
 388                 foreach my $f (@add, @del) {
 389                         my $p=pagename($f);
 390                         foreach my $page (keys %{$backlinks{$p}}) {
 391                                 my $file=$pagesources{$page};
 392                                 next if $rendered{$file};
 393                                 debug(sprintf(gettext("rendering %s, which links to %s"), $file, $p));
 394                                 render($file);
 395                                 $rendered{$file}=1;
 396                         }
 397                 }
 398         }
 399
 400         if (%rendered || @del) {
 401                 # rebuild dependant pages
 402                 foreach my $f (@files) {
 403                         next if $rendered{$f};
 404                         my $p=pagename($f);
 405                         if (exists $depends{$p}) {
 406                                 foreach my $file (keys %rendered, @del) {
 407                                         next if $f eq $file;
 408                                         my $page=pagename($file);
 409                                         if (pagespec_match($page, $depends{$p}, location => $p)) {
 410                                                 debug(sprintf(gettext("rendering %s, which depends on %s"), $f, $page));
 411                                                 render($f);
 412                                                 $rendered{$f}=1;
 413                                                 last;
 414                                         }
 415                                 }
 416                         }
 417                 }
 418
 419                 # handle backlinks; if a page has added/removed links,
 420                 # update the pages it links to
 421                 my %linkchanged;
 422                 foreach my $file (keys %rendered, @del) {
 423                         my $page=pagename($file);
 424
 425                         if (exists $links{$page}) {
 426                                 foreach my $link (map { bestlink($page, $_) } @{$links{$page}}) {
 427                                         if (length $link &&
 428                                             (! exists $oldlinks{$page} ||
 429                                              ! grep { bestlink($page, $_) eq $link } @{$oldlinks{$page}})) {
 430                                                 $linkchanged{$link}=1;
 431                                         }
 432                                 }
 433                         }
 434                         if (exists $oldlinks{$page}) {
 435                                 foreach my $link (map { bestlink($page, $_) } @{$oldlinks{$page}}) {
 436                                         if (length $link &&
 437                                             (! exists $links{$page} ||
 438                                              ! grep { bestlink($page, $_) eq $link } @{$links{$page}})) {
 439                                                 $linkchanged{$link}=1;
 440                                         }
 441                                 }
 442                         }
 443                 }
 444                 foreach my $link (keys %linkchanged) {
 445                         my $linkfile=$pagesources{$link};
 446                         if (defined $linkfile) {
 447                                 next if $rendered{$linkfile};
 448                                 debug(sprintf(gettext("rendering %s, to update its backlinks"), $linkfile));
 449                                 render($linkfile);
 450                                 $rendered{$linkfile}=1;
 451                         }
 452                 }
 453         }
 454
 455         # remove no longer rendered files
 456         foreach my $src (keys %rendered) {
 457                 my $page=pagename($src);
 458                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 459                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 460                                 debug(sprintf(gettext("removing %s, no longer rendered by %s"), $file, $page));
 461                                 prune($config{destdir}."/".$file);
 462                         }
 463                 }
 464         }
 465
 466         if (@del) {
 467                 run_hooks(delete => sub { shift->(@del) });
 468         }
 469         if (%rendered) {
 470                 run_hooks(change => sub { shift->(keys %rendered) });
 471         }
 472 } #}}}
 473
 474 sub commandline_render () { #{{{
 475         loadplugins();
 476         checkconfig();
 477         lockwiki();
 478         loadindex();
 479         unlockwiki();
 480
 481         my $srcfile=possibly_foolish_untaint($config{render});
 482         my $file=$srcfile;
 483         $file=~s/\Q$config{srcdir}\E\/?//;
 484
 485         my $type=pagetype($file);
 486         die sprintf(gettext("ikiwiki: cannot render %s"), $srcfile)."\n" unless defined $type;
 487         my $content=readfile($srcfile);
 488         my $page=pagename($file);
 489         $pagesources{$page}=$file;
 490         $content=filter($page, $page, $content);
 491         $content=preprocess($page, $page, $content);
 492         $content=linkify($page, $page, $content);
 493         $content=htmlize($page, $type, $content);
 494         $pagemtime{$page}=mtime($srcfile);
 495
 496         print genpage($page, $content);
 497         exit 0;
 498 } #}}}
 499
 500 1