IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use Fcntl q{:flock};
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX ();
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15         %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16         %pagesources %delpagesources %destsources %depends %depends_simple
  17         @mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
  18         %oldtypedlinks %autofiles @underlayfiles $lastrev $phase};
  19
  20 use Exporter q{import};
  21 our @EXPORT = qw(hook debug error htmlpage template template_depends
  22         deptype add_depends pagespec_match pagespec_match_list bestlink
  23         htmllink readfile writefile pagetype srcfile pagename
  24         displaytime strftime_utf8 will_render gettext ngettext urlto targetpage
  25         add_underlay pagetitle titlepage linkpage newpagefile
  26         inject add_link add_autofile useragent
  27         %config %links %pagestate %wikistate %renderedfiles
  28         %pagesources %destsources %typedlinks);
  29 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  30 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  31 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  32
  33 # Page dependency types.
  34 our $DEPEND_CONTENT=1;
  35 our $DEPEND_PRESENCE=2;
  36 our $DEPEND_LINKS=4;
  37
  38 # Phases of processing.
  39 sub PHASE_SCAN () { 0 }
  40 sub PHASE_RENDER () { 1 }
  41 $phase = PHASE_SCAN;
  42
  43 # Optimisation.
  44 use Memoize;
  45 memoize("abs2rel");
  46 memoize("sortspec_translate");
  47 memoize("pagespec_translate");
  48 memoize("template_file");
  49
  50 sub getsetup () {
  51         wikiname => {
  52                 type => "string",
  53                 default => "wiki",
  54                 description => "name of the wiki",
  55                 safe => 1,
  56                 rebuild => 1,
  57         },
  58         adminemail => {
  59                 type => "string",
  60                 default => undef,
  61                 example => 'me@example.com',
  62                 description => "contact email for wiki",
  63                 safe => 1,
  64                 rebuild => 0,
  65         },
  66         adminuser => {
  67                 type => "string",
  68                 default => [],
  69                 description => "users who are wiki admins",
  70                 safe => 1,
  71                 rebuild => 0,
  72         },
  73         banned_users => {
  74                 type => "string",
  75                 default => [],
  76                 description => "users who are banned from the wiki",
  77                 safe => 1,
  78                 rebuild => 0,
  79         },
  80         srcdir => {
  81                 type => "string",
  82                 default => undef,
  83                 example => "$ENV{HOME}/wiki",
  84                 description => "where the source of the wiki is located",
  85                 safe => 0, # path
  86                 rebuild => 1,
  87         },
  88         destdir => {
  89                 type => "string",
  90                 default => undef,
  91                 example => "/var/www/wiki",
  92                 description => "where to build the wiki",
  93                 safe => 0, # path
  94                 rebuild => 1,
  95         },
  96         url => {
  97                 type => "string",
  98                 default => '',
  99                 example => "http://example.com/wiki",
 100                 description => "base url to the wiki",
 101                 safe => 1,
 102                 rebuild => 1,
 103         },
 104         cgiurl => {
 105                 type => "string",
 106                 default => '',
 107                 example => "http://example.com/wiki/ikiwiki.cgi",
 108                 description => "url to the ikiwiki.cgi",
 109                 safe => 1,
 110                 rebuild => 1,
 111         },
 112         reverse_proxy => {
 113                 type => "boolean",
 114                 default => 0,
 115                 description => "do not adjust cgiurl if CGI is accessed via different URL",
 116                 advanced => 0,
 117                 safe => 1,
 118                 rebuild => 0, # only affects CGI requests
 119         },
 120         cgi_wrapper => {
 121                 type => "string",
 122                 default => '',
 123                 example => "/var/www/wiki/ikiwiki.cgi",
 124                 description => "filename of cgi wrapper to generate",
 125                 safe => 0, # file
 126                 rebuild => 0,
 127         },
 128         cgi_wrappermode => {
 129                 type => "string",
 130                 default => '06755',
 131                 description => "mode for cgi_wrapper (can safely be made suid)",
 132                 safe => 0,
 133                 rebuild => 0,
 134         },
 135         cgi_overload_delay => {
 136                 type => "string",
 137                 default => '',
 138                 example => "10",
 139                 description => "number of seconds to delay CGI requests when overloaded",
 140                 safe => 1,
 141                 rebuild => 0,
 142         },
 143         cgi_overload_message => {
 144                 type => "string",
 145                 default => '',
 146                 example => "Please wait",
 147                 description => "message to display when overloaded (may contain html)",
 148                 safe => 1,
 149                 rebuild => 0,
 150         },
 151         only_committed_changes => {
 152                 type => "boolean",
 153                 default => 0,
 154                 description => "enable optimization of only refreshing committed changes?",
 155                 safe => 1,
 156                 rebuild => 0,
 157         },
 158         rcs => {
 159                 type => "string",
 160                 default => '',
 161                 description => "rcs backend to use",
 162                 safe => 0, # don't allow overriding
 163                 rebuild => 0,
 164         },
 165         default_plugins => {
 166                 type => "internal",
 167                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 168                                 openid signinedit lockedit conditional
 169                                 recentchanges parentlinks editpage
 170                                 templatebody}],
 171                 description => "plugins to enable by default",
 172                 safe => 0,
 173                 rebuild => 1,
 174         },
 175         add_plugins => {
 176                 type => "string",
 177                 default => [],
 178                 description => "plugins to add to the default configuration",
 179                 safe => 1,
 180                 rebuild => 1,
 181         },
 182         disable_plugins => {
 183                 type => "string",
 184                 default => [],
 185                 description => "plugins to disable",
 186                 safe => 1,
 187                 rebuild => 1,
 188         },
 189         templatedir => {
 190                 type => "string",
 191                 default => "$installdir/share/ikiwiki/templates",
 192                 description => "additional directory to search for template files",
 193                 advanced => 1,
 194                 safe => 0, # path
 195                 rebuild => 1,
 196         },
 197         underlaydir => {
 198                 type => "string",
 199                 default => "$installdir/share/ikiwiki/basewiki",
 200                 description => "base wiki source location",
 201                 advanced => 1,
 202                 safe => 0, # path
 203                 rebuild => 0,
 204         },
 205         underlaydirbase => {
 206                 type => "internal",
 207                 default => "$installdir/share/ikiwiki",
 208                 description => "parent directory containing additional underlays",
 209                 safe => 0,
 210                 rebuild => 0,
 211         },
 212         wrappers => {
 213                 type => "internal",
 214                 default => [],
 215                 description => "wrappers to generate",
 216                 safe => 0,
 217                 rebuild => 0,
 218         },
 219         underlaydirs => {
 220                 type => "internal",
 221                 default => [],
 222                 description => "additional underlays to use",
 223                 safe => 0,
 224                 rebuild => 0,
 225         },
 226         verbose => {
 227                 type => "boolean",
 228                 example => 1,
 229                 description => "display verbose messages?",
 230                 safe => 1,
 231                 rebuild => 0,
 232         },
 233         syslog => {
 234                 type => "boolean",
 235                 example => 1,
 236                 description => "log to syslog?",
 237                 safe => 1,
 238                 rebuild => 0,
 239         },
 240         usedirs => {
 241                 type => "boolean",
 242                 default => 1,
 243                 description => "create output files named page/index.html?",
 244                 safe => 0, # changing requires manual transition
 245                 rebuild => 1,
 246         },
 247         prefix_directives => {
 248                 type => "boolean",
 249                 default => 1,
 250                 description => "use '!'-prefixed preprocessor directives?",
 251                 safe => 0, # changing requires manual transition
 252                 rebuild => 1,
 253         },
 254         indexpages => {
 255                 type => "boolean",
 256                 default => 0,
 257                 description => "use page/index.mdwn source files",
 258                 safe => 1,
 259                 rebuild => 1,
 260         },
 261         discussion => {
 262                 type => "boolean",
 263                 default => 1,
 264                 description => "enable Discussion pages?",
 265                 safe => 1,
 266                 rebuild => 1,
 267         },
 268         discussionpage => {
 269                 type => "string",
 270                 default => gettext("Discussion"),
 271                 description => "name of Discussion pages",
 272                 safe => 1,
 273                 rebuild => 1,
 274         },
 275         html5 => {
 276                 type => "boolean",
 277                 default => 0,
 278                 description => "use elements new in HTML5 like <section>?",
 279                 advanced => 0,
 280                 safe => 1,
 281                 rebuild => 1,
 282         },
 283         sslcookie => {
 284                 type => "boolean",
 285                 default => 0,
 286                 description => "only send cookies over SSL connections?",
 287                 advanced => 1,
 288                 safe => 1,
 289                 rebuild => 0,
 290         },
 291         default_pageext => {
 292                 type => "string",
 293                 default => "mdwn",
 294                 description => "extension to use for new pages",
 295                 safe => 0, # not sanitized
 296                 rebuild => 0,
 297         },
 298         htmlext => {
 299                 type => "string",
 300                 default => "html",
 301                 description => "extension to use for html files",
 302                 safe => 0, # not sanitized
 303                 rebuild => 1,
 304         },
 305         timeformat => {
 306                 type => "string",
 307                 default => '%c',
 308                 description => "strftime format string to display date",
 309                 advanced => 1,
 310                 safe => 1,
 311                 rebuild => 1,
 312         },
 313         locale => {
 314                 type => "string",
 315                 default => undef,
 316                 example => "en_US.UTF-8",
 317                 description => "UTF-8 locale to use",
 318                 advanced => 1,
 319                 safe => 0,
 320                 rebuild => 1,
 321         },
 322         userdir => {
 323                 type => "string",
 324                 default => "",
 325                 example => "users",
 326                 description => "put user pages below specified page",
 327                 safe => 1,
 328                 rebuild => 1,
 329         },
 330         numbacklinks => {
 331                 type => "integer",
 332                 default => 10,
 333                 description => "how many backlinks to show before hiding excess (0 to show all)",
 334                 safe => 1,
 335                 rebuild => 1,
 336         },
 337         hardlink => {
 338                 type => "boolean",
 339                 default => 0,
 340                 description => "attempt to hardlink source files? (optimisation for large files)",
 341                 advanced => 1,
 342                 safe => 0, # paranoia
 343                 rebuild => 0,
 344         },
 345         umask => {
 346                 type => "string",
 347                 example => "public",
 348                 description => "force ikiwiki to use a particular umask (keywords public, group or private, or a number)",
 349                 advanced => 1,
 350                 safe => 0, # paranoia
 351                 rebuild => 0,
 352         },
 353         wrappergroup => {
 354                 type => "string",
 355                 example => "ikiwiki",
 356                 description => "group for wrappers to run in",
 357                 advanced => 1,
 358                 safe => 0, # paranoia
 359                 rebuild => 0,
 360         },
 361         libdirs => {
 362                 type => "string",
 363                 default => [],
 364                 example => ["$ENV{HOME}/.local/share/ikiwiki"],
 365                 description => "extra library and plugin directories",
 366                 advanced => 1,
 367                 safe => 0, # directory
 368                 rebuild => 0,
 369         },
 370         libdir => {
 371                 type => "string",
 372                 default => "",
 373                 example => "$ENV{HOME}/.ikiwiki/",
 374                 description => "extra library and plugin directory (searched after libdirs)",
 375                 advanced => 1,
 376                 safe => 0, # directory
 377                 rebuild => 0,
 378         },
 379         ENV => {
 380                 type => "string",
 381                 default => {},
 382                 description => "environment variables",
 383                 safe => 0, # paranoia
 384                 rebuild => 0,
 385         },
 386         timezone => {
 387                 type => "string",
 388                 default => "",
 389                 example => "US/Eastern",
 390                 description => "time zone name",
 391                 safe => 1,
 392                 rebuild => 1,
 393         },
 394         include => {
 395                 type => "string",
 396                 default => undef,
 397                 example => '^\.htaccess$',
 398                 description => "regexp of normally excluded files to include",
 399                 advanced => 1,
 400                 safe => 0, # regexp
 401                 rebuild => 1,
 402         },
 403         exclude => {
 404                 type => "string",
 405                 default => undef,
 406                 example => '^(*\.private|Makefile)$',
 407                 description => "regexp of files that should be skipped",
 408                 advanced => 1,
 409                 safe => 0, # regexp
 410                 rebuild => 1,
 411         },
 412         wiki_file_prune_regexps => {
 413                 type => "internal",
 414                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 415                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 416                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 417                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 418                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 419                 description => "regexps of source files to ignore",
 420                 safe => 0,
 421                 rebuild => 1,
 422         },
 423         wiki_file_chars => {
 424                 type => "string",
 425                 description => "specifies the characters that are allowed in source filenames",
 426                 default => "-[:alnum:]+/.:_",
 427                 safe => 0,
 428                 rebuild => 1,
 429         },
 430         wiki_file_regexp => {
 431                 type => "internal",
 432                 description => "regexp of legal source files",
 433                 safe => 0,
 434                 rebuild => 1,
 435         },
 436         web_commit_regexp => {
 437                 type => "internal",
 438                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 439                 description => "regexp to parse web commits from logs",
 440                 safe => 0,
 441                 rebuild => 0,
 442         },
 443         cgi => {
 444                 type => "internal",
 445                 default => 0,
 446                 description => "run as a cgi",
 447                 safe => 0,
 448                 rebuild => 0,
 449         },
 450         cgi_disable_uploads => {
 451                 type => "internal",
 452                 default => 1,
 453                 description => "whether CGI should accept file uploads",
 454                 safe => 0,
 455                 rebuild => 0,
 456         },
 457         post_commit => {
 458                 type => "internal",
 459                 default => 0,
 460                 description => "run as a post-commit hook",
 461                 safe => 0,
 462                 rebuild => 0,
 463         },
 464         rebuild => {
 465                 type => "internal",
 466                 default => 0,
 467                 description => "running in rebuild mode",
 468                 safe => 0,
 469                 rebuild => 0,
 470         },
 471         setup => {
 472                 type => "internal",
 473                 default => undef,
 474                 description => "running in setup mode",
 475                 safe => 0,
 476                 rebuild => 0,
 477         },
 478         clean => {
 479                 type => "internal",
 480                 default => 0,
 481                 description => "running in clean mode",
 482                 safe => 0,
 483                 rebuild => 0,
 484         },
 485         refresh => {
 486                 type => "internal",
 487                 default => 0,
 488                 description => "running in refresh mode",
 489                 safe => 0,
 490                 rebuild => 0,
 491         },
 492         test_receive => {
 493                 type => "internal",
 494                 default => 0,
 495                 description => "running in receive test mode",
 496                 safe => 0,
 497                 rebuild => 0,
 498         },
 499         wrapper_background_command => {
 500                 type => "internal",
 501                 default => '',
 502                 description => "background shell command to run",
 503                 safe => 0,
 504                 rebuild => 0,
 505         },
 506         gettime => {
 507                 type => "internal",
 508                 description => "running in gettime mode",
 509                 safe => 0,
 510                 rebuild => 0,
 511         },
 512         w3mmode => {
 513                 type => "internal",
 514                 default => 0,
 515                 description => "running in w3mmode",
 516                 safe => 0,
 517                 rebuild => 0,
 518         },
 519         wikistatedir => {
 520                 type => "internal",
 521                 default => undef,
 522                 description => "path to the .ikiwiki directory holding ikiwiki state",
 523                 safe => 0,
 524                 rebuild => 0,
 525         },
 526         setupfile => {
 527                 type => "internal",
 528                 default => undef,
 529                 description => "path to setup file",
 530                 safe => 0,
 531                 rebuild => 0,
 532         },
 533         setuptype => {
 534                 type => "internal",
 535                 default => "Yaml",
 536                 description => "perl class to use to dump setup file",
 537                 safe => 0,
 538                 rebuild => 0,
 539         },
 540         allow_symlinks_before_srcdir => {
 541                 type => "boolean",
 542                 default => 0,
 543                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 544                 safe => 0,
 545                 rebuild => 0,
 546         },
 547         cookiejar => {
 548                 type => "string",
 549                 default => { file => "$ENV{HOME}/.ikiwiki/cookies" },
 550                 description => "cookie control",
 551                 safe => 0, # hooks into perl module internals
 552                 rebuild => 0,
 553         },
 554         useragent => {
 555                 type => "string",
 556                 default => "ikiwiki/$version",
 557                 example => "Wget/1.13.4 (linux-gnu)",
 558                 description => "set custom user agent string for outbound HTTP requests e.g. when fetching aggregated RSS feeds",
 559                 safe => 0,
 560                 rebuild => 0,
 561         },
 562         responsive_layout => {
 563                 type => "boolean",
 564                 default => 1,
 565                 description => "theme has a responsive layout? (mobile-optimized)",
 566                 safe => 1,
 567                 rebuild => 1,
 568         },
 569 }
 570
 571 sub getlibdirs () {
 572         my @libdirs;
 573         if ($config{libdirs}) {
 574                 @libdirs = @{$config{libdirs}};
 575         }
 576         if (length $config{libdir}) {
 577                 push @libdirs, $config{libdir};
 578         }
 579         return @libdirs;
 580 }
 581
 582 sub defaultconfig () {
 583         my %s=getsetup();
 584         my @ret;
 585         foreach my $key (keys %s) {
 586                 push @ret, $key, $s{$key}->{default};
 587         }
 588         return @ret;
 589 }
 590
 591 # URL to top of wiki as a path starting with /, valid from any wiki page or
 592 # the CGI; if that's not possible, an absolute URL. Either way, it ends with /
 593 my $local_url;
 594 # URL to CGI script, similar to $local_url
 595 my $local_cgiurl;
 596
 597 sub checkconfig () {
 598         # locale stuff; avoid LC_ALL since it overrides everything
 599         if (defined $ENV{LC_ALL}) {
 600                 $ENV{LANG} = $ENV{LC_ALL};
 601                 delete $ENV{LC_ALL};
 602         }
 603         if (defined $config{locale}) {
 604                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 605                         $ENV{LANG}=$config{locale};
 606                         define_gettext();
 607                 }
 608         }
 609
 610         if (! defined $config{wiki_file_regexp}) {
 611                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 612         }
 613
 614         if (ref $config{ENV} eq 'HASH') {
 615                 foreach my $val (keys %{$config{ENV}}) {
 616                         $ENV{$val}=$config{ENV}{$val};
 617                 }
 618         }
 619         if (defined $config{timezone} && length $config{timezone}) {
 620                 $ENV{TZ}=$config{timezone};
 621         }
 622         elsif (defined $ENV{TZ} && length $ENV{TZ}) {
 623                 $config{timezone}=$ENV{TZ};
 624         }
 625         else {
 626                 eval q{use Config qw()};
 627                 error($@) if $@;
 628
 629                 if ($Config::Config{d_gnulibc} && -e '/etc/localtime') {
 630                         $config{timezone}=$ENV{TZ}=':/etc/localtime';
 631                 }
 632                 else {
 633                         $config{timezone}=$ENV{TZ}='GMT';
 634                 }
 635         }
 636
 637         if ($config{w3mmode}) {
 638                 eval q{use Cwd q{abs_path}};
 639                 error($@) if $@;
 640                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 641                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 642                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 643                         unless $config{cgiurl} =~ m!file:///!;
 644                 $config{url}="file://".$config{destdir};
 645         }
 646
 647         if ($config{cgi} && ! length $config{url}) {
 648                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 649         }
 650
 651         if (defined $config{url} && length $config{url}) {
 652                 eval q{use URI};
 653                 my $baseurl = URI->new($config{url});
 654
 655                 $local_url = $baseurl->path . "/";
 656                 $local_cgiurl = undef;
 657
 658                 if (length $config{cgiurl}) {
 659                         my $cgiurl = URI->new($config{cgiurl});
 660
 661                         $local_cgiurl = $cgiurl->path;
 662
 663                         if ($cgiurl->scheme eq 'https' &&
 664                                 $baseurl->scheme eq 'http') {
 665                                 # We assume that the same content is available
 666                                 # over both http and https, because if it
 667                                 # wasn't, accessing the static content
 668                                 # from the CGI would be mixed-content,
 669                                 # which would be a security flaw.
 670
 671                                 if ($cgiurl->authority ne $baseurl->authority) {
 672                                         # use protocol-relative URL for
 673                                         # static content
 674                                         $local_url = "$config{url}/";
 675                                         $local_url =~ s{^http://}{//};
 676                                 }
 677                                 # else use host-relative URL for static content
 678
 679                                 # either way, CGI needs to be absolute
 680                                 $local_cgiurl = $config{cgiurl};
 681                         }
 682                         elsif ($cgiurl->scheme ne $baseurl->scheme) {
 683                                 # too far apart, fall back to absolute URLs
 684                                 $local_url = "$config{url}/";
 685                                 $local_cgiurl = $config{cgiurl};
 686                         }
 687                         elsif ($cgiurl->authority ne $baseurl->authority) {
 688                                 # slightly too far apart, fall back to
 689                                 # protocol-relative URLs
 690                                 $local_url = "$config{url}/";
 691                                 $local_url =~ s{^https?://}{//};
 692                                 $local_cgiurl = $config{cgiurl};
 693                                 $local_cgiurl =~ s{^https?://}{//};
 694                         }
 695                         # else keep host-relative URLs
 696                 }
 697
 698                 $local_url =~ s{//$}{/};
 699         }
 700         else {
 701                 $local_cgiurl = $config{cgiurl};
 702         }
 703
 704         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 705                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 706
 707         if (defined $config{umask}) {
 708                 my $u = possibly_foolish_untaint($config{umask});
 709
 710                 if ($u =~ m/^\d+$/) {
 711                         umask($u);
 712                 }
 713                 elsif ($u eq 'private') {
 714                         umask(077);
 715                 }
 716                 elsif ($u eq 'group') {
 717                         umask(027);
 718                 }
 719                 elsif ($u eq 'public') {
 720                         umask(022);
 721                 }
 722                 else {
 723                         error(sprintf(gettext("unsupported umask setting %s"), $u));
 724                 }
 725         }
 726
 727         run_hooks(checkconfig => sub { shift->() });
 728
 729         return 1;
 730 }
 731
 732 sub listplugins () {
 733         my %ret;
 734
 735         foreach my $dir (@INC, getlibdirs()) {
 736                 next unless defined $dir && length $dir;
 737                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 738                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 739                         $ret{$plugin}=1;
 740                 }
 741         }
 742         foreach my $dir (getlibdirs(), "$installdir/lib/ikiwiki") {
 743                 next unless defined $dir && length $dir;
 744                 foreach my $file (glob("$dir/plugins/*")) {
 745                         $ret{basename($file)}=1 if -x $file;
 746                 }
 747         }
 748
 749         return keys %ret;
 750 }
 751
 752 sub loadplugins () {
 753         foreach my $dir (getlibdirs()) {
 754                 unshift @INC, possibly_foolish_untaint($dir);
 755         }
 756
 757         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 758                 loadplugin($plugin);
 759         }
 760
 761         if ($config{rcs}) {
 762                 if (exists $hooks{rcs}) {
 763                         error(gettext("cannot use multiple rcs plugins"));
 764                 }
 765                 loadplugin($config{rcs});
 766         }
 767         if (! exists $hooks{rcs}) {
 768                 loadplugin("norcs");
 769         }
 770
 771         run_hooks(getopt => sub { shift->() });
 772         if (grep /^-/, @ARGV) {
 773                 print STDERR "Unknown option (or missing parameter): $_\n"
 774                         foreach grep /^-/, @ARGV;
 775                 usage();
 776         }
 777
 778         return 1;
 779 }
 780
 781 sub loadplugin ($;$) {
 782         my $plugin=shift;
 783         my $force=shift;
 784
 785         return if ! $force && grep { $_ eq $plugin} @{$config{disable_plugins}};
 786
 787         foreach my $possiblytainteddir (getlibdirs(), "$installdir/lib/ikiwiki") {
 788                 my $dir = possibly_foolish_untaint($possiblytainteddir);
 789                 if (defined $dir && -x "$dir/plugins/$plugin") {
 790                         eval { require IkiWiki::Plugin::external };
 791                         if ($@) {
 792                                 my $reason=$@;
 793                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 794                         }
 795                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 796                         $loaded_plugins{$plugin}=1;
 797                         return 1;
 798                 }
 799         }
 800
 801         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 802         eval qq{use $mod};
 803         if ($@) {
 804                 error("Failed to load plugin $mod: $@");
 805         }
 806         $loaded_plugins{$plugin}=1;
 807         return 1;
 808 }
 809
 810 sub error ($;$) {
 811         my $message=shift;
 812         my $cleaner=shift;
 813         log_message('err' => $message) if $config{syslog};
 814         if (defined $cleaner) {
 815                 $cleaner->();
 816         }
 817         die $message."\n";
 818 }
 819
 820 sub debug ($) {
 821         return unless $config{verbose};
 822         return log_message(debug => @_);
 823 }
 824
 825 my $log_open=0;
 826 my $log_failed=0;
 827 sub log_message ($$) {
 828         my $type=shift;
 829
 830         if ($config{syslog}) {
 831                 require Sys::Syslog;
 832                 if (! $log_open) {
 833                         Sys::Syslog::setlogsock('unix');
 834                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 835                         $log_open=1;
 836                 }
 837                 eval {
 838                         # keep a copy to avoid editing the original config repeatedly
 839                         my $wikiname = $config{wikiname};
 840                         utf8::encode($wikiname);
 841                         Sys::Syslog::syslog($type, "[$wikiname] %s", join(" ", @_));
 842                 };
 843                 if ($@) {
 844                     print STDERR "failed to syslog: $@" unless $log_failed;
 845                     $log_failed=1;
 846                     print STDERR "@_\n";
 847                 }
 848                 return $@;
 849         }
 850         elsif (! $config{cgi}) {
 851                 return print "@_\n";
 852         }
 853         else {
 854                 return print STDERR "@_\n";
 855         }
 856 }
 857
 858 sub possibly_foolish_untaint ($) {
 859         my $tainted=shift;
 860         my ($untainted)=$tainted=~/(.*)/s;
 861         return $untainted;
 862 }
 863
 864 sub basename ($) {
 865         my $file=shift;
 866
 867         $file=~s!.*/+!!;
 868         return $file;
 869 }
 870
 871 sub dirname ($) {
 872         my $file=shift;
 873
 874         $file=~s!/*[^/]+$!!;
 875         return $file;
 876 }
 877
 878 sub isinternal ($) {
 879         my $page=shift;
 880         return exists $pagesources{$page} &&
 881                 $pagesources{$page} =~ /\._([^.]+)$/;
 882 }
 883
 884 sub pagetype ($) {
 885         my $file=shift;
 886
 887         if ($file =~ /\.([^.]+)$/) {
 888                 return $1 if exists $hooks{htmlize}{$1};
 889         }
 890         my $base=basename($file);
 891         if (exists $hooks{htmlize}{$base} &&
 892             $hooks{htmlize}{$base}{noextension}) {
 893                 return $base;
 894         }
 895         return;
 896 }
 897
 898 my %pagename_cache;
 899
 900 sub pagename ($) {
 901         my $file=shift;
 902
 903         if (exists $pagename_cache{$file}) {
 904                 return $pagename_cache{$file};
 905         }
 906
 907         my $type=pagetype($file);
 908         my $page=$file;
 909         $page=~s/\Q.$type\E*$//
 910                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 911                         && !$hooks{htmlize}{$type}{noextension};
 912         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 913                 $page=$1;
 914         }
 915
 916         $pagename_cache{$file} = $page;
 917         return $page;
 918 }
 919
 920 sub newpagefile ($$) {
 921         my $page=shift;
 922         my $type=shift;
 923
 924         if (! $config{indexpages} || $page eq 'index') {
 925                 return $page.".".$type;
 926         }
 927         else {
 928                 return $page."/index.".$type;
 929         }
 930 }
 931
 932 sub targetpage ($$;$) {
 933         my $page=shift;
 934         my $ext=shift;
 935         my $filename=shift;
 936
 937         if (defined $filename) {
 938                 return $page."/".$filename.".".$ext;
 939         }
 940         elsif (! $config{usedirs} || $page eq 'index') {
 941                 return $page.".".$ext;
 942         }
 943         else {
 944                 return $page."/index.".$ext;
 945         }
 946 }
 947
 948 sub htmlpage ($) {
 949         my $page=shift;
 950
 951         return targetpage($page, $config{htmlext});
 952 }
 953
 954 sub srcfile_stat {
 955         my $file=shift;
 956         my $nothrow=shift;
 957
 958         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 959         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 960                 return "$dir/$file", stat(_) if -e "$dir/$file";
 961         }
 962         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 963         return;
 964 }
 965
 966 sub srcfile ($;$) {
 967         return (srcfile_stat(@_))[0];
 968 }
 969
 970 sub add_literal_underlay ($) {
 971         my $dir=shift;
 972
 973         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 974                 unshift @{$config{underlaydirs}}, $dir;
 975         }
 976 }
 977
 978 sub add_underlay ($) {
 979         my $dir = shift;
 980
 981         if ($dir !~ /^\//) {
 982                 $dir="$config{underlaydirbase}/$dir";
 983         }
 984
 985         add_literal_underlay($dir);
 986         # why does it return 1? we just don't know
 987         return 1;
 988 }
 989
 990 sub readfile ($;$$) {
 991         my $file=shift;
 992         my $binary=shift;
 993         my $wantfd=shift;
 994
 995         if (-l $file) {
 996                 error("cannot read a symlink ($file)");
 997         }
 998
 999         local $/=undef;
1000         open (my $in, "<", $file) || error("failed to read $file: $!");
1001         binmode($in) if ($binary);
1002         return \*$in if $wantfd;
1003         my $ret=<$in>;
1004         # check for invalid utf-8, and toss it back to avoid crashes
1005         if (! utf8::valid($ret)) {
1006                 $ret=encode_utf8($ret);
1007         }
1008         close $in || error("failed to read $file: $!");
1009         return $ret;
1010 }
1011
1012 sub prep_writefile ($$) {
1013         my $file=shift;
1014         my $destdir=shift;
1015
1016         my $test=$file;
1017         while (length $test) {
1018                 if (-l "$destdir/$test") {
1019                         error("cannot write to a symlink ($test)");
1020                 }
1021                 if (-f _ && $test ne $file) {
1022                         # Remove conflicting file.
1023                         foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1024                                 foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1025                                         if ($f eq $test) {
1026                                                 unlink("$destdir/$test");
1027                                                 last;
1028                                         }
1029                                 }
1030                         }
1031                 }
1032                 $test=dirname($test);
1033         }
1034
1035         my $dir=dirname("$destdir/$file");
1036         if (! -d $dir) {
1037                 my $d="";
1038                 foreach my $s (split(m!/+!, $dir)) {
1039                         $d.="$s/";
1040                         if (! -d $d) {
1041                                 mkdir($d) || error("failed to create directory $d: $!");
1042                         }
1043                 }
1044         }
1045
1046         return 1;
1047 }
1048
1049 sub writefile ($$$;$$) {
1050         my $file=shift; # can include subdirs
1051         my $destdir=shift; # directory to put file in
1052         my $content=shift;
1053         my $binary=shift;
1054         my $writer=shift;
1055
1056         prep_writefile($file, $destdir);
1057
1058         my $newfile="$destdir/$file.ikiwiki-new";
1059         if (-l $newfile) {
1060                 error("cannot write to a symlink ($newfile)");
1061         }
1062
1063         my $cleanup = sub { unlink($newfile) };
1064         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
1065         binmode($out) if ($binary);
1066         if ($writer) {
1067                 $writer->(\*$out, $cleanup);
1068         }
1069         else {
1070                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
1071         }
1072         close $out || error("failed saving $newfile: $!", $cleanup);
1073         rename($newfile, "$destdir/$file") ||
1074                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
1075
1076         return 1;
1077 }
1078
1079 my %cleared;
1080 sub will_render ($$;$) {
1081         my $page=shift;
1082         my $dest=shift;
1083         my $clear=shift;
1084
1085         # Important security check for independently created files.
1086         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
1087             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
1088                 my $from_other_page=0;
1089                 # Expensive, but rarely runs.
1090                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1091                         if (grep {
1092                                 $_ eq $dest ||
1093                                 dirname($_) eq $dest
1094                             } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1095                                 $from_other_page=1;
1096                                 last;
1097                         }
1098                 }
1099
1100                 error("$config{destdir}/$dest independently created, not overwriting with version from $page")
1101                         unless $from_other_page;
1102         }
1103
1104         # If $dest exists as a directory, remove conflicting files in it
1105         # rendered from other pages.
1106         if (-d _) {
1107                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
1108                         foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
1109                                 if (dirname($f) eq $dest) {
1110                                         unlink("$config{destdir}/$f");
1111                                         rmdir(dirname("$config{destdir}/$f"));
1112                                 }
1113                         }
1114                 }
1115         }
1116
1117         if (! $clear || $cleared{$page}) {
1118                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
1119         }
1120         else {
1121                 foreach my $old (@{$renderedfiles{$page}}) {
1122                         delete $destsources{$old};
1123                 }
1124                 $renderedfiles{$page}=[$dest];
1125                 $cleared{$page}=1;
1126         }
1127         $destsources{$dest}=$page;
1128
1129         return 1;
1130 }
1131
1132 sub bestlink ($$) {
1133         my $page=shift;
1134         my $link=shift;
1135
1136         my $cwd=$page;
1137         if ($link=~s/^\/+//) {
1138                 # absolute links
1139                 $cwd="";
1140         }
1141         $link=~s/\/$//;
1142
1143         do {
1144                 my $l=$cwd;
1145                 $l.="/" if length $l;
1146                 $l.=$link;
1147
1148                 if (exists $pagesources{$l}) {
1149                         return $l;
1150                 }
1151                 elsif (exists $pagecase{lc $l}) {
1152                         return $pagecase{lc $l};
1153                 }
1154         } while $cwd=~s{/?[^/]+$}{};
1155
1156         if (length $config{userdir}) {
1157                 my $l = "$config{userdir}/".lc($link);
1158                 if (exists $pagesources{$l}) {
1159                         return $l;
1160                 }
1161                 elsif (exists $pagecase{lc $l}) {
1162                         return $pagecase{lc $l};
1163                 }
1164         }
1165
1166         #print STDERR "warning: page $page, broken link: $link\n";
1167         return "";
1168 }
1169
1170 sub isinlinableimage ($) {
1171         my $file=shift;
1172
1173         return $file =~ /\.(png|gif|jpg|jpeg|svg)$/i;
1174 }
1175
1176 sub pagetitle ($;$) {
1177         my $page=shift;
1178         my $unescaped=shift;
1179
1180         if ($unescaped) {
1181                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
1182         }
1183         else {
1184                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
1185         }
1186
1187         return $page;
1188 }
1189
1190 sub titlepage ($) {
1191         my $title=shift;
1192         # support use w/o %config set
1193         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1194         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1195         return $title;
1196 }
1197
1198 sub linkpage ($) {
1199         my $link=shift;
1200         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1201         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1202         return $link;
1203 }
1204
1205 sub cgiurl (@) {
1206         my %params=@_;
1207
1208         my $cgiurl=$local_cgiurl;
1209
1210         if (exists $params{cgiurl}) {
1211                 $cgiurl=$params{cgiurl};
1212                 delete $params{cgiurl};
1213         }
1214
1215         unless (%params) {
1216                 return $cgiurl;
1217         }
1218
1219         return $cgiurl."?".
1220                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
1221 }
1222
1223 sub cgiurl_abs (@) {
1224         eval q{use URI};
1225         URI->new_abs(cgiurl(@_), $config{cgiurl});
1226 }
1227
1228 sub baseurl (;$) {
1229         my $page=shift;
1230
1231         return $local_url if ! defined $page;
1232
1233         $page=htmlpage($page);
1234         $page=~s/[^\/]+$//;
1235         $page=~s/[^\/]+\//..\//g;
1236         return $page;
1237 }
1238
1239 sub urlabs ($$) {
1240         my $url=shift;
1241         my $urlbase=shift;
1242
1243         return $url unless defined $urlbase && length $urlbase;
1244
1245         eval q{use URI};
1246         URI->new_abs($url, $urlbase)->as_string;
1247 }
1248
1249 sub abs2rel ($$) {
1250         # Work around very innefficient behavior in File::Spec if abs2rel
1251         # is passed two relative paths. It's much faster if paths are
1252         # absolute! (Debian bug #376658; fixed in debian unstable now)
1253         my $path="/".shift;
1254         my $base="/".shift;
1255
1256         require File::Spec;
1257         my $ret=File::Spec->abs2rel($path, $base);
1258         $ret=~s/^// if defined $ret;
1259         return $ret;
1260 }
1261
1262 sub displaytime ($;$$) {
1263         # Plugins can override this function to mark up the time to
1264         # display.
1265         my $time=formattime($_[0], $_[1]);
1266         if ($config{html5}) {
1267                 return '<time datetime="'.date_3339($_[0]).'"'.
1268                         ($_[2] ? ' pubdate="pubdate"' : '').
1269                         '>'.$time.'</time>';
1270         }
1271         else {
1272                 return '<span class="date">'.$time.'</span>';
1273         }
1274 }
1275
1276 sub formattime ($;$) {
1277         # Plugins can override this function to format the time.
1278         my $time=shift;
1279         my $format=shift;
1280         if (! defined $format) {
1281                 $format=$config{timeformat};
1282         }
1283
1284         return strftime_utf8($format, localtime($time));
1285 }
1286
1287 my $strftime_encoding;
1288 sub strftime_utf8 {
1289         # strftime doesn't know about encodings, so make sure
1290         # its output is properly treated as utf8.
1291         # Note that this does not handle utf-8 in the format string.
1292         ($strftime_encoding) = POSIX::setlocale(&POSIX::LC_TIME) =~ m#\.([^@]+)#
1293                 unless defined $strftime_encoding;
1294         $strftime_encoding
1295                 ? Encode::decode($strftime_encoding, POSIX::strftime(@_))
1296                 : POSIX::strftime(@_);
1297 }
1298
1299 sub date_3339 ($) {
1300         my $time=shift;
1301
1302         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
1303         POSIX::setlocale(&POSIX::LC_TIME, "C");
1304         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
1305         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
1306         return $ret;
1307 }
1308
1309 sub beautify_urlpath ($) {
1310         my $url=shift;
1311
1312         # Ensure url is not an empty link, and if necessary,
1313         # add ./ to avoid colon confusion.
1314         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1315                 $url="./$url";
1316         }
1317
1318         if ($config{usedirs}) {
1319                 $url =~ s!/index.$config{htmlext}$!/!;
1320         }
1321
1322         return $url;
1323 }
1324
1325 sub urlto ($;$$) {
1326         my $to=shift;
1327         my $from=shift;
1328         my $absolute=shift;
1329
1330         if (! length $to) {
1331                 $to = 'index';
1332         }
1333
1334         if (! $destsources{$to}) {
1335                 $to=htmlpage($to);
1336         }
1337
1338         if ($absolute) {
1339                 return $config{url}.beautify_urlpath("/".$to);
1340         }
1341
1342         if (! defined $from) {
1343                 my $u = $local_url || '';
1344                 $u =~ s{/$}{};
1345                 return $u.beautify_urlpath("/".$to);
1346         }
1347
1348         my $link = abs2rel($to, dirname(htmlpage($from)));
1349
1350         return beautify_urlpath($link);
1351 }
1352
1353 sub isselflink ($$) {
1354         # Plugins can override this function to support special types
1355         # of selflinks.
1356         my $page=shift;
1357         my $link=shift;
1358
1359         return $page eq $link;
1360 }
1361
1362 sub htmllink ($$$;@) {
1363         my $lpage=shift; # the page doing the linking
1364         my $page=shift; # the page that will contain the link (different for inline)
1365         my $link=shift;
1366         my %opts=@_;
1367
1368         $link=~s/\/$//;
1369
1370         my $bestlink;
1371         if (! $opts{forcesubpage}) {
1372                 $bestlink=bestlink($lpage, $link);
1373         }
1374         else {
1375                 $bestlink="$lpage/".lc($link);
1376         }
1377
1378         my $linktext;
1379         if (defined $opts{linktext}) {
1380                 $linktext=$opts{linktext};
1381         }
1382         else {
1383                 $linktext=pagetitle(basename($link));
1384         }
1385
1386         return "<span class=\"selflink\">$linktext</span>"
1387                 if length $bestlink && isselflink($page, $bestlink) &&
1388                    ! defined $opts{anchor};
1389
1390         if (! $destsources{$bestlink}) {
1391                 $bestlink=htmlpage($bestlink);
1392
1393                 if (! $destsources{$bestlink}) {
1394                         my $cgilink = "";
1395                         if (length $config{cgiurl}) {
1396                                 $cgilink = "<a href=\"".
1397                                         cgiurl(
1398                                                 do => "create",
1399                                                 page => $link,
1400                                                 from => $lpage
1401                                         )."\" rel=\"nofollow\">?</a>";
1402                         }
1403                         return "<span class=\"createlink\">$cgilink$linktext</span>"
1404                 }
1405         }
1406
1407         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1408         $bestlink=beautify_urlpath($bestlink);
1409
1410         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1411                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1412         }
1413
1414         if (defined $opts{anchor}) {
1415                 $bestlink.="#".$opts{anchor};
1416         }
1417
1418         my @attrs;
1419         foreach my $attr (qw{rel class title}) {
1420                 if (defined $opts{$attr}) {
1421                         push @attrs, " $attr=\"$opts{$attr}\"";
1422                 }
1423         }
1424
1425         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1426 }
1427
1428 sub userpage ($) {
1429         my $user=shift;
1430         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1431 }
1432
1433 sub openiduser ($) {
1434         my $user=shift;
1435
1436         if (defined $user && $user =~ m!^https?://! &&
1437             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1438                 my $display;
1439
1440                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1441                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1442                 }
1443                 else {
1444                         # backcompat with old version
1445                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1446                         $display=$oid->display;
1447                 }
1448
1449                 # Convert "user.somehost.com" to "user [somehost.com]"
1450                 # (also "user.somehost.co.uk")
1451                 if ($display !~ /\[/) {
1452                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1453                 }
1454                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1455                 # (also "https://somehost.com/user/")
1456                 if ($display !~ /\[/) {
1457                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1458                 }
1459                 $display=~s!^https?://!!; # make sure this is removed
1460                 eval q{use CGI 'escapeHTML'};
1461                 error($@) if $@;
1462                 return escapeHTML($display);
1463         }
1464         return;
1465 }
1466
1467 sub htmlize ($$$$) {
1468         my $page=shift;
1469         my $destpage=shift;
1470         my $type=shift;
1471         my $content=shift;
1472
1473         my $oneline = $content !~ /\n/;
1474
1475         if (exists $hooks{htmlize}{$type}) {
1476                 $content=$hooks{htmlize}{$type}{call}->(
1477                         page => $page,
1478                         content => $content,
1479                 );
1480         }
1481         else {
1482                 error("htmlization of $type not supported");
1483         }
1484
1485         run_hooks(sanitize => sub {
1486                 $content=shift->(
1487                         page => $page,
1488                         destpage => $destpage,
1489                         content => $content,
1490                 );
1491         });
1492
1493         if ($oneline) {
1494                 # hack to get rid of enclosing junk added by markdown
1495                 # and other htmlizers/sanitizers
1496                 $content=~s/^<p>//i;
1497                 $content=~s/<\/p>\n*$//i;
1498         }
1499
1500         return $content;
1501 }
1502
1503 sub linkify ($$$) {
1504         my $page=shift;
1505         my $destpage=shift;
1506         my $content=shift;
1507
1508         run_hooks(linkify => sub {
1509                 $content=shift->(
1510                         page => $page,
1511                         destpage => $destpage,
1512                         content => $content,
1513                 );
1514         });
1515
1516         return $content;
1517 }
1518
1519 our %preprocessing;
1520 our $preprocess_preview=0;
1521 sub preprocess ($$$;$$) {
1522         my $page=shift; # the page the data comes from
1523         my $destpage=shift; # the page the data will appear in (different for inline)
1524         my $content=shift;
1525         my $scan=shift;
1526         my $preview=shift;
1527
1528         # Using local because it needs to be set within any nested calls
1529         # of this function.
1530         local $preprocess_preview=$preview if defined $preview;
1531
1532         my $handle=sub {
1533                 my $escape=shift;
1534                 my $prefix=shift;
1535                 my $command=shift;
1536                 my $params=shift;
1537                 $params="" if ! defined $params;
1538
1539                 if (length $escape) {
1540                         return "[[$prefix$command $params]]";
1541                 }
1542                 elsif (exists $hooks{preprocess}{$command}) {
1543                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1544                         # Note: preserve order of params, some plugins may
1545                         # consider it significant.
1546                         my @params;
1547                         while ($params =~ m{
1548                                 (?:([-.\w]+)=)?         # 1: named parameter key?
1549                                 (?:
1550                                         """(.*?)"""     # 2: triple-quoted value
1551                                 |
1552                                         "([^"]*?)"      # 3: single-quoted value
1553                                 |
1554                                         '''(.*?)'''     # 4: triple-single-quote
1555                                 |
1556                                         <<([a-zA-Z]+)\n # 5: heredoc start
1557                                         (.*?)\n\5       # 6: heredoc value
1558                                 |
1559                                         (\S+)           # 7: unquoted value
1560                                 )
1561                                 (?:\s+|$)               # delimiter to next param
1562                         }msgx) {
1563                                 my $key=$1;
1564                                 my $val;
1565                                 if (defined $2) {
1566                                         $val=$2;
1567                                         $val=~s/\r\n/\n/mg;
1568                                         $val=~s/^\n+//g;
1569                                         $val=~s/\n+$//g;
1570                                 }
1571                                 elsif (defined $3) {
1572                                         $val=$3;
1573                                 }
1574                                 elsif (defined $4) {
1575                                         $val=$4;
1576                                 }
1577                                 elsif (defined $7) {
1578                                         $val=$7;
1579                                 }
1580                                 elsif (defined $6) {
1581                                         $val=$6;
1582                                 }
1583
1584                                 if (defined $key) {
1585                                         push @params, $key, $val;
1586                                 }
1587                                 else {
1588                                         push @params, $val, '';
1589                                 }
1590                         }
1591                         if ($preprocessing{$page}++ > 8) {
1592                                 # Avoid loops of preprocessed pages preprocessing
1593                                 # other pages that preprocess them, etc.
1594                                 return "[[!$command <span class=\"error\">".
1595                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1596                                                 $page, $preprocessing{$page}).
1597                                         "</span>]]";
1598                         }
1599                         my $ret;
1600                         if (! $scan) {
1601                                 $ret=eval {
1602                                         $hooks{preprocess}{$command}{call}->(
1603                                                 @params,
1604                                                 page => $page,
1605                                                 destpage => $destpage,
1606                                                 preview => $preprocess_preview,
1607                                         );
1608                                 };
1609                                 if ($@) {
1610                                         my $error=$@;
1611                                         chomp $error;
1612                                         $ret="[[!$command <span class=\"error\">".
1613                                                 gettext("Error").": $error"."</span>]]";
1614                                 }
1615                         }
1616                         else {
1617                                 # use void context during scan pass
1618                                 eval {
1619                                         $hooks{preprocess}{$command}{call}->(
1620                                                 @params,
1621                                                 page => $page,
1622                                                 destpage => $destpage,
1623                                                 preview => $preprocess_preview,
1624                                         );
1625                                 };
1626                                 $ret="";
1627                         }
1628                         $preprocessing{$page}--;
1629                         return $ret;
1630                 }
1631                 else {
1632                         return "[[$prefix$command $params]]";
1633                 }
1634         };
1635
1636         my $regex;
1637         if ($config{prefix_directives}) {
1638                 $regex = qr{
1639                         (\\?)           # 1: escape?
1640                         \[\[(!)         # directive open; 2: prefix
1641                         ([-\w]+)        # 3: command
1642                         (               # 4: the parameters..
1643                                 \s+     # Must have space if parameters present
1644                                 (?:
1645                                         (?:[-.\w]+=)?           # named parameter key?
1646                                         (?:
1647                                                 """.*?"""       # triple-quoted value
1648                                                 |
1649                                                 "[^"]*?"        # single-quoted value
1650                                                 |
1651                                                 '''.*?'''       # triple-single-quote
1652                                                 |
1653                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1654                                                 (?:.*?)\n\5     # heredoc value
1655                                                 |
1656                                                 [^"\s\]]+       # unquoted value
1657                                         )
1658                                         \s*                     # whitespace or end
1659                                                                 # of directive
1660                                 )
1661                         *)?             # 0 or more parameters
1662                         \]\]            # directive closed
1663                 }sx;
1664         }
1665         else {
1666                 $regex = qr{
1667                         (\\?)           # 1: escape?
1668                         \[\[(!?)        # directive open; 2: optional prefix
1669                         ([-\w]+)        # 3: command
1670                         \s+
1671                         (               # 4: the parameters..
1672                                 (?:
1673                                         (?:[-.\w]+=)?           # named parameter key?
1674                                         (?:
1675                                                 """.*?"""       # triple-quoted value
1676                                                 |
1677                                                 "[^"]*?"        # single-quoted value
1678                                                 |
1679                                                 '''.*?'''       # triple-single-quote
1680                                                 |
1681                                                 <<([a-zA-Z]+)\n # 5: heredoc start
1682                                                 (?:.*?)\n\5     # heredoc value
1683                                                 |
1684                                                 [^"\s\]]+       # unquoted value
1685                                         )
1686                                         \s*                     # whitespace or end
1687                                                                 # of directive
1688                                 )
1689                         *)              # 0 or more parameters
1690                         \]\]            # directive closed
1691                 }sx;
1692         }
1693
1694         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1695         return $content;
1696 }
1697
1698 sub filter ($$$) {
1699         my $page=shift;
1700         my $destpage=shift;
1701         my $content=shift;
1702
1703         run_hooks(filter => sub {
1704                 $content=shift->(page => $page, destpage => $destpage,
1705                         content => $content);
1706         });
1707
1708         return $content;
1709 }
1710
1711 sub check_canedit ($$$;$) {
1712         my $page=shift;
1713         my $q=shift;
1714         my $session=shift;
1715         my $nonfatal=shift;
1716
1717         my $canedit;
1718         run_hooks(canedit => sub {
1719                 return if defined $canedit;
1720                 my $ret=shift->($page, $q, $session);
1721                 if (defined $ret) {
1722                         if ($ret eq "") {
1723                                 $canedit=1;
1724                         }
1725                         elsif (ref $ret eq 'CODE') {
1726                                 $ret->() unless $nonfatal;
1727                                 $canedit=0;
1728                         }
1729                         elsif (defined $ret) {
1730                                 error($ret) unless $nonfatal;
1731                                 $canedit=0;
1732                         }
1733                 }
1734         });
1735         return defined $canedit ? $canedit : 1;
1736 }
1737
1738 sub check_content (@) {
1739         my %params=@_;
1740
1741         return 1 if ! exists $hooks{checkcontent}; # optimisation
1742
1743         if (exists $pagesources{$params{page}}) {
1744                 my @diff;
1745                 my %old=map { $_ => 1 }
1746                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1747                 foreach my $line (split("\n", $params{content})) {
1748                         push @diff, $line if ! exists $old{$line};
1749                 }
1750                 $params{diff}=join("\n", @diff);
1751         }
1752
1753         my $ok;
1754         run_hooks(checkcontent => sub {
1755                 return if defined $ok;
1756                 my $ret=shift->(%params);
1757                 if (defined $ret) {
1758                         if ($ret eq "") {
1759                                 $ok=1;
1760                         }
1761                         elsif (ref $ret eq 'CODE') {
1762                                 $ret->() unless $params{nonfatal};
1763                                 $ok=0;
1764                         }
1765                         elsif (defined $ret) {
1766                                 error($ret) unless $params{nonfatal};
1767                                 $ok=0;
1768                         }
1769                 }
1770
1771         });
1772         return defined $ok ? $ok : 1;
1773 }
1774
1775 sub check_canchange (@) {
1776         my %params = @_;
1777         my $cgi = $params{cgi};
1778         my $session = $params{session};
1779         my @changes = @{$params{changes}};
1780
1781         my %newfiles;
1782         foreach my $change (@changes) {
1783                 # This untaint is safe because we check file_pruned and
1784                 # wiki_file_regexp.
1785                 my ($file)=$change->{file}=~/$config{wiki_file_regexp}/;
1786                 $file=possibly_foolish_untaint($file);
1787                 if (! defined $file || ! length $file ||
1788                     file_pruned($file)) {
1789                         error(gettext("bad file name %s"), $file);
1790                 }
1791
1792                 my $type=pagetype($file);
1793                 my $page=pagename($file) if defined $type;
1794
1795                 if ($change->{action} eq 'add') {
1796                         $newfiles{$file}=1;
1797                 }
1798
1799                 if ($change->{action} eq 'change' ||
1800                     $change->{action} eq 'add') {
1801                         if (defined $page) {
1802                                 check_canedit($page, $cgi, $session);
1803                                 next;
1804                         }
1805                         else {
1806                                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
1807                                         IkiWiki::Plugin::attachment::check_canattach($session, $file, $change->{path});
1808                                         check_canedit($file, $cgi, $session);
1809                                         next;
1810                                 }
1811                         }
1812                 }
1813                 elsif ($change->{action} eq 'remove') {
1814                         # check_canremove tests to see if the file is present
1815                         # on disk. This will fail when a single commit adds a
1816                         # file and then removes it again. Avoid the problem
1817                         # by not testing the removal in such pairs of changes.
1818                         # (The add is still tested, just to make sure that
1819                         # no data is added to the repo that a web edit
1820                         # could not add.)
1821                         next if $newfiles{$file};
1822
1823                         if (IkiWiki::Plugin::remove->can("check_canremove")) {
1824                                 IkiWiki::Plugin::remove::check_canremove(defined $page ? $page : $file, $cgi, $session);
1825                                 check_canedit(defined $page ? $page : $file, $cgi, $session);
1826                                 next;
1827                         }
1828                 }
1829                 else {
1830                         error "unknown action ".$change->{action};
1831                 }
1832
1833                 error sprintf(gettext("you are not allowed to change %s"), $file);
1834         }
1835 }
1836
1837
1838 my $wikilock;
1839
1840 sub lockwiki () {
1841         # Take an exclusive lock on the wiki to prevent multiple concurrent
1842         # run issues. The lock will be dropped on program exit.
1843         if (! -d $config{wikistatedir}) {
1844                 mkdir($config{wikistatedir});
1845         }
1846         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1847                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1848         if (! flock($wikilock, LOCK_EX | LOCK_NB)) {
1849                 debug("failed to get lock; waiting...");
1850                 if (! flock($wikilock, LOCK_EX)) {
1851                         error("failed to get lock");
1852                 }
1853         }
1854         return 1;
1855 }
1856
1857 sub unlockwiki () {
1858         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1859         return close($wikilock) if $wikilock;
1860         return;
1861 }
1862
1863 my $commitlock;
1864
1865 sub commit_hook_enabled () {
1866         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1867                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1868         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1869                 close($commitlock) || error("failed closing commitlock: $!");
1870                 return 0;
1871         }
1872         close($commitlock) || error("failed closing commitlock: $!");
1873         return 1;
1874 }
1875
1876 sub disable_commit_hook () {
1877         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1878                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1879         if (! flock($commitlock, 2)) { # LOCK_EX
1880                 error("failed to get commit lock");
1881         }
1882         return 1;
1883 }
1884
1885 sub enable_commit_hook () {
1886         return close($commitlock) if $commitlock;
1887         return;
1888 }
1889
1890 sub loadindex () {
1891         %oldrenderedfiles=%pagectime=();
1892         my $rebuild=$config{rebuild};
1893         if (! $rebuild) {
1894                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1895                 %destsources=%renderedfiles=%pagecase=%pagestate=
1896                 %depends_simple=%typedlinks=%oldtypedlinks=();
1897         }
1898         my $in;
1899         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1900                 if (-e "$config{wikistatedir}/index") {
1901                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1902                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1903                 }
1904                 else {
1905                         # gettime on first build
1906                         $config{gettime}=1 unless defined $config{gettime};
1907                         return;
1908                 }
1909         }
1910
1911         my $index=Storable::fd_retrieve($in);
1912         if (! defined $index) {
1913                 return 0;
1914         }
1915
1916         my $pages;
1917         if (exists $index->{version} && ! ref $index->{version}) {
1918                 $pages=$index->{page};
1919                 %wikistate=%{$index->{state}};
1920                 # Handle plugins that got disabled by loading a new setup.
1921                 if (exists $config{setupfile}) {
1922                         require IkiWiki::Setup;
1923                         IkiWiki::Setup::disabled_plugins(
1924                                 grep { ! $loaded_plugins{$_} } keys %wikistate);
1925                 }
1926         }
1927         else {
1928                 $pages=$index;
1929                 %wikistate=();
1930         }
1931
1932         foreach my $src (keys %$pages) {
1933                 my $d=$pages->{$src};
1934                 my $page;
1935                 if (exists $d->{page} && ! $rebuild) {
1936                         $page=$d->{page};
1937                 }
1938                 else {
1939                         $page=pagename($src);
1940                 }
1941                 $pagectime{$page}=$d->{ctime};
1942                 $pagesources{$page}=$src;
1943                 if (! $rebuild) {
1944                         $pagemtime{$page}=$d->{mtime};
1945                         $renderedfiles{$page}=$d->{dest};
1946                         if (exists $d->{links} && ref $d->{links}) {
1947                                 $links{$page}=$d->{links};
1948                                 $oldlinks{$page}=[@{$d->{links}}];
1949                         }
1950                         if (ref $d->{depends_simple} eq 'ARRAY') {
1951                                 # old format
1952                                 $depends_simple{$page}={
1953                                         map { $_ => 1 } @{$d->{depends_simple}}
1954                                 };
1955                         }
1956                         elsif (exists $d->{depends_simple}) {
1957                                 $depends_simple{$page}=$d->{depends_simple};
1958                         }
1959                         if (exists $d->{dependslist}) {
1960                                 # old format
1961                                 $depends{$page}={
1962                                         map { $_ => $DEPEND_CONTENT }
1963                                                 @{$d->{dependslist}}
1964                                 };
1965                         }
1966                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1967                                 # old format
1968                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1969                         }
1970                         elsif (exists $d->{depends}) {
1971                                 $depends{$page}=$d->{depends};
1972                         }
1973                         if (exists $d->{state}) {
1974                                 $pagestate{$page}=$d->{state};
1975                         }
1976                         if (exists $d->{typedlinks}) {
1977                                 $typedlinks{$page}=$d->{typedlinks};
1978
1979                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
1980                                         next unless %$links;
1981                                         $oldtypedlinks{$page}{$type} = {%$links};
1982                                 }
1983                         }
1984                 }
1985                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1986         }
1987         foreach my $page (keys %pagesources) {
1988                 $pagecase{lc $page}=$page;
1989         }
1990         foreach my $page (keys %renderedfiles) {
1991                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1992         }
1993         $lastrev=$index->{lastrev};
1994         @underlayfiles=@{$index->{underlayfiles}} if ref $index->{underlayfiles};
1995         return close($in);
1996 }
1997
1998 sub saveindex () {
1999         run_hooks(savestate => sub { shift->() });
2000
2001         my @plugins=keys %loaded_plugins;
2002
2003         if (! -d $config{wikistatedir}) {
2004                 mkdir($config{wikistatedir});
2005         }
2006         my $newfile="$config{wikistatedir}/indexdb.new";
2007         my $cleanup = sub { unlink($newfile) };
2008         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
2009
2010         my %index;
2011         foreach my $page (keys %pagemtime) {
2012                 next unless $pagemtime{$page};
2013                 my $src=$pagesources{$page};
2014
2015                 $index{page}{$src}={
2016                         page => $page,
2017                         ctime => $pagectime{$page},
2018                         mtime => $pagemtime{$page},
2019                         dest => $renderedfiles{$page},
2020                         links => $links{$page},
2021                 };
2022
2023                 if (exists $depends{$page}) {
2024                         $index{page}{$src}{depends} = $depends{$page};
2025                 }
2026
2027                 if (exists $depends_simple{$page}) {
2028                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
2029                 }
2030
2031                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
2032                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
2033                 }
2034
2035                 if (exists $pagestate{$page}) {
2036                         $index{page}{$src}{state}=$pagestate{$page};
2037                 }
2038         }
2039
2040         $index{state}={};
2041         foreach my $id (@plugins) {
2042                 $index{state}{$id}={}; # used to detect disabled plugins
2043                 foreach my $key (keys %{$wikistate{$id}}) {
2044                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
2045                 }
2046         }
2047
2048         $index{lastrev}=$lastrev;
2049         $index{underlayfiles}=\@underlayfiles;
2050
2051         $index{version}="3";
2052         my $ret=Storable::nstore_fd(\%index, $out);
2053         return if ! defined $ret || ! $ret;
2054         close $out || error("failed saving to $newfile: $!", $cleanup);
2055         rename($newfile, "$config{wikistatedir}/indexdb") ||
2056                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
2057
2058         return 1;
2059 }
2060
2061 sub template_file ($) {
2062         my $name=shift;
2063
2064         my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
2065         my $template;
2066         if ($name !~ /\.tmpl$/ && exists $pagesources{$tpage}) {
2067                 $template=srcfile($pagesources{$tpage}, 1);
2068                 $name.=".tmpl";
2069         }
2070         else {
2071                 $template=srcfile($tpage, 1);
2072         }
2073
2074         if (defined $template) {
2075                 return $template, $tpage, 1 if wantarray;
2076                 return $template;
2077         }
2078         else {
2079                 $name=~s:/::; # avoid path traversal
2080                 foreach my $dir ($config{templatedir},
2081                                  "$installdir/share/ikiwiki/templates") {
2082                         if (-e "$dir/$name") {
2083                                 $template="$dir/$name";
2084                                 last;
2085                         }
2086                 }
2087                 if (defined $template) {
2088                         return $template, $tpage if wantarray;
2089                         return $template;
2090                 }
2091         }
2092
2093         return;
2094 }
2095
2096 sub template_depends ($$;@) {
2097         my $name=shift;
2098         my $page=shift;
2099
2100         my ($filename, $tpage, $untrusted)=template_file($name);
2101         if (! defined $filename) {
2102                 error(sprintf(gettext("template %s not found"), $name))
2103         }
2104
2105         if (defined $page && defined $tpage) {
2106                 add_depends($page, $tpage);
2107         }
2108
2109         my @opts=(
2110                 filter => sub {
2111                         my $text_ref = shift;
2112                         ${$text_ref} = decode_utf8(${$text_ref});
2113                         run_hooks(readtemplate => sub {
2114                                 ${$text_ref} = shift->(
2115                                         id => $name,
2116                                         page => $tpage,
2117                                         content => ${$text_ref},
2118                                         untrusted => $untrusted,
2119                                 );
2120                         });
2121                 },
2122                 loop_context_vars => 1,
2123                 die_on_bad_params => 0,
2124                 parent_global_vars => 1,
2125                 filename => $filename,
2126                 @_,
2127                 ($untrusted ? (no_includes => 1) : ()),
2128         );
2129         return @opts if wantarray;
2130
2131         require HTML::Template;
2132         return HTML::Template->new(@opts);
2133 }
2134
2135 sub template ($;@) {
2136         template_depends(shift, undef, @_);
2137 }
2138
2139 sub templateactions ($$) {
2140         my $template=shift;
2141         my $page=shift;
2142
2143         my $have_actions=0;
2144         my @actions;
2145         run_hooks(pageactions => sub {
2146                 push @actions, map { { action => $_ } }
2147                         grep { defined } shift->(page => $page);
2148         });
2149         $template->param(actions => \@actions);
2150
2151         if ($config{cgiurl} && exists $hooks{auth}) {
2152                 $template->param(prefsurl => cgiurl(do => "prefs"));
2153                 $have_actions=1;
2154         }
2155
2156         if ($have_actions || @actions) {
2157                 $template->param(have_actions => 1);
2158         }
2159 }
2160
2161 sub hook (@) {
2162         my %param=@_;
2163
2164         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
2165                 error 'hook requires type, call, and id parameters';
2166         }
2167
2168         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
2169
2170         $hooks{$param{type}}{$param{id}}=\%param;
2171         return 1;
2172 }
2173
2174 sub run_hooks ($$) {
2175         # Calls the given sub for each hook of the given type,
2176         # passing it the hook function to call.
2177         my $type=shift;
2178         my $sub=shift;
2179
2180         if (exists $hooks{$type}) {
2181                 my (@first, @middle, @last);
2182                 foreach my $id (keys %{$hooks{$type}}) {
2183                         if ($hooks{$type}{$id}{first}) {
2184                                 push @first, $id;
2185                         }
2186                         elsif ($hooks{$type}{$id}{last}) {
2187                                 push @last, $id;
2188                         }
2189                         else {
2190                                 push @middle, $id;
2191                         }
2192                 }
2193                 foreach my $id (@first, @middle, @last) {
2194                         $sub->($hooks{$type}{$id}{call});
2195                 }
2196         }
2197
2198         return 1;
2199 }
2200
2201 sub rcs_update () {
2202         $hooks{rcs}{rcs_update}{call}->(@_);
2203 }
2204
2205 sub rcs_prepedit ($) {
2206         $hooks{rcs}{rcs_prepedit}{call}->(@_);
2207 }
2208
2209 sub rcs_commit (@) {
2210         $hooks{rcs}{rcs_commit}{call}->(@_);
2211 }
2212
2213 sub rcs_commit_staged (@) {
2214         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
2215 }
2216
2217 sub rcs_add ($) {
2218         $hooks{rcs}{rcs_add}{call}->(@_);
2219 }
2220
2221 sub rcs_remove ($) {
2222         $hooks{rcs}{rcs_remove}{call}->(@_);
2223 }
2224
2225 sub rcs_rename ($$) {
2226         $hooks{rcs}{rcs_rename}{call}->(@_);
2227 }
2228
2229 sub rcs_recentchanges ($) {
2230         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
2231 }
2232
2233 sub rcs_diff ($;$) {
2234         $hooks{rcs}{rcs_diff}{call}->(@_);
2235 }
2236
2237 sub rcs_getctime ($) {
2238         $hooks{rcs}{rcs_getctime}{call}->(@_);
2239 }
2240
2241 sub rcs_getmtime ($) {
2242         $hooks{rcs}{rcs_getmtime}{call}->(@_);
2243 }
2244
2245 sub rcs_receive () {
2246         $hooks{rcs}{rcs_receive}{call}->();
2247 }
2248
2249 sub add_depends ($$;$) {
2250         my $page=shift;
2251         my $pagespec=shift;
2252         my $deptype=shift || $DEPEND_CONTENT;
2253
2254         # Is the pagespec a simple page name?
2255         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
2256             $pagespec !~ /[\s*?()!]/) {
2257                 $depends_simple{$page}{lc $pagespec} |= $deptype;
2258                 return 1;
2259         }
2260
2261         # Add explicit dependencies for influences.
2262         my $sub=pagespec_translate($pagespec);
2263         return unless defined $sub;
2264         foreach my $p (keys %pagesources) {
2265                 my $r=$sub->($p, location => $page);
2266                 my $i=$r->influences;
2267                 my $static=$r->influences_static;
2268                 foreach my $k (keys %$i) {
2269                         next unless $r || $static || $k eq $page;
2270                         $depends_simple{$page}{lc $k} |= $i->{$k};
2271                 }
2272                 last if $static;
2273         }
2274
2275         $depends{$page}{$pagespec} |= $deptype;
2276         return 1;
2277 }
2278
2279 sub deptype (@) {
2280         my $deptype=0;
2281         foreach my $type (@_) {
2282                 if ($type eq 'presence') {
2283                         $deptype |= $DEPEND_PRESENCE;
2284                 }
2285                 elsif ($type eq 'links') {
2286                         $deptype |= $DEPEND_LINKS;
2287                 }
2288                 elsif ($type eq 'content') {
2289                         $deptype |= $DEPEND_CONTENT;
2290                 }
2291         }
2292         return $deptype;
2293 }
2294
2295 my $file_prune_regexp;
2296 sub file_pruned ($) {
2297         my $file=shift;
2298
2299         if (defined $config{include} && length $config{include}) {
2300                 return 0 if $file =~ m/$config{include}/;
2301         }
2302
2303         if (! defined $file_prune_regexp) {
2304                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
2305                 $file_prune_regexp=qr/$file_prune_regexp/;
2306         }
2307         return $file =~ m/$file_prune_regexp/;
2308 }
2309
2310 sub define_gettext () {
2311         # If translation is needed, redefine the gettext function to do it.
2312         # Otherwise, it becomes a quick no-op.
2313         my $gettext_obj;
2314         my $getobj;
2315         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
2316             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
2317             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
2318                 $getobj=sub {
2319                         $gettext_obj=eval q{
2320                                 use Locale::gettext q{textdomain};
2321                                 Locale::gettext->domain('ikiwiki')
2322                         };
2323                 };
2324         }
2325
2326         no warnings 'redefine';
2327         *gettext=sub {
2328                 $getobj->() if $getobj;
2329                 if ($gettext_obj) {
2330                         $gettext_obj->get(shift);
2331                 }
2332                 else {
2333                         return shift;
2334                 }
2335         };
2336         *ngettext=sub {
2337                 $getobj->() if $getobj;
2338                 if ($gettext_obj) {
2339                         $gettext_obj->nget(@_);
2340                 }
2341                 else {
2342                         return ($_[2] == 1 ? $_[0] : $_[1])
2343                 }
2344         };
2345 }
2346
2347 sub gettext {
2348         define_gettext();
2349         gettext(@_);
2350 }
2351
2352 sub ngettext {
2353         define_gettext();
2354         ngettext(@_);
2355 }
2356
2357 sub yesno ($) {
2358         my $val=shift;
2359
2360         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
2361 }
2362
2363 sub inject {
2364         # Injects a new function into the symbol table to replace an
2365         # exported function.
2366         my %params=@_;
2367
2368         # This is deep ugly perl foo, beware.
2369         no strict;
2370         no warnings;
2371         if (! defined $params{parent}) {
2372                 $params{parent}='::';
2373                 $params{old}=\&{$params{name}};
2374                 $params{name}=~s/.*:://;
2375         }
2376         my $parent=$params{parent};
2377         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
2378                 $ns = $params{parent} . $ns;
2379                 inject(%params, parent => $ns) unless $ns eq '::main::';
2380                 *{$ns . $params{name}} = $params{call}
2381                         if exists ${$ns}{$params{name}} &&
2382                            \&{${$ns}{$params{name}}} == $params{old};
2383         }
2384         use strict;
2385         use warnings;
2386 }
2387
2388 sub add_link ($$;$) {
2389         my $page=shift;
2390         my $link=shift;
2391         my $type=shift;
2392
2393         push @{$links{$page}}, $link
2394                 unless grep { $_ eq $link } @{$links{$page}};
2395
2396         if (defined $type) {
2397                 $typedlinks{$page}{$type}{$link} = 1;
2398         }
2399 }
2400
2401 sub add_autofile ($$$) {
2402         my $file=shift;
2403         my $plugin=shift;
2404         my $generator=shift;
2405
2406         $autofiles{$file}{plugin}=$plugin;
2407         $autofiles{$file}{generator}=$generator;
2408 }
2409
2410 sub useragent () {
2411         return LWP::UserAgent->new(
2412                 cookie_jar => $config{cookiejar},
2413                 env_proxy => 1,         # respect proxy env vars
2414                 agent => $config{useragent},
2415         );
2416 }
2417
2418 sub sortspec_translate ($$) {
2419         my $spec = shift;
2420         my $reverse = shift;
2421
2422         my $code = "";
2423         my @data;
2424         while ($spec =~ m{
2425                 \s*
2426                 (-?)            # group 1: perhaps negated
2427                 \s*
2428                 (               # group 2: a word
2429                         \w+\([^\)]*\)   # command(params)
2430                         |
2431                         [^\s]+          # or anything else
2432                 )
2433                 \s*
2434         }gx) {
2435                 my $negated = $1;
2436                 my $word = $2;
2437                 my $params = undef;
2438
2439                 if ($word =~ m/^(\w+)\((.*)\)$/) {
2440                         # command with parameters
2441                         $params = $2;
2442                         $word = $1;
2443                 }
2444                 elsif ($word !~ m/^\w+$/) {
2445                         error(sprintf(gettext("invalid sort type %s"), $word));
2446                 }
2447
2448                 if (length $code) {
2449                         $code .= " || ";
2450                 }
2451
2452                 if ($negated) {
2453                         $code .= "-";
2454                 }
2455
2456                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
2457                         if (defined $params) {
2458                                 push @data, $params;
2459                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
2460                         }
2461                         else {
2462                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
2463                         }
2464                 }
2465                 else {
2466                         error(sprintf(gettext("unknown sort type %s"), $word));
2467                 }
2468         }
2469
2470         if (! length $code) {
2471                 # undefined sorting method... sort arbitrarily
2472                 return sub { 0 };
2473         }
2474
2475         if ($reverse) {
2476                 $code="-($code)";
2477         }
2478
2479         no warnings;
2480         return eval 'sub { '.$code.' }';
2481 }
2482
2483 sub pagespec_translate ($) {
2484         my $spec=shift;
2485
2486         # Convert spec to perl code.
2487         my $code="";
2488         my @data;
2489         while ($spec=~m{
2490                 \s*             # ignore whitespace
2491                 (               # 1: match a single word
2492                         \!              # !
2493                 |
2494                         \(              # (
2495                 |
2496                         \)              # )
2497                 |
2498                         \w+\([^\)]*\)   # command(params)
2499                 |
2500                         [^\s()]+        # any other text
2501                 )
2502                 \s*             # ignore whitespace
2503         }gx) {
2504                 my $word=$1;
2505                 if (lc $word eq 'and') {
2506                         $code.=' &';
2507                 }
2508                 elsif (lc $word eq 'or') {
2509                         $code.=' |';
2510                 }
2511                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2512                         $code.=' '.$word;
2513                 }
2514                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2515                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2516                                 push @data, $2;
2517                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2518                         }
2519                         else {
2520                                 push @data, qq{unknown function in pagespec "$word"};
2521                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2522                         }
2523                 }
2524                 else {
2525                         push @data, $word;
2526                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2527                 }
2528         }
2529
2530         if (! length $code) {
2531                 $code="IkiWiki::FailReason->new('empty pagespec')";
2532         }
2533
2534         no warnings;
2535         return eval 'sub { my $page=shift; '.$code.' }';
2536 }
2537
2538 sub pagespec_match ($$;@) {
2539         my $page=shift;
2540         my $spec=shift;
2541         my @params=@_;
2542
2543         # Backwards compatability with old calling convention.
2544         if (@params == 1) {
2545                 unshift @params, 'location';
2546         }
2547
2548         my $sub=pagespec_translate($spec);
2549         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2550                 if ! defined $sub;
2551         return $sub->($page, @params);
2552 }
2553
2554 # e.g. @pages = sort_pages("title", \@pages, reverse => "yes")
2555 #
2556 # Not exported yet, but could be in future if it is generally useful.
2557 # Note that this signature is not the same as IkiWiki::SortSpec::sort_pages,
2558 # which is "more internal".
2559 sub sort_pages ($$;@) {
2560         my $sort = shift;
2561         my $list = shift;
2562         my %params = @_;
2563         $sort = sortspec_translate($sort, $params{reverse});
2564         return IkiWiki::SortSpec::sort_pages($sort, @$list);
2565 }
2566
2567 sub pagespec_match_list ($$;@) {
2568         my $page=shift;
2569         my $pagespec=shift;
2570         my %params=@_;
2571
2572         # Backwards compatability with old calling convention.
2573         if (ref $page) {
2574                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2575                 $params{list}=$page;
2576                 $page=$params{location}; # ugh!
2577         }
2578
2579         my $sub=pagespec_translate($pagespec);
2580         error "syntax error in pagespec \"$pagespec\""
2581                 if ! defined $sub;
2582         my $sort=sortspec_translate($params{sort}, $params{reverse})
2583                 if defined $params{sort};
2584
2585         my @candidates;
2586         if (exists $params{list}) {
2587                 @candidates=exists $params{filter}
2588                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2589                         : @{$params{list}};
2590         }
2591         else {
2592                 @candidates=exists $params{filter}
2593                         ? grep { ! $params{filter}->($_) } keys %pagesources
2594                         : keys %pagesources;
2595         }
2596
2597         # clear params, remainder is passed to pagespec
2598         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2599         my $num=$params{num};
2600         delete @params{qw{num deptype reverse sort filter list}};
2601
2602         # when only the top matches will be returned, it's efficient to
2603         # sort before matching to pagespec,
2604         if (defined $num && defined $sort) {
2605                 @candidates=IkiWiki::SortSpec::sort_pages(
2606                         $sort, @candidates);
2607         }
2608
2609         my @matches;
2610         my $firstfail;
2611         my $count=0;
2612         my $accum=IkiWiki::SuccessReason->new();
2613         foreach my $p (@candidates) {
2614                 my $r=$sub->($p, %params, location => $page);
2615                 error(sprintf(gettext("cannot match pages: %s"), $r))
2616                         if $r->isa("IkiWiki::ErrorReason");
2617                 unless ($r || $r->influences_static) {
2618                         $r->remove_influence($p);
2619                 }
2620                 $accum |= $r;
2621                 if ($r) {
2622                         push @matches, $p;
2623                         last if defined $num && ++$count == $num;
2624                 }
2625         }
2626
2627         # Add simple dependencies for accumulated influences.
2628         my $i=$accum->influences;
2629         foreach my $k (keys %$i) {
2630                 $depends_simple{$page}{lc $k} |= $i->{$k};
2631         }
2632
2633         # when all matches will be returned, it's efficient to
2634         # sort after matching
2635         if (! defined $num && defined $sort) {
2636                 return IkiWiki::SortSpec::sort_pages(
2637                         $sort, @matches);
2638         }
2639         else {
2640                 return @matches;
2641         }
2642 }
2643
2644 sub pagespec_valid ($) {
2645         my $spec=shift;
2646
2647         return defined pagespec_translate($spec);
2648 }
2649
2650 sub glob2re ($) {
2651         my $re=quotemeta(shift);
2652         $re=~s/\\\*/.*/g;
2653         $re=~s/\\\?/./g;
2654         return qr/^$re$/i;
2655 }
2656
2657 package IkiWiki::FailReason;
2658
2659 use overload (
2660         '""'    => sub { $_[0][0] },
2661         '0+'    => sub { 0 },
2662         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2663         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2664         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2665         fallback => 1,
2666 );
2667
2668 our @ISA = 'IkiWiki::SuccessReason';
2669
2670 package IkiWiki::SuccessReason;
2671
2672 # A blessed array-ref:
2673 #
2674 # [0]: human-readable reason for success (or, in FailReason subclass, failure)
2675 # [1]{""}:
2676 #      - if absent or false, the influences of this evaluation are "static",
2677 #        see the influences_static method
2678 #      - if true, they are dynamic (not static)
2679 # [1]{any other key}:
2680 #      the dependency types of influences, as returned by the influences method
2681
2682 use overload (
2683         # in string context, it's the human-readable reason
2684         '""'    => sub { $_[0][0] },
2685         # in boolean context, SuccessReason is 1 and FailReason is 0
2686         '0+'    => sub { 1 },
2687         # negating a result gives the opposite result with the same influences
2688         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2689         # A & B = (A ? B : A) with the influences of both
2690         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2691         # A | B = (A ? A : B) with the influences of both
2692         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2693         fallback => 1,
2694 );
2695
2696 # SuccessReason->new("human-readable reason", page => deptype, ...)
2697
2698 sub new {
2699         my $class = shift;
2700         my $value = shift;
2701         return bless [$value, {@_}], $class;
2702 }
2703
2704 # influences(): return a reference to a copy of the hash
2705 # { page => dependency type } describing the pages that indirectly influenced
2706 # this result, but would not cause a dependency through ikiwiki's core
2707 # dependency logic.
2708 #
2709 # See [[todo/dependency_types]] for extensive discussion of what this means.
2710 #
2711 # influences(page => deptype, ...): remove all influences, replace them
2712 # with the arguments, and return a reference to a copy of the new influences.
2713
2714 sub influences {
2715         my $this=shift;
2716         $this->[1]={@_} if @_;
2717         my %i=%{$this->[1]};
2718         delete $i{""};
2719         return \%i;
2720 }
2721
2722 # True if this result has the same influences whichever page it matches,
2723 # For instance, whether bar matches backlink(foo) is influenced only by
2724 # the set of links in foo, so its only influence is { foo => DEPEND_LINKS },
2725 # which does not mention bar anywhere.
2726 #
2727 # False if this result would have different influences when matching
2728 # different pages. For instance, when testing whether link(foo) matches bar,
2729 # { bar => DEPEND_LINKS } is an influence on that result, because changing
2730 # bar's links could change the outcome; so its influences are not the same
2731 # as when testing whether link(foo) matches baz.
2732 #
2733 # Static influences are one of the things that make pagespec_match_list
2734 # more efficient than repeated calls to pagespec_match.
2735
2736 sub influences_static {
2737         return ! $_[0][1]->{""};
2738 }
2739
2740 # Change the influences of $this to be the influences of "$this & $other"
2741 # or "$this | $other".
2742 #
2743 # If both $this and $other are either successful or have influences,
2744 # or this is an "or" operation, the result has all the influences from
2745 # either of the arguments. It has dynamic influences if either argument
2746 # has dynamic influences.
2747 #
2748 # If this is an "and" operation, and at least one argument is a
2749 # FailReason with no influences, the result has no influences, and they
2750 # are not dynamic. For instance, link(foo) matching bar is influenced
2751 # by bar, but enabled(ddate) has no influences. Suppose ddate is disabled;
2752 # then (link(foo) and enabled(ddate)) not matching bar is not influenced by
2753 # bar, because it would be false however often you edit bar.
2754
2755 sub merge_influences {
2756         my $this=shift;
2757         my $other=shift;
2758         my $anded=shift;
2759
2760         # This "if" is odd because it needs to avoid negating $this
2761         # or $other, which would alter the objects in-place. Be careful.
2762         if (! $anded || (($this || %{$this->[1]}) &&
2763                          ($other || %{$other->[1]}))) {
2764                 foreach my $influence (keys %{$other->[1]}) {
2765                         $this->[1]{$influence} |= $other->[1]{$influence};
2766                 }
2767         }
2768         else {
2769                 # influence blocker
2770                 $this->[1]={};
2771         }
2772 }
2773
2774 # Change $this so it is not considered to be influenced by $torm.
2775
2776 sub remove_influence {
2777         my $this=shift;
2778         my $torm=shift;
2779
2780         delete $this->[1]{$torm};
2781 }
2782
2783 package IkiWiki::ErrorReason;
2784
2785 our @ISA = 'IkiWiki::FailReason';
2786
2787 package IkiWiki::PageSpec;
2788
2789 sub derel ($$) {
2790         my $path=shift;
2791         my $from=shift;
2792
2793         if ($path =~ m!^\.(/|$)!) {
2794                 if ($1) {
2795                         $from=~s#/?[^/]+$## if defined $from;
2796                         $path=~s#^\./##;
2797                         $path="$from/$path" if defined $from && length $from;
2798                 }
2799                 else {
2800                         $path = $from;
2801                         $path = "" unless defined $path;
2802                 }
2803         }
2804
2805         return $path;
2806 }
2807
2808 my %glob_cache;
2809
2810 sub match_glob ($$;@) {
2811         my $page=shift;
2812         my $glob=shift;
2813         my %params=@_;
2814
2815         $glob=derel($glob, $params{location});
2816
2817         # Instead of converting the glob to a regex every time,
2818         # cache the compiled regex to save time.
2819         my $re=$glob_cache{$glob};
2820         unless (defined $re) {
2821                 $glob_cache{$glob} = $re = IkiWiki::glob2re($glob);
2822         }
2823         if ($page =~ $re) {
2824                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2825                         return IkiWiki::SuccessReason->new("$glob matches $page");
2826                 }
2827                 else {
2828                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2829                 }
2830         }
2831         else {
2832                 return IkiWiki::FailReason->new("$glob does not match $page");
2833         }
2834 }
2835
2836 sub match_internal ($$;@) {
2837         return match_glob(shift, shift, @_, internal => 1)
2838 }
2839
2840 sub match_page ($$;@) {
2841         my $page=shift;
2842         my $match=match_glob($page, shift, @_);
2843         if ($match) {
2844                 my $source=exists $IkiWiki::pagesources{$page} ?
2845                         $IkiWiki::pagesources{$page} :
2846                         $IkiWiki::delpagesources{$page};
2847                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
2848                 if (! defined $type) {
2849                         return IkiWiki::FailReason->new("$page is not a page");
2850                 }
2851         }
2852         return $match;
2853 }
2854
2855 sub match_link ($$;@) {
2856         my $page=shift;
2857         my $link=lc(shift);
2858         my %params=@_;
2859
2860         $link=derel($link, $params{location});
2861         my $from=exists $params{location} ? $params{location} : '';
2862         my $linktype=$params{linktype};
2863         my $qualifier='';
2864         if (defined $linktype) {
2865                 $qualifier=" with type $linktype";
2866         }
2867
2868         my $links = $IkiWiki::links{$page};
2869         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2870                 unless $links && @{$links};
2871         my $bestlink = IkiWiki::bestlink($from, $link);
2872         foreach my $p (@{$links}) {
2873                 next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});
2874
2875                 if (length $bestlink) {
2876                         if ($bestlink eq IkiWiki::bestlink($page, $p)) {
2877                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2878                         }
2879                 }
2880                 else {
2881                         if (match_glob($p, $link, %params)) {
2882                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2883                         }
2884                         my ($p_rel)=$p=~/^\/?(.*)/;
2885                         $link=~s/^\///;
2886                         if (match_glob($p_rel, $link, %params)) {
2887                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2888                         }
2889                 }
2890         }
2891         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2892 }
2893
2894 sub match_backlink ($$;@) {
2895         my $page=shift;
2896         my $testpage=shift;
2897         my %params=@_;
2898         if ($testpage eq '.') {
2899                 $testpage = $params{'location'}
2900         }
2901         my $ret=match_link($testpage, $page, @_);
2902         $ret->influences($testpage => $IkiWiki::DEPEND_LINKS);
2903         return $ret;
2904 }
2905
2906 sub match_created_before ($$;@) {
2907         my $page=shift;
2908         my $testpage=shift;
2909         my %params=@_;
2910
2911         $testpage=derel($testpage, $params{location});
2912
2913         if (exists $IkiWiki::pagectime{$testpage}) {
2914                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2915                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2916                 }
2917                 else {
2918                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2919                 }
2920         }
2921         else {
2922                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2923         }
2924 }
2925
2926 sub match_created_after ($$;@) {
2927         my $page=shift;
2928         my $testpage=shift;
2929         my %params=@_;
2930
2931         $testpage=derel($testpage, $params{location});
2932
2933         if (exists $IkiWiki::pagectime{$testpage}) {
2934                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2935                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2936                 }
2937                 else {
2938                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2939                 }
2940         }
2941         else {
2942                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2943         }
2944 }
2945
2946 sub match_creation_day ($$;@) {
2947         my $page=shift;
2948         my $d=shift;
2949         if ($d !~ /^\d+$/) {
2950                 return IkiWiki::ErrorReason->new("invalid day $d");
2951         }
2952         if ((localtime($IkiWiki::pagectime{$page}))[3] == $d) {
2953                 return IkiWiki::SuccessReason->new('creation_day matched');
2954         }
2955         else {
2956                 return IkiWiki::FailReason->new('creation_day did not match');
2957         }
2958 }
2959
2960 sub match_creation_month ($$;@) {
2961         my $page=shift;
2962         my $m=shift;
2963         if ($m !~ /^\d+$/) {
2964                 return IkiWiki::ErrorReason->new("invalid month $m");
2965         }
2966         if ((localtime($IkiWiki::pagectime{$page}))[4] + 1 == $m) {
2967                 return IkiWiki::SuccessReason->new('creation_month matched');
2968         }
2969         else {
2970                 return IkiWiki::FailReason->new('creation_month did not match');
2971         }
2972 }
2973
2974 sub match_creation_year ($$;@) {
2975         my $page=shift;
2976         my $y=shift;
2977         if ($y !~ /^\d+$/) {
2978                 return IkiWiki::ErrorReason->new("invalid year $y");
2979         }
2980         if ((localtime($IkiWiki::pagectime{$page}))[5] + 1900 == $y) {
2981                 return IkiWiki::SuccessReason->new('creation_year matched');
2982         }
2983         else {
2984                 return IkiWiki::FailReason->new('creation_year did not match');
2985         }
2986 }
2987
2988 sub match_user ($$;@) {
2989         shift;
2990         my $user=shift;
2991         my %params=@_;
2992
2993         if (! exists $params{user}) {
2994                 return IkiWiki::ErrorReason->new("no user specified");
2995         }
2996
2997         my $regexp=IkiWiki::glob2re($user);
2998
2999         if (defined $params{user} && $params{user}=~$regexp) {
3000                 return IkiWiki::SuccessReason->new("user is $user");
3001         }
3002         elsif (! defined $params{user}) {
3003                 return IkiWiki::FailReason->new("not logged in");
3004         }
3005         else {
3006                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
3007         }
3008 }
3009
3010 sub match_admin ($$;@) {
3011         shift;
3012         shift;
3013         my %params=@_;
3014
3015         if (! exists $params{user}) {
3016                 return IkiWiki::ErrorReason->new("no user specified");
3017         }
3018
3019         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
3020                 return IkiWiki::SuccessReason->new("user is an admin");
3021         }
3022         elsif (! defined $params{user}) {
3023                 return IkiWiki::FailReason->new("not logged in");
3024         }
3025         else {
3026                 return IkiWiki::FailReason->new("user is not an admin");
3027         }
3028 }
3029
3030 sub match_ip ($$;@) {
3031         shift;
3032         my $ip=shift;
3033         my %params=@_;
3034
3035         if (! exists $params{ip}) {
3036                 return IkiWiki::ErrorReason->new("no IP specified");
3037         }
3038
3039         my $regexp=IkiWiki::glob2re(lc $ip);
3040
3041         if (defined $params{ip} && lc $params{ip}=~$regexp) {
3042                 return IkiWiki::SuccessReason->new("IP is $ip");
3043         }
3044         else {
3045                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
3046         }
3047 }
3048
3049 package IkiWiki::SortSpec;
3050
3051 # This is in the SortSpec namespace so that the $a and $b that sort() uses
3052 # are easily available in this namespace, for cmp functions to use them.
3053 sub sort_pages {
3054         my $f=shift;
3055         sort $f @_
3056 }
3057
3058 sub cmp_title {
3059         IkiWiki::pagetitle(IkiWiki::basename($a))
3060         cmp
3061         IkiWiki::pagetitle(IkiWiki::basename($b))
3062 }
3063
3064 sub cmp_path { IkiWiki::pagetitle($a) cmp IkiWiki::pagetitle($b) }
3065 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
3066 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
3067
3068 1