IkiWiki/UserInfo.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Storable;
   8 use IkiWiki;
   9
  10 sub userinfo_retrieve () {
  11         my $userinfo=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
  12         return $userinfo;
  13 }
  14
  15 sub userinfo_store ($) {
  16         my $userinfo=shift;
  17
  18         my $newfile="$config{wikistatedir}/userdb.new";
  19         my $oldmask=umask(077);
  20         my $ret=Storable::lock_nstore($userinfo, $newfile);
  21         umask($oldmask);
  22         if (defined $ret && $ret) {
  23                 if (! rename($newfile, "$config{wikistatedir}/userdb")) {
  24                         unlink($newfile);
  25                         $ret=undef;
  26                 }
  27         }
  28         return $ret;
  29 }
  30
  31 sub userinfo_get ($$) {
  32         my $user=shift;
  33         my $field=shift;
  34
  35         my $userinfo=userinfo_retrieve();
  36         if (! defined $userinfo ||
  37             ! exists $userinfo->{$user} || ! ref $userinfo->{$user} ||
  38             ! exists $userinfo->{$user}->{$field}) {
  39                 return "";
  40         }
  41         return $userinfo->{$user}->{$field};
  42 }
  43
  44 sub userinfo_set ($$$) {
  45         my $user=shift;
  46         my $field=shift;
  47         my $value=shift;
  48
  49         my $userinfo=userinfo_retrieve();
  50         if (! defined $userinfo ||
  51             ! exists $userinfo->{$user} || ! ref $userinfo->{$user}) {
  52                 return "";
  53         }
  54
  55         $userinfo->{$user}->{$field}=$value;
  56         return userinfo_store($userinfo);
  57 }
  58
  59 sub userinfo_setall ($$) {
  60         my $user=shift;
  61         my $info=shift;
  62
  63         my $userinfo=userinfo_retrieve();
  64         if (! defined $userinfo) {
  65                 $userinfo={};
  66         }
  67         $userinfo->{$user}=$info;
  68         return userinfo_store($userinfo);
  69 }
  70
  71 sub is_admin ($) {
  72         my $user_name=shift;
  73
  74         return grep { $_ eq $user_name } @{$config{adminuser}};
  75 }
  76
  77 # XXX deprecated, should be removed eventually
  78 sub get_banned_users () {
  79         my @ret;
  80         my $userinfo=userinfo_retrieve();
  81         foreach my $user (keys %{$userinfo}) {
  82                 push @ret, $user if $userinfo->{$user}->{banned};
  83         }
  84         return @ret;
  85 }
  86
  87 # XXX deprecated, should be removed eventually
  88 sub set_banned_users (@) {
  89         my %banned=map { $_ => 1 } @_;
  90         my $userinfo=userinfo_retrieve();
  91         foreach my $user (keys %{$userinfo}) {
  92                 $userinfo->{$user}->{banned} = $banned{$user};
  93         }
  94         return userinfo_store($userinfo);
  95 }
  96
  97 1