IkiWiki/Plugin/bzr.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::bzr;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use open qw{:utf8 :std};
  10
  11 sub import {
  12         hook(type => "checkconfig", id => "bzr", call => \&checkconfig);
  13         hook(type => "getsetup", id => "bzr", call => \&getsetup);
  14         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  15         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  16         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  17         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  18         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  19         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  20         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  21         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  22         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  23         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  24         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  25 }
  26
  27 sub checkconfig () {
  28         if (defined $config{bzr_wrapper} && length $config{bzr_wrapper}) {
  29                 push @{$config{wrappers}}, {
  30                         wrapper => $config{bzr_wrapper},
  31                         wrappermode => (defined $config{bzr_wrappermode} ? $config{bzr_wrappermode} : "06755"),
  32                 };
  33         }
  34 }
  35
  36 sub getsetup () {
  37         return
  38                 plugin => {
  39                         safe => 0, # rcs plugin
  40                         rebuild => undef,
  41                         section => "rcs",
  42                 },
  43                 bzr_wrapper => {
  44                         type => "string",
  45                         #example => "", # FIXME add example
  46                         description => "bzr post-commit hook to generate",
  47                         safe => 0, # file
  48                         rebuild => 0,
  49                 },
  50                 bzr_wrappermode => {
  51                         type => "string",
  52                         example => '06755',
  53                         description => "mode for bzr_wrapper (can safely be made suid)",
  54                         safe => 0,
  55                         rebuild => 0,
  56                 },
  57                 historyurl => {
  58                         type => "string",
  59                         #example => "", # FIXME add example
  60                         description => "url to show file history, using loggerhead ([[file]] substituted)",
  61                         safe => 1,
  62                         rebuild => 1,
  63                 },
  64                 diffurl => {
  65                         type => "string",
  66                         example => "http://example.com/revision?start_revid=[[r2]]#[[file]]-s",
  67                         description => "url to view a diff, using loggerhead ([[file]] and [[r2]] substituted)",
  68                         safe => 1,
  69                         rebuild => 1,
  70                 },
  71 }
  72
  73 sub bzr_log ($) {
  74         my $out = shift;
  75         my @infos = ();
  76         my $key = undef;
  77
  78         my %info;
  79         while (<$out>) {
  80                 my $line = $_;
  81                 my ($value);
  82                 if ($line =~ /^message:/) {
  83                         $key = "message";
  84                         $info{$key} = "";
  85                 }
  86                 elsif ($line =~ /^(modified|added|renamed|renamed and modified|removed):/) {
  87                         $key = "files";
  88                         $info{$key} = "" unless defined $info{$key};
  89                 }
  90                 elsif (defined($key) and $line =~ /^  (.*)/) {
  91                         $info{$key} .= "$1\n";
  92                 }
  93                 elsif ($line eq "------------------------------------------------------------\n") {
  94                         push @infos, {%info} if keys %info;
  95                         %info = ();
  96                         $key = undef;
  97                 }
  98                 elsif ($line =~ /: /) {
  99                         chomp $line;
 100                         if ($line =~ /^revno: (\d+)/) {
 101                             $key = "revno";
 102                             $value = $1;
 103                         }
 104                         else {
 105                                 ($key, $value) = split /: +/, $line, 2;
 106                         }
 107                         $info{$key} = $value;
 108                 }
 109         }
 110         close $out;
 111         push @infos, {%info} if keys %info;
 112
 113         return @infos;
 114 }
 115
 116 sub rcs_update () {
 117         my @cmdline = ("bzr", "update", "--quiet", $config{srcdir});
 118         if (system(@cmdline) != 0) {
 119                 warn "'@cmdline' failed: $!";
 120         }
 121 }
 122
 123 sub rcs_prepedit ($) {
 124         return "";
 125 }
 126
 127 sub bzr_author ($) {
 128         my $session=shift;
 129
 130         return unless defined $session;
 131
 132         my $user=$session->param("name");
 133         my $ipaddr=$session->remote_addr();
 134
 135         if (defined $user) {
 136                 return IkiWiki::possibly_foolish_untaint($user);
 137         }
 138         elsif (defined $ipaddr) {
 139                 return "Anonymous from ".IkiWiki::possibly_foolish_untaint($ipaddr);
 140         }
 141         else {
 142                 return "Anonymous";
 143         }
 144 }
 145
 146 sub rcs_commit (@) {
 147         my %params=@_;
 148
 149         my $user=bzr_author($params{session});
 150
 151         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 152         if (! length $params{message}) {
 153                 $params{message} = "no message given";
 154         }
 155
 156         my @cmdline = ("bzr", "commit", "--quiet", "-m", $params{message},
 157                        (defined $user ? ("--author", $user) : ()),
 158                        $config{srcdir}."/".$params{file});
 159         if (system(@cmdline) != 0) {
 160                 warn "'@cmdline' failed: $!";
 161         }
 162
 163         return undef; # success
 164 }
 165
 166 sub rcs_commit_staged (@) {
 167         my %params=@_;
 168
 169         my $user=bzr_author($params{session});
 170
 171         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 172         if (! length $params{message}) {
 173                 $params{message} = "no message given";
 174         }
 175
 176         my @cmdline = ("bzr", "commit", "--quiet", "-m", $params{message},
 177                        (defined $user ? ("--author", $user) : ()),
 178                        $config{srcdir});
 179         if (system(@cmdline) != 0) {
 180                 warn "'@cmdline' failed: $!";
 181         }
 182
 183         return undef; # success
 184 }
 185
 186 sub rcs_add ($) {
 187         my ($file) = @_;
 188
 189         my @cmdline = ("bzr", "add", "--quiet", "$config{srcdir}/$file");
 190         if (system(@cmdline) != 0) {
 191                 warn "'@cmdline' failed: $!";
 192         }
 193 }
 194
 195 sub rcs_remove ($) {
 196         my ($file) = @_;
 197
 198         my @cmdline = ("bzr", "rm", "--quiet", "$config{srcdir}/$file");
 199         if (system(@cmdline) != 0) {
 200                 warn "'@cmdline' failed: $!";
 201         }
 202 }
 203
 204 sub rcs_rename ($$) {
 205         my ($src, $dest) = @_;
 206
 207         my $parent = IkiWiki::dirname($dest);
 208         if (system("bzr", "add", "--quiet", "$config{srcdir}/$parent") != 0) {
 209                 warn("bzr add $parent failed\n");
 210         }
 211
 212         my @cmdline = ("bzr", "mv", "--quiet", "$config{srcdir}/$src", "$config{srcdir}/$dest");
 213         if (system(@cmdline) != 0) {
 214                 warn "'@cmdline' failed: $!";
 215         }
 216 }
 217
 218 sub rcs_recentchanges ($) {
 219         my ($num) = @_;
 220
 221         my @cmdline = ("bzr", "log", "-v", "--show-ids", "--limit", $num,
 222                            $config{srcdir});
 223         open (my $out, "@cmdline |");
 224
 225         eval q{use Date::Parse};
 226         error($@) if $@;
 227
 228         my @ret;
 229         foreach my $info (bzr_log($out)) {
 230                 my @pages = ();
 231                 my @message = ();
 232
 233                 foreach my $msgline (split(/\n/, $info->{message})) {
 234                         push @message, { line => $msgline };
 235                 }
 236
 237                 foreach my $file (split(/\n/, $info->{files})) {
 238                         my ($filename, $fileid) = ($file =~ /^(.*?) +([^ ]+)$/);
 239
 240                         # Skip directories
 241                         next if ($filename =~ /\/$/);
 242
 243                         # Skip source name in renames
 244                         $filename =~ s/^.* => //;
 245
 246                         my $efilename = uri_escape_utf8($filename);
 247
 248                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 249                         $diffurl =~ s/\[\[file\]\]/$efilename/go;
 250                         $diffurl =~ s/\[\[file-id\]\]/$fileid/go;
 251                         $diffurl =~ s/\[\[r2\]\]/$info->{revno}/go;
 252
 253                         push @pages, {
 254                                 page => pagename($filename),
 255                                 diffurl => $diffurl,
 256                         };
 257                 }
 258
 259                 my $user = $info->{"committer"};
 260                 if (defined($info->{"author"})) { $user = $info->{"author"}; }
 261                 $user =~ s/\s*<.*>\s*$//;
 262                 $user =~ s/^\s*//;
 263
 264                 push @ret, {
 265                         rev        => $info->{"revno"},
 266                         user       => $user,
 267                         committype => "bzr",
 268                         when       => str2time($info->{"timestamp"}),
 269                         message    => [@message],
 270                         pages      => [@pages],
 271                 };
 272         }
 273
 274         return @ret;
 275 }
 276
 277 sub rcs_diff ($;$) {
 278         my $taintedrev=shift;
 279         my $maxlines=shift;
 280         my ($rev) = $taintedrev =~ /^(\d+(\.\d+)*)$/; # untaint
 281
 282         my $prevspec = "before:" . $rev;
 283         my $revspec = "revno:" . $rev;
 284         my @cmdline = ("bzr", "diff", "--old", $config{srcdir},
 285                 "--new", $config{srcdir},
 286                 "-r", $prevspec . ".." . $revspec);
 287         open (my $out, "@cmdline |");
 288         my @lines;
 289         while (my $line=<$out>) {
 290                 last if defined $maxlines && @lines == $maxlines;
 291                 push @lines, $line;
 292         }
 293         if (wantarray) {
 294                 return @lines;
 295         }
 296         else {
 297                 return join("", @lines);
 298         }
 299 }
 300
 301 sub extract_timestamp (@) {
 302         open (my $out, "-|", @_);
 303         my @log = bzr_log($out);
 304
 305         if (length(scalar(@log)) < 1) {
 306                 return 0;
 307         }
 308
 309         eval q{use Date::Parse};
 310         error($@) if $@;
 311
 312         my $time = str2time($log[0]->{"timestamp"});
 313         return $time;
 314 }
 315
 316 sub rcs_getctime ($) {
 317         my ($file) = @_;
 318
 319         my @cmdline = ("bzr", "log", "--forward", "--limit", '1', "$config{srcdir}/$file");
 320         return extract_timestamp(@cmdline);
 321 }
 322
 323 sub rcs_getmtime ($) {
 324         my ($file) = @_;
 325
 326         my @cmdline = ("bzr", "log", "--limit", '1', "$config{srcdir}/$file");
 327         return extract_timestamp(@cmdline);
 328 }
 329
 330 1