IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use HTML::Entities;
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX;
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15             %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16             %pagesources %destsources %depends %depends_simple %hooks
  17             %forcerebuild %loaded_plugins @autofiles %dellinks
  18             %delrenderedfiles};
  19
  20 use Exporter q{import};
  21 our @EXPORT = qw(hook debug error template htmlpage deptype
  22                  add_depends pagespec_match pagespec_match_list bestlink
  23                  htmllink readfile writefile pagetype srcfile pagename
  24                  displaytime will_render gettext urlto targetpage
  25                  add_underlay pagetitle titlepage linkpage newpagefile
  26                  inject add_link add_autofile
  27                  %config %links %pagestate %wikistate %renderedfiles
  28                  %pagesources %destsources);
  29 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  30 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  31 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  32
  33 # Page dependency types.
  34 our $DEPEND_CONTENT=1;
  35 our $DEPEND_PRESENCE=2;
  36 our $DEPEND_LINKS=4;
  37
  38 # Optimisation.
  39 use Memoize;
  40 memoize("abs2rel");
  41 memoize("pagespec_translate");
  42 memoize("template_file");
  43
  44 sub getsetup () {
  45         wikiname => {
  46                 type => "string",
  47                 default => "wiki",
  48                 description => "name of the wiki",
  49                 safe => 1,
  50                 rebuild => 1,
  51         },
  52         adminemail => {
  53                 type => "string",
  54                 default => undef,
  55                 example => 'me@example.com',
  56                 description => "contact email for wiki",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         adminuser => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are wiki admins",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         banned_users => {
  68                 type => "string",
  69                 default => [],
  70                 description => "users who are banned from the wiki",
  71                 safe => 1,
  72                 rebuild => 0,
  73         },
  74         srcdir => {
  75                 type => "string",
  76                 default => undef,
  77                 example => "$ENV{HOME}/wiki",
  78                 description => "where the source of the wiki is located",
  79                 safe => 0, # path
  80                 rebuild => 1,
  81         },
  82         destdir => {
  83                 type => "string",
  84                 default => undef,
  85                 example => "/var/www/wiki",
  86                 description => "where to build the wiki",
  87                 safe => 0, # path
  88                 rebuild => 1,
  89         },
  90         url => {
  91                 type => "string",
  92                 default => '',
  93                 example => "http://example.com/wiki",
  94                 description => "base url to the wiki",
  95                 safe => 1,
  96                 rebuild => 1,
  97         },
  98         cgiurl => {
  99                 type => "string",
 100                 default => '',
 101                 example => "http://example.com/wiki/ikiwiki.cgi",
 102                 description => "url to the ikiwiki.cgi",
 103                 safe => 1,
 104                 rebuild => 1,
 105         },
 106         cgi_wrapper => {
 107                 type => "string",
 108                 default => '',
 109                 example => "/var/www/wiki/ikiwiki.cgi",
 110                 description => "filename of cgi wrapper to generate",
 111                 safe => 0, # file
 112                 rebuild => 0,
 113         },
 114         cgi_wrappermode => {
 115                 type => "string",
 116                 default => '06755',
 117                 description => "mode for cgi_wrapper (can safely be made suid)",
 118                 safe => 0,
 119                 rebuild => 0,
 120         },
 121         rcs => {
 122                 type => "string",
 123                 default => '',
 124                 description => "rcs backend to use",
 125                 safe => 0, # don't allow overriding
 126                 rebuild => 0,
 127         },
 128         default_plugins => {
 129                 type => "internal",
 130                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 131                                 openid signinedit lockedit conditional
 132                                 recentchanges parentlinks editpage}],
 133                 description => "plugins to enable by default",
 134                 safe => 0,
 135                 rebuild => 1,
 136         },
 137         add_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to add to the default configuration",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         disable_plugins => {
 145                 type => "string",
 146                 default => [],
 147                 description => "plugins to disable",
 148                 safe => 1,
 149                 rebuild => 1,
 150         },
 151         templatedir => {
 152                 type => "string",
 153                 default => "$installdir/share/ikiwiki/templates",
 154                 description => "location of template files",
 155                 advanced => 1,
 156                 safe => 0, # path
 157                 rebuild => 1,
 158         },
 159         templatedirs => {
 160                 type => "internal",
 161                 default => [],
 162                 description => "additional directories containing template files",
 163                 safe => 0,
 164                 rebuild => 0,
 165         },
 166         underlaydir => {
 167                 type => "string",
 168                 default => "$installdir/share/ikiwiki/basewiki",
 169                 description => "base wiki source location",
 170                 advanced => 1,
 171                 safe => 0, # path
 172                 rebuild => 0,
 173         },
 174         underlaydirbase => {
 175                 type => "internal",
 176                 default => "$installdir/share/ikiwiki",
 177                 description => "parent directory containing additional underlays",
 178                 safe => 0,
 179                 rebuild => 0,
 180         },
 181         wrappers => {
 182                 type => "internal",
 183                 default => [],
 184                 description => "wrappers to generate",
 185                 safe => 0,
 186                 rebuild => 0,
 187         },
 188         underlaydirs => {
 189                 type => "internal",
 190                 default => [],
 191                 description => "additional underlays to use",
 192                 safe => 0,
 193                 rebuild => 0,
 194         },
 195         verbose => {
 196                 type => "boolean",
 197                 example => 1,
 198                 description => "display verbose messages?",
 199                 safe => 1,
 200                 rebuild => 0,
 201         },
 202         syslog => {
 203                 type => "boolean",
 204                 example => 1,
 205                 description => "log to syslog?",
 206                 safe => 1,
 207                 rebuild => 0,
 208         },
 209         usedirs => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "create output files named page/index.html?",
 213                 safe => 0, # changing requires manual transition
 214                 rebuild => 1,
 215         },
 216         prefix_directives => {
 217                 type => "boolean",
 218                 default => 1,
 219                 description => "use '!'-prefixed preprocessor directives?",
 220                 safe => 0, # changing requires manual transition
 221                 rebuild => 1,
 222         },
 223         indexpages => {
 224                 type => "boolean",
 225                 default => 0,
 226                 description => "use page/index.mdwn source files",
 227                 safe => 1,
 228                 rebuild => 1,
 229         },
 230         discussion => {
 231                 type => "boolean",
 232                 default => 1,
 233                 description => "enable Discussion pages?",
 234                 safe => 1,
 235                 rebuild => 1,
 236         },
 237         discussionpage => {
 238                 type => "string",
 239                 default => gettext("Discussion"),
 240                 description => "name of Discussion pages",
 241                 safe => 1,
 242                 rebuild => 1,
 243         },
 244         sslcookie => {
 245                 type => "boolean",
 246                 default => 0,
 247                 description => "only send cookies over SSL connections?",
 248                 advanced => 1,
 249                 safe => 1,
 250                 rebuild => 0,
 251         },
 252         default_pageext => {
 253                 type => "string",
 254                 default => "mdwn",
 255                 description => "extension to use for new pages",
 256                 safe => 0, # not sanitized
 257                 rebuild => 0,
 258         },
 259         htmlext => {
 260                 type => "string",
 261                 default => "html",
 262                 description => "extension to use for html files",
 263                 safe => 0, # not sanitized
 264                 rebuild => 1,
 265         },
 266         timeformat => {
 267                 type => "string",
 268                 default => '%c',
 269                 description => "strftime format string to display date",
 270                 advanced => 1,
 271                 safe => 1,
 272                 rebuild => 1,
 273         },
 274         locale => {
 275                 type => "string",
 276                 default => undef,
 277                 example => "en_US.UTF-8",
 278                 description => "UTF-8 locale to use",
 279                 advanced => 1,
 280                 safe => 0,
 281                 rebuild => 1,
 282         },
 283         userdir => {
 284                 type => "string",
 285                 default => "",
 286                 example => "users",
 287                 description => "put user pages below specified page",
 288                 safe => 1,
 289                 rebuild => 1,
 290         },
 291         numbacklinks => {
 292                 type => "integer",
 293                 default => 10,
 294                 description => "how many backlinks to show before hiding excess (0 to show all)",
 295                 safe => 1,
 296                 rebuild => 1,
 297         },
 298         hardlink => {
 299                 type => "boolean",
 300                 default => 0,
 301                 description => "attempt to hardlink source files? (optimisation for large files)",
 302                 advanced => 1,
 303                 safe => 0, # paranoia
 304                 rebuild => 0,
 305         },
 306         umask => {
 307                 type => "integer",
 308                 example => "022",
 309                 description => "force ikiwiki to use a particular umask",
 310                 advanced => 1,
 311                 safe => 0, # paranoia
 312                 rebuild => 0,
 313         },
 314         wrappergroup => {
 315                 type => "string",
 316                 example => "ikiwiki",
 317                 description => "group for wrappers to run in",
 318                 advanced => 1,
 319                 safe => 0, # paranoia
 320                 rebuild => 0,
 321         },
 322         libdir => {
 323                 type => "string",
 324                 default => "",
 325                 example => "$ENV{HOME}/.ikiwiki/",
 326                 description => "extra library and plugin directory",
 327                 advanced => 1,
 328                 safe => 0, # directory
 329                 rebuild => 0,
 330         },
 331         ENV => {
 332                 type => "string",
 333                 default => {},
 334                 description => "environment variables",
 335                 safe => 0, # paranoia
 336                 rebuild => 0,
 337         },
 338         exclude => {
 339                 type => "string",
 340                 default => undef,
 341                 example => '\.wav$',
 342                 description => "regexp of source files to ignore",
 343                 advanced => 1,
 344                 safe => 0, # regexp
 345                 rebuild => 1,
 346         },
 347         wiki_file_prune_regexps => {
 348                 type => "internal",
 349                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
 350                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 351                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 352                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 353                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 354                 description => "regexps of source files to ignore",
 355                 safe => 0,
 356                 rebuild => 1,
 357         },
 358         wiki_file_chars => {
 359                 type => "string",
 360                 description => "specifies the characters that are allowed in source filenames",
 361                 default => "-[:alnum:]+/.:_",
 362                 safe => 0,
 363                 rebuild => 1,
 364         },
 365         wiki_file_regexp => {
 366                 type => "internal",
 367                 description => "regexp of legal source files",
 368                 safe => 0,
 369                 rebuild => 1,
 370         },
 371         web_commit_regexp => {
 372                 type => "internal",
 373                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 374                 description => "regexp to parse web commits from logs",
 375                 safe => 0,
 376                 rebuild => 0,
 377         },
 378         cgi => {
 379                 type => "internal",
 380                 default => 0,
 381                 description => "run as a cgi",
 382                 safe => 0,
 383                 rebuild => 0,
 384         },
 385         cgi_disable_uploads => {
 386                 type => "internal",
 387                 default => 1,
 388                 description => "whether CGI should accept file uploads",
 389                 safe => 0,
 390                 rebuild => 0,
 391         },
 392         post_commit => {
 393                 type => "internal",
 394                 default => 0,
 395                 description => "run as a post-commit hook",
 396                 safe => 0,
 397                 rebuild => 0,
 398         },
 399         rebuild => {
 400                 type => "internal",
 401                 default => 0,
 402                 description => "running in rebuild mode",
 403                 safe => 0,
 404                 rebuild => 0,
 405         },
 406         setup => {
 407                 type => "internal",
 408                 default => undef,
 409                 description => "running in setup mode",
 410                 safe => 0,
 411                 rebuild => 0,
 412         },
 413         refresh => {
 414                 type => "internal",
 415                 default => 0,
 416                 description => "running in refresh mode",
 417                 safe => 0,
 418                 rebuild => 0,
 419         },
 420         test_receive => {
 421                 type => "internal",
 422                 default => 0,
 423                 description => "running in receive test mode",
 424                 safe => 0,
 425                 rebuild => 0,
 426         },
 427         getctime => {
 428                 type => "internal",
 429                 default => 0,
 430                 description => "running in getctime mode",
 431                 safe => 0,
 432                 rebuild => 0,
 433         },
 434         w3mmode => {
 435                 type => "internal",
 436                 default => 0,
 437                 description => "running in w3mmode",
 438                 safe => 0,
 439                 rebuild => 0,
 440         },
 441         wikistatedir => {
 442                 type => "internal",
 443                 default => undef,
 444                 description => "path to the .ikiwiki directory holding ikiwiki state",
 445                 safe => 0,
 446                 rebuild => 0,
 447         },
 448         setupfile => {
 449                 type => "internal",
 450                 default => undef,
 451                 description => "path to setup file",
 452                 safe => 0,
 453                 rebuild => 0,
 454         },
 455         allow_symlinks_before_srcdir => {
 456                 type => "boolean",
 457                 default => 0,
 458                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 459                 safe => 0,
 460                 rebuild => 0,
 461         },
 462 }
 463
 464 sub defaultconfig () {
 465         my %s=getsetup();
 466         my @ret;
 467         foreach my $key (keys %s) {
 468                 push @ret, $key, $s{$key}->{default};
 469         }
 470         use Data::Dumper;
 471         return @ret;
 472 }
 473
 474 sub checkconfig () {
 475         # locale stuff; avoid LC_ALL since it overrides everything
 476         if (defined $ENV{LC_ALL}) {
 477                 $ENV{LANG} = $ENV{LC_ALL};
 478                 delete $ENV{LC_ALL};
 479         }
 480         if (defined $config{locale}) {
 481                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 482                         $ENV{LANG}=$config{locale};
 483                         define_gettext();
 484                 }
 485         }
 486
 487         if (! defined $config{wiki_file_regexp}) {
 488                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 489         }
 490
 491         if (ref $config{ENV} eq 'HASH') {
 492                 foreach my $val (keys %{$config{ENV}}) {
 493                         $ENV{$val}=$config{ENV}{$val};
 494                 }
 495         }
 496
 497         if ($config{w3mmode}) {
 498                 eval q{use Cwd q{abs_path}};
 499                 error($@) if $@;
 500                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 501                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 502                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 503                         unless $config{cgiurl} =~ m!file:///!;
 504                 $config{url}="file://".$config{destdir};
 505         }
 506
 507         if ($config{cgi} && ! length $config{url}) {
 508                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 509         }
 510
 511         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 512                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 513
 514         if (defined $config{umask}) {
 515                 umask(possibly_foolish_untaint($config{umask}));
 516         }
 517
 518         run_hooks(checkconfig => sub { shift->() });
 519
 520         return 1;
 521 }
 522
 523 sub listplugins () {
 524         my %ret;
 525
 526         foreach my $dir (@INC, $config{libdir}) {
 527                 next unless defined $dir && length $dir;
 528                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 529                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 530                         $ret{$plugin}=1;
 531                 }
 532         }
 533         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 534                 next unless defined $dir && length $dir;
 535                 foreach my $file (glob("$dir/plugins/*")) {
 536                         $ret{basename($file)}=1 if -x $file;
 537                 }
 538         }
 539
 540         return keys %ret;
 541 }
 542
 543 sub loadplugins () {
 544         if (defined $config{libdir} && length $config{libdir}) {
 545                 unshift @INC, possibly_foolish_untaint($config{libdir});
 546         }
 547
 548         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 549                 loadplugin($plugin);
 550         }
 551
 552         if ($config{rcs}) {
 553                 if (exists $hooks{rcs}) {
 554                         error(gettext("cannot use multiple rcs plugins"));
 555                 }
 556                 loadplugin($config{rcs});
 557         }
 558         if (! exists $hooks{rcs}) {
 559                 loadplugin("norcs");
 560         }
 561
 562         run_hooks(getopt => sub { shift->() });
 563         if (grep /^-/, @ARGV) {
 564                 print STDERR "Unknown option (or missing parameter): $_\n"
 565                         foreach grep /^-/, @ARGV;
 566                 usage();
 567         }
 568
 569         return 1;
 570 }
 571
 572 sub loadplugin ($) {
 573         my $plugin=shift;
 574
 575         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 576
 577         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 578                          "$installdir/lib/ikiwiki") {
 579                 if (defined $dir && -x "$dir/plugins/$plugin") {
 580                         eval { require IkiWiki::Plugin::external };
 581                         if ($@) {
 582                                 my $reason=$@;
 583                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 584                         }
 585                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 586                         $loaded_plugins{$plugin}=1;
 587                         return 1;
 588                 }
 589         }
 590
 591         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 592         eval qq{use $mod};
 593         if ($@) {
 594                 error("Failed to load plugin $mod: $@");
 595         }
 596         $loaded_plugins{$plugin}=1;
 597         return 1;
 598 }
 599
 600 sub error ($;$) {
 601         my $message=shift;
 602         my $cleaner=shift;
 603         log_message('err' => $message) if $config{syslog};
 604         if (defined $cleaner) {
 605                 $cleaner->();
 606         }
 607         die $message."\n";
 608 }
 609
 610 sub debug ($) {
 611         return unless $config{verbose};
 612         return log_message(debug => @_);
 613 }
 614
 615 my $log_open=0;
 616 sub log_message ($$) {
 617         my $type=shift;
 618
 619         if ($config{syslog}) {
 620                 require Sys::Syslog;
 621                 if (! $log_open) {
 622                         Sys::Syslog::setlogsock('unix');
 623                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 624                         $log_open=1;
 625                 }
 626                 return eval {
 627                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 628                 };
 629         }
 630         elsif (! $config{cgi}) {
 631                 return print "@_\n";
 632         }
 633         else {
 634                 return print STDERR "@_\n";
 635         }
 636 }
 637
 638 sub possibly_foolish_untaint ($) {
 639         my $tainted=shift;
 640         my ($untainted)=$tainted=~/(.*)/s;
 641         return $untainted;
 642 }
 643
 644 sub basename ($) {
 645         my $file=shift;
 646
 647         $file=~s!.*/+!!;
 648         return $file;
 649 }
 650
 651 sub dirname ($) {
 652         my $file=shift;
 653
 654         $file=~s!/*[^/]+$!!;
 655         return $file;
 656 }
 657
 658 sub isinternal ($) {
 659         my $page=shift;
 660         return exists $pagesources{$page} &&
 661                 $pagesources{$page} =~ /\._([^.]+)$/;
 662 }
 663
 664 sub pagetype ($) {
 665         my $file=shift;
 666
 667         if ($file =~ /\.([^.]+)$/) {
 668                 return $1 if exists $hooks{htmlize}{$1};
 669         }
 670         my $base=basename($file);
 671         if (exists $hooks{htmlize}{$base} &&
 672             $hooks{htmlize}{$base}{noextension}) {
 673                 return $base;
 674         }
 675         return;
 676 }
 677
 678 my %pagename_cache;
 679
 680 sub pagename ($) {
 681         my $file=shift;
 682
 683         if (exists $pagename_cache{$file}) {
 684                 return $pagename_cache{$file};
 685         }
 686
 687         my $type=pagetype($file);
 688         my $page=$file;
 689         $page=~s/\Q.$type\E*$//
 690                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 691                         && !$hooks{htmlize}{$type}{noextension};
 692         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 693                 $page=$1;
 694         }
 695
 696         $pagename_cache{$file} = $page;
 697         return $page;
 698 }
 699
 700 sub newpagefile ($$) {
 701         my $page=shift;
 702         my $type=shift;
 703
 704         if (! $config{indexpages} || $page eq 'index') {
 705                 return $page.".".$type;
 706         }
 707         else {
 708                 return $page."/index.".$type;
 709         }
 710 }
 711
 712 sub targetpage ($$;$) {
 713         my $page=shift;
 714         my $ext=shift;
 715         my $filename=shift;
 716
 717         if (defined $filename) {
 718                 return $page."/".$filename.".".$ext;
 719         }
 720         elsif (! $config{usedirs} || $page eq 'index') {
 721                 return $page.".".$ext;
 722         }
 723         else {
 724                 return $page."/index.".$ext;
 725         }
 726 }
 727
 728 sub htmlpage ($) {
 729         my $page=shift;
 730
 731         return targetpage($page, $config{htmlext});
 732 }
 733
 734 sub srcfile_stat {
 735         my $file=shift;
 736         my $nothrow=shift;
 737
 738         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 739         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 740                 return "$dir/$file", stat(_) if -e "$dir/$file";
 741         }
 742         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 743         return;
 744 }
 745
 746 sub srcfile ($;$) {
 747         return (srcfile_stat(@_))[0];
 748 }
 749
 750 sub add_underlay ($) {
 751         my $dir=shift;
 752
 753         if ($dir !~ /^\//) {
 754                 $dir="$config{underlaydirbase}/$dir";
 755         }
 756
 757         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 758                 unshift @{$config{underlaydirs}}, $dir;
 759         }
 760
 761         return 1;
 762 }
 763
 764 sub readfile ($;$$) {
 765         my $file=shift;
 766         my $binary=shift;
 767         my $wantfd=shift;
 768
 769         if (-l $file) {
 770                 error("cannot read a symlink ($file)");
 771         }
 772
 773         local $/=undef;
 774         open (my $in, "<", $file) || error("failed to read $file: $!");
 775         binmode($in) if ($binary);
 776         return \*$in if $wantfd;
 777         my $ret=<$in>;
 778         # check for invalid utf-8, and toss it back to avoid crashes
 779         if (! utf8::valid($ret)) {
 780                 $ret=encode_utf8($ret);
 781         }
 782         close $in || error("failed to read $file: $!");
 783         return $ret;
 784 }
 785
 786 sub prep_writefile ($$) {
 787         my $file=shift;
 788         my $destdir=shift;
 789
 790         my $test=$file;
 791         while (length $test) {
 792                 if (-l "$destdir/$test") {
 793                         error("cannot write to a symlink ($test)");
 794                 }
 795                 $test=dirname($test);
 796         }
 797
 798         my $dir=dirname("$destdir/$file");
 799         if (! -d $dir) {
 800                 my $d="";
 801                 foreach my $s (split(m!/+!, $dir)) {
 802                         $d.="$s/";
 803                         if (! -d $d) {
 804                                 mkdir($d) || error("failed to create directory $d: $!");
 805                         }
 806                 }
 807         }
 808
 809         return 1;
 810 }
 811
 812 sub writefile ($$$;$$) {
 813         my $file=shift; # can include subdirs
 814         my $destdir=shift; # directory to put file in
 815         my $content=shift;
 816         my $binary=shift;
 817         my $writer=shift;
 818
 819         prep_writefile($file, $destdir);
 820
 821         my $newfile="$destdir/$file.ikiwiki-new";
 822         if (-l $newfile) {
 823                 error("cannot write to a symlink ($newfile)");
 824         }
 825
 826         my $cleanup = sub { unlink($newfile) };
 827         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 828         binmode($out) if ($binary);
 829         if ($writer) {
 830                 $writer->(\*$out, $cleanup);
 831         }
 832         else {
 833                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 834         }
 835         close $out || error("failed saving $newfile: $!", $cleanup);
 836         rename($newfile, "$destdir/$file") ||
 837                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 838
 839         return 1;
 840 }
 841
 842 my %cleared;
 843 sub will_render ($$;$) {
 844         my $page=shift;
 845         my $dest=shift;
 846         my $clear=shift;
 847
 848         # Important security check.
 849         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 850             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 851                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 852         }
 853
 854         if (! $clear || $cleared{$page}) {
 855                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 856         }
 857         else {
 858                 foreach my $old (@{$renderedfiles{$page}}) {
 859                         delete $destsources{$old};
 860                 }
 861                 $renderedfiles{$page}=[$dest];
 862                 $cleared{$page}=1;
 863         }
 864         $destsources{$dest}=$page;
 865
 866         return 1;
 867 }
 868
 869 sub bestlink ($$) {
 870         my $page=shift;
 871         my $link=shift;
 872
 873         my $cwd=$page;
 874         if ($link=~s/^\/+//) {
 875                 # absolute links
 876                 $cwd="";
 877         }
 878         $link=~s/\/$//;
 879
 880         do {
 881                 my $l=$cwd;
 882                 $l.="/" if length $l;
 883                 $l.=$link;
 884
 885                 if (exists $pagesources{$l}) {
 886                         return $l;
 887                 }
 888                 elsif (exists $pagecase{lc $l}) {
 889                         return $pagecase{lc $l};
 890                 }
 891         } while $cwd=~s{/?[^/]+$}{};
 892
 893         if (length $config{userdir}) {
 894                 my $l = "$config{userdir}/".lc($link);
 895                 if (exists $pagesources{$l}) {
 896                         return $l;
 897                 }
 898                 elsif (exists $pagecase{lc $l}) {
 899                         return $pagecase{lc $l};
 900                 }
 901         }
 902
 903         #print STDERR "warning: page $page, broken link: $link\n";
 904         return "";
 905 }
 906
 907 sub isinlinableimage ($) {
 908         my $file=shift;
 909
 910         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 911 }
 912
 913 sub pagetitle ($;$) {
 914         my $page=shift;
 915         my $unescaped=shift;
 916
 917         if ($unescaped) {
 918                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 919         }
 920         else {
 921                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 922         }
 923
 924         return $page;
 925 }
 926
 927 sub titlepage ($) {
 928         my $title=shift;
 929         # support use w/o %config set
 930         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 931         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 932         return $title;
 933 }
 934
 935 sub linkpage ($) {
 936         my $link=shift;
 937         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 938         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 939         return $link;
 940 }
 941
 942 sub cgiurl (@) {
 943         my %params=@_;
 944
 945         return $config{cgiurl}."?".
 946                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 947 }
 948
 949 sub baseurl (;$) {
 950         my $page=shift;
 951
 952         return "$config{url}/" if ! defined $page;
 953
 954         $page=htmlpage($page);
 955         $page=~s/[^\/]+$//;
 956         $page=~s/[^\/]+\//..\//g;
 957         return $page;
 958 }
 959
 960 sub abs2rel ($$) {
 961         # Work around very innefficient behavior in File::Spec if abs2rel
 962         # is passed two relative paths. It's much faster if paths are
 963         # absolute! (Debian bug #376658; fixed in debian unstable now)
 964         my $path="/".shift;
 965         my $base="/".shift;
 966
 967         require File::Spec;
 968         my $ret=File::Spec->abs2rel($path, $base);
 969         $ret=~s/^// if defined $ret;
 970         return $ret;
 971 }
 972
 973 sub displaytime ($;$) {
 974         # Plugins can override this function to mark up the time to
 975         # display.
 976         return '<span class="date">'.formattime(@_).'</span>';
 977 }
 978
 979 sub formattime ($;$) {
 980         # Plugins can override this function to format the time.
 981         my $time=shift;
 982         my $format=shift;
 983         if (! defined $format) {
 984                 $format=$config{timeformat};
 985         }
 986
 987         # strftime doesn't know about encodings, so make sure
 988         # its output is properly treated as utf8
 989         return decode_utf8(POSIX::strftime($format, localtime($time)));
 990 }
 991
 992 sub beautify_urlpath ($) {
 993         my $url=shift;
 994
 995         # Ensure url is not an empty link, and if necessary,
 996         # add ./ to avoid colon confusion.
 997         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
 998                 $url="./$url";
 999         }
1000
1001         if ($config{usedirs}) {
1002                 $url =~ s!/index.$config{htmlext}$!/!;
1003         }
1004
1005         return $url;
1006 }
1007
1008 sub urlto ($$;$) {
1009         my $to=shift;
1010         my $from=shift;
1011         my $absolute=shift;
1012
1013         if (! length $to) {
1014                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
1015         }
1016
1017         if (! $destsources{$to}) {
1018                 $to=htmlpage($to);
1019         }
1020
1021         if ($absolute) {
1022                 return $config{url}.beautify_urlpath("/".$to);
1023         }
1024
1025         my $link = abs2rel($to, dirname(htmlpage($from)));
1026
1027         return beautify_urlpath($link);
1028 }
1029
1030 sub htmllink ($$$;@) {
1031         my $lpage=shift; # the page doing the linking
1032         my $page=shift; # the page that will contain the link (different for inline)
1033         my $link=shift;
1034         my %opts=@_;
1035
1036         $link=~s/\/$//;
1037
1038         my $bestlink;
1039         if (! $opts{forcesubpage}) {
1040                 $bestlink=bestlink($lpage, $link);
1041         }
1042         else {
1043                 $bestlink="$lpage/".lc($link);
1044         }
1045
1046         my $linktext;
1047         if (defined $opts{linktext}) {
1048                 $linktext=$opts{linktext};
1049         }
1050         else {
1051                 $linktext=pagetitle(basename($link));
1052         }
1053
1054         return "<span class=\"selflink\">$linktext</span>"
1055                 if length $bestlink && $page eq $bestlink &&
1056                    ! defined $opts{anchor};
1057
1058         if (! $destsources{$bestlink}) {
1059                 $bestlink=htmlpage($bestlink);
1060
1061                 if (! $destsources{$bestlink}) {
1062                         return $linktext unless length $config{cgiurl};
1063                         return "<span class=\"createlink\"><a href=\"".
1064                                 cgiurl(
1065                                         do => "create",
1066                                         page => lc($link),
1067                                         from => $lpage
1068                                 ).
1069                                 "\" rel=\"nofollow\">?</a>$linktext</span>"
1070                 }
1071         }
1072
1073         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1074         $bestlink=beautify_urlpath($bestlink);
1075
1076         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1077                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1078         }
1079
1080         if (defined $opts{anchor}) {
1081                 $bestlink.="#".$opts{anchor};
1082         }
1083
1084         my @attrs;
1085         foreach my $attr (qw{rel class title}) {
1086                 if (defined $opts{$attr}) {
1087                         push @attrs, " $attr=\"$opts{$attr}\"";
1088                 }
1089         }
1090
1091         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1092 }
1093
1094 sub openiduser ($) {
1095         my $user=shift;
1096
1097         if ($user =~ m!^https?://! &&
1098             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1099                 my $display;
1100
1101                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1102                         # this works in at least 2.x
1103                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1104                 }
1105                 else {
1106                         # this only works in 1.x
1107                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1108                         $display=$oid->display;
1109                 }
1110
1111                 # Convert "user.somehost.com" to "user [somehost.com]"
1112                 # (also "user.somehost.co.uk")
1113                 if ($display !~ /\[/) {
1114                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1115                 }
1116                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1117                 # (also "https://somehost.com/user/")
1118                 if ($display !~ /\[/) {
1119                         $display=~s/^https?:\/\/(.+)\/([^\/]+)\/?$/$2 [$1]/;
1120                 }
1121                 $display=~s!^https?://!!; # make sure this is removed
1122                 eval q{use CGI 'escapeHTML'};
1123                 error($@) if $@;
1124                 return escapeHTML($display);
1125         }
1126         return;
1127 }
1128
1129 sub userlink ($) {
1130         my $user=shift;
1131
1132         my $oiduser=eval { openiduser($user) };
1133         if (defined $oiduser) {
1134                 return "<a href=\"$user\">$oiduser</a>";
1135         }
1136         else {
1137                 eval q{use CGI 'escapeHTML'};
1138                 error($@) if $@;
1139
1140                 return htmllink("", "", escapeHTML(
1141                         length $config{userdir} ? $config{userdir}."/".$user : $user
1142                 ), noimageinline => 1);
1143         }
1144 }
1145
1146 sub htmlize ($$$$) {
1147         my $page=shift;
1148         my $destpage=shift;
1149         my $type=shift;
1150         my $content=shift;
1151
1152         my $oneline = $content !~ /\n/;
1153
1154         if (exists $hooks{htmlize}{$type}) {
1155                 $content=$hooks{htmlize}{$type}{call}->(
1156                         page => $page,
1157                         content => $content,
1158                 );
1159         }
1160         else {
1161                 error("htmlization of $type not supported");
1162         }
1163
1164         run_hooks(sanitize => sub {
1165                 $content=shift->(
1166                         page => $page,
1167                         destpage => $destpage,
1168                         content => $content,
1169                 );
1170         });
1171
1172         if ($oneline) {
1173                 # hack to get rid of enclosing junk added by markdown
1174                 # and other htmlizers
1175                 $content=~s/^<p>//i;
1176                 $content=~s/<\/p>$//i;
1177                 chomp $content;
1178         }
1179
1180         return $content;
1181 }
1182
1183 sub linkify ($$$) {
1184         my $page=shift;
1185         my $destpage=shift;
1186         my $content=shift;
1187
1188         run_hooks(linkify => sub {
1189                 $content=shift->(
1190                         page => $page,
1191                         destpage => $destpage,
1192                         content => $content,
1193                 );
1194         });
1195
1196         return $content;
1197 }
1198
1199 our %preprocessing;
1200 our $preprocess_preview=0;
1201 sub preprocess ($$$;$$) {
1202         my $page=shift; # the page the data comes from
1203         my $destpage=shift; # the page the data will appear in (different for inline)
1204         my $content=shift;
1205         my $scan=shift;
1206         my $preview=shift;
1207
1208         # Using local because it needs to be set within any nested calls
1209         # of this function.
1210         local $preprocess_preview=$preview if defined $preview;
1211
1212         my $handle=sub {
1213                 my $escape=shift;
1214                 my $prefix=shift;
1215                 my $command=shift;
1216                 my $params=shift;
1217                 $params="" if ! defined $params;
1218
1219                 if (length $escape) {
1220                         return "[[$prefix$command $params]]";
1221                 }
1222                 elsif (exists $hooks{preprocess}{$command}) {
1223                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1224                         # Note: preserve order of params, some plugins may
1225                         # consider it significant.
1226                         my @params;
1227                         while ($params =~ m{
1228                                 (?:([-\w]+)=)?          # 1: named parameter key?
1229                                 (?:
1230                                         """(.*?)"""     # 2: triple-quoted value
1231                                 |
1232                                         "([^"]+)"       # 3: single-quoted value
1233                                 |
1234                                         (\S+)           # 4: unquoted value
1235                                 )
1236                                 (?:\s+|$)               # delimiter to next param
1237                         }sgx) {
1238                                 my $key=$1;
1239                                 my $val;
1240                                 if (defined $2) {
1241                                         $val=$2;
1242                                         $val=~s/\r\n/\n/mg;
1243                                         $val=~s/^\n+//g;
1244                                         $val=~s/\n+$//g;
1245                                 }
1246                                 elsif (defined $3) {
1247                                         $val=$3;
1248                                 }
1249                                 elsif (defined $4) {
1250                                         $val=$4;
1251                                 }
1252
1253                                 if (defined $key) {
1254                                         push @params, $key, $val;
1255                                 }
1256                                 else {
1257                                         push @params, $val, '';
1258                                 }
1259                         }
1260                         if ($preprocessing{$page}++ > 3) {
1261                                 # Avoid loops of preprocessed pages preprocessing
1262                                 # other pages that preprocess them, etc.
1263                                 return "[[!$command <span class=\"error\">".
1264                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1265                                                 $page, $preprocessing{$page}).
1266                                         "</span>]]";
1267                         }
1268                         my $ret;
1269                         if (! $scan) {
1270                                 $ret=eval {
1271                                         $hooks{preprocess}{$command}{call}->(
1272                                                 @params,
1273                                                 page => $page,
1274                                                 destpage => $destpage,
1275                                                 preview => $preprocess_preview,
1276                                         );
1277                                 };
1278                                 if ($@) {
1279                                         my $error=$@;
1280                                         chomp $error;
1281                                         $ret="[[!$command <span class=\"error\">".
1282                                                 gettext("Error").": $error"."</span>]]";
1283                                 }
1284                         }
1285                         else {
1286                                 # use void context during scan pass
1287                                 eval {
1288                                         $hooks{preprocess}{$command}{call}->(
1289                                                 @params,
1290                                                 page => $page,
1291                                                 destpage => $destpage,
1292                                                 preview => $preprocess_preview,
1293                                         );
1294                                 };
1295                                 $ret="";
1296                         }
1297                         $preprocessing{$page}--;
1298                         return $ret;
1299                 }
1300                 else {
1301                         return "[[$prefix$command $params]]";
1302                 }
1303         };
1304
1305         my $regex;
1306         if ($config{prefix_directives}) {
1307                 $regex = qr{
1308                         (\\?)           # 1: escape?
1309                         \[\[(!)         # directive open; 2: prefix
1310                         ([-\w]+)        # 3: command
1311                         (               # 4: the parameters..
1312                                 \s+     # Must have space if parameters present
1313                                 (?:
1314                                         (?:[-\w]+=)?            # named parameter key?
1315                                         (?:
1316                                                 """.*?"""       # triple-quoted value
1317                                                 |
1318                                                 "[^"]+"         # single-quoted value
1319                                                 |
1320                                                 [^"\s\]]+       # unquoted value
1321                                         )
1322                                         \s*                     # whitespace or end
1323                                                                 # of directive
1324                                 )
1325                         *)?             # 0 or more parameters
1326                         \]\]            # directive closed
1327                 }sx;
1328         }
1329         else {
1330                 $regex = qr{
1331                         (\\?)           # 1: escape?
1332                         \[\[(!?)        # directive open; 2: optional prefix
1333                         ([-\w]+)        # 3: command
1334                         \s+
1335                         (               # 4: the parameters..
1336                                 (?:
1337                                         (?:[-\w]+=)?            # named parameter key?
1338                                         (?:
1339                                                 """.*?"""       # triple-quoted value
1340                                                 |
1341                                                 "[^"]+"         # single-quoted value
1342                                                 |
1343                                                 [^"\s\]]+       # unquoted value
1344                                         )
1345                                         \s*                     # whitespace or end
1346                                                                 # of directive
1347                                 )
1348                         *)              # 0 or more parameters
1349                         \]\]            # directive closed
1350                 }sx;
1351         }
1352
1353         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1354         return $content;
1355 }
1356
1357 sub filter ($$$) {
1358         my $page=shift;
1359         my $destpage=shift;
1360         my $content=shift;
1361
1362         run_hooks(filter => sub {
1363                 $content=shift->(page => $page, destpage => $destpage,
1364                         content => $content);
1365         });
1366
1367         return $content;
1368 }
1369
1370 sub indexlink () {
1371         return "<a href=\"$config{url}\">$config{wikiname}</a>";
1372 }
1373
1374 sub check_canedit ($$$;$) {
1375         my $page=shift;
1376         my $q=shift;
1377         my $session=shift;
1378         my $nonfatal=shift;
1379
1380         my $canedit;
1381         run_hooks(canedit => sub {
1382                 return if defined $canedit;
1383                 my $ret=shift->($page, $q, $session);
1384                 if (defined $ret) {
1385                         if ($ret eq "") {
1386                                 $canedit=1;
1387                         }
1388                         elsif (ref $ret eq 'CODE') {
1389                                 $ret->() unless $nonfatal;
1390                                 $canedit=0;
1391                         }
1392                         elsif (defined $ret) {
1393                                 error($ret) unless $nonfatal;
1394                                 $canedit=0;
1395                         }
1396                 }
1397         });
1398         return defined $canedit ? $canedit : 1;
1399 }
1400
1401 sub check_content (@) {
1402         my %params=@_;
1403
1404         return 1 if ! exists $hooks{checkcontent}; # optimisation
1405
1406         if (exists $pagesources{$params{page}}) {
1407                 my @diff;
1408                 my %old=map { $_ => 1 }
1409                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1410                 foreach my $line (split("\n", $params{content})) {
1411                         push @diff, $line if ! exists $old{$line};
1412                 }
1413                 $params{diff}=join("\n", @diff);
1414         }
1415
1416         my $ok;
1417         run_hooks(checkcontent => sub {
1418                 return if defined $ok;
1419                 my $ret=shift->(%params);
1420                 if (defined $ret) {
1421                         if ($ret eq "") {
1422                                 $ok=1;
1423                         }
1424                         elsif (ref $ret eq 'CODE') {
1425                                 $ret->() unless $params{nonfatal};
1426                                 $ok=0;
1427                         }
1428                         elsif (defined $ret) {
1429                                 error($ret) unless $params{nonfatal};
1430                                 $ok=0;
1431                         }
1432                 }
1433
1434         });
1435         return defined $ok ? $ok : 1;
1436 }
1437
1438 my $wikilock;
1439
1440 sub lockwiki () {
1441         # Take an exclusive lock on the wiki to prevent multiple concurrent
1442         # run issues. The lock will be dropped on program exit.
1443         if (! -d $config{wikistatedir}) {
1444                 mkdir($config{wikistatedir});
1445         }
1446         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1447                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1448         if (! flock($wikilock, 2)) { # LOCK_EX
1449                 error("failed to get lock");
1450         }
1451         return 1;
1452 }
1453
1454 sub unlockwiki () {
1455         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1456         return close($wikilock) if $wikilock;
1457         return;
1458 }
1459
1460 my $commitlock;
1461
1462 sub commit_hook_enabled () {
1463         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1464                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1465         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1466                 close($commitlock) || error("failed closing commitlock: $!");
1467                 return 0;
1468         }
1469         close($commitlock) || error("failed closing commitlock: $!");
1470         return 1;
1471 }
1472
1473 sub disable_commit_hook () {
1474         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1475                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1476         if (! flock($commitlock, 2)) { # LOCK_EX
1477                 error("failed to get commit lock");
1478         }
1479         return 1;
1480 }
1481
1482 sub enable_commit_hook () {
1483         return close($commitlock) if $commitlock;
1484         return;
1485 }
1486
1487 sub loadindex () {
1488         %oldrenderedfiles=%pagectime=();
1489         if (! $config{rebuild}) {
1490                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1491                 %destsources=%renderedfiles=%pagecase=%pagestate=
1492                 %depends_simple=();
1493         }
1494         my $in;
1495         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1496                 if (-e "$config{wikistatedir}/index") {
1497                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1498                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1499                 }
1500                 else {
1501                         return;
1502                 }
1503         }
1504
1505         my $index=Storable::fd_retrieve($in);
1506         if (! defined $index) {
1507                 return 0;
1508         }
1509
1510         my $pages;
1511         if (exists $index->{version} && ! ref $index->{version}) {
1512                 $pages=$index->{page};
1513                 %wikistate=%{$index->{state}};
1514         }
1515         else {
1516                 $pages=$index;
1517                 %wikistate=();
1518         }
1519
1520         foreach my $src (keys %$pages) {
1521                 my $d=$pages->{$src};
1522                 my $page=pagename($src);
1523                 $pagectime{$page}=$d->{ctime};
1524                 if (! $config{rebuild}) {
1525                         $pagesources{$page}=$src;
1526                         $pagemtime{$page}=$d->{mtime};
1527                         $renderedfiles{$page}=$d->{dest};
1528                         if (exists $d->{links} && ref $d->{links}) {
1529                                 $links{$page}=$d->{links};
1530                                 $oldlinks{$page}=[@{$d->{links}}];
1531                         }
1532                         if (ref $d->{depends_simple} eq 'ARRAY') {
1533                                 # old format
1534                                 $depends_simple{$page}={
1535                                         map { $_ => 1 } @{$d->{depends_simple}}
1536                                 };
1537                         }
1538                         elsif (exists $d->{depends_simple}) {
1539                                 $depends_simple{$page}=$d->{depends_simple};
1540                         }
1541                         if (exists $d->{dependslist}) {
1542                                 # old format
1543                                 $depends{$page}={
1544                                         map { $_ => $DEPEND_CONTENT }
1545                                                 @{$d->{dependslist}}
1546                                 };
1547                         }
1548                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1549                                 # old format
1550                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1551                         }
1552                         elsif (exists $d->{depends}) {
1553                                 $depends{$page}=$d->{depends};
1554                         }
1555                         if (exists $d->{state}) {
1556                                 $pagestate{$page}=$d->{state};
1557                         }
1558                 }
1559                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1560         }
1561         foreach my $page (keys %pagesources) {
1562                 $pagecase{lc $page}=$page;
1563         }
1564         foreach my $page (keys %renderedfiles) {
1565                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1566         }
1567         return close($in);
1568 }
1569
1570 sub saveindex () {
1571         run_hooks(savestate => sub { shift->() });
1572
1573         my %hookids;
1574         foreach my $type (keys %hooks) {
1575                 $hookids{$_}=1 foreach keys %{$hooks{$type}};
1576         }
1577         my @hookids=keys %hookids;
1578
1579         if (! -d $config{wikistatedir}) {
1580                 mkdir($config{wikistatedir});
1581         }
1582         my $newfile="$config{wikistatedir}/indexdb.new";
1583         my $cleanup = sub { unlink($newfile) };
1584         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1585
1586         my %index;
1587         foreach my $page (keys %pagemtime) {
1588                 next unless $pagemtime{$page};
1589                 my $src=$pagesources{$page};
1590
1591                 $index{page}{$src}={
1592                         ctime => $pagectime{$page},
1593                         mtime => $pagemtime{$page},
1594                         dest => $renderedfiles{$page},
1595                         links => $links{$page},
1596                 };
1597
1598                 if (exists $depends{$page}) {
1599                         $index{page}{$src}{depends} = $depends{$page};
1600                 }
1601
1602                 if (exists $depends_simple{$page}) {
1603                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
1604                 }
1605
1606                 if (exists $pagestate{$page}) {
1607                         foreach my $id (@hookids) {
1608                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1609                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1610                                 }
1611                         }
1612                 }
1613         }
1614
1615         $index{state}={};
1616         foreach my $id (@hookids) {
1617                 foreach my $key (keys %{$wikistate{$id}}) {
1618                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1619                 }
1620         }
1621
1622         $index{version}="3";
1623         my $ret=Storable::nstore_fd(\%index, $out);
1624         return if ! defined $ret || ! $ret;
1625         close $out || error("failed saving to $newfile: $!", $cleanup);
1626         rename($newfile, "$config{wikistatedir}/indexdb") ||
1627                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1628
1629         return 1;
1630 }
1631
1632 sub template_file ($) {
1633         my $template=shift;
1634
1635         foreach my $dir ($config{templatedir}, @{$config{templatedirs}},
1636                          "$installdir/share/ikiwiki/templates") {
1637                 return "$dir/$template" if -e "$dir/$template";
1638         }
1639         return;
1640 }
1641
1642 sub template_params (@) {
1643         my $filename=template_file(shift);
1644
1645         if (! defined $filename) {
1646                 return if wantarray;
1647                 return "";
1648         }
1649
1650         my @ret=(
1651                 filter => sub {
1652                         my $text_ref = shift;
1653                         ${$text_ref} = decode_utf8(${$text_ref});
1654                 },
1655                 filename => $filename,
1656                 loop_context_vars => 1,
1657                 die_on_bad_params => 0,
1658                 @_
1659         );
1660         return wantarray ? @ret : {@ret};
1661 }
1662
1663 sub template ($;@) {
1664         require HTML::Template;
1665         return HTML::Template->new(template_params(@_));
1666 }
1667
1668 sub misctemplate ($$;@) {
1669         my $title=shift;
1670         my $pagebody=shift;
1671
1672         my $template=template("misc.tmpl");
1673         $template->param(
1674                 title => $title,
1675                 indexlink => indexlink(),
1676                 wikiname => $config{wikiname},
1677                 pagebody => $pagebody,
1678                 baseurl => baseurl(),
1679                 @_,
1680         );
1681         run_hooks(pagetemplate => sub {
1682                 shift->(page => "", destpage => "", template => $template);
1683         });
1684         return $template->output;
1685 }
1686
1687 sub hook (@) {
1688         my %param=@_;
1689
1690         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1691                 error 'hook requires type, call, and id parameters';
1692         }
1693
1694         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1695
1696         $hooks{$param{type}}{$param{id}}=\%param;
1697         return 1;
1698 }
1699
1700 sub run_hooks ($$) {
1701         # Calls the given sub for each hook of the given type,
1702         # passing it the hook function to call.
1703         my $type=shift;
1704         my $sub=shift;
1705
1706         if (exists $hooks{$type}) {
1707                 my (@first, @middle, @last);
1708                 foreach my $id (keys %{$hooks{$type}}) {
1709                         if ($hooks{$type}{$id}{first}) {
1710                                 push @first, $id;
1711                         }
1712                         elsif ($hooks{$type}{$id}{last}) {
1713                                 push @last, $id;
1714                         }
1715                         else {
1716                                 push @middle, $id;
1717                         }
1718                 }
1719                 foreach my $id (@first, @middle, @last) {
1720                         $sub->($hooks{$type}{$id}{call});
1721                 }
1722         }
1723
1724         return 1;
1725 }
1726
1727 sub rcs_update () {
1728         $hooks{rcs}{rcs_update}{call}->(@_);
1729 }
1730
1731 sub rcs_prepedit ($) {
1732         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1733 }
1734
1735 sub rcs_commit ($$$;$$) {
1736         $hooks{rcs}{rcs_commit}{call}->(@_);
1737 }
1738
1739 sub rcs_commit_staged ($$$) {
1740         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
1741 }
1742
1743 sub rcs_add ($) {
1744         $hooks{rcs}{rcs_add}{call}->(@_);
1745 }
1746
1747 sub rcs_remove ($) {
1748         $hooks{rcs}{rcs_remove}{call}->(@_);
1749 }
1750
1751 sub rcs_rename ($$) {
1752         $hooks{rcs}{rcs_rename}{call}->(@_);
1753 }
1754
1755 sub rcs_recentchanges ($) {
1756         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
1757 }
1758
1759 sub rcs_diff ($) {
1760         $hooks{rcs}{rcs_diff}{call}->(@_);
1761 }
1762
1763 sub rcs_getctime ($) {
1764         $hooks{rcs}{rcs_getctime}{call}->(@_);
1765 }
1766
1767 sub rcs_receive () {
1768         $hooks{rcs}{rcs_receive}{call}->();
1769 }
1770
1771 sub add_depends ($$;$) {
1772         my $page=shift;
1773         my $pagespec=shift;
1774         my $deptype=shift || $DEPEND_CONTENT;
1775
1776         # Is the pagespec a simple page name?
1777         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
1778             $pagespec !~ /[\s*?()!]/) {
1779                 $depends_simple{$page}{lc $pagespec} |= $deptype;
1780                 return 1;
1781         }
1782
1783         # Add explicit dependencies for influences.
1784         my $sub=pagespec_translate($pagespec);
1785         return if $@;
1786         foreach my $p (keys %pagesources) {
1787                 my $r=$sub->($p, location => $page);
1788                 my $i=$r->influences;
1789                 foreach my $k (keys %$i) {
1790                         $depends_simple{$page}{lc $k} |= $i->{$k};
1791                 }
1792                 last if $r->influences_static;
1793         }
1794
1795         $depends{$page}{$pagespec} |= $deptype;
1796         return 1;
1797 }
1798
1799 sub deptype (@) {
1800         my $deptype=0;
1801         foreach my $type (@_) {
1802                 if ($type eq 'presence') {
1803                         $deptype |= $DEPEND_PRESENCE;
1804                 }
1805                 elsif ($type eq 'links') {
1806                         $deptype |= $DEPEND_LINKS;
1807                 }
1808                 elsif ($type eq 'content') {
1809                         $deptype |= $DEPEND_CONTENT;
1810                 }
1811         }
1812         return $deptype;
1813 }
1814
1815 sub file_pruned ($;$) {
1816         my $file=shift;
1817         if (@_) {
1818                 require File::Spec;
1819                 $file=File::Spec->canonpath($file);
1820                 my $base=File::Spec->canonpath(shift);
1821                 return if $file eq $base;
1822                 $file =~ s#^\Q$base\E/+##;
1823         }
1824
1825         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1826         return $file =~ m/$regexp/;
1827 }
1828
1829 sub define_gettext () {
1830         # If translation is needed, redefine the gettext function to do it.
1831         # Otherwise, it becomes a quick no-op.
1832         no warnings 'redefine';
1833         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1834             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1835             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1836                 *gettext=sub {
1837                         my $gettext_obj=eval q{
1838                                 use Locale::gettext q{textdomain};
1839                                 Locale::gettext->domain('ikiwiki')
1840                         };
1841
1842                         if ($gettext_obj) {
1843                                 $gettext_obj->get(shift);
1844                         }
1845                         else {
1846                                 return shift;
1847                         }
1848                 };
1849         }
1850         else {
1851                 *gettext=sub { return shift };
1852         }
1853 }
1854
1855 sub gettext {
1856         define_gettext();
1857         gettext(@_);
1858 }
1859
1860 sub yesno ($) {
1861         my $val=shift;
1862
1863         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
1864 }
1865
1866 sub inject {
1867         # Injects a new function into the symbol table to replace an
1868         # exported function.
1869         my %params=@_;
1870
1871         # This is deep ugly perl foo, beware.
1872         no strict;
1873         no warnings;
1874         if (! defined $params{parent}) {
1875                 $params{parent}='::';
1876                 $params{old}=\&{$params{name}};
1877                 $params{name}=~s/.*:://;
1878         }
1879         my $parent=$params{parent};
1880         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
1881                 $ns = $params{parent} . $ns;
1882                 inject(%params, parent => $ns) unless $ns eq '::main::';
1883                 *{$ns . $params{name}} = $params{call}
1884                         if exists ${$ns}{$params{name}} &&
1885                            \&{${$ns}{$params{name}}} == $params{old};
1886         }
1887         use strict;
1888         use warnings;
1889 }
1890
1891 sub add_link ($$) {
1892         my $page=shift;
1893         my $link=shift;
1894
1895         push @{$links{$page}}, $link
1896                 unless grep { $_ eq $link } @{$links{$page}};
1897 }
1898
1899 sub add_autofile ($) {
1900         my $addfile=shift;
1901         my ($file,$page) = verify_src_file($addfile,$config{srcdir});
1902         if ($page) {
1903                 push @autofiles, $file;
1904         }
1905 }
1906
1907 sub pagespec_translate ($) {
1908         my $spec=shift;
1909
1910         # Convert spec to perl code.
1911         my $code="";
1912         my @data;
1913         while ($spec=~m{
1914                 \s*             # ignore whitespace
1915                 (               # 1: match a single word
1916                         \!              # !
1917                 |
1918                         \(              # (
1919                 |
1920                         \)              # )
1921                 |
1922                         \w+\([^\)]*\)   # command(params)
1923                 |
1924                         [^\s()]+        # any other text
1925                 )
1926                 \s*             # ignore whitespace
1927         }gx) {
1928                 my $word=$1;
1929                 if (lc $word eq 'and') {
1930                         $code.=' &';
1931                 }
1932                 elsif (lc $word eq 'or') {
1933                         $code.=' |';
1934                 }
1935                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1936                         $code.=' '.$word;
1937                 }
1938                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1939                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1940                                 push @data, $2;
1941                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
1942                         }
1943                         else {
1944                                 push @data, qq{unknown function in pagespec "$word"};
1945                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
1946                         }
1947                 }
1948                 else {
1949                         push @data, $word;
1950                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
1951                 }
1952         }
1953
1954         if (! length $code) {
1955                 $code="IkiWiki::FailReason->new('empty pagespec')";
1956         }
1957
1958         no warnings;
1959         return eval 'sub { my $page=shift; '.$code.' }';
1960 }
1961
1962 sub pagespec_match ($$;@) {
1963         my $page=shift;
1964         my $spec=shift;
1965         my @params=@_;
1966
1967         # Backwards compatability with old calling convention.
1968         if (@params == 1) {
1969                 unshift @params, 'location';
1970         }
1971
1972         my $sub=pagespec_translate($spec);
1973         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
1974                 if $@ || ! defined $sub;
1975         return $sub->($page, @params);
1976 }
1977
1978 sub pagespec_match_list ($$;@) {
1979         my $page=shift;
1980         my $pagespec=shift;
1981         my %params=@_;
1982
1983         # Backwards compatability with old calling convention.
1984         if (ref $page) {
1985                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
1986                 $params{list}=$page;
1987                 $page=$params{location}; # ugh!
1988         }
1989
1990         my $sub=pagespec_translate($pagespec);
1991         error "syntax error in pagespec \"$pagespec\""
1992                 if $@ || ! defined $sub;
1993
1994         my @candidates;
1995         if (exists $params{list}) {
1996                 @candidates=exists $params{filter}
1997                         ? grep { ! $params{filter}->($_) } @{$params{list}}
1998                         : @{$params{list}};
1999         }
2000         else {
2001                 @candidates=exists $params{filter}
2002                         ? grep { ! $params{filter}->($_) } keys %pagesources
2003                         : keys %pagesources;
2004         }
2005
2006         if (defined $params{sort}) {
2007                 my $f;
2008                 if ($params{sort} eq 'title') {
2009                         $f=sub { pagetitle(basename($a)) cmp pagetitle(basename($b)) };
2010                 }
2011                 elsif ($params{sort} eq 'title_natural') {
2012                         eval q{use Sort::Naturally};
2013                         if ($@) {
2014                                 error(gettext("Sort::Naturally needed for title_natural sort"));
2015                         }
2016                         $f=sub { Sort::Naturally::ncmp(pagetitle(basename($a)), pagetitle(basename($b))) };
2017                 }
2018                 elsif ($params{sort} eq 'mtime') {
2019                         $f=sub { $pagemtime{$b} <=> $pagemtime{$a} };
2020                 }
2021                 elsif ($params{sort} eq 'age') {
2022                         $f=sub { $pagectime{$b} <=> $pagectime{$a} };
2023                 }
2024                 else {
2025                         error sprintf(gettext("unknown sort type %s"), $params{sort});
2026                 }
2027                 @candidates = sort { &$f } @candidates;
2028         }
2029
2030         @candidates=reverse(@candidates) if $params{reverse};
2031
2032         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2033
2034         # clear params, remainder is passed to pagespec
2035         my $num=$params{num};
2036         delete @params{qw{num deptype reverse sort filter list}};
2037
2038         my @matches;
2039         my $firstfail;
2040         my $count=0;
2041         my $accum=IkiWiki::SuccessReason->new();
2042         foreach my $p (@candidates) {
2043                 my $r=$sub->($p, %params, location => $page);
2044                 error(sprintf(gettext("cannot match pages: %s"), $r))
2045                         if $r->isa("IkiWiki::ErrorReason");
2046                 $accum |= $r;
2047                 if ($r) {
2048                         push @matches, $p;
2049                         last if defined $num && ++$count == $num;
2050                 }
2051         }
2052
2053         # Add simple dependencies for accumulated influences.
2054         my $i=$accum->influences;
2055         foreach my $k (keys %$i) {
2056                 $depends_simple{$page}{lc $k} |= $i->{$k};
2057         }
2058
2059         return @matches;
2060 }
2061
2062 sub pagespec_valid ($) {
2063         my $spec=shift;
2064
2065         my $sub=pagespec_translate($spec);
2066         return ! $@;
2067 }
2068
2069 sub glob2re ($) {
2070         my $re=quotemeta(shift);
2071         $re=~s/\\\*/.*/g;
2072         $re=~s/\\\?/./g;
2073         return $re;
2074 }
2075
2076 package IkiWiki::FailReason;
2077
2078 use overload (
2079         '""'    => sub { $_[0][0] },
2080         '0+'    => sub { 0 },
2081         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2082         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2083         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2084         fallback => 1,
2085 );
2086
2087 our @ISA = 'IkiWiki::SuccessReason';
2088
2089 package IkiWiki::SuccessReason;
2090
2091 use overload (
2092         '""'    => sub { $_[0][0] },
2093         '0+'    => sub { 1 },
2094         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2095         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2096         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2097         fallback => 1,
2098 );
2099
2100 sub new {
2101         my $class = shift;
2102         my $value = shift;
2103         return bless [$value, {@_}], $class;
2104 }
2105
2106 sub influences {
2107         my $this=shift;
2108         $this->[1]={@_} if @_;
2109         my %i=%{$this->[1]};
2110         delete $i{""};
2111         return \%i;
2112 }
2113
2114 sub influences_static {
2115         return ! $_[0][1]->{""};
2116 }
2117
2118 sub merge_influences {
2119         my $this=shift;
2120         my $other=shift;
2121         my $anded=shift;
2122
2123         if (! $anded || (($this || %{$this->[1]}) &&
2124                         ($other || %{$other->[1]}))) {
2125                 foreach my $influence (keys %{$other->[1]}) {
2126                         $this->[1]{$influence} |= $other->[1]{$influence};
2127                 }
2128         }
2129         else {
2130                 # influence blocker
2131                 $this->[1]={};
2132         }
2133 }
2134
2135 package IkiWiki::ErrorReason;
2136
2137 our @ISA = 'IkiWiki::FailReason';
2138
2139 package IkiWiki::PageSpec;
2140
2141 sub derel ($$) {
2142         my $path=shift;
2143         my $from=shift;
2144
2145         if ($path =~ m!^\./!) {
2146                 $from=~s#/?[^/]+$## if defined $from;
2147                 $path=~s#^\./##;
2148                 $path="$from/$path" if length $from;
2149         }
2150
2151         return $path;
2152 }
2153
2154 sub match_glob ($$;@) {
2155         my $page=shift;
2156         my $glob=shift;
2157         my %params=@_;
2158
2159         $glob=derel($glob, $params{location});
2160
2161         my $regexp=IkiWiki::glob2re($glob);
2162         if ($page=~/^$regexp$/i) {
2163                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2164                         return IkiWiki::SuccessReason->new("$glob matches $page");
2165                 }
2166                 else {
2167                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2168                 }
2169         }
2170         else {
2171                 return IkiWiki::FailReason->new("$glob does not match $page");
2172         }
2173 }
2174
2175 sub match_internal ($$;@) {
2176         return match_glob($_[0], $_[1], @_, internal => 1)
2177 }
2178
2179 sub match_link ($$;@) {
2180         my $page=shift;
2181         my $link=lc(shift);
2182         my %params=@_;
2183
2184         $link=derel($link, $params{location});
2185         my $from=exists $params{location} ? $params{location} : '';
2186
2187         my $links = $IkiWiki::links{$page};
2188         return IkiWiki::FailReason->new("$page has no links", "" => 1)
2189                 unless $links && @{$links};
2190         my $bestlink = IkiWiki::bestlink($from, $link);
2191         foreach my $p (@{$links}) {
2192                 if (length $bestlink) {
2193                         return IkiWiki::SuccessReason->new("$page links to $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2194                                 if $bestlink eq IkiWiki::bestlink($page, $p);
2195                 }
2196                 else {
2197                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2198                                 if match_glob($p, $link, %params);
2199                         my ($p_rel)=$p=~/^\/?(.*)/;
2200                         $link=~s/^\///;
2201                         return IkiWiki::SuccessReason->new("$page links to page $p_rel matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2202                                 if match_glob($p_rel, $link, %params);
2203                 }
2204         }
2205         return IkiWiki::FailReason->new("$page does not link to $link", "" => 1);
2206 }
2207
2208 sub match_backlink ($$;@) {
2209         my $ret=match_link($_[1], $_[0], @_);
2210         $ret->influences($_[1] => $IkiWiki::DEPEND_LINKS);
2211         return $ret;
2212 }
2213
2214 sub match_created_before ($$;@) {
2215         my $page=shift;
2216         my $testpage=shift;
2217         my %params=@_;
2218
2219         $testpage=derel($testpage, $params{location});
2220
2221         if (exists $IkiWiki::pagectime{$testpage}) {
2222                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2223                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2224                 }
2225                 else {
2226                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2227                 }
2228         }
2229         else {
2230                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2231         }
2232 }
2233
2234 sub match_created_after ($$;@) {
2235         my $page=shift;
2236         my $testpage=shift;
2237         my %params=@_;
2238
2239         $testpage=derel($testpage, $params{location});
2240
2241         if (exists $IkiWiki::pagectime{$testpage}) {
2242                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2243                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2244                 }
2245                 else {
2246                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2247                 }
2248         }
2249         else {
2250                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2251         }
2252 }
2253
2254 sub match_creation_day ($$;@) {
2255         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
2256                 return IkiWiki::SuccessReason->new('creation_day matched');
2257         }
2258         else {
2259                 return IkiWiki::FailReason->new('creation_day did not match');
2260         }
2261 }
2262
2263 sub match_creation_month ($$;@) {
2264         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
2265                 return IkiWiki::SuccessReason->new('creation_month matched');
2266         }
2267         else {
2268                 return IkiWiki::FailReason->new('creation_month did not match');
2269         }
2270 }
2271
2272 sub match_creation_year ($$;@) {
2273         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
2274                 return IkiWiki::SuccessReason->new('creation_year matched');
2275         }
2276         else {
2277                 return IkiWiki::FailReason->new('creation_year did not match');
2278         }
2279 }
2280
2281 sub match_user ($$;@) {
2282         shift;
2283         my $user=shift;
2284         my %params=@_;
2285
2286         if (! exists $params{user}) {
2287                 return IkiWiki::ErrorReason->new("no user specified");
2288         }
2289
2290         if (defined $params{user} && lc $params{user} eq lc $user) {
2291                 return IkiWiki::SuccessReason->new("user is $user");
2292         }
2293         elsif (! defined $params{user}) {
2294                 return IkiWiki::FailReason->new("not logged in");
2295         }
2296         else {
2297                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2298         }
2299 }
2300
2301 sub match_admin ($$;@) {
2302         shift;
2303         shift;
2304         my %params=@_;
2305
2306         if (! exists $params{user}) {
2307                 return IkiWiki::ErrorReason->new("no user specified");
2308         }
2309
2310         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2311                 return IkiWiki::SuccessReason->new("user is an admin");
2312         }
2313         elsif (! defined $params{user}) {
2314                 return IkiWiki::FailReason->new("not logged in");
2315         }
2316         else {
2317                 return IkiWiki::FailReason->new("user is not an admin");
2318         }
2319 }
2320
2321 sub match_ip ($$;@) {
2322         shift;
2323         my $ip=shift;
2324         my %params=@_;
2325
2326         if (! exists $params{ip}) {
2327                 return IkiWiki::ErrorReason->new("no IP specified");
2328         }
2329
2330         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2331                 return IkiWiki::SuccessReason->new("IP is $ip");
2332         }
2333         else {
2334                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2335         }
2336 }
2337
2338 1