IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                         section => "core",
  53                 },
  54                 rss => {
  55                         type => "boolean",
  56                         example => 0,
  57                         description => "enable rss feeds by default?",
  58                         safe => 1,
  59                         rebuild => 1,
  60                 },
  61                 atom => {
  62                         type => "boolean",
  63                         example => 0,
  64                         description => "enable atom feeds by default?",
  65                         safe => 1,
  66                         rebuild => 1,
  67                 },
  68                 allowrss => {
  69                         type => "boolean",
  70                         example => 0,
  71                         description => "allow rss feeds to be used?",
  72                         safe => 1,
  73                         rebuild => 1,
  74                 },
  75                 allowatom => {
  76                         type => "boolean",
  77                         example => 0,
  78                         description => "allow atom feeds to be used?",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 pingurl => {
  83                         type => "string",
  84                         example => "http://rpc.technorati.com/rpc/ping",
  85                         description => "urls to ping (using XML-RPC) on feed update",
  86                         safe => 1,
  87                         rebuild => 0,
  88                 },
  89 }
  90
  91 sub checkconfig () {
  92         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  93                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  94         }
  95         if ($config{rss}) {
  96                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  97         }
  98         if ($config{atom}) {
  99                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
 100         }
 101         if (! exists $config{pingurl}) {
 102                 $config{pingurl}=[];
 103         }
 104 }
 105
 106 sub format (@) {
 107         my %params=@_;
 108
 109         # Fill in the inline content generated earlier. This is actually an
 110         # optimisation.
 111         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 112                 delete @inline[$1,]
 113         }eg;
 114         return $params{content};
 115 }
 116
 117 sub sessioncgi ($$) {
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if ($q->param('do') eq 'blog') {
 122                 my $page=titlepage(decode_utf8($q->param('title')));
 123                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 124                 # if the page already exists, munge it to be unique
 125                 my $from=$q->param('from');
 126                 my $add="";
 127                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 128                         $add=1 unless length $add;
 129                         $add++;
 130                 }
 131                 $q->param('page', $page.$add);
 132                 # now go create the page
 133                 $q->param('do', 'create');
 134                 # make sure the editpage plugin in loaded
 135                 if (IkiWiki->can("cgi_editpage")) {
 136                         IkiWiki::cgi_editpage($q, $session);
 137                 }
 138                 else {
 139                         error(gettext("page editing not allowed"));
 140                 }
 141                 exit;
 142         }
 143 }
 144
 145 # Back to ikiwiki namespace for the rest, this code is very much
 146 # internal to ikiwiki even though it's separated into a plugin.
 147 package IkiWiki;
 148
 149 my %toping;
 150 my %feedlinks;
 151
 152 sub preprocess_inline (@) {
 153         my %params=@_;
 154
 155         if (! exists $params{pages} && ! exists $params{pagenames}) {
 156                 error gettext("missing pages parameter");
 157         }
 158         my $raw=yesno($params{raw});
 159         my $archive=yesno($params{archive});
 160         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 161         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 162         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 163         my $feeds=! $nested && (exists $params{feeds} ? yesno($params{feeds}) : !$quick);
 164         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 165         my $feedonly=yesno($params{feedonly});
 166         if (! exists $params{show} && ! $archive) {
 167                 $params{show}=10;
 168         }
 169         if (! exists $params{feedshow} && exists $params{show}) {
 170                 $params{feedshow}=$params{show};
 171         }
 172         my $desc;
 173         if (exists $params{description}) {
 174                 $desc = $params{description}
 175         }
 176         else {
 177                 $desc = $config{wikiname};
 178         }
 179         my $actions=yesno($params{actions});
 180         if (exists $params{template}) {
 181                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 182         }
 183         else {
 184                 $params{template} = $archive ? "archivepage" : "inlinepage";
 185         }
 186
 187         my @list;
 188
 189         if (exists $params{pagenames}) {
 190                 foreach my $p (qw(sort pages)) {
 191                         if (exists $params{$p}) {
 192                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 193                                         "pagenames", $p);
 194                         }
 195                 }
 196
 197                 @list = map { bestlink($params{page}, $_) }
 198                         split ' ', $params{pagenames};
 199
 200                 if (yesno($params{reverse})) {
 201                         @list=reverse(@list);
 202                 }
 203
 204                 foreach my $p (@list) {
 205                         add_depends($params{page}, $p, deptype($quick ? "presence" : "content"));
 206                 }
 207         }
 208         else {
 209                 my $num=0;
 210                 if ($params{show}) {
 211                         $num=$params{show};
 212                 }
 213                 if ($params{feedshow} && $num < $params{feedshow} && $num > 0) {
 214                         $num=$params{feedshow};
 215                 }
 216                 if ($params{skip} && $num) {
 217                         $num+=$params{skip};
 218                 }
 219
 220                 @list = pagespec_match_list($params{page}, $params{pages},
 221                         deptype => deptype($quick ? "presence" : "content"),
 222                         filter => sub { $_[0] eq $params{page} },
 223                         sort => exists $params{sort} ? $params{sort} : "age",
 224                         reverse => yesno($params{reverse}),
 225                         ($num ? (num => $num) : ()),
 226                 );
 227         }
 228
 229         if (exists $params{skip}) {
 230                 @list=@list[$params{skip} .. $#list];
 231         }
 232
 233         my @feedlist;
 234         if ($feeds) {
 235                 if (exists $params{feedshow} &&
 236                     $params{feedshow} && @list > $params{feedshow}) {
 237                         @feedlist=@list[0..$params{feedshow} - 1];
 238                 }
 239                 else {
 240                         @feedlist=@list;
 241                 }
 242         }
 243
 244         if ($params{show} && @list > $params{show}) {
 245                 @list=@list[0..$params{show} - 1];
 246         }
 247
 248         if ($feeds && exists $params{feedpages}) {
 249                 @feedlist = pagespec_match_list(
 250                         $params{page}, "($params{pages}) and ($params{feedpages})",
 251                         deptype => deptype($quick ? "presence" : "content"),
 252                         list => \@feedlist,
 253                 );
 254         }
 255
 256         my ($feedbase, $feednum);
 257         if ($feeds) {
 258                 # Ensure that multiple feeds on a page go to unique files.
 259
 260                 # Feedfile can lead to conflicts if usedirs is not enabled,
 261                 # so avoid supporting it in that case.
 262                 delete $params{feedfile} if ! $config{usedirs};
 263                 # Tight limits on legal feedfiles, to avoid security issues
 264                 # and conflicts.
 265                 if (defined $params{feedfile}) {
 266                         if ($params{feedfile} =~ /\// ||
 267                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 268                                 error("illegal feedfile");
 269                         }
 270                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 271                 }
 272                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 273
 274                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 275                 if (exists $knownfeeds{$feedid}) {
 276                         $feednum=$knownfeeds{$feedid};
 277                 }
 278                 else {
 279                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 280                                 if ($feeds) {
 281                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 282                                 }
 283                         }
 284                         else {
 285                                 $feednum=$knownfeeds{$feedid}="";
 286                                 if ($feeds) {
 287                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 288                                 }
 289                         }
 290                 }
 291         }
 292
 293         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 294         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 295
 296         my $ret="";
 297
 298         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 299             (exists $params{postform} && yesno($params{postform}))) &&
 300             IkiWiki->can("cgi_editpage")) {
 301                 # Add a blog post form, with feed buttons.
 302                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 303                 $formtemplate->param(cgiurl => $config{cgiurl});
 304                 $formtemplate->param(rootpage => rootpage(%params));
 305                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 306                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 307                 if (exists $params{postformtext}) {
 308                         $formtemplate->param(postformtext =>
 309                                 $params{postformtext});
 310                 }
 311                 else {
 312                         $formtemplate->param(postformtext =>
 313                                 gettext("Add a new post titled:"));
 314                 }
 315                 $ret.=$formtemplate->output;
 316
 317                 # The post form includes the feed buttons, so
 318                 # emptyfeeds cannot be hidden.
 319                 $emptyfeeds=1;
 320         }
 321         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 322                 # Add feed buttons.
 323                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 324                 $linktemplate->param(rssurl => $rssurl) if $rss;
 325                 $linktemplate->param(atomurl => $atomurl) if $atom;
 326                 $ret.=$linktemplate->output;
 327         }
 328
 329         if (! $feedonly) {
 330                 require HTML::Template;
 331                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 332                 if (! @params) {
 333                         error sprintf(gettext("nonexistant template %s"), $params{template});
 334                 }
 335                 my $template=HTML::Template->new(@params) unless $raw;
 336                 my $needcontent=$raw || (!($archive && $quick) && $template->query(name => 'content'));
 337
 338                 foreach my $page (@list) {
 339                         my $file = $pagesources{$page};
 340                         my $type = pagetype($file);
 341                         if (! $raw) {
 342                                 if ($needcontent) {
 343                                         # Get the content before populating the
 344                                         # template, since getting the content uses
 345                                         # the same template if inlines are nested.
 346                                         my $content=get_inline_content($page, $params{destpage});
 347                                         $template->param(content => $content);
 348                                 }
 349                                 $template->param(pageurl => urlto($page, $params{destpage}));
 350                                 $template->param(inlinepage => $page);
 351                                 $template->param(title => pagetitle(basename($page)));
 352                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 353                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 354                                 $template->param(first => 1) if $page eq $list[0];
 355                                 $template->param(last => 1) if $page eq $list[$#list];
 356
 357                                 if ($actions) {
 358                                         my $file = $pagesources{$page};
 359                                         my $type = pagetype($file);
 360                                         if ($config{discussion}) {
 361                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 362                                                     (length $config{cgiurl} ||
 363                                                      exists $pagesources{$page."/".lc($config{discussionpage})})) {
 364                                                         $template->param(have_actions => 1);
 365                                                         $template->param(discussionlink =>
 366                                                                 htmllink($page,
 367                                                                         $params{destpage},
 368                                                                         $config{discussionpage},
 369                                                                         noimageinline => 1,
 370                                                                         forcesubpage => 1));
 371                                                 }
 372                                         }
 373                                         if (length $config{cgiurl} &&
 374                                             defined $type &&
 375                                             IkiWiki->can("cgi_editpage")) {
 376                                                 $template->param(have_actions => 1);
 377                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 378
 379                                         }
 380                                 }
 381
 382                                 run_hooks(pagetemplate => sub {
 383                                         shift->(page => $page, destpage => $params{destpage},
 384                                                 template => $template,);
 385                                 });
 386
 387                                 $ret.=$template->output;
 388                                 $template->clear_params;
 389                         }
 390                         else {
 391                                 if (defined $type) {
 392                                         $ret.="\n".
 393                                               linkify($page, $params{destpage},
 394                                               preprocess($page, $params{destpage},
 395                                               filter($page, $params{destpage},
 396                                               readfile(srcfile($file)))));
 397                                 }
 398                                 else {
 399                                         $ret.="\n".
 400                                               readfile(srcfile($file));
 401                                 }
 402                         }
 403                 }
 404         }
 405
 406         if ($feeds && ($emptyfeeds || @feedlist)) {
 407                 if ($rss) {
 408                         my $rssp=$feedbase."rss".$feednum;
 409                         will_render($params{destpage}, $rssp);
 410                         if (! $params{preview}) {
 411                                 writefile($rssp, $config{destdir},
 412                                         genfeed("rss",
 413                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 414                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 415                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 416                         }
 417                 }
 418                 if ($atom) {
 419                         my $atomp=$feedbase."atom".$feednum;
 420                         will_render($params{destpage}, $atomp);
 421                         if (! $params{preview}) {
 422                                 writefile($atomp, $config{destdir},
 423                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 424                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 425                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 426                         }
 427                 }
 428         }
 429
 430         clear_inline_content_cache();
 431
 432         return $ret if $raw || $nested;
 433         push @inline, $ret;
 434         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 435 }
 436
 437 sub pagetemplate_inline (@) {
 438         my %params=@_;
 439         my $page=$params{page};
 440         my $template=$params{template};
 441
 442         $template->param(feedlinks => $feedlinks{$page})
 443                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 444 }
 445
 446 {
 447 my %inline_content;
 448 my $cached_destpage="";
 449
 450 sub get_inline_content ($$) {
 451         my $page=shift;
 452         my $destpage=shift;
 453
 454         if (exists $inline_content{$page} && $cached_destpage eq $destpage) {
 455                 return $inline_content{$page};
 456         }
 457
 458         my $file=$pagesources{$page};
 459         my $type=pagetype($file);
 460         my $ret="";
 461         if (defined $type) {
 462                 $nested++;
 463                 $ret=htmlize($page, $destpage, $type,
 464                        linkify($page, $destpage,
 465                        preprocess($page, $destpage,
 466                        filter($page, $destpage,
 467                        readfile(srcfile($file))))));
 468                 $nested--;
 469         }
 470
 471         if ($cached_destpage ne $destpage) {
 472                 clear_inline_content_cache();
 473                 $cached_destpage=$destpage;
 474         }
 475         return $inline_content{$page}=$ret;
 476 }
 477
 478 sub clear_inline_content_cache () {
 479         %inline_content=();
 480 }
 481
 482 }
 483
 484 sub date_822 ($) {
 485         my $time=shift;
 486
 487         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 488         POSIX::setlocale(&POSIX::LC_TIME, "C");
 489         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 490         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 491         return $ret;
 492 }
 493
 494 sub date_3339 ($) {
 495         my $time=shift;
 496
 497         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 498         POSIX::setlocale(&POSIX::LC_TIME, "C");
 499         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 500         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 501         return $ret;
 502 }
 503
 504 sub absolute_urls ($$) {
 505         # sucky sub because rss sucks
 506         my $content=shift;
 507         my $baseurl=shift;
 508
 509         my $url=$baseurl;
 510         $url=~s/[^\/]+$//;
 511
 512         # what is the non path part of the url?
 513         my $top_uri = URI->new($url);
 514         $top_uri->path_query(""); # reset the path
 515         my $urltop = $top_uri->as_string;
 516
 517         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 518         # relative to another wiki page
 519         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 520         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 521         # relative to the top of the site
 522         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 523         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 524         return $content;
 525 }
 526
 527 sub genfeed ($$$$$@) {
 528         my $feedtype=shift;
 529         my $feedurl=shift;
 530         my $feeddesc=shift;
 531         my $guid=shift;
 532         my $page=shift;
 533         my @pages=@_;
 534
 535         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 536
 537         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 538         my $content="";
 539         my $lasttime = 0;
 540         foreach my $p (@pages) {
 541                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 542                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 543
 544                 $itemtemplate->param(
 545                         title => pagetitle(basename($p)),
 546                         url => $u,
 547                         permalink => $u,
 548                         cdate_822 => date_822($pagectime{$p}),
 549                         mdate_822 => date_822($pagemtime{$p}),
 550                         cdate_3339 => date_3339($pagectime{$p}),
 551                         mdate_3339 => date_3339($pagemtime{$p}),
 552                 );
 553
 554                 if (exists $pagestate{$p}) {
 555                         if (exists $pagestate{$p}{meta}{guid}) {
 556                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 557                         }
 558
 559                         if (exists $pagestate{$p}{meta}{updated}) {
 560                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 561                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 562                         }
 563                 }
 564
 565                 if ($itemtemplate->query(name => "enclosure")) {
 566                         my $file=$pagesources{$p};
 567                         my $type=pagetype($file);
 568                         if (defined $type) {
 569                                 $itemtemplate->param(content => $pcontent);
 570                         }
 571                         else {
 572                                 my $size=(srcfile_stat($file))[8];
 573                                 my $mime="unknown";
 574                                 eval q{use File::MimeInfo};
 575                                 if (! $@) {
 576                                         $mime = mimetype($file);
 577                                 }
 578                                 $itemtemplate->param(
 579                                         enclosure => $u,
 580                                         type => $mime,
 581                                         length => $size,
 582                                 );
 583                         }
 584                 }
 585                 else {
 586                         $itemtemplate->param(content => $pcontent);
 587                 }
 588
 589                 run_hooks(pagetemplate => sub {
 590                         shift->(page => $p, destpage => $page,
 591                                 template => $itemtemplate);
 592                 });
 593
 594                 $content.=$itemtemplate->output;
 595                 $itemtemplate->clear_params;
 596
 597                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 598         }
 599
 600         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 601         $template->param(
 602                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 603                 wikiname => $config{wikiname},
 604                 pageurl => $url,
 605                 content => $content,
 606                 feeddesc => $feeddesc,
 607                 guid => $guid,
 608                 feeddate => date_3339($lasttime),
 609                 feedurl => $feedurl,
 610                 version => $IkiWiki::version,
 611         );
 612         run_hooks(pagetemplate => sub {
 613                 shift->(page => $page, destpage => $page,
 614                         template => $template);
 615         });
 616
 617         return $template->output;
 618 }
 619
 620 sub pingurl (@) {
 621         return unless @{$config{pingurl}} && %toping;
 622
 623         eval q{require RPC::XML::Client};
 624         if ($@) {
 625                 debug(gettext("RPC::XML::Client not found, not pinging"));
 626                 return;
 627         }
 628
 629         # daemonize here so slow pings don't slow down wiki updates
 630         defined(my $pid = fork) or error("Can't fork: $!");
 631         return if $pid;
 632         chdir '/';
 633         POSIX::setsid() or error("Can't start a new session: $!");
 634         open STDIN, '/dev/null';
 635         open STDOUT, '>/dev/null';
 636         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 637
 638         # Don't need to keep a lock on the wiki as a daemon.
 639         IkiWiki::unlockwiki();
 640
 641         foreach my $page (keys %toping) {
 642                 my $title=pagetitle(basename($page), 0);
 643                 my $url=urlto($page, "", 1);
 644                 foreach my $pingurl (@{$config{pingurl}}) {
 645                         debug("Pinging $pingurl for $page");
 646                         eval {
 647                                 my $client = RPC::XML::Client->new($pingurl);
 648                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 649                                         $title, $url);
 650                                 my $res = $client->send_request($req);
 651                                 if (! ref $res) {
 652                                         error("Did not receive response to ping");
 653                                 }
 654                                 my $r=$res->value;
 655                                 if (! exists $r->{flerror} || $r->{flerror}) {
 656                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 657                                 }
 658                         };
 659                         if ($@) {
 660                                 error "Ping failed: $@";
 661                         }
 662                 }
 663         }
 664
 665         exit 0; # daemon done
 666 }
 667
 668
 669 sub rootpage (@) {
 670         my %params=@_;
 671
 672         my $rootpage;
 673         if (exists $params{rootpage}) {
 674                 $rootpage=bestlink($params{page}, $params{rootpage});
 675                 if (!length $rootpage) {
 676                         $rootpage=$params{rootpage};
 677                 }
 678         }
 679         else {
 680                 $rootpage=$params{page};
 681         }
 682         return $rootpage;
 683 }
 684
 685 1