IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("istranslatable");
  27 memoize("_istranslation");
  28 memoize("percenttranslated");
  29
  30 sub import { #{{{
  31         hook(type => "getsetup", id => "po", call => \&getsetup);
  32         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  33         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  34         hook(type => "scan", id => "po", call => \&scan, last =>1);
  35         hook(type => "filter", id => "po", call => \&filter);
  36         hook(type => "htmlize", id => "po", call => \&htmlize);
  37         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  38         hook(type => "rename", id => "po", call => \&renamepages);
  39         hook(type => "delete", id => "po", call => \&mydelete);
  40         hook(type => "change", id => "po", call => \&change);
  41         hook(type => "editcontent", id => "po", call => \&editcontent);
  42
  43         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  44         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  45         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  46         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  47         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  48         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  49         $origsubs{'urlto'}=\&IkiWiki::urlto;
  50         inject(name => "IkiWiki::urlto", call => \&myurlto);
  51 } #}}}
  52
  53
  54 # ,----
  55 # | Table of contents
  56 # `----
  57
  58 # 1. Hooks
  59 # 2. Injected functions
  60 # 3. Blackboxes for private data
  61 # 4. Helper functions
  62 # 5. PageSpec's
  63
  64
  65 # ,----
  66 # | Hooks
  67 # `----
  68
  69 sub getsetup () { #{{{
  70         return
  71                 plugin => {
  72                         safe => 0,
  73                         rebuild => 1,
  74                 },
  75                 po_master_language => {
  76                         type => "string",
  77                         example => {
  78                                 'code' => 'en',
  79                                 'name' => 'English'
  80                         },
  81                         description => "master language (non-PO files)",
  82                         safe => 1,
  83                         rebuild => 1,
  84                 },
  85                 po_slave_languages => {
  86                         type => "string",
  87                         example => {
  88                                 'fr' => 'Français',
  89                                 'es' => 'Castellano',
  90                                 'de' => 'Deutsch'
  91                         },
  92                         description => "slave languages (PO files)",
  93                         safe => 1,
  94                         rebuild => 1,
  95                 },
  96                 po_translatable_pages => {
  97                         type => "pagespec",
  98                         example => "!*/Discussion",
  99                         description => "PageSpec controlling which pages are translatable",
 100                         link => "ikiwiki/PageSpec",
 101                         safe => 1,
 102                         rebuild => 1,
 103                 },
 104                 po_link_to => {
 105                         type => "string",
 106                         example => "current",
 107                         description => "internal linking behavior (default/current/negotiated)",
 108                         safe => 1,
 109                         rebuild => 1,
 110                 },
 111 } #}}}
 112
 113 sub checkconfig () { #{{{
 114         foreach my $field (qw{po_master_language po_slave_languages}) {
 115                 if (! exists $config{$field} || ! defined $config{$field}) {
 116                         error(sprintf(gettext("Must specify %s"), $field));
 117                 }
 118         }
 119         if (! (keys %{$config{po_slave_languages}})) {
 120                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 121         }
 122         map {
 123                 islanguagecode($_)
 124                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 125         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 126         if (! exists $config{po_translatable_pages} ||
 127             ! defined $config{po_translatable_pages}) {
 128                 $config{po_translatable_pages}="";
 129         }
 130         if (! exists $config{po_link_to} ||
 131             ! defined $config{po_link_to}) {
 132                 $config{po_link_to}='default';
 133         }
 134         elsif (! grep {
 135                         $config{po_link_to} eq $_
 136                 } ('default', 'current', 'negotiated')) {
 137                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 138                                 $config{po_link_to}));
 139                 $config{po_link_to}='default';
 140         }
 141         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 142                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 143                 $config{po_link_to}='default';
 144         }
 145         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 146 } #}}}
 147
 148 sub needsbuild () { #{{{
 149         my $needsbuild=shift;
 150
 151         # backup @needsbuild content so that change() can know whether
 152         # a given master page was rendered because its source file was changed
 153         @origneedsbuild=(@$needsbuild);
 154
 155         flushmemoizecache();
 156         buildtranslationscache();
 157
 158         # make existing translations depend on the corresponding master page
 159         foreach my $master (keys %translations) {
 160                 map add_depends($_, $master), values %{otherlanguages($master)};
 161         }
 162 } #}}}
 163
 164 # Massage the recorded state of internal links so that:
 165 # - it matches the actually generated links, rather than the links as written
 166 #   in the pages' source
 167 # - backlinks are consistent in all cases
 168 sub scan (@) { #{{{
 169         my %params=@_;
 170         my $page=$params{page};
 171         my $content=$params{content};
 172
 173         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 174
 175         if (istranslation($page)) {
 176                 foreach my $destpage (@{$links{$page}}) {
 177                         if (istranslatable($destpage)) {
 178                                 # replace one occurence of $destpage in $links{$page}
 179                                 # (we only want to replace the one that was added by
 180                                 # IkiWiki::Plugin::link::scan, other occurences may be
 181                                 # there for other reasons)
 182                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 183                                         if (@{$links{$page}}[$i] eq $destpage) {
 184                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 185                                                 last;
 186                                         }
 187                                 }
 188                         }
 189                 }
 190         }
 191         elsif (! istranslatable($page) && ! istranslation($page)) {
 192                 foreach my $destpage (@{$links{$page}}) {
 193                         if (istranslatable($destpage)) {
 194                                 # make sure any destpage's translations has
 195                                 # $page in its backlinks
 196                                 push @{$links{$page}},
 197                                         values %{otherlanguages($destpage)};
 198                         }
 199                 }
 200         }
 201 } #}}}
 202
 203 # We use filter to convert PO to the master page's format,
 204 # since the rest of ikiwiki should not work on PO files.
 205 sub filter (@) { #{{{
 206         my %params = @_;
 207
 208         my $page = $params{page};
 209         my $destpage = $params{destpage};
 210         my $content = decode_utf8(encode_utf8($params{content}));
 211
 212         return $content if ( ! istranslation($page)
 213                              || alreadyfiltered($page, $destpage) );
 214
 215         # CRLF line terminators make poor Locale::Po4a feel bad
 216         $content=~s/\r\n/\n/g;
 217
 218         # Implementation notes
 219         #
 220         # 1. Locale::Po4a reads/writes from/to files, and I'm too lazy
 221         #    to learn how to disguise a variable as a file.
 222         # 2. There are incompatibilities between some File::Temp versions
 223         #    (including 0.18, bundled with Lenny's perl-modules package)
 224         #    and others (e.g. 0.20, previously present in the archive as
 225         #    a standalone package): under certain circumstances, some
 226         #    return a relative filename, whereas others return an absolute one;
 227         #    we here use this module in a way that is at least compatible
 228         #    with 0.18 and 0.20. Beware, hit'n'run refactorers!
 229         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 230                                     DIR => File::Spec->tmpdir,
 231                                     UNLINK => 1)->filename;
 232         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 233                                      DIR => File::Spec->tmpdir,
 234                                      UNLINK => 1)->filename;
 235
 236         writefile(basename($infile), File::Spec->tmpdir, $content);
 237
 238         my $masterfile = srcfile($pagesources{masterpage($page)});
 239         my (@pos,@masters);
 240         push @pos,$infile;
 241         push @masters,$masterfile;
 242         my %options = (
 243                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 244         );
 245         my $doc=Locale::Po4a::Chooser::new('text',%options);
 246         $doc->process(
 247                 'po_in_name'    => \@pos,
 248                 'file_in_name'  => \@masters,
 249                 'file_in_charset'  => 'utf-8',
 250                 'file_out_charset' => 'utf-8',
 251         ) or error("[po/filter:$page]: failed to translate");
 252         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 253         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 254
 255         # Unlinking should happen automatically, thanks to File::Temp,
 256         # but it does not work here, probably because of the way writefile()
 257         # and Locale::Po4a::write() work.
 258         unlink $infile, $outfile;
 259
 260         setalreadyfiltered($page, $destpage);
 261         return $content;
 262 } #}}}
 263
 264 sub htmlize (@) { #{{{
 265         my %params=@_;
 266
 267         my $page = $params{page};
 268         my $content = $params{content};
 269
 270         # ignore PO files this plugin did not create
 271         return $content unless istranslation($page);
 272
 273         # force content to be htmlize'd as if it was the same type as the master page
 274         return IkiWiki::htmlize($page, $page,
 275                                 pagetype(srcfile($pagesources{masterpage($page)})),
 276                                 $content);
 277 } #}}}
 278
 279 sub pagetemplate (@) { #{{{
 280         my %params=@_;
 281         my $page=$params{page};
 282         my $destpage=$params{destpage};
 283         my $template=$params{template};
 284
 285         my ($masterpage, $lang) = istranslation($page);
 286
 287         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 288                 $template->param(percenttranslated => percenttranslated($page));
 289         }
 290         if ($template->query(name => "istranslation")) {
 291                 $template->param(istranslation => scalar istranslation($page));
 292         }
 293         if ($template->query(name => "istranslatable")) {
 294                 $template->param(istranslatable => istranslatable($page));
 295         }
 296         if ($template->query(name => "HOMEPAGEURL")) {
 297                 $template->param(homepageurl => homepageurl($page));
 298         }
 299         if ($template->query(name => "otherlanguages")) {
 300                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 301                 map add_depends($page, $_), (values %{otherlanguages($page)});
 302         }
 303         # Rely on IkiWiki::Render's genpage() to decide wether
 304         # a discussion link should appear on $page; this is not
 305         # totally accurate, though: some broken links may be generated
 306         # when cgiurl is disabled.
 307         # This compromise avoids some code duplication, and will probably
 308         # prevent future breakage when ikiwiki internals change.
 309         # Known limitations are preferred to future random bugs.
 310         if ($template->param('discussionlink') && istranslation($page)) {
 311                 $template->param('discussionlink' => htmllink(
 312                                                         $page,
 313                                                         $destpage,
 314                                                         $masterpage . '/' . gettext("Discussion"),
 315                                                         noimageinline => 1,
 316                                                         forcesubpage => 0,
 317                                                         linktext => gettext("Discussion"),
 318                                                         ));
 319         }
 320         # Remove broken parentlink to ./index.html on home page's translations.
 321         # It works because this hook has the "last" parameter set, to ensure it
 322         # runs after parentlinks' own pagetemplate hook.
 323         if ($template->param('parentlinks')
 324             && istranslation($page)
 325             && $masterpage eq "index") {
 326                 $template->param('parentlinks' => []);
 327         }
 328 } # }}}
 329
 330 # Add the renamed page translations to the list of to-be-renamed pages.
 331 # Save information about master page rename, so that:
 332 # - our delete hook can ignore the translations not renamed already
 333 # - our change hook can rename the translations accordingly.
 334 sub renamepages() { #{{{
 335         my $torename=shift;
 336         my @torename=@{$torename};
 337
 338         foreach my $rename (@torename) {
 339                 next unless istranslatable($rename->{src});
 340                 my %otherpages=%{otherlanguages($rename->{src})};
 341                 while (my ($lang, $otherpage) = each %otherpages) {
 342                         push @{$torename}, {
 343                                 src => $otherpage,
 344                                 srcfile => $pagesources{$otherpage},
 345                                 dest => otherlanguage($rename->{dest}, $lang),
 346                                 destfile => $rename->{dest}.".".$lang.".po",
 347                                 required => 0,
 348                         };
 349                 }
 350         }
 351 } #}}}
 352
 353 sub mydelete(@) { #{{{
 354         my @deleted=@_;
 355
 356         map {
 357                 deletetranslations($_);
 358         } grep { istranslatablefile($_) } @deleted;
 359 } #}}}
 360
 361 sub change(@) { #{{{
 362         my @rendered=@_;
 363
 364         my $updated_po_files=0;
 365
 366         # Refresh/create POT and PO files as needed.
 367         foreach my $file (@rendered) {
 368                 next unless istranslatablefile($file);
 369                 my $page=pagename($file);
 370                 my $masterfile=srcfile($file);
 371                 my $updated_pot_file=0;
 372                 # Only refresh Pot file if it does not exist, or if
 373                 # $pagesources{$page} was changed: don't if only the HTML was
 374                 # refreshed, e.g. because of a dependency.
 375                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 376                     || ! -e potfile($masterfile)) {
 377                         refreshpot($masterfile);
 378                         $updated_pot_file=1;
 379                 }
 380                 my @pofiles;
 381                 map {
 382                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 383                 } (pofiles($masterfile));
 384                 if (@pofiles) {
 385                         refreshpofiles($masterfile, @pofiles);
 386                         map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
 387                         $updated_po_files=1;
 388                 }
 389         }
 390
 391         if ($updated_po_files) {
 392                 commit_and_refresh(
 393                         gettext("updated PO files"),
 394                         "IkiWiki::Plugin::po::change");
 395         }
 396 } #}}}
 397
 398 # As we're previewing or saving a page, the content may have
 399 # changed, so tell the next filter() invocation it must not be lazy.
 400 sub editcontent () { #{{{
 401         my %params=@_;
 402
 403         unsetalreadyfiltered($params{page}, $params{page});
 404         return $params{content};
 405 } #}}}
 406
 407
 408 # ,----
 409 # | Injected functions
 410 # `----
 411
 412 # Implement po_link_to 'current' and 'negotiated' settings.
 413 sub mybestlink ($$) { #{{{
 414         my $page=shift;
 415         my $link=shift;
 416
 417         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 418         if (length $res
 419             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 420             && istranslatable($res)
 421             && istranslation($page)) {
 422                 return $res . "." . lang($page);
 423         }
 424         return $res;
 425 } #}}}
 426
 427 sub mybeautify_urlpath ($) { #{{{
 428         my $url=shift;
 429
 430         my $res=$origsubs{'beautify_urlpath'}->($url);
 431         if ($config{po_link_to} eq "negotiated") {
 432                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 433                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 434                 map {
 435                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 436                 } (keys %{$config{po_slave_languages}});
 437         }
 438         return $res;
 439 } #}}}
 440
 441 sub mytargetpage ($$) { #{{{
 442         my $page=shift;
 443         my $ext=shift;
 444
 445         if (istranslation($page) || istranslatable($page)) {
 446                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 447                 if (! $config{usedirs} || $masterpage eq 'index') {
 448                         return $masterpage . "." . $lang . "." . $ext;
 449                 }
 450                 else {
 451                         return $masterpage . "/index." . $lang . "." . $ext;
 452                 }
 453         }
 454         return $origsubs{'targetpage'}->($page, $ext);
 455 } #}}}
 456
 457 sub myurlto ($$;$) { #{{{
 458         my $to=shift;
 459         my $from=shift;
 460         my $absolute=shift;
 461
 462         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 463         if (! length $to
 464             && $config{po_link_to} eq "current"
 465             && istranslatable('index')) {
 466                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 467         }
 468         return $origsubs{'urlto'}->($to,$from,$absolute);
 469 } #}}}
 470
 471
 472 # ,----
 473 # | Blackboxes for private data
 474 # `----
 475
 476 {
 477         my %filtered;
 478
 479         sub alreadyfiltered($$) { #{{{
 480                 my $page=shift;
 481                 my $destpage=shift;
 482
 483                 return ( exists $filtered{$page}{$destpage}
 484                          && $filtered{$page}{$destpage} eq 1 );
 485         } #}}}
 486
 487         sub setalreadyfiltered($$) { #{{{
 488                 my $page=shift;
 489                 my $destpage=shift;
 490
 491                 $filtered{$page}{$destpage}=1;
 492         } #}}}
 493
 494         sub unsetalreadyfiltered($$) { #{{{
 495                 my $page=shift;
 496                 my $destpage=shift;
 497
 498                 if (exists $filtered{$page}{$destpage}) {
 499                         delete $filtered{$page}{$destpage};
 500                 }
 501         } #}}}
 502
 503         sub resetalreadyfiltered() { #{{{
 504                 undef %filtered;
 505         } #}}}
 506 }
 507
 508 # ,----
 509 # | Helper functions
 510 # `----
 511
 512 sub maybe_add_leading_slash ($;$) { #{{{
 513         my $str=shift;
 514         my $add=shift;
 515         $add=1 unless defined $add;
 516         return '/' . $str if $add;
 517         return $str;
 518 } #}}}
 519
 520 sub istranslatablefile ($) { #{{{
 521         my $file=shift;
 522
 523         return 0 unless defined $file;
 524         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 525         return 0 if $file =~ /\.pot$/;
 526         return 1 if pagespec_match(pagename($file), $config{po_translatable_pages});
 527         return;
 528 } #}}}
 529
 530 sub istranslatable ($) { #{{{
 531         my $page=shift;
 532
 533         $page=~s#^/##;
 534         return 1 if istranslatablefile($pagesources{$page});
 535         return;
 536 } #}}}
 537
 538 sub _istranslation ($) { #{{{
 539         my $page=shift;
 540
 541         my $hasleadingslash = ($page=~s#^/##);
 542         my $file=$pagesources{$page};
 543         return 0 unless (defined $file
 544                          && defined pagetype($file)
 545                          && pagetype($file) eq 'po');
 546         return 0 if $file =~ /\.pot$/;
 547
 548         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 549         return 0 unless (defined $masterpage && defined $lang
 550                          && length $masterpage && length $lang
 551                          && defined $pagesources{$masterpage}
 552                          && defined $config{po_slave_languages}{$lang});
 553
 554         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang)
 555                 if istranslatable($masterpage);
 556 } #}}}
 557
 558 sub istranslation ($) { #{{{
 559         my $page=shift;
 560
 561         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 562                 my $hasleadingslash = ($masterpage=~s#^/##);
 563                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 564                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 565         }
 566         return;
 567 } #}}}
 568
 569 sub masterpage ($) { #{{{
 570         my $page=shift;
 571
 572         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 573                 return $masterpage;
 574         }
 575         return $page;
 576 } #}}}
 577
 578 sub lang ($) { #{{{
 579         my $page=shift;
 580
 581         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 582                 return $lang;
 583         }
 584         return $config{po_master_language}{code};
 585 } #}}}
 586
 587 sub islanguagecode ($) { #{{{
 588         my $code=shift;
 589
 590         return ($code =~ /^[a-z]{2}$/);
 591 } #}}}
 592
 593 sub otherlanguage ($$) { #{{{
 594         my $page=shift;
 595         my $code=shift;
 596
 597         return masterpage($page) if $code eq $config{po_master_language}{code};
 598         return masterpage($page) . '.' . $code;
 599 } #}}}
 600
 601 sub otherlanguages ($) { #{{{
 602         my $page=shift;
 603
 604         my %ret;
 605         return \%ret unless (istranslation($page) || istranslatable($page));
 606         my $curlang=lang($page);
 607         foreach my $lang
 608                 ($config{po_master_language}{code}, keys %{$config{po_slave_languages}}) {
 609                 next if $lang eq $curlang;
 610                 $ret{$lang}=otherlanguage($page, $lang);
 611         }
 612         return \%ret;
 613 } #}}}
 614
 615 sub potfile ($) { #{{{
 616         my $masterfile=shift;
 617
 618         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 619         $dir='' if $dir eq './';
 620         return File::Spec->catpath('', $dir, $name . ".pot");
 621 } #}}}
 622
 623 sub pofile ($$) { #{{{
 624         my $masterfile=shift;
 625         my $lang=shift;
 626
 627         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 628         $dir='' if $dir eq './';
 629         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 630 } #}}}
 631
 632 sub pofiles ($) { #{{{
 633         my $masterfile=shift;
 634
 635         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 636 } #}}}
 637
 638 sub refreshpot ($) { #{{{
 639         my $masterfile=shift;
 640
 641         my $potfile=potfile($masterfile);
 642         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 643         my $doc=Locale::Po4a::Chooser::new('text',%options);
 644         $doc->{TT}{utf_mode} = 1;
 645         $doc->{TT}{file_in_charset} = 'utf-8';
 646         $doc->{TT}{file_out_charset} = 'utf-8';
 647         $doc->read($masterfile);
 648         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 649         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 650         # compulsory since this module prevents us from using the porefs option.
 651         my %po_options = ('porefs' => 'none');
 652         $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
 653         $doc->{TT}{po_out}->set_charset('utf-8');
 654         # do the actual work
 655         $doc->parse;
 656         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 657         $doc->writepo($potfile);
 658 } #}}}
 659
 660 sub refreshpofiles ($@) { #{{{
 661         my $masterfile=shift;
 662         my @pofiles=@_;
 663
 664         my $potfile=potfile($masterfile);
 665         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 666
 667         foreach my $pofile (@pofiles) {
 668                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 669                 if (-e $pofile) {
 670                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 671                                 or error("[po/refreshpofiles:$pofile] failed to update");
 672                 }
 673                 else {
 674                         File::Copy::syscopy($potfile,$pofile)
 675                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 676                 }
 677         }
 678 } #}}}
 679
 680 sub buildtranslationscache() { #{{{
 681         # use istranslation's side-effect
 682         map istranslation($_), (keys %pagesources);
 683 } #}}}
 684
 685 sub resettranslationscache() { #{{{
 686         undef %translations;
 687 } #}}}
 688
 689 sub flushmemoizecache() { #{{{
 690         Memoize::flush_cache("istranslatable");
 691         Memoize::flush_cache("_istranslation");
 692         Memoize::flush_cache("percenttranslated");
 693 } #}}}
 694
 695 sub urlto_with_orig_beautiful_urlpath($$) { #{{{
 696         my $to=shift;
 697         my $from=shift;
 698
 699         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 700         my $res=urlto($to, $from);
 701         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 702
 703         return $res;
 704 } #}}}
 705
 706 sub percenttranslated ($) { #{{{
 707         my $page=shift;
 708
 709         return gettext("N/A") unless istranslation($page);
 710         my $file=srcfile($pagesources{$page});
 711         my $masterfile = srcfile($pagesources{masterpage($page)});
 712         my (@pos,@masters);
 713         push @pos,$file;
 714         push @masters,$masterfile;
 715         my %options = (
 716                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 717         );
 718         my $doc=Locale::Po4a::Chooser::new('text',%options);
 719         $doc->process(
 720                 'po_in_name'    => \@pos,
 721                 'file_in_name'  => \@masters,
 722                 'file_in_charset'  => 'utf-8',
 723                 'file_out_charset' => 'utf-8',
 724         ) or error("[po/percenttranslated:$page]: failed to translate");
 725         my ($percent,$hit,$queries) = $doc->stats();
 726         return $percent;
 727 } #}}}
 728
 729 sub languagename ($) { #{{{
 730         my $code=shift;
 731
 732         return $config{po_master_language}{name}
 733                 if $code eq $config{po_master_language}{code};
 734         return $config{po_slave_languages}{$code}
 735                 if defined $config{po_slave_languages}{$code};
 736         return;
 737 } #}}}
 738
 739 sub otherlanguagesloop ($) { #{{{
 740         my $page=shift;
 741
 742         my @ret;
 743         my %otherpages=%{otherlanguages($page)};
 744         while (my ($lang, $otherpage) = each %otherpages) {
 745                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 746                         push @ret, {
 747                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 748                                 code => $lang,
 749                                 language => languagename($lang),
 750                                 master => 1,
 751                         };
 752                 }
 753                 else {
 754                         push @ret, {
 755                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 756                                 code => $lang,
 757                                 language => languagename($lang),
 758                                 percent => percenttranslated($otherpage),
 759                         }
 760                 }
 761         }
 762         return sort {
 763                         return -1 if $a->{code} eq $config{po_master_language}{code};
 764                         return 1 if $b->{code} eq $config{po_master_language}{code};
 765                         return $a->{language} cmp $b->{language};
 766                 } @ret;
 767 } #}}}
 768
 769 sub homepageurl (;$) { #{{{
 770         my $page=shift;
 771
 772         return urlto('', $page);
 773 } #}}}
 774
 775 sub deletetranslations ($) { #{{{
 776         my $deletedmasterfile=shift;
 777
 778         my $deletedmasterpage=pagename($deletedmasterfile);
 779         my @todelete;
 780         map {
 781                 my $file = newpagefile($deletedmasterpage.'.'.$_, 'po');
 782                 my $absfile = "$config{srcdir}/$file";
 783                 if (-e $absfile && ! -l $absfile && ! -d $absfile) {
 784                         push @todelete, $file;
 785                 }
 786         } keys %{$config{po_slave_languages}};
 787
 788         map {
 789                 if ($config{rcs}) {
 790                         IkiWiki::rcs_remove($_);
 791                 }
 792                 else {
 793                         IkiWiki::prune("$config{srcdir}/$_");
 794                 }
 795         } @todelete;
 796
 797         if (scalar @todelete) {
 798                 commit_and_refresh(
 799                         gettext("removed obsolete PO files"),
 800                         "IkiWiki::Plugin::po::deletetranslations");
 801         }
 802 } #}}}
 803
 804 sub commit_and_refresh ($$) { #{{{
 805         my ($msg, $author) = (shift, shift);
 806
 807         if ($config{rcs}) {
 808                 IkiWiki::disable_commit_hook();
 809                 IkiWiki::rcs_commit_staged($msg, $author, "127.0.0.1");
 810                 IkiWiki::enable_commit_hook();
 811                 IkiWiki::rcs_update();
 812         }
 813         # Reinitialize module's private variables.
 814         resetalreadyfiltered();
 815         resettranslationscache();
 816         flushmemoizecache();
 817         # Trigger a wiki refresh.
 818         require IkiWiki::Render;
 819         # without preliminary saveindex/loadindex, refresh()
 820         # complains about a lot of uninitialized variables
 821         IkiWiki::saveindex();
 822         IkiWiki::loadindex();
 823         IkiWiki::refresh();
 824         IkiWiki::saveindex();
 825 } #}}}
 826
 827 # ,----
 828 # | PageSpec's
 829 # `----
 830
 831 package IkiWiki::PageSpec;
 832 use warnings;
 833 use strict;
 834 use IkiWiki 2.00;
 835
 836 sub match_istranslation ($;@) { #{{{
 837         my $page=shift;
 838
 839         if (IkiWiki::Plugin::po::istranslation($page)) {
 840                 return IkiWiki::SuccessReason->new("is a translation page");
 841         }
 842         else {
 843                 return IkiWiki::FailReason->new("is not a translation page");
 844         }
 845 } #}}}
 846
 847 sub match_istranslatable ($;@) { #{{{
 848         my $page=shift;
 849
 850         if (IkiWiki::Plugin::po::istranslatable($page)) {
 851                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 852         }
 853         else {
 854                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 855         }
 856 } #}}}
 857
 858 sub match_lang ($$;@) { #{{{
 859         my $page=shift;
 860         my $wanted=shift;
 861
 862         my $regexp=IkiWiki::glob2re($wanted);
 863         my $lang=IkiWiki::Plugin::po::lang($page);
 864         if ($lang!~/^$regexp$/i) {
 865                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 866         }
 867         else {
 868                 return IkiWiki::SuccessReason->new("file language is $wanted");
 869         }
 870 } #}}}
 871
 872 sub match_currentlang ($$;@) { #{{{
 873         my $page=shift;
 874         shift;
 875         my %params=@_;
 876
 877         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 878
 879         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 880         my $lang=IkiWiki::Plugin::po::lang($page);
 881
 882         if ($lang eq $currentlang) {
 883                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 884         }
 885         else {
 886                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 887         }
 888 } #}}}
 889
 890 1