IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8
   9 my %meta;
  10 my %title;
  11 my %permalink;
  12 my %author;
  13 my %authorurl;
  14
  15 sub import { #{{{
  16         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  17         hook(type => "filter", id => "meta", call => \&filter);
  18         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  19 } # }}}
  20
  21 sub filter (@) { #{{{
  22         my %params=@_;
  23
  24         $meta{$params{page}}='';
  25
  26         return $params{content};
  27 } # }}}
  28
  29 sub scrub ($) { #{{{
  30         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  31                 return IkiWiki::Plugin::htmlscrubber::sanitize(content => shift);
  32         }
  33         else {
  34                 return shift;
  35         }
  36 } #}}}
  37
  38 sub preprocess (@) { #{{{
  39         if (! @_) {
  40                 return "";
  41         }
  42         my %params=@_;
  43         my $key=shift;
  44         my $value=$params{$key};
  45         delete $params{$key};
  46         my $page=$params{page};
  47         delete $params{page};
  48         delete $params{destpage};
  49
  50         eval q{use HTML::Entities};
  51         # Always dencode, even if encoding later, since it might not be
  52         # fully encoded.
  53         $value=decode_entities($value);
  54
  55         if ($key eq 'link') {
  56                 if (%params) {
  57                         $meta{$page}.=scrub("<link href=\"".encode_entities($value)."\" ".
  58                                 join(" ", map { encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\"" } keys %params).
  59                                 " />\n");
  60                 }
  61                 else {
  62                         # hidden WikiLink
  63                         push @{$links{$page}}, $value;
  64                 }
  65         }
  66         elsif ($key eq 'title') {
  67                 $title{$page}=encode_entities($value);
  68         }
  69         elsif ($key eq 'permalink') {
  70                 $permalink{$page}=$value;
  71                 $meta{$page}.=scrub("<link rel=\"bookmark\" href=\"".encode_entities($value)."\" />\n");
  72         }
  73         elsif ($key eq 'stylesheet') {
  74                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
  75                 my $title=exists $params{title} ? $params{title} : $value;
  76                 # adding .css to the value prevents using any old web
  77                 # editable page as a stylesheet
  78                 my $stylesheet=bestlink($page, $value.".css");
  79                 if (! length $stylesheet) {
  80                         return "[[meta ".gettext("stylesheet not found")."]]";
  81                 }
  82                 $meta{$page}.='<link href="'.$stylesheet.
  83                         '" rel="'.encode_entities($rel).
  84                         '" title="'.encode_entities($title).
  85                         "\" style=\"text/css\" />\n";
  86         }
  87         elsif ($key eq 'openid') {
  88                 if (exists $params{server}) {
  89                         $meta{$page}.='<link href="'.encode_entities($params{server}).
  90                                 "\" rel=\"openid.server\" />\n";
  91                 }
  92                 $meta{$page}.='<link href="'.encode_entities($value).
  93                         "\" rel=\"openid.delegate\" />\n";
  94         }
  95         else {
  96                 $meta{$page}.=scrub("<meta name=\"".encode_entities($key).
  97                         "\" content=\"".encode_entities($value)."\" />\n");
  98                 if ($key eq 'author') {
  99                         $author{$page}=$value;
 100                 }
 101                 elsif ($key eq 'authorurl') {
 102                         $authorurl{$page}=$value;
 103                 }
 104         }
 105
 106         return "";
 107 } # }}}
 108
 109 sub pagetemplate (@) { #{{{
 110         my %params=@_;
 111         my $page=$params{page};
 112         my $template=$params{template};
 113
 114         $template->param(meta => $meta{$page})
 115                 if exists $meta{$page} && $template->query(name => "meta");
 116         if (exists $title{$page} && $template->query(name => "title")) {
 117                 $template->param(title => $title{$page});
 118                 $template->param(title_overridden => 1);
 119         }
 120         $template->param(permalink => $permalink{$page})
 121                 if exists $permalink{$page} && $template->query(name => "permalink");
 122         $template->param(author => $author{$page})
 123                 if exists $author{$page} && $template->query(name => "author");
 124         $template->param(authorurl => $authorurl{$page})
 125                 if exists $authorurl{$page} && $template->query(name => "authorurl");
 126
 127 } # }}}
 128
 129 1