IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9
  10 my (%backlinks, %rendered);
  11 our %brokenlinks;
  12 my $links_calculated=0;
  13
  14 sub calculate_links () {
  15         return if $links_calculated;
  16         %backlinks=%brokenlinks=();
  17         foreach my $page (keys %links) {
  18                 foreach my $link (@{$links{$page}}) {
  19                         my $bestlink=bestlink($page, $link);
  20                         if (length $bestlink) {
  21                                 $backlinks{$bestlink}{$page}=1
  22                                         if $bestlink ne $page;
  23                         }
  24                         else {
  25                                 push @{$brokenlinks{$link}}, $page;
  26                         }
  27                 }
  28         }
  29         $links_calculated=1;
  30 }
  31
  32 sub backlink_pages ($) {
  33         my $page=shift;
  34
  35         calculate_links();
  36
  37         return keys %{$backlinks{$page}};
  38 }
  39
  40 sub backlinks ($) {
  41         my $page=shift;
  42
  43         my @links;
  44         foreach my $p (backlink_pages($page)) {
  45                 my $href=urlto($p, $page);
  46
  47                 # Trim common dir prefixes from both pages.
  48                 my $p_trimmed=$p;
  49                 my $page_trimmed=$page;
  50                 my $dir;
  51                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  52                         defined $dir &&
  53                         $p_trimmed=~s/^\Q$dir\E// &&
  54                         $page_trimmed=~s/^\Q$dir\E//;
  55
  56                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  57         }
  58         return @links;
  59 }
  60
  61 sub genpage ($$) {
  62         my $page=shift;
  63         my $content=shift;
  64
  65         my $templatefile;
  66         run_hooks(templatefile => sub {
  67                 return if defined $templatefile;
  68                 my $file=shift->(page => $page);
  69                 if (defined $file && defined template_file($file)) {
  70                         $templatefile=$file;
  71                 }
  72         });
  73         my $template=template(defined $templatefile ? $templatefile : 'page.tmpl', blind_cache => 1);
  74         my $actions=0;
  75
  76         if (length $config{cgiurl}) {
  77                 $template->param(editurl => cgiurl(do => "edit", page => $page))
  78                         if IkiWiki->can("cgi_editpage");
  79                 $template->param(prefsurl => cgiurl(do => "prefs"))
  80                         if exists $hooks{auth};
  81                 $actions++;
  82         }
  83
  84         if (defined $config{historyurl} && length $config{historyurl}) {
  85                 my $u=$config{historyurl};
  86                 $u=~s/\[\[file\]\]/$pagesources{$page}/g;
  87                 $template->param(historyurl => $u);
  88                 $actions++;
  89         }
  90         if ($config{discussion}) {
  91                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/ &&
  92                    (length $config{cgiurl} ||
  93                     exists $links{$page."/".$config{discussionpage}})) {
  94                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
  95                         $actions++;
  96                 }
  97         }
  98
  99         if ($actions) {
 100                 $template->param(have_actions => 1);
 101         }
 102
 103         my @backlinks=sort { $a->{page} cmp $b->{page} } backlinks($page);
 104         my ($backlinks, $more_backlinks);
 105         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 106                 $backlinks=\@backlinks;
 107                 $more_backlinks=[];
 108         }
 109         else {
 110                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 111                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 112         }
 113
 114         $template->param(
 115                 title => $page eq 'index'
 116                         ? $config{wikiname}
 117                         : pagetitle(basename($page)),
 118                 wikiname => $config{wikiname},
 119                 content => $content,
 120                 backlinks => $backlinks,
 121                 more_backlinks => $more_backlinks,
 122                 mtime => displaytime($pagemtime{$page}),
 123                 ctime => displaytime($pagectime{$page}),
 124                 baseurl => baseurl($page),
 125         );
 126
 127         run_hooks(pagetemplate => sub {
 128                 shift->(page => $page, destpage => $page, template => $template);
 129         });
 130
 131         $content=$template->output;
 132
 133         run_hooks(postscan => sub {
 134                 shift->(page => $page, content => $content);
 135         });
 136
 137         run_hooks(format => sub {
 138                 $content=shift->(
 139                         page => $page,
 140                         content => $content,
 141                 );
 142         });
 143
 144         return $content;
 145 }
 146
 147 sub scan ($) {
 148         my $file=shift;
 149
 150         debug(sprintf(gettext("scanning %s"), $file));
 151
 152         my $type=pagetype($file);
 153         if (defined $type) {
 154                 my $srcfile=srcfile($file);
 155                 my $content=readfile($srcfile);
 156                 my $page=pagename($file);
 157                 will_render($page, htmlpage($page), 1);
 158
 159                 if ($config{discussion}) {
 160                         # Discussion links are a special case since they're
 161                         # not in the text of the page, but on its template.
 162                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 163                 }
 164                 else {
 165                         $links{$page}=[];
 166                 }
 167
 168                 run_hooks(scan => sub {
 169                         shift->(
 170                                 page => $page,
 171                                 content => $content,
 172                         );
 173                 });
 174
 175                 # Preprocess in scan-only mode.
 176                 preprocess($page, $page, $content, 1);
 177         }
 178         else {
 179                 will_render($file, $file, 1);
 180         }
 181 }
 182
 183 sub fast_file_copy (@) {
 184         my $srcfile=shift;
 185         my $destfile=shift;
 186         my $srcfd=shift;
 187         my $destfd=shift;
 188         my $cleanup=shift;
 189
 190         my $blksize = 16384;
 191         my ($len, $buf, $written);
 192         while ($len = sysread $srcfd, $buf, $blksize) {
 193                 if (! defined $len) {
 194                         next if $! =~ /^Interrupted/;
 195                         error("failed to read $srcfile: $!", $cleanup);
 196                 }
 197                 my $offset = 0;
 198                 while ($len) {
 199                         defined($written = syswrite $destfd, $buf, $len, $offset)
 200                                 or error("failed to write $destfile: $!", $cleanup);
 201                         $len -= $written;
 202                         $offset += $written;
 203                 }
 204         }
 205 }
 206
 207 sub render ($$) {
 208         my $file=shift;
 209         return if $rendered{$file};
 210         debug(shift);
 211         $rendered{$file}=1;
 212
 213         my $type=pagetype($file);
 214         my $srcfile=srcfile($file);
 215         if (defined $type) {
 216                 my $page=pagename($file);
 217                 delete $depends{$page};
 218                 delete $depends_simple{$page};
 219                 will_render($page, htmlpage($page), 1);
 220                 return if $type=~/^_/;
 221
 222                 my $content=htmlize($page, $page, $type,
 223                         linkify($page, $page,
 224                         preprocess($page, $page,
 225                         filter($page, $page,
 226                         readfile($srcfile)))));
 227
 228                 my $output=htmlpage($page);
 229                 writefile($output, $config{destdir}, genpage($page, $content));
 230         }
 231         else {
 232                 delete $depends{$file};
 233                 delete $depends_simple{$file};
 234                 will_render($file, $file, 1);
 235
 236                 if ($config{hardlink}) {
 237                         # only hardlink if owned by same user
 238                         my @stat=stat($srcfile);
 239                         if ($stat[4] == $>) {
 240                                 prep_writefile($file, $config{destdir});
 241                                 unlink($config{destdir}."/".$file);
 242                                 if (link($srcfile, $config{destdir}."/".$file)) {
 243                                         return;
 244                                 }
 245                         }
 246                         # if hardlink fails, fall back to copying
 247                 }
 248
 249                 my $srcfd=readfile($srcfile, 1, 1);
 250                 writefile($file, $config{destdir}, undef, 1, sub {
 251                         fast_file_copy($srcfile, $file, $srcfd, @_);
 252                 });
 253         }
 254 }
 255
 256 sub prune ($) {
 257         my $file=shift;
 258
 259         unlink($file);
 260         my $dir=dirname($file);
 261         while (rmdir($dir)) {
 262                 $dir=dirname($dir);
 263         }
 264 }
 265
 266 sub srcdir_check () {
 267         # security check, avoid following symlinks in the srcdir path by default
 268         my $test=$config{srcdir};
 269         while (length $test) {
 270                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 271                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 272                 }
 273                 unless ($test=~s/\/+$//) {
 274                         $test=dirname($test);
 275                 }
 276         }
 277
 278 }
 279
 280 sub find_src_files () {
 281         my @files;
 282         my %pages;
 283         eval q{use File::Find};
 284         error($@) if $@;
 285         find({
 286                 no_chdir => 1,
 287                 wanted => sub {
 288                         my $file=decode_utf8($_);
 289                         $file=~s/^\Q$config{srcdir}\E\/?//;
 290                         return if -l $_ || -d _ || ! length $file;
 291                         my $page = pagename($file);
 292                         if (! exists $pagesources{$page} &&
 293                             file_pruned($file)) {
 294                                 $File::Find::prune=1;
 295                                 return;
 296                         }
 297
 298                         my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 299                         if (! defined $f) {
 300                                 warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 301                         }
 302                         else {
 303                                 push @files, $f;
 304                                 if ($pages{$page}) {
 305                                         debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 306                                 }
 307                                 $pages{$page}=1;
 308                         }
 309                 },
 310         }, $config{srcdir});
 311         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 312                 find({
 313                         no_chdir => 1,
 314                         wanted => sub {
 315                                 my $file=decode_utf8($_);
 316                                 $file=~s/^\Q$dir\E\/?//;
 317                                 return if -l $_ || -d _ || ! length $file;
 318                                 my $page=pagename($file);
 319                                 if (! exists $pagesources{$page} &&
 320                                     file_pruned($file)) {
 321                                         $File::Find::prune=1;
 322                                         return;
 323                                 }
 324
 325                                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 326                                 if (! defined $f) {
 327                                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 328                                 }
 329                                 else {
 330                                         # avoid underlaydir override
 331                                         # attacks; see security.mdwn
 332                                         if (! -l "$config{srcdir}/$f" &&
 333                                             ! -e _) {
 334                                                 if (! $pages{$page}) {
 335                                                         push @files, $f;
 336                                                         $pages{$page}=1;
 337                                                 }
 338                                         }
 339                                 }
 340                         },
 341                 }, $dir);
 342         };
 343         return \@files, \%pages;
 344 }
 345
 346 sub find_new_files ($) {
 347         my $files=shift;
 348         my @new;
 349         my @internal_new;
 350
 351         foreach my $file (@$files) {
 352                 my $page=pagename($file);
 353                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 354                         # the page has changed its type
 355                         $forcerebuild{$page}=1;
 356                 }
 357                 $pagesources{$page}=$file;
 358                 if (! $pagemtime{$page}) {
 359                         if (isinternal($page)) {
 360                                 push @internal_new, $file;
 361                         }
 362                         else {
 363                                 push @new, $file;
 364                                 if ($config{getctime} && -e "$config{srcdir}/$file") {
 365                                         eval {
 366                                                 my $time=rcs_getctime("$config{srcdir}/$file");
 367                                                 $pagectime{$page}=$time;
 368                                         };
 369                                         if ($@) {
 370                                                 print STDERR $@;
 371                                         }
 372                                 }
 373                         }
 374                         $pagecase{lc $page}=$page;
 375                         if (! exists $pagectime{$page}) {
 376                                 $pagectime{$page}=(srcfile_stat($file))[10];
 377                         }
 378                 }
 379         }
 380
 381         return \@new, \@internal_new;
 382 }
 383
 384 sub find_del_files ($) {
 385         my $pages=shift;
 386         my @del;
 387         my @internal_del;
 388
 389         foreach my $page (keys %pagemtime) {
 390                 if (! $pages->{$page}) {
 391                         if (isinternal($page)) {
 392                                 push @internal_del, $pagesources{$page};
 393                         }
 394                         else {
 395                                 debug(sprintf(gettext("removing old page %s"), $page));
 396                                 push @del, $pagesources{$page};
 397                         }
 398                         $links{$page}=[];
 399                         $renderedfiles{$page}=[];
 400                         $pagemtime{$page}=0;
 401                         foreach my $old (@{$oldrenderedfiles{$page}}) {
 402                                 prune($config{destdir}."/".$old);
 403                         }
 404                         delete $pagesources{$page};
 405                         foreach my $source (keys %destsources) {
 406                                 if ($destsources{$source} eq $page) {
 407                                         delete $destsources{$source};
 408                                 }
 409                         }
 410                 }
 411         }
 412
 413         return \@del, \@internal_del;
 414 }
 415
 416 sub find_changed ($) {
 417         my $files=shift;
 418         my @changed;
 419         my @internal_changed;
 420         foreach my $file (@$files) {
 421                 my $page=pagename($file);
 422                 my ($srcfile, @stat)=srcfile_stat($file);
 423                 if (! exists $pagemtime{$page} ||
 424                     $stat[9] > $pagemtime{$page} ||
 425                     $forcerebuild{$page}) {
 426                         $pagemtime{$page}=$stat[9];
 427
 428                         if (isinternal($page)) {
 429                                 # Preprocess internal page in scan-only mode.
 430                                 preprocess($page, $page, readfile($srcfile), 1);
 431                                 push @internal_changed, $file;
 432                         }
 433                         else {
 434                                 push @changed, $file;
 435                         }
 436                 }
 437         }
 438         return \@changed, \@internal_changed;
 439 }
 440
 441 sub calculate_old_links ($$) {
 442         my ($changed, $del)=@_;
 443         my %oldlink_targets;
 444         foreach my $file (@$changed, @$del) {
 445                 my $page=pagename($file);
 446                 if (exists $oldlinks{$page}) {
 447                         foreach my $l (@{$oldlinks{$page}}) {
 448                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 449                         }
 450                 }
 451         }
 452         return \%oldlink_targets;
 453 }
 454
 455 sub derender_internal ($) {
 456         my $file=shift;
 457         my $page=pagename($file);
 458         delete $depends{$page};
 459         delete $depends_simple{$page};
 460         foreach my $old (@{$renderedfiles{$page}}) {
 461                 delete $destsources{$old};
 462         }
 463         $renderedfiles{$page}=[];
 464 }
 465
 466 sub render_linkers ($) {
 467         my $f=shift;
 468         my $p=pagename($f);
 469         foreach my $page (keys %{$backlinks{$p}}) {
 470                 my $file=$pagesources{$page};
 471                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 472         }
 473 }
 474
 475 sub remove_unrendered () {
 476         foreach my $src (keys %rendered) {
 477                 my $page=pagename($src);
 478                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 479                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 480                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 481                                 prune($config{destdir}."/".$file);
 482                         }
 483                 }
 484         }
 485 }
 486
 487 sub calculate_changed_links ($$$) {
 488         my ($changed, $del, $oldlink_targets)=@_;
 489
 490         my (%backlinkchanged, %linkchangers);
 491
 492         foreach my $file (@$changed, @$del) {
 493                 my $page=pagename($file);
 494
 495                 if (exists $links{$page}) {
 496                         foreach my $l (@{$links{$page}}) {
 497                                 my $target=bestlink($page, $l);
 498                                 if (! exists $oldlink_targets->{$page}{$l} ||
 499                                     $target ne $oldlink_targets->{$page}{$l}) {
 500                                         $backlinkchanged{$target}=1;
 501                                         $linkchangers{lc($page)}=1;
 502                                 }
 503                                 delete $oldlink_targets->{$page}{$l};
 504                         }
 505                 }
 506                 if (exists $oldlink_targets->{$page} &&
 507                     %{$oldlink_targets->{$page}}) {
 508                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 509                                 $backlinkchanged{$target}=1;
 510                         }
 511                         $linkchangers{lc($page)}=1;
 512                 }
 513         }
 514
 515         return \%backlinkchanged, \%linkchangers;
 516 }
 517
 518 sub render_dependent ($$$$$$$) {
 519         my ($files, $new, $internal_new, $del, $internal_del,
 520                 $internal_changed, $linkchangers)=@_;
 521
 522         my @changed=(keys %rendered, @$del);
 523         my @exists_changed=(@$new, @$del);
 524
 525         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 526         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 527
 528         foreach my $f (@$files) {
 529                 next if $rendered{$f};
 530                 my $p=pagename($f);
 531                 my $reason = undef;
 532
 533                 if (exists $depends_simple{$p}) {
 534                         foreach my $d (keys %{$depends_simple{$p}}) {
 535                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 536                                      $lc_changed{$d})
 537                                     ||
 538                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 539                                      $lc_exists_changed{$d})
 540                                     ||
 541                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 542                                      $linkchangers->{$d})
 543                                 ) {
 544                                         $reason = $d;
 545                                         last;
 546                                 }
 547                         }
 548                 }
 549
 550                 if (exists $depends{$p} && ! defined $reason) {
 551                         foreach my $dep (keys %{$depends{$p}}) {
 552                                 my $sub=pagespec_translate($dep);
 553                                 next if $@ || ! defined $sub;
 554
 555                                 # only consider internal files
 556                                 # if the page explicitly depends
 557                                 # on such files
 558                                 my $internal_dep=$dep =~ /internal\(/;
 559
 560                                 my $in=sub {
 561                                         my $list=shift;
 562                                         my $type=shift;
 563                                         foreach my $file (@$list) {
 564                                                 next if $file eq $f;
 565                                                 my $page=pagename($file);
 566                                                 if ($sub->($page, location => $p)) {
 567                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 568                                                                 next unless $linkchangers->{lc($page)};
 569                                                         }
 570                                                         return $page;
 571                                                 }
 572                                         }
 573                                         return undef;
 574                                 };
 575
 576                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 577                                         last if $reason =
 578                                                 $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 579                                         last if $internal_dep && ($reason =
 580                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 581                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 582                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT));
 583                                 }
 584                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 585                                         last if $reason =
 586                                                 $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 587                                         last if $internal_dep && ($reason =
 588                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 589                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE));
 590                                 }
 591                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 592                                         last if $reason =
 593                                                 $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 594                                         last if $internal_dep && ($reason =
 595                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 596                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 597                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS));
 598                                 }
 599                         }
 600                 }
 601
 602                 if (defined $reason) {
 603                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 604                         return 1;
 605                 }
 606         }
 607
 608         return 0;
 609 }
 610
 611 sub render_backlinks ($) {
 612         my $backlinkchanged=shift;
 613         foreach my $link (keys %$backlinkchanged) {
 614                 my $linkfile=$pagesources{$link};
 615                 if (defined $linkfile) {
 616                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 617                 }
 618         }
 619 }
 620
 621 sub refresh () {
 622         srcdir_check();
 623         run_hooks(refresh => sub { shift->() });
 624         my ($files, $pages)=find_src_files();
 625         my ($new, $internal_new)=find_new_files($files);
 626         my ($del, $internal_del)=find_del_files($pages);
 627         my ($changed, $internal_changed)=find_changed($files);
 628         run_hooks(needsbuild => sub { shift->($changed) });
 629         my $oldlink_targets=calculate_old_links($changed, $del);
 630
 631         foreach my $file (@$changed) {
 632                 scan($file);
 633         }
 634
 635         calculate_links();
 636
 637         foreach my $file (@$changed) {
 638                 render($file, sprintf(gettext("building %s"), $file));
 639         }
 640         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 641                 derender_internal($file);
 642         }
 643
 644         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 645                 $del, $oldlink_targets);
 646
 647         foreach my $file (@$new, @$del) {
 648                 render_linkers($file);
 649         }
 650
 651         if (@$changed || @$internal_changed ||
 652             @$del || @$internal_del || @$internal_new) {
 653                 1 while render_dependent($files, $new, $internal_new,
 654                         $del, $internal_del, $internal_changed,
 655                         $linkchangers);
 656         }
 657
 658         render_backlinks($backlinkchanged);
 659         remove_unrendered();
 660
 661         if (@$del) {
 662                 run_hooks(delete => sub { shift->(@$del) });
 663         }
 664         if (%rendered) {
 665                 run_hooks(change => sub { shift->(keys %rendered) });
 666         }
 667 }
 668
 669 sub commandline_render () {
 670         lockwiki();
 671         loadindex();
 672         unlockwiki();
 673
 674         my $srcfile=possibly_foolish_untaint($config{render});
 675         my $file=$srcfile;
 676         $file=~s/\Q$config{srcdir}\E\/?//;
 677
 678         my $type=pagetype($file);
 679         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 680         my $content=readfile($srcfile);
 681         my $page=pagename($file);
 682         $pagesources{$page}=$file;
 683         $content=filter($page, $page, $content);
 684         $content=preprocess($page, $page, $content);
 685         $content=linkify($page, $page, $content);
 686         $content=htmlize($page, $page, $type, $content);
 687         $pagemtime{$page}=(stat($srcfile))[9];
 688         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 689
 690         print genpage($page, $content);
 691         exit 0;
 692 }
 693
 694 1