IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 2.00;
   8
   9 my %meta;
  10 my %title;
  11 my %permalink;
  12 my %author;
  13 my %authorurl;
  14 my %license;
  15 my %copyright;
  16
  17 sub import { #{{{
  18         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  19         hook(type => "filter", id => "meta", call => \&filter);
  20         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  21 } # }}}
  22
  23 sub filter (@) { #{{{
  24         my %params=@_;
  25
  26         $meta{$params{page}}='';
  27
  28         return $params{content};
  29 } # }}}
  30
  31 sub scrub ($) { #{{{
  32         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  33                 return IkiWiki::Plugin::htmlscrubber::sanitize(content => shift);
  34         }
  35         else {
  36                 return shift;
  37         }
  38 } #}}}
  39
  40 sub preprocess (@) { #{{{
  41         if (! @_) {
  42                 return "";
  43         }
  44         my %params=@_;
  45         my $key=shift;
  46         my $value=$params{$key};
  47         delete $params{$key};
  48         my $page=$params{page};
  49         delete $params{page};
  50         delete $params{destpage};
  51         delete $params{preview};
  52
  53         eval q{use HTML::Entities};
  54         # Always dencode, even if encoding later, since it might not be
  55         # fully encoded.
  56         $value=decode_entities($value);
  57
  58         if ($key eq 'link') {
  59                 if (%params) {
  60                         $meta{$page}.=scrub("<link href=\"".encode_entities($value)."\" ".
  61                                 join(" ", map { encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\"" } keys %params).
  62                                 " />\n");
  63                 }
  64                 else {
  65                         # hidden WikiLink
  66                         push @{$links{$page}}, $value;
  67                 }
  68         }
  69         elsif ($key eq 'title') {
  70                 $title{$page}=HTML::Entities::encode_numeric($value);
  71         }
  72         elsif ($key eq 'permalink') {
  73                 $permalink{$page}=$value;
  74                 $meta{$page}.=scrub("<link rel=\"bookmark\" href=\"".encode_entities($value)."\" />\n");
  75         }
  76         elsif ($key eq 'date') {
  77                 eval q{use Date::Parse};
  78                 if (! $@) {
  79                         my $time = str2time($value);
  80                         $IkiWiki::pagectime{$page}=$time if defined $time;
  81                 }
  82         }
  83         elsif ($key eq 'stylesheet') {
  84                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
  85                 my $title=exists $params{title} ? $params{title} : $value;
  86                 # adding .css to the value prevents using any old web
  87                 # editable page as a stylesheet
  88                 my $stylesheet=bestlink($page, $value.".css");
  89                 if (! length $stylesheet) {
  90                         return "[[meta ".gettext("stylesheet not found")."]]";
  91                 }
  92                 $meta{$page}.='<link href="'.urlto($stylesheet, $page).
  93                         '" rel="'.encode_entities($rel).
  94                         '" title="'.encode_entities($title).
  95                         "\" type=\"text/css\" />\n";
  96         }
  97         elsif ($key eq 'openid') {
  98                 if (exists $params{server}) {
  99                         $meta{$page}.='<link href="'.encode_entities($params{server}).
 100                                 "\" rel=\"openid.server\" />\n";
 101                 }
 102                 $meta{$page}.='<link href="'.encode_entities($value).
 103                         "\" rel=\"openid.delegate\" />\n";
 104         }
 105         elsif ($key eq 'license') {
 106                 $meta{$page}.="<link rel=\"license\" href=\"#page_license\" />\n";
 107                 $license{$page}=$value;
 108         }
 109         elsif ($key eq 'copyright') {
 110                 $meta{$page}.="<link rel=\"copyright\" href=\"#page_copyright\" />\n";
 111                 $copyright{$page}=$value;
 112         }
 113         else {
 114                 $meta{$page}.=scrub("<meta name=\"".encode_entities($key).
 115                         "\" content=\"".encode_entities($value)."\" />\n");
 116                 if ($key eq 'author') {
 117                         $author{$page}=$value;
 118                 }
 119                 elsif ($key eq 'authorurl') {
 120                         $authorurl{$page}=$value;
 121                 }
 122         }
 123
 124         return "";
 125 } # }}}
 126
 127 sub pagetemplate (@) { #{{{
 128         my %params=@_;
 129         my $page=$params{page};
 130         my $destpage=$params{destpage};
 131         my $template=$params{template};
 132
 133         $template->param(meta => $meta{$page})
 134                 if exists $meta{$page} && $template->query(name => "meta");
 135         if (exists $title{$page} && $template->query(name => "title")) {
 136                 $template->param(title => $title{$page});
 137                 $template->param(title_overridden => 1);
 138         }
 139         $template->param(permalink => $permalink{$page})
 140                 if exists $permalink{$page} && $template->query(name => "permalink");
 141         $template->param(author => $author{$page})
 142                 if exists $author{$page} && $template->query(name => "author");
 143         $template->param(authorurl => $authorurl{$page})
 144                 if exists $authorurl{$page} && $template->query(name => "authorurl");
 145
 146         if ($page ne $destpage &&
 147             ((exists $license{$page}   && ! exists $license{$destpage}) ||
 148              (exists $copyright{$page} && ! exists $copyright{$destpage}))) {
 149                 # Force a scan of the destpage to get its copyright/license
 150                 # info. If the info is declared after an inline, it will
 151                 # otherwise not be available at this point.
 152                 IkiWiki::scan($pagesources{$destpage});
 153         }
 154
 155         if (exists $license{$page} && $template->query(name => "license") &&
 156             ($page eq $destpage || ! exists $license{$destpage} ||
 157              $license{$page} ne $license{$destpage})) {
 158                 $template->param(license => IkiWiki::linkify($page, $destpage, $license{$page}));
 159         }
 160         if (exists $copyright{$page} && $template->query(name => "copyright") &&
 161             ($page eq $destpage || ! exists $copyright{$destpage} ||
 162              $copyright{$page} ne $copyright{$destpage})) {
 163                 $template->param(copyright => IkiWiki::linkify($page, $destpage, $copyright{$page}));
 164         }
 165 } # }}}
 166
 167 1