IkiWiki/Rcs/tla.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use POSIX qw(setlocale LC_CTYPE);
   7
   8 package IkiWiki;
   9
  10 sub quiet_system (@) {
  11         # See Debian bug #385939.
  12         open (SAVEOUT, ">&STDOUT");
  13         close STDOUT;
  14         open (STDOUT, ">/dev/null");
  15         my $ret=system(@_);
  16         close STDOUT;
  17         open (STDOUT, ">&SAVEOUT");
  18         close SAVEOUT;
  19         return $ret;
  20 }
  21
  22 sub rcs_update () { #{{{
  23         if (-d "$config{srcdir}/{arch}") {
  24                 if (quiet_system("tla", "replay", "-d", $config{srcdir}) != 0) {
  25                         warn("tla replay failed\n");
  26                 }
  27         }
  28 } #}}}
  29
  30 sub rcs_prepedit ($) { #{{{
  31         my $file=shift;
  32
  33         if (-d "$config{srcdir}/{arch}") {
  34                 # For Arch, return the tree-id of archive when
  35                 # editing begins.
  36                 my $rev=`tla tree-id $config{srcdir}`;
  37                 return defined $rev ? $rev : "";
  38         }
  39 } #}}}
  40
  41 sub rcs_commit ($$$;$$) { #{{{
  42         my $file=shift;
  43         my $message=shift;
  44         my $rcstoken=shift;
  45         my $user=shift;
  46         my $ipaddr=shift;
  47
  48         if (defined $user) {
  49                 $message="web commit by $user".(length $message ? ": $message" : "");
  50         }
  51         elsif (defined $ipaddr) {
  52                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
  53         }
  54
  55         if (-d "$config{srcdir}/{arch}") {
  56                 # Check to see if the page has been changed by someone
  57                 # else since rcs_prepedit was called.
  58                 my ($oldrev)=$rcstoken=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
  59                 my $rev=`tla tree-id $config{srcdir}`;
  60                 if (defined $rev && defined $oldrev && $rev ne $oldrev) {
  61                         # Merge their changes into the file that we've
  62                         # changed.
  63                         if (quiet_system("tla", "update", "-d",
  64                                    "$config{srcdir}") != 0) {
  65                                 warn("tla update failed\n");
  66                         }
  67                 }
  68
  69                 if (quiet_system("tla", "commit",
  70                            "-L".possibly_foolish_untaint($message),
  71                            '-d', $config{srcdir}) != 0) {
  72                         my $conflict=readfile("$config{srcdir}/$file");
  73                         if (system("tla", "undo", "-n", "--quiet", "-d", "$config{srcdir}") != 0) {
  74                                 warn("tla undo failed\n");
  75                         }
  76                         return $conflict;
  77                 }
  78         }
  79         return undef # success
  80 } #}}}
  81
  82 sub rcs_add ($) { #{{{
  83         my $file=shift;
  84
  85         if (-d "$config{srcdir}/{arch}") {
  86                 if (quiet_system("tla", "add", "$config{srcdir}/$file") != 0) {
  87                         warn("tla add failed\n");
  88                 }
  89         }
  90 } #}}}
  91
  92 sub rcs_recentchanges ($) {
  93         my $num=shift;
  94         my @ret;
  95
  96         return unless -d "$config{srcdir}/{arch}";
  97
  98         eval q{use Date::Parse};
  99         error($@) if $@;
 100         eval q{use Mail::Header};
 101         error($@) if $@;
 102
 103         my $logs = `tla logs -d $config{srcdir}`;
 104         my @changesets = reverse split(/\n/, $logs);
 105
 106         for (my $i=0; $i<$num && $i<$#changesets; $i++) {
 107                 my ($change)=$changesets[$i]=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
 108
 109                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 110                 my $head = Mail::Header->new(\*LOG);
 111                 close(LOG);
 112
 113                 my $rev = $head->get("Revision");
 114                 my $summ = $head->get("Summary");
 115                 my $newfiles = $head->get("New-files");
 116                 my $modfiles = $head->get("Modified-files");
 117                 my $remfiles = $head->get("Removed-files");
 118                 my $user = $head->get("Creator");
 119
 120                 my @paths = grep { !/^(.*\/)?\.arch-ids\/.*\.id$/ }
 121                         split(/ /, "$newfiles $modfiles .arch-ids/fake.id");
 122
 123                 my $sdate = $head->get("Standard-date");
 124                 my $when = time - str2time($sdate, 'UTC');
 125
 126                 my $committype = "web";
 127                 if (defined $summ && $summ =~ /$config{web_commit_regexp}/) {
 128                         $user = defined $2 ? "$2" : "$3";
 129                         $summ = $4;
 130                 }
 131                 else {
 132                         $committype="tla";
 133                 }
 134
 135                 my @message;
 136                 push @message, { line => escapeHTML($summ) };
 137
 138                 my @pages;
 139
 140                 foreach my $file (@paths) {
 141                         my $diffurl=$config{diffurl};
 142                         $diffurl=~s/\[\[file\]\]/$file/g;
 143                         $diffurl=~s/\[\[rev\]\]/$change/g;
 144                         push @pages, {
 145                                 page => pagename($file),
 146                                 diffurl => $diffurl,
 147                         } if length $file;
 148                 }
 149                 push @ret, { rev => $change,
 150                         user => $user,
 151                         committype => $committype,
 152                         when => $when,
 153                         message => [@message],
 154                         pages => [@pages],
 155                 } if @pages;
 156
 157                 last if $i == $num;
 158         }
 159
 160         return @ret;
 161 }
 162
 163 sub rcs_notify () { #{{{
 164         # FIXME: Not set
 165         if (! exists $ENV{ARCH_VERSION}) {
 166                 error("ARCH_VERSION is not set, not running from tla post-commit hook, cannot send notifications");
 167         }
 168         my $rev=int(possibly_foolish_untaint($ENV{REV}));
 169
 170         eval q{use Mail::Header};
 171         error($@) if $@;
 172         open(LOG, $ENV{"ARCH_LOG"});
 173         my $head = Mail::Header->new(\*LOG);
 174         close(LOG);
 175
 176         my $user = $head->get("Creator");
 177
 178         my $newfiles = $head->get("New-files");
 179         my $modfiles = $head->get("Modified-files");
 180         my $remfiles = $head->get("Removed-files");
 181
 182         my @changed_pages = grep { !/(^.*\/)?\.arch-ids\/.*\.id$/ }
 183                 split(/ /, "$newfiles $modfiles $remfiles .arch-ids/fake.id");
 184
 185         require IkiWiki::UserInfo;
 186         send_commit_mails(
 187                 sub {
 188                         my $message = $head->get("Summary");
 189                         if ($message =~ /$config{web_commit_regexp}/) {
 190                                 $user=defined $2 ? "$2" : "$3";
 191                                 $message=$4;
 192                         }
 193                 },
 194                 sub {
 195                         my $logs = `tla logs -d $config{srcdir}`;
 196                         my @changesets = reverse split(/\n/, $logs);
 197                         my $i;
 198
 199                         for($i=0;$i<$#changesets;$i++) {
 200                                 last if $changesets[$i] eq $rev;
 201                         }
 202
 203                         my $revminusone = $changesets[$i+1];
 204                         `tla diff -d $ENV{ARCH_TREE_ROOT} $revminusone`;
 205                 }, $user, @changed_pages);
 206 } #}}}
 207
 208 sub rcs_getctime ($) { #{{{
 209         my $file=shift;
 210         eval q{use Date::Parse};
 211         error($@) if $@;
 212         eval q{use Mail::Header};
 213         error($@) if $@;
 214
 215         my $logs = `tla logs -d $config{srcdir}`;
 216         my @changesets = reverse split(/\n/, $logs);
 217         my $sdate;
 218
 219         for (my $i=0; $i<$#changesets; $i++) {
 220                 my $change = $changesets[$i];
 221
 222                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 223                 my $head = Mail::Header->new(\*LOG);
 224                 close(LOG);
 225
 226                 $sdate = $head->get("Standard-date");
 227                 my $newfiles = $head->get("New-files");
 228
 229                 my ($lastcreation) = grep {/^$file$/} split(/ /, "$newfiles");
 230                 last if defined($lastcreation);
 231         }
 232
 233         my $date=str2time($sdate, 'UTC');
 234         debug("found ctime ".localtime($date)." for $file");
 235         return $date;
 236 } #}}}
 237
 238 1