IkiWiki/Plugin/rename.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::rename;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 2.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "rename", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "rename", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "rename", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "rename", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22 }
  23
  24 sub check_canrename ($$$$$$) {
  25         my $src=shift;
  26         my $srcfile=shift;
  27         my $dest=shift;
  28         my $destfile=shift;
  29         my $q=shift;
  30         my $session=shift;
  31
  32         my $attachment=! defined pagetype($pagesources{$src});
  33
  34         # Must be a known source file.
  35         if (! exists $pagesources{$src}) {
  36                 error(sprintf(gettext("%s does not exist"),
  37                         htmllink("", "", $src, noimageinline => 1)));
  38         }
  39
  40         # Must exist on disk, and be a regular file.
  41         if (! -e "$config{srcdir}/$srcfile") {
  42                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be renamed"), $srcfile));
  43         }
  44         elsif (-l "$config{srcdir}/$srcfile" && ! -f _) {
  45                 error(sprintf(gettext("%s is not a file"), $srcfile));
  46         }
  47
  48         # Must be editable.
  49         IkiWiki::check_canedit($src, $q, $session);
  50         if ($attachment) {
  51                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  52                         IkiWiki::Plugin::attachment::check_canattach($session, $src, $srcfile);
  53                 }
  54                 else {
  55                         error("renaming of attachments is not allowed");
  56                 }
  57         }
  58
  59         # Dest checks can be omitted by passing undef.
  60         if (defined $dest) {
  61                 if ($srcfile eq $destfile) {
  62                         error(gettext("no change to the file name was specified"));
  63                 }
  64
  65                 # Must be a legal filename, and not absolute.
  66                 if (IkiWiki::file_pruned($destfile, $config{srcdir}) ||
  67                     $destfile=~/^\//) {
  68                         error(sprintf(gettext("illegal name")));
  69                 }
  70
  71                 # Must not be a known source file.
  72                 if ($src ne $dest && exists $pagesources{$dest}) {
  73                         error(sprintf(gettext("%s already exists"),
  74                                 htmllink("", "", $dest, noimageinline => 1)));
  75                 }
  76
  77                 # Must not exist on disk already.
  78                 if (-l "$config{srcdir}/$destfile" || -e _) {
  79                         error(sprintf(gettext("%s already exists on disk"), $destfile));
  80                 }
  81
  82                 # Must be editable.
  83                 IkiWiki::check_canedit($dest, $q, $session);
  84                 if ($attachment) {
  85                         # Note that $srcfile is used here, not $destfile,
  86                         # because it wants the current file, to check it.
  87                         IkiWiki::Plugin::attachment::check_canattach($session, $dest, $srcfile);
  88                 }
  89         }
  90 }
  91
  92 sub rename_form ($$$) {
  93         my $q=shift;
  94         my $session=shift;
  95         my $page=shift;
  96
  97         eval q{use CGI::FormBuilder};
  98         error($@) if $@;
  99         my $f = CGI::FormBuilder->new(
 100                 name => "rename",
 101                 title => sprintf(gettext("rename %s"), pagetitle($page)),
 102                 header => 0,
 103                 charset => "utf-8",
 104                 method => 'POST',
 105                 javascript => 0,
 106                 params => $q,
 107                 action => $config{cgiurl},
 108                 stylesheet => IkiWiki::baseurl()."style.css",
 109                 fields => [qw{do page new_name attachment}],
 110         );
 111
 112         $f->field(name => "do", type => "hidden", value => "rename", force => 1);
 113         $f->field(name => "page", type => "hidden", value => $page, force => 1);
 114         $f->field(name => "new_name", value => pagetitle($page, 1), size => 60);
 115         if (!$q->param("attachment")) {
 116                 # insert the standard extensions
 117                 my @page_types;
 118                 if (exists $IkiWiki::hooks{htmlize}) {
 119                         @page_types=grep { !/^_/ }
 120                                 keys %{$IkiWiki::hooks{htmlize}};
 121                 }
 122
 123                 # make sure the current extension is in the list
 124                 my ($ext) = $pagesources{$page}=~/\.([^.]+)$/;
 125                 if (! $IkiWiki::hooks{htmlize}{$ext}) {
 126                         unshift(@page_types, $ext);
 127                 }
 128
 129                 $f->field(name => "type", type => 'select',
 130                         options => \@page_types,
 131                         value => $ext, force => 1);
 132
 133                 foreach my $p (keys %pagesources) {
 134                         if ($pagesources{$p}=~m/^\Q$page\E\//) {
 135                                 $f->field(name => "subpages",
 136                                         label => "",
 137                                         type => "checkbox",
 138                                         options => [ [ 1 => gettext("Also rename SubPages and attachments") ] ],
 139                                         value => 1,
 140                                         force => 1);
 141                                 last;
 142                         }
 143                 }
 144         }
 145         $f->field(name => "attachment", type => "hidden");
 146
 147         return $f, ["Rename", "Cancel"];
 148 }
 149
 150 sub rename_start ($$$$) {
 151         my $q=shift;
 152         my $session=shift;
 153         my $attachment=shift;
 154         my $page=shift;
 155
 156         check_canrename($page, $pagesources{$page}, undef, undef,
 157                 $q, $session);
 158
 159         # Save current form state to allow returning to it later
 160         # without losing any edits.
 161         # (But don't save what button was submitted, to avoid
 162         # looping back to here.)
 163         # Note: "_submit" is CGI::FormBuilder internals.
 164         $q->param(-name => "_submit", -value => "");
 165         $session->param(postrename => scalar $q->Vars);
 166         IkiWiki::cgi_savesession($session);
 167
 168         if (defined $attachment) {
 169                 $q->param(-name => "attachment", -value => $attachment);
 170         }
 171         my ($f, $buttons)=rename_form($q, $session, $page);
 172         IkiWiki::showform($f, $buttons, $session, $q);
 173         exit 0;
 174 }
 175
 176 sub postrename ($;$$$) {
 177         my $session=shift;
 178         my $src=shift;
 179         my $dest=shift;
 180         my $attachment=shift;
 181
 182         # Load saved form state and return to edit page.
 183         my $postrename=CGI->new($session->param("postrename"));
 184         $session->clear("postrename");
 185         IkiWiki::cgi_savesession($session);
 186
 187         if (defined $dest) {
 188                 if (! $attachment) {
 189                         # They renamed the page they were editing. This requires
 190                         # fixups to the edit form state.
 191                         # Tweak the edit form to be editing the new page.
 192                         $postrename->param("page", $dest);
 193                 }
 194
 195                 # Update edit form content to fix any links present
 196                 # on it.
 197                 $postrename->param("editcontent",
 198                         renamelink_hook($dest, $src, $dest,
 199                                  $postrename->param("editcontent")));
 200
 201                 # Get a new edit token; old was likely invalidated.
 202                 $postrename->param("rcsinfo",
 203                         IkiWiki::rcs_prepedit($pagesources{$dest}));
 204         }
 205
 206         IkiWiki::cgi_editpage($postrename, $session);
 207 }
 208
 209 sub formbuilder (@) {
 210         my %params=@_;
 211         my $form=$params{form};
 212
 213         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 214             $form->field("do") eq "create")) {
 215                 my $q=$params{cgi};
 216                 my $session=$params{session};
 217
 218                 if ($form->submitted eq "Rename" && $form->field("do") eq "edit") {
 219                         rename_start($q, $session, 0, $form->field("page"));
 220                 }
 221                 elsif ($form->submitted eq "Rename Attachment") {
 222                         my @selected=$q->param("attachment_select");
 223                         if (@selected > 1) {
 224                                 error(gettext("Only one attachment can be renamed at a time."));
 225                         }
 226                         elsif (! @selected) {
 227                                 error(gettext("Please select the attachment to rename."))
 228                         }
 229                         rename_start($q, $session, 1, $selected[0]);
 230                 }
 231         }
 232 }
 233
 234 my $renamesummary;
 235
 236 sub formbuilder_setup (@) {
 237         my %params=@_;
 238         my $form=$params{form};
 239         my $q=$params{cgi};
 240
 241         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 242             $form->field("do") eq "create")) {
 243                 # Rename button for the page, and also for attachments.
 244                 push @{$params{buttons}}, "Rename" if $form->field("do") eq "edit";
 245                 $form->tmpl_param("field-rename" => '<input name="_submit" type="submit" value="Rename Attachment" />');
 246
 247                 if (defined $renamesummary) {
 248                         $form->tmpl_param(message => $renamesummary);
 249                 }
 250         }
 251 }
 252
 253 sub sessioncgi ($$) {
 254         my $q=shift;
 255
 256         if ($q->param("do") eq 'rename') {
 257                 my $session=shift;
 258                 my ($form, $buttons)=rename_form($q, $session, $q->param("page"));
 259                 IkiWiki::decode_form_utf8($form);
 260
 261                 if ($form->submitted eq 'Cancel') {
 262                         postrename($session);
 263                 }
 264                 elsif ($form->submitted eq 'Rename' && $form->validate) {
 265                         # Queue of rename actions to perfom.
 266                         my @torename;
 267
 268                         # These untaints are safe because of the checks
 269                         # performed in check_canrename later.
 270                         my $src=$q->param("page");
 271                         my $srcfile=IkiWiki::possibly_foolish_untaint($pagesources{$src});
 272                         my $dest=IkiWiki::possibly_foolish_untaint(titlepage($q->param("new_name")));
 273                         my $destfile=$dest;
 274                         if (! $q->param("attachment")) {
 275                                 my $type=$q->param('type');
 276                                 if (defined $type && length $type && $IkiWiki::hooks{htmlize}{$type}) {
 277                                         $type=IkiWiki::possibly_foolish_untaint($type);
 278                                 }
 279                                 else {
 280                                         my ($ext)=$srcfile=~/\.([^.]+)$/;
 281                                         $type=$ext;
 282                                 }
 283
 284                                 $destfile=newpagefile($dest, $type);
 285                         }
 286                         push @torename, {
 287                                 src => $src,
 288                                 srcfile => $srcfile,
 289                                 dest => $dest,
 290                                 destfile => $destfile,
 291                                 required => 1,
 292                         };
 293
 294                         IkiWiki::run_hooks(rename => sub { shift->(\@torename); });
 295
 296                         # See if any subpages need to be renamed.
 297                         if ($q->param("subpages") && $src ne $dest) {
 298                                 foreach my $p (keys %pagesources) {
 299                                         next unless $pagesources{$p}=~m/^\Q$src\E\//;
 300                                         # If indexpages is enabled, the
 301                                         # srcfile should not be confused
 302                                         # with a subpage.
 303                                         next if $pagesources{$p} eq $srcfile;
 304
 305                                         my $d=$pagesources{$p};
 306                                         $d=~s/^\Q$src\E\//$dest\//;
 307                                         push @torename, {
 308                                                 src => $p,
 309                                                 srcfile => $pagesources{$p},
 310                                                 dest => pagename($d),
 311                                                 destfile => $d,
 312                                                 required => 0,
 313                                         };
 314                                 }
 315                         }
 316
 317                         require IkiWiki::Render;
 318                         IkiWiki::disable_commit_hook() if $config{rcs};
 319                         my %origpagesources=%pagesources;
 320
 321                         # First file renaming.
 322                         foreach my $rename (@torename) {
 323                                 if ($rename->{required}) {
 324                                         do_rename($rename, $q, $session);
 325                                 }
 326                                 else {
 327                                         eval {do_rename($rename, $q, $session)};
 328                                         if ($@) {
 329                                                 $rename->{error}=$@;
 330                                                 next;
 331                                         }
 332                                 }
 333
 334                                 # Temporarily tweak pagesources to point to
 335                                 # the renamed file, in case fixlinks needs
 336                                 # to edit it.
 337                                 $pagesources{$rename->{src}}=$rename->{destfile};
 338                         }
 339                         IkiWiki::rcs_commit_staged(
 340                                 sprintf(gettext("rename %s to %s"), $srcfile, $destfile),
 341                                 $session->param("name"), $ENV{REMOTE_ADDR}) if $config{rcs};
 342
 343                         # Then link fixups.
 344                         foreach my $rename (@torename) {
 345                                 next if $rename->{src} eq $rename->{dest};
 346                                 next if $rename->{error};
 347                                 foreach my $p (fixlinks($rename, $session)) {
 348                                         # map old page names to new
 349                                         foreach my $r (@torename) {
 350                                                 next if $rename->{error};
 351                                                 if ($r->{src} eq $p) {
 352                                                         $p=$r->{dest};
 353                                                         last;
 354                                                 }
 355                                         }
 356                                         push @{$rename->{fixedlinks}}, $p;
 357                                 }
 358                         }
 359
 360                         # Then refresh.
 361                         %pagesources=%origpagesources;
 362                         if ($config{rcs}) {
 363                                 IkiWiki::enable_commit_hook();
 364                                 IkiWiki::rcs_update();
 365                         }
 366                         IkiWiki::refresh();
 367                         IkiWiki::saveindex();
 368
 369                         # Find pages with remaining, broken links.
 370                         foreach my $rename (@torename) {
 371                                 next if $rename->{src} eq $rename->{dest};
 372
 373                                 foreach my $page (keys %links) {
 374                                         my $broken=0;
 375                                         foreach my $link (@{$links{$page}}) {
 376                                                 my $bestlink=bestlink($page, $link);
 377                                                 if ($bestlink eq $rename->{src}) {
 378                                                         push @{$rename->{brokenlinks}}, $page;
 379                                                         last;
 380                                                 }
 381                                         }
 382                                 }
 383                         }
 384
 385                         # Generate a summary, that will be shown at the top
 386                         # of the edit template.
 387                         $renamesummary="";
 388                         foreach my $rename (@torename) {
 389                                 my $template=template("renamesummary.tmpl");
 390                                 $template->param(src => $rename->{srcfile});
 391                                 $template->param(dest => $rename->{destfile});
 392                                 $template->param(error => $rename->{error});
 393                                 if ($rename->{src} ne $rename->{dest}) {
 394                                         $template->param(brokenlinks_checked => 1);
 395                                         $template->param(brokenlinks => [
 396                                                 map {
 397                                                         {
 398                                                                 page => htmllink($rename->{dest}, $rename->{dest}, $_,
 399                                                                                 noimageinline => 1)
 400                                                         }
 401                                                 } @{$rename->{brokenlinks}}
 402                                         ]);
 403                                         $template->param(fixedlinks => [
 404                                                 map {
 405                                                         {
 406                                                                 page => htmllink($rename->{dest}, $rename->{dest}, $_,
 407                                                                                 noimageinline => 1)
 408                                                         }
 409                                                 } @{$rename->{fixedlinks}}
 410                                         ]);
 411                                 }
 412                                 $renamesummary.=$template->output;
 413                         }
 414
 415                         postrename($session, $src, $dest, $q->param("attachment"));
 416                 }
 417                 else {
 418                         IkiWiki::showform($form, $buttons, $session, $q);
 419                 }
 420
 421                 exit 0;
 422         }
 423 }
 424
 425 sub renamelink_hook ($$$$) {
 426         my ($page, $src, $dest, $content)=@_;
 427
 428         IkiWiki::run_hooks(renamelink => sub {
 429                 $content=shift->(
 430                         page => $page,
 431                         oldpage => $src,
 432                         newpage => $dest,
 433                         content => $content,
 434                 );
 435         });
 436
 437         return $content;
 438 }
 439
 440 sub do_rename ($$$) {
 441         my $rename=shift;
 442         my $q=shift;
 443         my $session=shift;
 444
 445         # First, check if this rename is allowed.
 446         check_canrename($rename->{src},
 447                 $rename->{srcfile},
 448                 $rename->{dest},
 449                 $rename->{destfile},
 450                 $q, $session);
 451
 452         # Ensure that the dest directory exists and is ok.
 453         IkiWiki::prep_writefile($rename->{destfile}, $config{srcdir});
 454
 455         if ($config{rcs}) {
 456                 IkiWiki::rcs_rename($rename->{srcfile}, $rename->{destfile});
 457         }
 458         else {
 459                 if (! rename($config{srcdir}."/".$rename->{srcfile},
 460                              $config{srcdir}."/".$rename->{destfile})) {
 461                         error("rename: $!");
 462                 }
 463         }
 464
 465 }
 466
 467 sub fixlinks ($$$) {
 468         my $rename=shift;
 469         my $session=shift;
 470
 471         my @fixedlinks;
 472
 473         foreach my $page (keys %links) {
 474                 my $needfix=0;
 475                 foreach my $link (@{$links{$page}}) {
 476                         my $bestlink=bestlink($page, $link);
 477                         if ($bestlink eq $rename->{src}) {
 478                                 $needfix=1;
 479                                 last;
 480                         }
 481                 }
 482                 if ($needfix) {
 483                         my $file=$pagesources{$page};
 484                         my $oldcontent=readfile($config{srcdir}."/".$file);
 485                         my $content=renamelink_hook($page, $rename->{src}, $rename->{dest}, $oldcontent);
 486                         if ($oldcontent ne $content) {
 487                                 my $token=IkiWiki::rcs_prepedit($file);
 488                                 eval { writefile($file, $config{srcdir}, $content) };
 489                                 next if $@;
 490                                 my $conflict=IkiWiki::rcs_commit(
 491                                         $file,
 492                                         sprintf(gettext("update for rename of %s to %s"), $rename->{srcfile}, $rename->{destfile}),
 493                                         $token,
 494                                         $session->param("name"),
 495                                         $ENV{REMOTE_ADDR}
 496                                 );
 497                                 push @fixedlinks, $page if ! defined $conflict;
 498                         }
 499                 }
 500         }
 501
 502         return @fixedlinks;
 503 }
 504
 505 1