IkiWiki/Rcs/mercurial.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use Encode;
   7 use open qw{:utf8 :std};
   8
   9 package IkiWiki;
  10
  11 sub mercurial_log($) {
  12         my $out = shift;
  13         my @infos;
  14
  15         while (<$out>) {
  16                 my $line = $_;
  17                 my ($key, $value);
  18
  19                 if (/^description:/) {
  20                         $key = "description";
  21                         $value = "";
  22
  23                         # slurp everything as the description text
  24                         # until the next changeset
  25                         while (<$out>) {
  26                                 if (/^changeset: /) {
  27                                         $line = $_;
  28                                         last;
  29                                 }
  30
  31                                 $value .= $_;
  32                         }
  33
  34                         local $/ = "";
  35                         chomp $value;
  36                         $infos[$#infos]{$key} = $value;
  37                 }
  38
  39                 chomp $line;
  40                 ($key, $value) = split /: +/, $line, 2;
  41
  42                 if ($key eq "changeset") {
  43                         push @infos, {};
  44
  45                         # remove the revision index, which is strictly
  46                         # local to the repository
  47                         $value =~ s/^\d+://;
  48                 }
  49
  50                 $infos[$#infos]{$key} = $value;
  51         }
  52         close $out;
  53
  54         return @infos;
  55 }
  56
  57 sub rcs_update () { #{{{
  58         my @cmdline = ("hg", "-R", "$config{srcdir}", "update");
  59         if (system(@cmdline) != 0) {
  60                 warn "'@cmdline' failed: $!";
  61         }
  62 } #}}}
  63
  64 sub rcs_prepedit ($) { #{{{
  65         return "";
  66 } #}}}
  67
  68 sub rcs_commit ($$$;$$) { #{{{
  69         my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
  70
  71         if (defined $user) {
  72                 $user = possibly_foolish_untaint($user);
  73         }
  74         elsif (defined $ipaddr) {
  75                 $user = "Anonymous from $ipaddr";
  76         }
  77         else {
  78                 $user = "Anonymous";
  79         }
  80
  81         $message = possibly_foolish_untaint($message);
  82
  83         my @cmdline = ("hg", "-R", "$config{srcdir}", "commit",
  84                        "-m", "$message", "-u", "$user");
  85         if (system(@cmdline) != 0) {
  86                 warn "'@cmdline' failed: $!";
  87         }
  88
  89         return undef; # success
  90 } #}}}
  91
  92 sub rcs_add ($) { # {{{
  93         my ($file) = @_;
  94
  95         my @cmdline = ("hg", "-R", "$config{srcdir}", "add", "$file");
  96         if (system(@cmdline) != 0) {
  97                 warn "'@cmdline' failed: $!";
  98         }
  99 } #}}}
 100
 101 sub rcs_recentchanges ($) { #{{{
 102         my ($num) = @_;
 103
 104         eval q{use CGI 'escapeHTML'};
 105         error($@) if $@;
 106
 107         my @cmdline = ("hg", "-R", $config{srcdir}, "log", "-v", "-l", $num);
 108         open (my $out, "@cmdline |");
 109
 110         eval q{use Date::Parse};
 111         error($@) if $@;
 112
 113         my @ret;
 114         foreach my $info (mercurial_log($out)) {
 115                 my @pages = ();
 116                 my @message = ();
 117
 118                 foreach my $msgline (split(/\n/, $info->{description})) {
 119                         push @message, { line => $msgline };
 120                 }
 121
 122                 foreach my $file (split / /,$info->{files}) {
 123                         my $diffurl = $config{'diffurl'};
 124                         $diffurl =~ s/\[\[file\]\]/$file/go;
 125                         $diffurl =~ s/\[\[r2\]\]/$info->{changeset}/go;
 126
 127                         push @pages, {
 128                                 page => pagename($file),
 129                                 diffurl => $diffurl,
 130                         };
 131                 }
 132
 133                 my $user = $info->{"user"};
 134                 $user =~ s/\s*<.*>\s*$//;
 135                 $user =~ s/^\s*//;
 136
 137                 push @ret, {
 138                         rev        => $info->{"changeset"},
 139                         user       => $user,
 140                         committype => "mercurial",
 141                         when       => str2time($info->{"date"}),
 142                         message    => [@message],
 143                         pages      => [@pages],
 144                 };
 145         }
 146
 147         return @ret;
 148 } #}}}
 149
 150 sub rcs_notify () { #{{{
 151         # TODO
 152 } #}}}
 153
 154 sub rcs_getctime ($) { #{{{
 155         my ($file) = @_;
 156
 157         # XXX filename passes through the shell here, should try to avoid
 158         # that just in case
 159         my @cmdline = ("hg", "-R", $config{srcdir}, "log", "-v", "-l", '1', $file);
 160         open (my $out, "@cmdline |");
 161
 162         my @log = mercurial_log($out);
 163
 164         if (length @log < 1) {
 165                 return 0;
 166         }
 167
 168         eval q{use Date::Parse};
 169         error($@) if $@;
 170
 171         my $ctime = str2time($log[0]->{"date"});
 172         return $ctime;
 173 } #}}}
 174
 175 1