IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild $gettext_obj};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render gettext
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version, next is ikiwiki version
  20 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  21 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  22
  23 # Optimisation.
  24 use Memoize;
  25 memoize("abs2rel");
  26 memoize("pagespec_translate");
  27 memoize("file_pruned");
  28
  29 sub defaultconfig () { #{{{
  30         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./,
  31                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  32                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//],
  33         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  34         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  35         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  36         verbose => 0,
  37         syslog => 0,
  38         wikiname => "wiki",
  39         default_pageext => "mdwn",
  40         cgi => 0,
  41         rcs => '',
  42         notify => 0,
  43         url => '',
  44         cgiurl => '',
  45         historyurl => '',
  46         diffurl => '',
  47         rss => 0,
  48         atom => 0,
  49         discussion => 1,
  50         rebuild => 0,
  51         refresh => 0,
  52         getctime => 0,
  53         w3mmode => 0,
  54         wrapper => undef,
  55         wrappermode => undef,
  56         svnrepo => undef,
  57         svnpath => "trunk",
  58         gitorigin_branch => "origin",
  59         gitmaster_branch => "master",
  60         srcdir => undef,
  61         destdir => undef,
  62         pingurl => [],
  63         templatedir => "$installdir/share/ikiwiki/templates",
  64         underlaydir => "$installdir/share/ikiwiki/basewiki",
  65         setup => undef,
  66         adminuser => undef,
  67         adminemail => undef,
  68         plugin => [qw{mdwn inline htmlscrubber passwordauth signinedit
  69                       lockedit conditional}],
  70         timeformat => '%c',
  71         locale => undef,
  72         sslcookie => 0,
  73         httpauth => 0,
  74         userdir => "",
  75 } #}}}
  76
  77 sub checkconfig () { #{{{
  78         # locale stuff; avoid LC_ALL since it overrides everything
  79         if (defined $ENV{LC_ALL}) {
  80                 $ENV{LANG} = $ENV{LC_ALL};
  81                 delete $ENV{LC_ALL};
  82         }
  83         if (defined $config{locale}) {
  84                 eval q{use POSIX};
  85                 error($@) if $@;
  86                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
  87                         $ENV{LANG}=$config{locale};
  88                         $gettext_obj=undef;
  89                 }
  90         }
  91
  92         if ($config{w3mmode}) {
  93                 eval q{use Cwd q{abs_path}};
  94                 error($@) if $@;
  95                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  96                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  97                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  98                         unless $config{cgiurl} =~ m!file:///!;
  99                 $config{url}="file://".$config{destdir};
 100         }
 101
 102         if ($config{cgi} && ! length $config{url}) {
 103                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 104         }
 105
 106         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 107                 unless exists $config{wikistatedir};
 108
 109         if ($config{rcs}) {
 110                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 111                 if ($@) {
 112                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 113                 }
 114         }
 115         else {
 116                 require IkiWiki::Rcs::Stub;
 117         }
 118
 119         run_hooks(checkconfig => sub { shift->() });
 120 } #}}}
 121
 122 sub loadplugins () { #{{{
 123         loadplugin($_) foreach @{$config{plugin}};
 124
 125         run_hooks(getopt => sub { shift->() });
 126         if (grep /^-/, @ARGV) {
 127                 print STDERR "Unknown option: $_\n"
 128                         foreach grep /^-/, @ARGV;
 129                 usage();
 130         }
 131 } #}}}
 132
 133 sub loadplugin ($) { #{{{
 134         my $plugin=shift;
 135
 136         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 137
 138         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 139         eval qq{use $mod};
 140         if ($@) {
 141                 error("Failed to load plugin $mod: $@");
 142         }
 143 } #}}}
 144
 145 sub error ($;$) { #{{{
 146         my $message=shift;
 147         my $cleaner=shift;
 148         if ($config{cgi}) {
 149                 print "Content-type: text/html\n\n";
 150                 print misctemplate(gettext("Error"),
 151                         "<p>".gettext("Error").": $message</p>");
 152         }
 153         log_message(debug => $message) if $config{syslog};
 154         if (defined $cleaner) {
 155                 $cleaner->();
 156         }
 157         die $message."\n";
 158 } #}}}
 159
 160 sub debug ($) { #{{{
 161         return unless $config{verbose};
 162         log_message(debug => @_);
 163 } #}}}
 164
 165 my $log_open=0;
 166 sub log_message ($$) { #{{{
 167         my $type=shift;
 168
 169         if ($config{syslog}) {
 170                 require Sys::Syslog;
 171                 unless ($log_open) {
 172                         Sys::Syslog::setlogsock('unix');
 173                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 174                         $log_open=1;
 175                 }
 176                 eval {
 177                         Sys::Syslog::syslog($type, "%s", join(" ", @_));
 178                 }
 179         }
 180         elsif (! $config{cgi}) {
 181                 print "@_\n";
 182         }
 183         else {
 184                 print STDERR "@_\n";
 185         }
 186 } #}}}
 187
 188 sub possibly_foolish_untaint ($) { #{{{
 189         my $tainted=shift;
 190         my ($untainted)=$tainted=~/(.*)/;
 191         return $untainted;
 192 } #}}}
 193
 194 sub basename ($) { #{{{
 195         my $file=shift;
 196
 197         $file=~s!.*/+!!;
 198         return $file;
 199 } #}}}
 200
 201 sub dirname ($) { #{{{
 202         my $file=shift;
 203
 204         $file=~s!/*[^/]+$!!;
 205         return $file;
 206 } #}}}
 207
 208 sub pagetype ($) { #{{{
 209         my $page=shift;
 210
 211         if ($page =~ /\.([^.]+)$/) {
 212                 return $1 if exists $hooks{htmlize}{$1};
 213         }
 214         return undef;
 215 } #}}}
 216
 217 sub pagename ($) { #{{{
 218         my $file=shift;
 219
 220         my $type=pagetype($file);
 221         my $page=$file;
 222         $page=~s/\Q.$type\E*$// if defined $type;
 223         return $page;
 224 } #}}}
 225
 226 sub htmlpage ($) { #{{{
 227         my $page=shift;
 228
 229         return $page.".html";
 230 } #}}}
 231
 232 sub srcfile ($) { #{{{
 233         my $file=shift;
 234
 235         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 236         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 237         error("internal error: $file cannot be found");
 238 } #}}}
 239
 240 sub readfile ($;$$) { #{{{
 241         my $file=shift;
 242         my $binary=shift;
 243         my $wantfd=shift;
 244
 245         if (-l $file) {
 246                 error("cannot read a symlink ($file)");
 247         }
 248
 249         local $/=undef;
 250         open (IN, $file) || error("failed to read $file: $!");
 251         binmode(IN) if ($binary);
 252         return \*IN if $wantfd;
 253         my $ret=<IN>;
 254         close IN || error("failed to read $file: $!");
 255         return $ret;
 256 } #}}}
 257
 258 sub writefile ($$$;$$) { #{{{
 259         my $file=shift; # can include subdirs
 260         my $destdir=shift; # directory to put file in
 261         my $content=shift;
 262         my $binary=shift;
 263         my $writer=shift;
 264
 265         my $test=$file;
 266         while (length $test) {
 267                 if (-l "$destdir/$test") {
 268                         error("cannot write to a symlink ($test)");
 269                 }
 270                 $test=dirname($test);
 271         }
 272         my $newfile="$destdir/$file.ikiwiki-new";
 273         if (-l $newfile) {
 274                 error("cannot write to a symlink ($newfile)");
 275         }
 276
 277         my $dir=dirname($newfile);
 278         if (! -d $dir) {
 279                 my $d="";
 280                 foreach my $s (split(m!/+!, $dir)) {
 281                         $d.="$s/";
 282                         if (! -d $d) {
 283                                 mkdir($d) || error("failed to create directory $d: $!");
 284                         }
 285                 }
 286         }
 287
 288         my $cleanup = sub { unlink($newfile) };
 289         open (OUT, ">$newfile") || error("failed to write $newfile: $!", $cleanup);
 290         binmode(OUT) if ($binary);
 291         if ($writer) {
 292                 $writer->(\*OUT, $cleanup);
 293         }
 294         else {
 295                 print OUT $content || error("failed writing to $newfile: $!", $cleanup);
 296         }
 297         close OUT || error("failed saving $newfile: $!", $cleanup);
 298         rename($newfile, "$destdir/$file") ||
 299                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 300 } #}}}
 301
 302 my %cleared;
 303 sub will_render ($$;$) { #{{{
 304         my $page=shift;
 305         my $dest=shift;
 306         my $clear=shift;
 307
 308         # Important security check.
 309         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 310             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 311                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 312         }
 313
 314         if (! $clear || $cleared{$page}) {
 315                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 316         }
 317         else {
 318                 $renderedfiles{$page}=[$dest];
 319                 $cleared{$page}=1;
 320         }
 321 } #}}}
 322
 323 sub bestlink ($$) { #{{{
 324         my $page=shift;
 325         my $link=shift;
 326
 327         my $cwd=$page;
 328         if ($link=~s/^\/+//) {
 329                 # absolute links
 330                 $cwd="";
 331         }
 332
 333         do {
 334                 my $l=$cwd;
 335                 $l.="/" if length $l;
 336                 $l.=$link;
 337
 338                 if (exists $links{$l}) {
 339                         return $l;
 340                 }
 341                 elsif (exists $pagecase{lc $l}) {
 342                         return $pagecase{lc $l};
 343                 }
 344         } while $cwd=~s!/?[^/]+$!!;
 345
 346         if (length $config{userdir} && exists $links{"$config{userdir}/".lc($link)}) {
 347                 return "$config{userdir}/".lc($link);
 348         }
 349
 350         #print STDERR "warning: page $page, broken link: $link\n";
 351         return "";
 352 } #}}}
 353
 354 sub isinlinableimage ($) { #{{{
 355         my $file=shift;
 356
 357         $file=~/\.(png|gif|jpg|jpeg)$/i;
 358 } #}}}
 359
 360 sub pagetitle ($;$) { #{{{
 361         my $page=shift;
 362         my $unescaped=shift;
 363
 364         if ($unescaped) {
 365                 $page=~s/__(\d+)__/chr($1)/eg;
 366         }
 367         else {
 368                 $page=~s/__(\d+)__/&#$1;/g;
 369         }
 370         $page=~y/_/ /;
 371
 372         return $page;
 373 } #}}}
 374
 375 sub titlepage ($) { #{{{
 376         my $title=shift;
 377         $title=~y/ /_/;
 378         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 379         return $title;
 380 } #}}}
 381
 382 sub cgiurl (@) { #{{{
 383         my %params=@_;
 384
 385         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 386 } #}}}
 387
 388 sub baseurl (;$) { #{{{
 389         my $page=shift;
 390
 391         return "$config{url}/" if ! defined $page;
 392
 393         $page=~s/[^\/]+$//;
 394         $page=~s/[^\/]+\//..\//g;
 395         return $page;
 396 } #}}}
 397
 398 sub abs2rel ($$) { #{{{
 399         # Work around very innefficient behavior in File::Spec if abs2rel
 400         # is passed two relative paths. It's much faster if paths are
 401         # absolute! (Debian bug #376658; fixed in debian unstable now)
 402         my $path="/".shift;
 403         my $base="/".shift;
 404
 405         require File::Spec;
 406         my $ret=File::Spec->abs2rel($path, $base);
 407         $ret=~s/^// if defined $ret;
 408         return $ret;
 409 } #}}}
 410
 411 sub displaytime ($) { #{{{
 412         my $time=shift;
 413
 414         eval q{use POSIX};
 415         error($@) if $@;
 416         # strftime doesn't know about encodings, so make sure
 417         # its output is properly treated as utf8
 418         return decode_utf8(POSIX::strftime(
 419                         $config{timeformat}, localtime($time)));
 420 } #}}}
 421
 422 sub htmllink ($$$;$$$) { #{{{
 423         my $lpage=shift; # the page doing the linking
 424         my $page=shift; # the page that will contain the link (different for inline)
 425         my $link=shift;
 426         my $noimageinline=shift; # don't turn links into inline html images
 427         my $forcesubpage=shift; # force a link to a subpage
 428         my $linktext=shift; # set to force the link text to something
 429
 430         my $bestlink;
 431         if (! $forcesubpage) {
 432                 $bestlink=bestlink($lpage, $link);
 433         }
 434         else {
 435                 $bestlink="$lpage/".lc($link);
 436         }
 437
 438         $linktext=pagetitle(basename($link)) unless defined $linktext;
 439
 440         return "<span class=\"selflink\">$linktext</span>"
 441                 if length $bestlink && $page eq $bestlink;
 442
 443         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 444                 $bestlink=htmlpage($bestlink);
 445         }
 446         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 447                 return $linktext unless length $config{cgiurl};
 448                 return "<span><a href=\"".
 449                         cgiurl(do => "create", page => lc($link), from => $page).
 450                         "\">?</a>$linktext</span>"
 451         }
 452
 453         $bestlink=abs2rel($bestlink, dirname($page));
 454
 455         if (! $noimageinline && isinlinableimage($bestlink)) {
 456                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 457         }
 458
 459         return "<a href=\"$bestlink\">$linktext</a>";
 460 } #}}}
 461
 462 sub htmlize ($$$) { #{{{
 463         my $page=shift;
 464         my $type=shift;
 465         my $content=shift;
 466
 467         if (exists $hooks{htmlize}{$type}) {
 468                 $content=$hooks{htmlize}{$type}{call}->(
 469                         page => $page,
 470                         content => $content,
 471                 );
 472         }
 473         else {
 474                 error("htmlization of $type not supported");
 475         }
 476
 477         run_hooks(sanitize => sub {
 478                 $content=shift->(
 479                         page => $page,
 480                         content => $content,
 481                 );
 482         });
 483
 484         return $content;
 485 } #}}}
 486
 487 sub linkify ($$$) { #{{{
 488         my $lpage=shift; # the page containing the links
 489         my $page=shift; # the page the link will end up on (different for inline)
 490         my $content=shift;
 491
 492         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 493                 defined $2
 494                         ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 495                         : ( $1 ? "[[$3]]"    : htmllink($lpage, $page, titlepage($3)))
 496         }eg;
 497
 498         return $content;
 499 } #}}}
 500
 501 my %preprocessing;
 502 sub preprocess ($$$;$) { #{{{
 503         my $page=shift; # the page the data comes from
 504         my $destpage=shift; # the page the data will appear in (different for inline)
 505         my $content=shift;
 506         my $scan=shift;
 507
 508         my $handle=sub {
 509                 my $escape=shift;
 510                 my $command=shift;
 511                 my $params=shift;
 512                 if (length $escape) {
 513                         return "[[$command $params]]";
 514                 }
 515                 elsif (exists $hooks{preprocess}{$command}) {
 516                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 517                         # Note: preserve order of params, some plugins may
 518                         # consider it significant.
 519                         my @params;
 520                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 521                                 my $key=$1;
 522                                 my $val;
 523                                 if (defined $2) {
 524                                         $val=$2;
 525                                         $val=~s/\r\n/\n/mg;
 526                                         $val=~s/^\n+//g;
 527                                         $val=~s/\n+$//g;
 528                                 }
 529                                 elsif (defined $3) {
 530                                         $val=$3;
 531                                 }
 532                                 elsif (defined $4) {
 533                                         $val=$4;
 534                                 }
 535
 536                                 if (defined $key) {
 537                                         push @params, $key, $val;
 538                                 }
 539                                 else {
 540                                         push @params, $val, '';
 541                                 }
 542                         }
 543                         if ($preprocessing{$page}++ > 3) {
 544                                 # Avoid loops of preprocessed pages preprocessing
 545                                 # other pages that preprocess them, etc.
 546                                 #translators: The first parameter is a
 547                                 #translators: preprocessor directive name,
 548                                 #translators: the second a page name, the
 549                                 #translators: third a number.
 550                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 551                                         $command, $page, $preprocessing{$page}).
 552                                 "]]";
 553                         }
 554                         my $ret=$hooks{preprocess}{$command}{call}->(
 555                                 @params,
 556                                 page => $page,
 557                                 destpage => $destpage,
 558                         );
 559                         $preprocessing{$page}--;
 560                         return $ret;
 561                 }
 562                 else {
 563                         return "[[$command $params]]";
 564                 }
 565         };
 566
 567         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 568         return $content;
 569 } #}}}
 570
 571 sub filter ($$) { #{{{
 572         my $page=shift;
 573         my $content=shift;
 574
 575         run_hooks(filter => sub {
 576                 $content=shift->(page => $page, content => $content);
 577         });
 578
 579         return $content;
 580 } #}}}
 581
 582 sub indexlink () { #{{{
 583         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 584 } #}}}
 585
 586 sub lockwiki () { #{{{
 587         # Take an exclusive lock on the wiki to prevent multiple concurrent
 588         # run issues. The lock will be dropped on program exit.
 589         if (! -d $config{wikistatedir}) {
 590                 mkdir($config{wikistatedir});
 591         }
 592         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 593                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 594         if (! flock(WIKILOCK, 2 | 4)) {
 595                 debug("wiki seems to be locked, waiting for lock");
 596                 my $wait=600; # arbitrary, but don't hang forever to
 597                               # prevent process pileup
 598                 for (1..$wait) {
 599                         return if flock(WIKILOCK, 2 | 4);
 600                         sleep 1;
 601                 }
 602                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 603         }
 604 } #}}}
 605
 606 sub unlockwiki () { #{{{
 607         close WIKILOCK;
 608 } #}}}
 609
 610 sub loadindex () { #{{{
 611         open (IN, "$config{wikistatedir}/index") || return;
 612         while (<IN>) {
 613                 $_=possibly_foolish_untaint($_);
 614                 chomp;
 615                 my %items;
 616                 $items{link}=[];
 617                 $items{dest}=[];
 618                 foreach my $i (split(/ /, $_)) {
 619                         my ($item, $val)=split(/=/, $i, 2);
 620                         push @{$items{$item}}, decode_entities($val);
 621                 }
 622
 623                 next unless exists $items{src}; # skip bad lines for now
 624
 625                 my $page=pagename($items{src}[0]);
 626                 if (! $config{rebuild}) {
 627                         $pagesources{$page}=$items{src}[0];
 628                         $oldpagemtime{$page}=$items{mtime}[0];
 629                         $oldlinks{$page}=[@{$items{link}}];
 630                         $links{$page}=[@{$items{link}}];
 631                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 632                         $renderedfiles{$page}=[@{$items{dest}}];
 633                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 634                         $pagecase{lc $page}=$page;
 635                 }
 636                 $pagectime{$page}=$items{ctime}[0];
 637         }
 638         close IN;
 639 } #}}}
 640
 641 sub saveindex () { #{{{
 642         run_hooks(savestate => sub { shift->() });
 643
 644         if (! -d $config{wikistatedir}) {
 645                 mkdir($config{wikistatedir});
 646         }
 647         my $newfile="$config{wikistatedir}/index.new";
 648         my $cleanup = sub { unlink($newfile) };
 649         open (OUT, ">$newfile") || error("cannot write to $newfile: $!", $cleanup);
 650         foreach my $page (keys %oldpagemtime) {
 651                 next unless $oldpagemtime{$page};
 652                 my $line="mtime=$oldpagemtime{$page} ".
 653                         "ctime=$pagectime{$page} ".
 654                         "src=$pagesources{$page}";
 655                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 656                 my %count;
 657                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 658                 if (exists $depends{$page}) {
 659                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 660                 }
 661                 print OUT $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 662         }
 663         close OUT || error("failed saving to $newfile: $!", $cleanup);
 664         rename($newfile, "$config{wikistatedir}/index") ||
 665                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 666 } #}}}
 667
 668 sub template_file ($) { #{{{
 669         my $template=shift;
 670
 671         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 672                 return "$dir/$template" if -e "$dir/$template";
 673         }
 674         return undef;
 675 } #}}}
 676
 677 sub template_params (@) { #{{{
 678         my $filename=template_file(shift);
 679
 680         if (! defined $filename) {
 681                 return if wantarray;
 682                 return "";
 683         }
 684
 685         require HTML::Template;
 686         my @ret=(
 687                 filter => sub {
 688                         my $text_ref = shift;
 689                         $$text_ref=&Encode::decode_utf8($$text_ref);
 690                 },
 691                 filename => $filename,
 692                 loop_context_vars => 1,
 693                 die_on_bad_params => 0,
 694                 @_
 695         );
 696         return wantarray ? @ret : {@ret};
 697 } #}}}
 698
 699 sub template ($;@) { #{{{
 700         HTML::Template->new(template_params(@_));
 701 } #}}}
 702
 703 sub misctemplate ($$;@) { #{{{
 704         my $title=shift;
 705         my $pagebody=shift;
 706
 707         my $template=template("misc.tmpl");
 708         $template->param(
 709                 title => $title,
 710                 indexlink => indexlink(),
 711                 wikiname => $config{wikiname},
 712                 pagebody => $pagebody,
 713                 baseurl => baseurl(),
 714                 @_,
 715         );
 716         run_hooks(pagetemplate => sub {
 717                 shift->(page => "", destpage => "", template => $template);
 718         });
 719         return $template->output;
 720 }#}}}
 721
 722 sub hook (@) { # {{{
 723         my %param=@_;
 724
 725         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 726                 error "hook requires type, call, and id parameters";
 727         }
 728
 729         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 730
 731         $hooks{$param{type}}{$param{id}}=\%param;
 732 } # }}}
 733
 734 sub run_hooks ($$) { # {{{
 735         # Calls the given sub for each hook of the given type,
 736         # passing it the hook function to call.
 737         my $type=shift;
 738         my $sub=shift;
 739
 740         if (exists $hooks{$type}) {
 741                 my @deferred;
 742                 foreach my $id (keys %{$hooks{$type}}) {
 743                         if ($hooks{$type}{$id}{last}) {
 744                                 push @deferred, $id;
 745                                 next;
 746                         }
 747                         $sub->($hooks{$type}{$id}{call});
 748                 }
 749                 foreach my $id (@deferred) {
 750                         $sub->($hooks{$type}{$id}{call});
 751                 }
 752         }
 753 } #}}}
 754
 755 sub globlist_to_pagespec ($) { #{{{
 756         my @globlist=split(' ', shift);
 757
 758         my (@spec, @skip);
 759         foreach my $glob (@globlist) {
 760                 if ($glob=~/^!(.*)/) {
 761                         push @skip, $glob;
 762                 }
 763                 else {
 764                         push @spec, $glob;
 765                 }
 766         }
 767
 768         my $spec=join(" or ", @spec);
 769         if (@skip) {
 770                 my $skip=join(" and ", @skip);
 771                 if (length $spec) {
 772                         $spec="$skip and ($spec)";
 773                 }
 774                 else {
 775                         $spec=$skip;
 776                 }
 777         }
 778         return $spec;
 779 } #}}}
 780
 781 sub is_globlist ($) { #{{{
 782         my $s=shift;
 783         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 784 } #}}}
 785
 786 sub safequote ($) { #{{{
 787         my $s=shift;
 788         $s=~s/[{}]//g;
 789         return "q{$s}";
 790 } #}}}
 791
 792 sub add_depends ($$) { #{{{
 793         my $page=shift;
 794         my $pagespec=shift;
 795
 796         if (! exists $depends{$page}) {
 797                 $depends{$page}=$pagespec;
 798         }
 799         else {
 800                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 801         }
 802 } # }}}
 803
 804 sub file_pruned ($$) { #{{{
 805         require File::Spec;
 806         my $file=File::Spec->canonpath(shift);
 807         my $base=File::Spec->canonpath(shift);
 808         $file=~s#^\Q$base\E/*##;
 809
 810         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
 811         $file =~ m/$regexp/;
 812 } #}}}
 813
 814 sub gettext { #{{{
 815         # Only use gettext in the rare cases it's needed.
 816         if (exists $ENV{LANG} || exists $ENV{LC_ALL} || exists $ENV{LC_MESSAGES}) {
 817                 if (! $gettext_obj) {
 818                         $gettext_obj=eval q{
 819                                 use Locale::gettext q{textdomain};
 820                                 Locale::gettext->domain('ikiwiki')
 821                         };
 822                         if ($@) {
 823                                 print STDERR "$@";
 824                                 $gettext_obj=undef;
 825                                 return shift;
 826                         }
 827                 }
 828                 return $gettext_obj->get(shift);
 829         }
 830         else {
 831                 return shift;
 832         }
 833 } #}}}
 834
 835 sub pagespec_merge ($$) { #{{{
 836         my $a=shift;
 837         my $b=shift;
 838
 839         return $a if $a eq $b;
 840
 841         # Support for old-style GlobLists.
 842         if (is_globlist($a)) {
 843                 $a=globlist_to_pagespec($a);
 844         }
 845         if (is_globlist($b)) {
 846                 $b=globlist_to_pagespec($b);
 847         }
 848
 849         return "($a) or ($b)";
 850 } #}}}
 851
 852 sub pagespec_translate ($) { #{{{
 853         # This assumes that $page is in scope in the function
 854         # that evalulates the translated pagespec code.
 855         my $spec=shift;
 856
 857         # Support for old-style GlobLists.
 858         if (is_globlist($spec)) {
 859                 $spec=globlist_to_pagespec($spec);
 860         }
 861
 862         # Convert spec to perl code.
 863         my $code="";
 864         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 865                 my $word=$1;
 866                 if (lc $word eq "and") {
 867                         $code.=" &&";
 868                 }
 869                 elsif (lc $word eq "or") {
 870                         $code.=" ||";
 871                 }
 872                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 873                         $code.=" ".$word;
 874                 }
 875                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
 876                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
 877                                 $code.=" IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).")";
 878                         }
 879                         else {
 880                                 $code.=" 0";
 881                         }
 882                 }
 883                 else {
 884                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \$from)";
 885                 }
 886         }
 887
 888         return $code;
 889 } #}}}
 890
 891 sub pagespec_match ($$;$) { #{{{
 892         my $page=shift;
 893         my $spec=shift;
 894         my $from=shift;
 895
 896         return eval pagespec_translate($spec);
 897 } #}}}
 898
 899 package IkiWiki::PageSpec;
 900
 901 sub match_glob ($$$) { #{{{
 902         my $page=shift;
 903         my $glob=shift;
 904         my $from=shift;
 905         if (! defined $from){
 906                 $from = "";
 907         }
 908
 909         # relative matching
 910         if ($glob =~ m!^\./!) {
 911                 $from=~s!/?[^/]+$!!;
 912                 $glob=~s!^\./!!;
 913                 $glob="$from/$glob" if length $from;
 914         }
 915
 916         # turn glob into safe regexp
 917         $glob=quotemeta($glob);
 918         $glob=~s/\\\*/.*/g;
 919         $glob=~s/\\\?/./g;
 920
 921         return $page=~/^$glob$/i;
 922 } #}}}
 923
 924 sub match_link ($$) { #{{{
 925         my $page=shift;
 926         my $link=lc(shift);
 927
 928         my $links = $IkiWiki::links{$page} or return undef;
 929         foreach my $p (@$links) {
 930                 return 1 if lc $p eq $link;
 931         }
 932         return 0;
 933 } #}}}
 934
 935 sub match_backlink ($$) { #{{{
 936         match_link(pop, pop);
 937 } #}}}
 938
 939 sub match_created_before ($$) { #{{{
 940         my $page=shift;
 941         my $testpage=shift;
 942
 943         if (exists $IkiWiki::pagectime{$testpage}) {
 944                 return $IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage};
 945         }
 946         else {
 947                 return 0;
 948         }
 949 } #}}}
 950
 951 sub match_created_after ($$) { #{{{
 952         my $page=shift;
 953         my $testpage=shift;
 954
 955         if (exists $IkiWiki::pagectime{$testpage}) {
 956                 return $IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage};
 957         }
 958         else {
 959                 return 0;
 960         }
 961 } #}}}
 962
 963 sub match_creation_day ($$) { #{{{
 964         return ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift);
 965 } #}}}
 966
 967 sub match_creation_month ($$) { #{{{
 968         return ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift);
 969 } #}}}
 970
 971 sub match_creation_year ($$) { #{{{
 972         return ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift);
 973 } #}}}
 974
 975 1