IkiWiki/Plugin/pinger.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::pinger;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 my %pages;
   9 my $pinged=0;
  10
  11 sub import {
  12         hook(type => "getsetup", id => "pinger", call => \&getsetup);
  13         hook(type => "needsbuild", id => "pinger", call => \&needsbuild);
  14         hook(type => "preprocess", id => "ping", call => \&preprocess);
  15         hook(type => "delete", id => "pinger", call => \&ping);
  16         hook(type => "rendered", id => "pinger", call => \&ping);
  17 }
  18
  19 sub getsetup () {
  20         return
  21                 plugin => {
  22                         safe => 1,
  23                         rebuild => 0,
  24                 },
  25                 pinger_timeout => {
  26                         type => "integer",
  27                         example => 15,
  28                         description => "how many seconds to try pinging before timing out",
  29                         safe => 1,
  30                         rebuild => 0,
  31                 },
  32 }
  33
  34 sub needsbuild (@) {
  35         my $needsbuild=shift;
  36         foreach my $page (keys %pagestate) {
  37                 if (exists $pagestate{$page}{pinger}) {
  38                         $pages{$page}=1;
  39                         if (exists $pagesources{$page} &&
  40                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  41                                 # remove state, will be re-added if
  42                                 # the ping directive is still present
  43                                 # on rebuild.
  44                                 delete $pagestate{$page}{pinger};
  45                         }
  46                 }
  47         }
  48         return $needsbuild;
  49 }
  50
  51 sub preprocess (@) {
  52         my %params=@_;
  53         if (! exists $params{from} || ! exists $params{to}) {
  54                 error gettext("requires 'from' and 'to' parameters");
  55         }
  56         if ($params{from} eq $config{url}) {
  57                 $pagestate{$params{destpage}}{pinger}{$params{to}}=1;
  58                 $pages{$params{destpage}}=1;
  59                 return sprintf(gettext("Will ping %s"), $params{to});
  60         }
  61         else {
  62                 return sprintf(gettext("Ignoring ping directive for wiki %s (this wiki is %s)"), $params{from}, $config{url});
  63         }
  64 }
  65
  66 sub ping {
  67         if (! $pinged && %pages) {
  68                 $pinged=1;
  69
  70                 eval q{use Net::INET6Glue::INET_is_INET6}; # may not be available
  71
  72                 my $ua;
  73                 eval {
  74                         # We pass the for_url parameter, even though it's
  75                         # undef, because that will make sure we crash if used
  76                         # with an older IkiWiki.pm that didn't automatically
  77                         # try to use LWPx::ParanoidAgent.
  78                         $ua=useragent(for_url => undef);
  79                 };
  80                 if ($@) {
  81                         debug(gettext("LWP not found, not pinging").": $@");
  82                         return;
  83                 }
  84                 $ua->timeout($config{pinger_timeout} || 15);
  85
  86                 # daemonise here so slow pings don't slow down wiki updates
  87                 defined(my $pid = fork) or error("Can't fork: $!");
  88                 return if $pid;
  89                 chdir '/';
  90                 open STDIN, '/dev/null';
  91                 open STDOUT, '>/dev/null';
  92                 POSIX::setsid() or error("Can't start a new session: $!");
  93                 open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
  94
  95                 # Don't need to keep a lock on the wiki as a daemon.
  96                 IkiWiki::unlockwiki();
  97
  98                 my %urls;
  99                 foreach my $page (%pages) {
 100                         if (exists $pagestate{$page}{pinger}) {
 101                                 $urls{$_}=1 foreach keys %{$pagestate{$page}{pinger}};
 102                         }
 103                 }
 104                 foreach my $url (keys %urls) {
 105                         # Try to avoid pinging ourselves. If this check
 106                         # fails, it's not the end of the world, since we
 107                         # only ping when a page was changed, so a ping loop
 108                         # will still be avoided.
 109                         next if $url=~/^\Q$config{cgiurl}\E/;
 110                         my $local_cgiurl = IkiWiki::cgiurl();
 111                         next if $url=~/^\Q$local_cgiurl\E/;
 112
 113                         $ua->get($url);
 114                 }
 115
 116                 exit 0;
 117         }
 118 }
 119
 120 1