ikiwiki-mass-rebuild

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4
   5 sub supplemental_groups {
   6         my $user=shift;
   7
   8         my @list;
   9         while (my @fields=getgrent()) {
  10                 if (grep { $_ eq $user } split(' ', $fields[3])) {
  11                         push @list, $fields[2];
  12                 }
  13         }
  14
  15         return @list;
  16 }
  17
  18 sub processline {
  19         my $user=shift;
  20         my $setup=shift;
  21
  22         if (! getpwnam("$user")) {
  23                 print STDERR "warning: user $user does not exist\n";
  24                 return
  25         }
  26         if (! -f "$setup") {
  27                 print STDERR "warning: $setup does not exist, skipping\n";
  28                 return;
  29         }
  30         print "Processing $setup as user $user ...\n";
  31         # su is not used because it passes arguments through the shell,
  32         # which is not safe for untrusted setup file names.
  33         defined(my $pid = fork) or die "Can’t fork: $!";
  34         if (! $pid) {
  35                 my ($uuid, $ugid) = (getpwnam($user))[2, 3];
  36                 my $grouplist=join(" ", $ugid, $ugid, supplemental_groups($user));
  37                 undef $!;
  38                 $)=$grouplist;
  39                 if ($!) {
  40                         die "failed to set egid $grouplist: $!";
  41                 }
  42                 $(=$ugid;
  43                 $<=$uuid;
  44                 $>=$uuid;
  45                 if ($< != $uuid || $> != $uuid || $( != $ugid) {
  46                         die "failed to drop permissions to $user";
  47                 }
  48                 %ENV=(
  49                         PATH => $ENV{PATH},
  50                         HOME => (getpwnam($user))[7],
  51                 );
  52                 exec("ikiwiki", "-setup", $setup, @ARGV);
  53                 die "failed to run ikiwiki: $!";
  54         }
  55         waitpid($pid,0);
  56         if ($?) {
  57                 print STDERR "Processing $setup as user $user failed with code $?\n";
  58         }
  59 }
  60
  61 sub processlist {
  62         my $file=shift;
  63         my $forceuser=shift;
  64
  65         my $list;
  66         open ($list, "<$file") || die "$file: $!";
  67         while (<$list>) {
  68                 chomp;
  69                 s/^\s+//;
  70                 s/\s+$//;
  71                 next if /^#/ || ! length;
  72
  73                 if (/^([^\s]+)\s+([^\s]+)$/) {
  74                         my $user=$1;
  75                         my $setup=$2;
  76                         if (defined $forceuser && $forceuser ne $user) {
  77                                 print STDERR "warning: in $file line $., attempt to set user to $user, but user forced to $forceuser. Skipping\n";
  78                         }
  79                         processline($user, $setup);
  80                 }
  81                 elsif (/^([^\s]+)$/) {
  82                         my $user=$1;
  83                         my $home=(getpwnam($user))[7];
  84                         if (defined $home && -d $home) {
  85                                 my $dotfile="$home/.ikiwiki/wikilist";
  86                                 if (-e $dotfile) {
  87                                         processlist($dotfile, $user);
  88                                 }
  89                         }
  90                 }
  91         }
  92         close $list;
  93 }
  94
  95 my $wikilist="/etc/ikiwiki/wikilist";
  96
  97 if (-e $wikilist) {
  98         processlist($wikilist);
  99 }
 100