IkiWiki/Plugin/pagestats.pm

   1 #!/usr/bin/perl
   2 #
   3 # Produce page statistics in various forms.
   4 #
   5 # Currently supported:
   6 #   cloud: produces statistics in the form of a del.icio.us-style tag cloud
   7 #          (default)
   8 #   table: produces a table with the number of backlinks for each page
   9 #
  10 # by Enrico Zini
  11 package IkiWiki::Plugin::pagestats;
  12
  13 use warnings;
  14 use strict;
  15 use IkiWiki 3.00;
  16
  17 # Names of the HTML classes to use for the tag cloud
  18 our @classes = ('smallestPC', 'smallPC', 'normalPC', 'bigPC', 'biggestPC' );
  19
  20 sub import {
  21         hook(type => "getsetup", id => "pagestats", call => \&getsetup);
  22         hook(type => "preprocess", id => "pagestats", call => \&preprocess);
  23 }
  24
  25 sub getsetup () {
  26         return
  27                 plugin => {
  28                         safe => 1,
  29                         rebuild => undef,
  30                         section => "widget",
  31                 },
  32 }
  33
  34 sub linktext ($%) {
  35         # Return the text of the link to a tag, depending on option linktext.
  36         my ($page, %params) = @_;
  37         if (exists $params{show} &&
  38                 exists $pagestate{$page} &&
  39                 exists $pagestate{$page}{meta}{$params{show}}) {
  40                 return $pagestate{$page}{meta}{$params{show}};
  41         }
  42         else {
  43                 return undef;
  44         }
  45 }
  46
  47 sub preprocess (@) {
  48         my %params=@_;
  49         $params{pages}="*" unless defined $params{pages};
  50         my $style = ($params{style} or 'cloud');
  51
  52         # Backwards compatibility
  53         if (defined $params{show} && $params{show} =~ m/^\d+$/) {
  54                 $params{limit} = $params{show};
  55                 delete $params{show};
  56         }
  57
  58         my %counts;
  59         my $max = 0;
  60         foreach my $page (pagespec_match_list($params{page}, $params{pages},
  61                                   # update when a displayed page is added/removed
  62                                   deptype => deptype("presence"))) {
  63                 use IkiWiki::Render;
  64
  65                 my @backlinks = IkiWiki::backlink_pages($page);
  66
  67                 if (exists $params{among}) {
  68                         # only consider backlinks from the amoung pages
  69                         @backlinks = pagespec_match_list(
  70                                 $params{page}, $params{among},
  71                                 # update whenever links on those pages change
  72                                 deptype => deptype("links"),
  73                                 list => \@backlinks
  74                         );
  75                 }
  76                 else {
  77                         # update when any page with links changes,
  78                         # in case the links point to our displayed pages
  79                         add_depends($params{page}, "*", deptype("links"));
  80                 }
  81
  82                 $counts{$page} = scalar(@backlinks);
  83                 $max = $counts{$page} if $counts{$page} > $max;
  84         }
  85
  86         if (exists $params{limit}) {
  87                 my $i=0;
  88                 my %show;
  89                 foreach my $key (sort { $counts{$b} <=> $counts{$a} } keys %counts) {
  90                         last if ++$i > $params{limit};
  91                         $show{$key}=$counts{$key};
  92                 }
  93                 %counts=%show;
  94         }
  95
  96         if ($style eq 'table') {
  97                 return "<table class='".(exists $params{class} ? $params{class} : "pageStats")."'>\n".
  98                         join("\n", map {
  99                                 "<tr><td>".
 100                                 htmllink($params{page}, $params{destpage}, $_, noimageinline => 1, linktext => linktext($_, %params)).
 101                                 "</td><td>".$counts{$_}."</td></tr>"
 102                         }
 103                         sort { $counts{$b} <=> $counts{$a} } keys %counts).
 104                         "\n</table>\n" ;
 105         }
 106         else {
 107                 # In case of misspelling, default to a page cloud
 108
 109                 my $res;
 110                 if ($style eq 'list') {
 111                         $res = "<ul class='".(exists $params{class} ? $params{class} : "list")."'>\n";
 112                 }
 113                 else {
 114                         $res = "<div class='".(exists $params{class} ? $params{class} : "pagecloud")."'>\n";
 115                 }
 116                 foreach my $page (sort keys %counts) {
 117                         next unless $counts{$page} > 0;
 118
 119                         my $class = $classes[$counts{$page} * scalar(@classes) / ($max + 1)];
 120
 121                         $res.="<li>" if $style eq 'list';
 122                         $res .= "<span class=\"$class\">".
 123                                                         htmllink($params{page}, $params{destpage}, $page, linktext => linktext($page, %params)).
 124                                 "</span>\n";
 125                         $res.="</li>" if $style eq 'list';
 126
 127                 }
 128                 if ($style eq 'list') {
 129                         $res .= "</ul>\n";
 130                 }
 131                 else {
 132                         $res .= "</div>\n";
 133                 }
 134
 135                 return $res;
 136         }
 137 }
 138
 139 1