IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use HTML::Entities;
   9 use URI::Escape q{uri_escape_utf8};
  10 use POSIX;
  11 use Storable;
  12 use open qw{:utf8 :std};
  13
  14 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  15             %pagestate %wikistate %renderedfiles %oldrenderedfiles
  16             %pagesources %destsources %depends %hooks %forcerebuild
  17             $gettext_obj %loaded_plugins};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  21                  bestlink htmllink readfile writefile pagetype srcfile pagename
  22                  displaytime will_render gettext urlto targetpage
  23                  add_underlay pagetitle titlepage linkpage newpagefile
  24                  inject
  25                  %config %links %pagestate %wikistate %renderedfiles
  26                  %pagesources %destsources);
  27 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  28 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  29 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  30
  31 # Optimisation.
  32 use Memoize;
  33 memoize("abs2rel");
  34 memoize("pagespec_translate");
  35 memoize("file_pruned");
  36
  37 sub getsetup () { #{{{
  38         wikiname => {
  39                 type => "string",
  40                 default => "wiki",
  41                 description => "name of the wiki",
  42                 safe => 1,
  43                 rebuild => 1,
  44         },
  45         adminemail => {
  46                 type => "string",
  47                 default => undef,
  48                 example => 'me@example.com',
  49                 description => "contact email for wiki",
  50                 safe => 1,
  51                 rebuild => 0,
  52         },
  53         adminuser => {
  54                 type => "string",
  55                 default => [],
  56                 description => "users who are wiki admins",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         banned_users => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are banned from the wiki",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         srcdir => {
  68                 type => "string",
  69                 default => undef,
  70                 example => "$ENV{HOME}/wiki",
  71                 description => "where the source of the wiki is located",
  72                 safe => 0, # path
  73                 rebuild => 1,
  74         },
  75         destdir => {
  76                 type => "string",
  77                 default => undef,
  78                 example => "/var/www/wiki",
  79                 description => "where to build the wiki",
  80                 safe => 0, # path
  81                 rebuild => 1,
  82         },
  83         url => {
  84                 type => "string",
  85                 default => '',
  86                 example => "http://example.com/wiki",
  87                 description => "base url to the wiki",
  88                 safe => 1,
  89                 rebuild => 1,
  90         },
  91         cgiurl => {
  92                 type => "string",
  93                 default => '',
  94                 example => "http://example.com/wiki/ikiwiki.cgi",
  95                 description => "url to the ikiwiki.cgi",
  96                 safe => 1,
  97                 rebuild => 1,
  98         },
  99         cgi_wrapper => {
 100                 type => "string",
 101                 default => '',
 102                 example => "/var/www/wiki/ikiwiki.cgi",
 103                 description => "cgi wrapper to generate",
 104                 safe => 0, # file
 105                 rebuild => 0,
 106         },
 107         cgi_wrappermode => {
 108                 type => "string",
 109                 default => '06755',
 110                 description => "mode for cgi_wrapper (can safely be made suid)",
 111                 safe => 0,
 112                 rebuild => 0,
 113         },
 114         rcs => {
 115                 type => "string",
 116                 default => '',
 117                 description => "rcs backend to use",
 118                 safe => 0, # don't allow overriding
 119                 rebuild => 0,
 120         },
 121         default_plugins => {
 122                 type => "internal",
 123                 default => [qw{mdwn link inline htmlscrubber passwordauth
 124                                 openid signinedit lockedit conditional
 125                                 recentchanges parentlinks editpage}],
 126                 description => "plugins to enable by default",
 127                 safe => 0,
 128                 rebuild => 1,
 129         },
 130         add_plugins => {
 131                 type => "string",
 132                 default => [],
 133                 description => "plugins to add to the default configuration",
 134                 safe => 1,
 135                 rebuild => 1,
 136         },
 137         disable_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to disable",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         templatedir => {
 145                 type => "string",
 146                 default => "$installdir/share/ikiwiki/templates",
 147                 description => "location of template files",
 148                 advanced => 1,
 149                 safe => 0, # path
 150                 rebuild => 1,
 151         },
 152         underlaydir => {
 153                 type => "string",
 154                 default => "$installdir/share/ikiwiki/basewiki",
 155                 description => "base wiki source location",
 156                 advanced => 1,
 157                 safe => 0, # path
 158                 rebuild => 0,
 159         },
 160         wrappers => {
 161                 type => "internal",
 162                 default => [],
 163                 description => "wrappers to generate",
 164                 safe => 0,
 165                 rebuild => 0,
 166         },
 167         underlaydirs => {
 168                 type => "internal",
 169                 default => [],
 170                 description => "additional underlays to use",
 171                 safe => 0,
 172                 rebuild => 0,
 173         },
 174         verbose => {
 175                 type => "boolean",
 176                 example => 1,
 177                 description => "display verbose messages when building?",
 178                 safe => 1,
 179                 rebuild => 0,
 180         },
 181         syslog => {
 182                 type => "boolean",
 183                 example => 1,
 184                 description => "log to syslog?",
 185                 safe => 1,
 186                 rebuild => 0,
 187         },
 188         usedirs => {
 189                 type => "boolean",
 190                 default => 1,
 191                 description => "create output files named page/index.html?",
 192                 safe => 0, # changing requires manual transition
 193                 rebuild => 1,
 194         },
 195         prefix_directives => {
 196                 type => "boolean",
 197                 default => 0,
 198                 description => "use '!'-prefixed preprocessor directives?",
 199                 safe => 0, # changing requires manual transition
 200                 rebuild => 1,
 201         },
 202         indexpages => {
 203                 type => "boolean",
 204                 default => 0,
 205                 description => "use page/index.mdwn source files",
 206                 safe => 1,
 207                 rebuild => 1,
 208         },
 209         discussion => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "enable Discussion pages?",
 213                 safe => 1,
 214                 rebuild => 1,
 215         },
 216         sslcookie => {
 217                 type => "boolean",
 218                 default => 0,
 219                 description => "only send cookies over SSL connections?",
 220                 advanced => 1,
 221                 safe => 1,
 222                 rebuild => 0,
 223         },
 224         default_pageext => {
 225                 type => "string",
 226                 default => "mdwn",
 227                 description => "extension to use for new pages",
 228                 safe => 0, # not sanitized
 229                 rebuild => 0,
 230         },
 231         htmlext => {
 232                 type => "string",
 233                 default => "html",
 234                 description => "extension to use for html files",
 235                 safe => 0, # not sanitized
 236                 rebuild => 1,
 237         },
 238         timeformat => {
 239                 type => "string",
 240                 default => '%c',
 241                 description => "strftime format string to display date",
 242                 advanced => 1,
 243                 safe => 1,
 244                 rebuild => 1,
 245         },
 246         locale => {
 247                 type => "string",
 248                 default => undef,
 249                 example => "en_US.UTF-8",
 250                 description => "UTF-8 locale to use",
 251                 advanced => 1,
 252                 safe => 0,
 253                 rebuild => 1,
 254         },
 255         userdir => {
 256                 type => "string",
 257                 default => "",
 258                 example => "users",
 259                 description => "put user pages below specified page",
 260                 safe => 1,
 261                 rebuild => 1,
 262         },
 263         numbacklinks => {
 264                 type => "integer",
 265                 default => 10,
 266                 description => "how many backlinks to show before hiding excess (0 to show all)",
 267                 safe => 1,
 268                 rebuild => 1,
 269         },
 270         hardlink => {
 271                 type => "boolean",
 272                 default => 0,
 273                 description => "attempt to hardlink source files? (optimisation for large files)",
 274                 advanced => 1,
 275                 safe => 0, # paranoia
 276                 rebuild => 0,
 277         },
 278         umask => {
 279                 type => "integer",
 280                 description => "",
 281                 example => "022",
 282                 description => "force ikiwiki to use a particular umask",
 283                 advanced => 1,
 284                 safe => 0, # paranoia
 285                 rebuild => 0,
 286         },
 287         libdir => {
 288                 type => "string",
 289                 default => "",
 290                 example => "$ENV{HOME}/.ikiwiki/",
 291                 description => "extra library and plugin directory",
 292                 advanced => 1,
 293                 safe => 0, # directory
 294                 rebuild => 0,
 295         },
 296         ENV => {
 297                 type => "string",
 298                 default => {},
 299                 description => "environment variables",
 300                 safe => 0, # paranoia
 301                 rebuild => 0,
 302         },
 303         exclude => {
 304                 type => "string",
 305                 default => undef,
 306                 example => '\.wav$',
 307                 description => "regexp of source files to ignore",
 308                 advanced => 1,
 309                 safe => 0, # regexp
 310                 rebuild => 1,
 311         },
 312         wiki_file_prune_regexps => {
 313                 type => "internal",
 314                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\./, qr/\/\./,
 315                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 316                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 317                         qr/(^|\/)_MTN\//,
 318                         qr/\.dpkg-tmp$/],
 319                 description => "regexps of source files to ignore",
 320                 safe => 0,
 321                 rebuild => 1,
 322         },
 323         wiki_file_chars => {
 324                 type => "string",
 325                 description => "specifies the characters that are allowed in source filenames",
 326                 default => "-[:alnum:]+/.:_",
 327                 safe => 0,
 328                 rebuild => 1,
 329         },
 330         wiki_file_regexp => {
 331                 type => "internal",
 332                 description => "regexp of legal source files",
 333                 safe => 0,
 334                 rebuild => 1,
 335         },
 336         web_commit_regexp => {
 337                 type => "internal",
 338                 default => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
 339                 description => "regexp to parse web commits from logs",
 340                 safe => 0,
 341                 rebuild => 0,
 342         },
 343         cgi => {
 344                 type => "internal",
 345                 default => 0,
 346                 description => "run as a cgi",
 347                 safe => 0,
 348                 rebuild => 0,
 349         },
 350         cgi_disable_uploads => {
 351                 type => "internal",
 352                 default => 1,
 353                 description => "whether CGI should accept file uploads",
 354                 safe => 0,
 355                 rebuild => 0,
 356         },
 357         post_commit => {
 358                 type => "internal",
 359                 default => 0,
 360                 description => "run as a post-commit hook",
 361                 safe => 0,
 362                 rebuild => 0,
 363         },
 364         rebuild => {
 365                 type => "internal",
 366                 default => 0,
 367                 description => "running in rebuild mode",
 368                 safe => 0,
 369                 rebuild => 0,
 370         },
 371         setup => {
 372                 type => "internal",
 373                 default => undef,
 374                 description => "running in setup mode",
 375                 safe => 0,
 376                 rebuild => 0,
 377         },
 378         refresh => {
 379                 type => "internal",
 380                 default => 0,
 381                 description => "running in refresh mode",
 382                 safe => 0,
 383                 rebuild => 0,
 384         },
 385         test_receive => {
 386                 type => "internal",
 387                 default => 0,
 388                 description => "running in receive test mode",
 389                 safe => 0,
 390                 rebuild => 0,
 391         },
 392         getctime => {
 393                 type => "internal",
 394                 default => 0,
 395                 description => "running in getctime mode",
 396                 safe => 0,
 397                 rebuild => 0,
 398         },
 399         w3mmode => {
 400                 type => "internal",
 401                 default => 0,
 402                 description => "running in w3mmode",
 403                 safe => 0,
 404                 rebuild => 0,
 405         },
 406         setupfile => {
 407                 type => "internal",
 408                 default => undef,
 409                 description => "path to setup file",
 410                 safe => 0,
 411                 rebuild => 0,
 412         },
 413         allow_symlinks_before_srcdir => {
 414                 type => "boolean",
 415                 default => 0,
 416                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 417                 safe => 0,
 418                 rebuild => 0,
 419         },
 420 } #}}}
 421
 422 sub defaultconfig () { #{{{
 423         my %s=getsetup();
 424         my @ret;
 425         foreach my $key (keys %s) {
 426                 push @ret, $key, $s{$key}->{default};
 427         }
 428         use Data::Dumper;
 429         return @ret;
 430 } #}}}
 431
 432 sub checkconfig () { #{{{
 433         # locale stuff; avoid LC_ALL since it overrides everything
 434         if (defined $ENV{LC_ALL}) {
 435                 $ENV{LANG} = $ENV{LC_ALL};
 436                 delete $ENV{LC_ALL};
 437         }
 438         if (defined $config{locale}) {
 439                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 440                         $ENV{LANG}=$config{locale};
 441                         $gettext_obj=undef;
 442                 }
 443         }
 444
 445         if (! defined $config{wiki_file_regexp}) {
 446                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 447         }
 448
 449         if (ref $config{ENV} eq 'HASH') {
 450                 foreach my $val (keys %{$config{ENV}}) {
 451                         $ENV{$val}=$config{ENV}{$val};
 452                 }
 453         }
 454
 455         if ($config{w3mmode}) {
 456                 eval q{use Cwd q{abs_path}};
 457                 error($@) if $@;
 458                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 459                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 460                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 461                         unless $config{cgiurl} =~ m!file:///!;
 462                 $config{url}="file://".$config{destdir};
 463         }
 464
 465         if ($config{cgi} && ! length $config{url}) {
 466                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 467         }
 468
 469         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 470                 unless exists $config{wikistatedir};
 471
 472         if (defined $config{umask}) {
 473                 umask(possibly_foolish_untaint($config{umask}));
 474         }
 475
 476         run_hooks(checkconfig => sub { shift->() });
 477
 478         return 1;
 479 } #}}}
 480
 481 sub listplugins () { #{{{
 482         my %ret;
 483
 484         foreach my $dir (@INC, $config{libdir}) {
 485                 next unless defined $dir && length $dir;
 486                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 487                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 488                         $ret{$plugin}=1;
 489                 }
 490         }
 491         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 492                 next unless defined $dir && length $dir;
 493                 foreach my $file (glob("$dir/plugins/*")) {
 494                         $ret{basename($file)}=1 if -x $file;
 495                 }
 496         }
 497
 498         return keys %ret;
 499 } #}}}
 500
 501 sub loadplugins () { #{{{
 502         if (defined $config{libdir} && length $config{libdir}) {
 503                 unshift @INC, possibly_foolish_untaint($config{libdir});
 504         }
 505
 506         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 507                 loadplugin($plugin);
 508         }
 509
 510         if ($config{rcs}) {
 511                 if (exists $IkiWiki::hooks{rcs}) {
 512                         error(gettext("cannot use multiple rcs plugins"));
 513                 }
 514                 loadplugin($config{rcs});
 515         }
 516         if (! exists $IkiWiki::hooks{rcs}) {
 517                 loadplugin("norcs");
 518         }
 519
 520         run_hooks(getopt => sub { shift->() });
 521         if (grep /^-/, @ARGV) {
 522                 print STDERR "Unknown option: $_\n"
 523                         foreach grep /^-/, @ARGV;
 524                 usage();
 525         }
 526
 527         return 1;
 528 } #}}}
 529
 530 sub loadplugin ($) { #{{{
 531         my $plugin=shift;
 532
 533         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 534
 535         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 536                          "$installdir/lib/ikiwiki") {
 537                 if (defined $dir && -x "$dir/plugins/$plugin") {
 538                         eval { require IkiWiki::Plugin::external };
 539                         if ($@) {
 540                                 my $reason=$@;
 541                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 542                         }
 543                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 544                         $loaded_plugins{$plugin}=1;
 545                         return 1;
 546                 }
 547         }
 548
 549         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 550         eval qq{use $mod};
 551         if ($@) {
 552                 error("Failed to load plugin $mod: $@");
 553         }
 554         $loaded_plugins{$plugin}=1;
 555         return 1;
 556 } #}}}
 557
 558 sub error ($;$) { #{{{
 559         my $message=shift;
 560         my $cleaner=shift;
 561         log_message('err' => $message) if $config{syslog};
 562         if (defined $cleaner) {
 563                 $cleaner->();
 564         }
 565         die $message."\n";
 566 } #}}}
 567
 568 sub debug ($) { #{{{
 569         return unless $config{verbose};
 570         return log_message(debug => @_);
 571 } #}}}
 572
 573 my $log_open=0;
 574 sub log_message ($$) { #{{{
 575         my $type=shift;
 576
 577         if ($config{syslog}) {
 578                 require Sys::Syslog;
 579                 if (! $log_open) {
 580                         Sys::Syslog::setlogsock('unix');
 581                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 582                         $log_open=1;
 583                 }
 584                 return eval {
 585                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 586                 };
 587         }
 588         elsif (! $config{cgi}) {
 589                 return print "@_\n";
 590         }
 591         else {
 592                 return print STDERR "@_\n";
 593         }
 594 } #}}}
 595
 596 sub possibly_foolish_untaint ($) { #{{{
 597         my $tainted=shift;
 598         my ($untainted)=$tainted=~/(.*)/s;
 599         return $untainted;
 600 } #}}}
 601
 602 sub basename ($) { #{{{
 603         my $file=shift;
 604
 605         $file=~s!.*/+!!;
 606         return $file;
 607 } #}}}
 608
 609 sub dirname ($) { #{{{
 610         my $file=shift;
 611
 612         $file=~s!/*[^/]+$!!;
 613         return $file;
 614 } #}}}
 615
 616 sub pagetype ($) { #{{{
 617         my $page=shift;
 618
 619         if ($page =~ /\.([^.]+)$/) {
 620                 return $1 if exists $hooks{htmlize}{$1};
 621         }
 622         return;
 623 } #}}}
 624
 625 sub isinternal ($) { #{{{
 626         my $page=shift;
 627         return exists $pagesources{$page} &&
 628                 $pagesources{$page} =~ /\._([^.]+)$/;
 629 } #}}}
 630
 631 sub pagename ($) { #{{{
 632         my $file=shift;
 633
 634         my $type=pagetype($file);
 635         my $page=$file;
 636         $page=~s/\Q.$type\E*$// if defined $type && !$hooks{htmlize}{$type}{keepextension};
 637         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 638                 $page=$1;
 639         }
 640         return $page;
 641 } #}}}
 642
 643 sub newpagefile ($$) { #{{{
 644         my $page=shift;
 645         my $type=shift;
 646
 647         if (! $config{indexpages} || $page eq 'index') {
 648                 return $page.".".$type;
 649         }
 650         else {
 651                 return $page."/index.".$type;
 652         }
 653 } #}}}
 654
 655 sub targetpage ($$) { #{{{
 656         my $page=shift;
 657         my $ext=shift;
 658
 659         my $targetpage='';
 660         run_hooks(targetpage => sub {
 661                 $targetpage=shift->(
 662                         page => $page,
 663                         ext => $ext,
 664                 );
 665         });
 666
 667         if (defined $targetpage && (length($targetpage) > 0)) {
 668                 return $targetpage;
 669         }
 670         elsif (! $config{usedirs} || $page eq 'index') {
 671                 return $page.".".$ext;
 672         }
 673         else {
 674                 return $page."/index.".$ext;
 675         }
 676 } #}}}
 677
 678 sub htmlpage ($) { #{{{
 679         my $page=shift;
 680
 681         return targetpage($page, $config{htmlext});
 682 } #}}}
 683
 684 sub srcfile_stat { #{{{
 685         my $file=shift;
 686         my $nothrow=shift;
 687
 688         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 689         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 690                 return "$dir/$file", stat(_) if -e "$dir/$file";
 691         }
 692         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 693         return;
 694 } #}}}
 695
 696 sub srcfile ($;$) { #{{{
 697         return (srcfile_stat(@_))[0];
 698 } #}}}
 699
 700 sub add_underlay ($) { #{{{
 701         my $dir=shift;
 702
 703         if ($dir !~ /^\//) {
 704                 $dir="$config{underlaydir}/../$dir";
 705         }
 706
 707         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 708                 unshift @{$config{underlaydirs}}, $dir;
 709         }
 710
 711         return 1;
 712 } #}}}
 713
 714 sub readfile ($;$$) { #{{{
 715         my $file=shift;
 716         my $binary=shift;
 717         my $wantfd=shift;
 718
 719         if (-l $file) {
 720                 error("cannot read a symlink ($file)");
 721         }
 722
 723         local $/=undef;
 724         open (my $in, "<", $file) || error("failed to read $file: $!");
 725         binmode($in) if ($binary);
 726         return \*$in if $wantfd;
 727         my $ret=<$in>;
 728         close $in || error("failed to read $file: $!");
 729         return $ret;
 730 } #}}}
 731
 732 sub prep_writefile ($$) { #{{{
 733         my $file=shift;
 734         my $destdir=shift;
 735
 736         my $test=$file;
 737         while (length $test) {
 738                 if (-l "$destdir/$test") {
 739                         error("cannot write to a symlink ($test)");
 740                 }
 741                 $test=dirname($test);
 742         }
 743
 744         my $dir=dirname("$destdir/$file");
 745         if (! -d $dir) {
 746                 my $d="";
 747                 foreach my $s (split(m!/+!, $dir)) {
 748                         $d.="$s/";
 749                         if (! -d $d) {
 750                                 mkdir($d) || error("failed to create directory $d: $!");
 751                         }
 752                 }
 753         }
 754
 755         return 1;
 756 } #}}}
 757
 758 sub writefile ($$$;$$) { #{{{
 759         my $file=shift; # can include subdirs
 760         my $destdir=shift; # directory to put file in
 761         my $content=shift;
 762         my $binary=shift;
 763         my $writer=shift;
 764
 765         prep_writefile($file, $destdir);
 766
 767         my $newfile="$destdir/$file.ikiwiki-new";
 768         if (-l $newfile) {
 769                 error("cannot write to a symlink ($newfile)");
 770         }
 771
 772         my $cleanup = sub { unlink($newfile) };
 773         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 774         binmode($out) if ($binary);
 775         if ($writer) {
 776                 $writer->(\*$out, $cleanup);
 777         }
 778         else {
 779                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 780         }
 781         close $out || error("failed saving $newfile: $!", $cleanup);
 782         rename($newfile, "$destdir/$file") ||
 783                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 784
 785         return 1;
 786 } #}}}
 787
 788 my %cleared;
 789 sub will_render ($$;$) { #{{{
 790         my $page=shift;
 791         my $dest=shift;
 792         my $clear=shift;
 793
 794         # Important security check.
 795         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 796             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 797                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 798         }
 799
 800         if (! $clear || $cleared{$page}) {
 801                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 802         }
 803         else {
 804                 foreach my $old (@{$renderedfiles{$page}}) {
 805                         delete $destsources{$old};
 806                 }
 807                 $renderedfiles{$page}=[$dest];
 808                 $cleared{$page}=1;
 809         }
 810         $destsources{$dest}=$page;
 811
 812         return 1;
 813 } #}}}
 814
 815 sub bestlink ($$) { #{{{
 816         my $page=shift;
 817         my $link=shift;
 818
 819         my $cwd=$page;
 820         if ($link=~s/^\/+//) {
 821                 # absolute links
 822                 $cwd="";
 823         }
 824         $link=~s/\/$//;
 825
 826         do {
 827                 my $l=$cwd;
 828                 $l.="/" if length $l;
 829                 $l.=$link;
 830
 831                 if (exists $links{$l}) {
 832                         return $l;
 833                 }
 834                 elsif (exists $pagecase{lc $l}) {
 835                         return $pagecase{lc $l};
 836                 }
 837         } while $cwd=~s{/?[^/]+$}{};
 838
 839         if (length $config{userdir}) {
 840                 my $l = "$config{userdir}/".lc($link);
 841                 if (exists $links{$l}) {
 842                         return $l;
 843                 }
 844                 elsif (exists $pagecase{lc $l}) {
 845                         return $pagecase{lc $l};
 846                 }
 847         }
 848
 849         #print STDERR "warning: page $page, broken link: $link\n";
 850         return "";
 851 } #}}}
 852
 853 sub isinlinableimage ($) { #{{{
 854         my $file=shift;
 855
 856         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 857 } #}}}
 858
 859 sub pagetitle ($;$) { #{{{
 860         my $page=shift;
 861         my $unescaped=shift;
 862
 863         if ($unescaped) {
 864                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 865         }
 866         else {
 867                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 868         }
 869
 870         return $page;
 871 } #}}}
 872
 873 sub titlepage ($) { #{{{
 874         my $title=shift;
 875         # support use w/o %config set
 876         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 877         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 878         return $title;
 879 } #}}}
 880
 881 sub linkpage ($) { #{{{
 882         my $link=shift;
 883         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 884         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 885         return $link;
 886 } #}}}
 887
 888 sub cgiurl (@) { #{{{
 889         my %params=@_;
 890
 891         return $config{cgiurl}."?".
 892                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 893 } #}}}
 894
 895 sub baseurl (;$) { #{{{
 896         my $page=shift;
 897
 898         return "$config{url}/" if ! defined $page;
 899
 900         $page=htmlpage($page);
 901         $page=~s/[^\/]+$//;
 902         $page=~s/[^\/]+\//..\//g;
 903         return $page;
 904 } #}}}
 905
 906 sub abs2rel ($$) { #{{{
 907         # Work around very innefficient behavior in File::Spec if abs2rel
 908         # is passed two relative paths. It's much faster if paths are
 909         # absolute! (Debian bug #376658; fixed in debian unstable now)
 910         my $path="/".shift;
 911         my $base="/".shift;
 912
 913         require File::Spec;
 914         my $ret=File::Spec->abs2rel($path, $base);
 915         $ret=~s/^// if defined $ret;
 916         return $ret;
 917 } #}}}
 918
 919 sub displaytime ($;$) { #{{{
 920         # Plugins can override this function to mark up the time to
 921         # display.
 922         return '<span class="date">'.formattime(@_).'</span>';
 923 } #}}}
 924
 925 sub formattime ($;$) { #{{{
 926         # Plugins can override this function to format the time.
 927         my $time=shift;
 928         my $format=shift;
 929         if (! defined $format) {
 930                 $format=$config{timeformat};
 931         }
 932
 933         # strftime doesn't know about encodings, so make sure
 934         # its output is properly treated as utf8
 935         return decode_utf8(POSIX::strftime($format, localtime($time)));
 936 } #}}}
 937
 938 sub beautify_urlpath ($) { #{{{
 939         my $url=shift;
 940
 941         if ($config{usedirs}) {
 942                 $url =~ s!/index.$config{htmlext}$!/!;
 943         }
 944
 945         run_hooks(tweakurlpath => sub {
 946                 $url=shift->(url => $url);
 947         });
 948
 949         # Ensure url is not an empty link, and
 950         # if it's relative, make that explicit to avoid colon confusion.
 951         if ($url !~ /^\//) {
 952                 $url="./$url";
 953         }
 954
 955         return $url;
 956 } #}}}
 957
 958 sub urlto ($$;$) { #{{{
 959         my $to=shift;
 960         my $from=shift;
 961         my $absolute=shift;
 962
 963         if (! length $to) {
 964                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
 965         }
 966
 967         if (! $destsources{$to}) {
 968                 $to=htmlpage($to);
 969         }
 970
 971         if ($absolute) {
 972                 return $config{url}.beautify_urlpath("/".$to);
 973         }
 974
 975         my $link = abs2rel($to, dirname(htmlpage($from)));
 976
 977         return beautify_urlpath($link);
 978 } #}}}
 979
 980 sub htmllink ($$$;@) { #{{{
 981         my $lpage=shift; # the page doing the linking
 982         my $page=shift; # the page that will contain the link (different for inline)
 983         my $link=shift;
 984         my %opts=@_;
 985
 986         $link=~s/\/$//;
 987
 988         my $bestlink;
 989         if (! $opts{forcesubpage}) {
 990                 $bestlink=bestlink($lpage, $link);
 991         }
 992         else {
 993                 $bestlink="$lpage/".lc($link);
 994         }
 995
 996         my $linktext;
 997         if (defined $opts{linktext}) {
 998                 $linktext=$opts{linktext};
 999         }
1000         else {
1001                 $linktext=pagetitle(basename($link));
1002         }
1003
1004         return "<span class=\"selflink\">$linktext</span>"
1005                 if length $bestlink && $page eq $bestlink &&
1006                    ! defined $opts{anchor};
1007
1008         if (! $destsources{$bestlink}) {
1009                 $bestlink=htmlpage($bestlink);
1010
1011                 if (! $destsources{$bestlink}) {
1012                         return $linktext unless length $config{cgiurl};
1013                         return "<span class=\"createlink\"><a href=\"".
1014                                 cgiurl(
1015                                         do => "create",
1016                                         page => lc($link),
1017                                         from => $lpage
1018                                 ).
1019                                 "\" rel=\"nofollow\">?</a>$linktext</span>"
1020                 }
1021         }
1022
1023         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1024         $bestlink=beautify_urlpath($bestlink);
1025
1026         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1027                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1028         }
1029
1030         if (defined $opts{anchor}) {
1031                 $bestlink.="#".$opts{anchor};
1032         }
1033
1034         my @attrs;
1035         if (defined $opts{rel}) {
1036                 push @attrs, ' rel="'.$opts{rel}.'"';
1037         }
1038         if (defined $opts{class}) {
1039                 push @attrs, ' class="'.$opts{class}.'"';
1040         }
1041
1042         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1043 } #}}}
1044
1045 sub userlink ($) { #{{{
1046         my $user=shift;
1047
1048         my $oiduser=eval { openiduser($user) };
1049         if (defined $oiduser) {
1050                 return "<a href=\"$user\">$oiduser</a>";
1051         }
1052         else {
1053                 eval q{use CGI 'escapeHTML'};
1054                 error($@) if $@;
1055
1056                 return htmllink("", "", escapeHTML(
1057                         length $config{userdir} ? $config{userdir}."/".$user : $user
1058                 ), noimageinline => 1);
1059         }
1060 } #}}}
1061
1062 sub htmlize ($$$$) { #{{{
1063         my $page=shift;
1064         my $destpage=shift;
1065         my $type=shift;
1066         my $content=shift;
1067
1068         my $oneline = $content !~ /\n/;
1069
1070         if (exists $hooks{htmlize}{$type}) {
1071                 $content=$hooks{htmlize}{$type}{call}->(
1072                         page => $page,
1073                         content => $content,
1074                 );
1075         }
1076         else {
1077                 error("htmlization of $type not supported");
1078         }
1079
1080         run_hooks(sanitize => sub {
1081                 $content=shift->(
1082                         page => $page,
1083                         destpage => $destpage,
1084                         content => $content,
1085                 );
1086         });
1087
1088         if ($oneline) {
1089                 # hack to get rid of enclosing junk added by markdown
1090                 # and other htmlizers
1091                 $content=~s/^<p>//i;
1092                 $content=~s/<\/p>$//i;
1093                 chomp $content;
1094         }
1095
1096         return $content;
1097 } #}}}
1098
1099 sub linkify ($$$) { #{{{
1100         my $page=shift;
1101         my $destpage=shift;
1102         my $content=shift;
1103
1104         run_hooks(linkify => sub {
1105                 $content=shift->(
1106                         page => $page,
1107                         destpage => $destpage,
1108                         content => $content,
1109                 );
1110         });
1111
1112         return $content;
1113 } #}}}
1114
1115 our %preprocessing;
1116 our $preprocess_preview=0;
1117 sub preprocess ($$$;$$) { #{{{
1118         my $page=shift; # the page the data comes from
1119         my $destpage=shift; # the page the data will appear in (different for inline)
1120         my $content=shift;
1121         my $scan=shift;
1122         my $preview=shift;
1123
1124         # Using local because it needs to be set within any nested calls
1125         # of this function.
1126         local $preprocess_preview=$preview if defined $preview;
1127
1128         my $handle=sub {
1129                 my $escape=shift;
1130                 my $prefix=shift;
1131                 my $command=shift;
1132                 my $params=shift;
1133                 $params="" if ! defined $params;
1134
1135                 if (length $escape) {
1136                         return "[[$prefix$command $params]]";
1137                 }
1138                 elsif (exists $hooks{preprocess}{$command}) {
1139                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1140                         # Note: preserve order of params, some plugins may
1141                         # consider it significant.
1142                         my @params;
1143                         while ($params =~ m{
1144                                 (?:([-\w]+)=)?          # 1: named parameter key?
1145                                 (?:
1146                                         """(.*?)"""     # 2: triple-quoted value
1147                                 |
1148                                         "([^"]+)"       # 3: single-quoted value
1149                                 |
1150                                         (\S+)           # 4: unquoted value
1151                                 )
1152                                 (?:\s+|$)               # delimiter to next param
1153                         }sgx) {
1154                                 my $key=$1;
1155                                 my $val;
1156                                 if (defined $2) {
1157                                         $val=$2;
1158                                         $val=~s/\r\n/\n/mg;
1159                                         $val=~s/^\n+//g;
1160                                         $val=~s/\n+$//g;
1161                                 }
1162                                 elsif (defined $3) {
1163                                         $val=$3;
1164                                 }
1165                                 elsif (defined $4) {
1166                                         $val=$4;
1167                                 }
1168
1169                                 if (defined $key) {
1170                                         push @params, $key, $val;
1171                                 }
1172                                 else {
1173                                         push @params, $val, '';
1174                                 }
1175                         }
1176                         if ($preprocessing{$page}++ > 3) {
1177                                 # Avoid loops of preprocessed pages preprocessing
1178                                 # other pages that preprocess them, etc.
1179                                 return "[[!$command <span class=\"error\">".
1180                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1181                                                 $page, $preprocessing{$page}).
1182                                         "</span>]]";
1183                         }
1184                         my $ret;
1185                         if (! $scan) {
1186                                 $ret=eval {
1187                                         $hooks{preprocess}{$command}{call}->(
1188                                                 @params,
1189                                                 page => $page,
1190                                                 destpage => $destpage,
1191                                                 preview => $preprocess_preview,
1192                                         );
1193                                 };
1194                                 if ($@) {
1195                                         chomp $@;
1196                                         $ret="[[!$command <span class=\"error\">".
1197                                                 gettext("Error").": $@"."</span>]]";
1198                                 }
1199                         }
1200                         else {
1201                                 # use void context during scan pass
1202                                 eval {
1203                                         $hooks{preprocess}{$command}{call}->(
1204                                                 @params,
1205                                                 page => $page,
1206                                                 destpage => $destpage,
1207                                                 preview => $preprocess_preview,
1208                                         );
1209                                 };
1210                                 $ret="";
1211                         }
1212                         $preprocessing{$page}--;
1213                         return $ret;
1214                 }
1215                 else {
1216                         return "[[$prefix$command $params]]";
1217                 }
1218         };
1219
1220         my $regex;
1221         if ($config{prefix_directives}) {
1222                 $regex = qr{
1223                         (\\?)           # 1: escape?
1224                         \[\[(!)         # directive open; 2: prefix
1225                         ([-\w]+)        # 3: command
1226                         (               # 4: the parameters..
1227                                 \s+     # Must have space if parameters present
1228                                 (?:
1229                                         (?:[-\w]+=)?            # named parameter key?
1230                                         (?:
1231                                                 """.*?"""       # triple-quoted value
1232                                                 |
1233                                                 "[^"]+"         # single-quoted value
1234                                                 |
1235                                                 [^\s\]]+        # unquoted value
1236                                         )
1237                                         \s*                     # whitespace or end
1238                                                                 # of directive
1239                                 )
1240                         *)?             # 0 or more parameters
1241                         \]\]            # directive closed
1242                 }sx;
1243         }
1244         else {
1245                 $regex = qr{
1246                         (\\?)           # 1: escape?
1247                         \[\[(!?)        # directive open; 2: optional prefix
1248                         ([-\w]+)        # 3: command
1249                         \s+
1250                         (               # 4: the parameters..
1251                                 (?:
1252                                         (?:[-\w]+=)?            # named parameter key?
1253                                         (?:
1254                                                 """.*?"""       # triple-quoted value
1255                                                 |
1256                                                 "[^"]+"         # single-quoted value
1257                                                 |
1258                                                 [^\s\]]+        # unquoted value
1259                                         )
1260                                         \s*                     # whitespace or end
1261                                                                 # of directive
1262                                 )
1263                         *)              # 0 or more parameters
1264                         \]\]            # directive closed
1265                 }sx;
1266         }
1267
1268         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1269         return $content;
1270 } #}}}
1271
1272 sub filter ($$$) { #{{{
1273         my $page=shift;
1274         my $destpage=shift;
1275         my $content=shift;
1276
1277         run_hooks(filter => sub {
1278                 $content=shift->(page => $page, destpage => $destpage,
1279                         content => $content);
1280         });
1281
1282         return $content;
1283 } #}}}
1284
1285 sub indexlink () { #{{{
1286         return "<a href=\"$config{url}\">$config{wikiname}</a>";
1287 } #}}}
1288
1289 my $wikilock;
1290
1291 sub lockwiki (;$) { #{{{
1292         my $wait=@_ ? shift : 1;
1293         # Take an exclusive lock on the wiki to prevent multiple concurrent
1294         # run issues. The lock will be dropped on program exit.
1295         if (! -d $config{wikistatedir}) {
1296                 mkdir($config{wikistatedir});
1297         }
1298         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1299                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1300         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
1301                 if ($wait) {
1302                         debug("wiki seems to be locked, waiting for lock");
1303                         my $wait=600; # arbitrary, but don't hang forever to
1304                                       # prevent process pileup
1305                         for (1..$wait) {
1306                                 return if flock($wikilock, 2 | 4);
1307                                 sleep 1;
1308                         }
1309                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
1310                 }
1311                 else {
1312                         return 0;
1313                 }
1314         }
1315         return 1;
1316 } #}}}
1317
1318 sub unlockwiki () { #{{{
1319         return close($wikilock) if $wikilock;
1320         return;
1321 } #}}}
1322
1323 my $commitlock;
1324
1325 sub commit_hook_enabled () { #{{{
1326         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1327                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1328         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1329                 close($commitlock) || error("failed closing commitlock: $!");
1330                 return 0;
1331         }
1332         close($commitlock) || error("failed closing commitlock: $!");
1333         return 1;
1334 } #}}}
1335
1336 sub disable_commit_hook () { #{{{
1337         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1338                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1339         if (! flock($commitlock, 2)) { # LOCK_EX
1340                 error("failed to get commit lock");
1341         }
1342         return 1;
1343 } #}}}
1344
1345 sub enable_commit_hook () { #{{{
1346         return close($commitlock) if $commitlock;
1347         return;
1348 } #}}}
1349
1350 sub loadindex () { #{{{
1351         %oldrenderedfiles=%pagectime=();
1352         if (! $config{rebuild}) {
1353                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1354                 %destsources=%renderedfiles=%pagecase=%pagestate=();
1355         }
1356         my $in;
1357         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1358                 if (-e "$config{wikistatedir}/index") {
1359                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1360                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1361                 }
1362                 else {
1363                         return;
1364                 }
1365         }
1366
1367         my $index=Storable::fd_retrieve($in);
1368         if (! defined $index) {
1369                 return 0;
1370         }
1371
1372         my $pages;
1373         if (exists $index->{version} && ! ref $index->{version}) {
1374                 $pages=$index->{page};
1375                 %wikistate=%{$index->{state}};
1376         }
1377         else {
1378                 $pages=$index;
1379                 %wikistate=();
1380         }
1381
1382         foreach my $src (keys %$pages) {
1383                 my $d=$pages->{$src};
1384                 my $page=pagename($src);
1385                 $pagectime{$page}=$d->{ctime};
1386                 if (! $config{rebuild}) {
1387                         $pagesources{$page}=$src;
1388                         $pagemtime{$page}=$d->{mtime};
1389                         $renderedfiles{$page}=$d->{dest};
1390                         if (exists $d->{links} && ref $d->{links}) {
1391                                 $links{$page}=$d->{links};
1392                                 $oldlinks{$page}=[@{$d->{links}}];
1393                         }
1394                         if (exists $d->{depends}) {
1395                                 $depends{$page}=$d->{depends};
1396                         }
1397                         if (exists $d->{state}) {
1398                                 $pagestate{$page}=$d->{state};
1399                         }
1400                 }
1401                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1402         }
1403         foreach my $page (keys %pagesources) {
1404                 $pagecase{lc $page}=$page;
1405         }
1406         foreach my $page (keys %renderedfiles) {
1407                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1408         }
1409         return close($in);
1410 } #}}}
1411
1412 sub saveindex () { #{{{
1413         run_hooks(savestate => sub { shift->() });
1414
1415         my %hookids;
1416         foreach my $type (keys %hooks) {
1417                 $hookids{$_}=1 foreach keys %{$hooks{$type}};
1418         }
1419         my @hookids=keys %hookids;
1420
1421         if (! -d $config{wikistatedir}) {
1422                 mkdir($config{wikistatedir});
1423         }
1424         my $newfile="$config{wikistatedir}/indexdb.new";
1425         my $cleanup = sub { unlink($newfile) };
1426         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1427
1428         my %index;
1429         foreach my $page (keys %pagemtime) {
1430                 next unless $pagemtime{$page};
1431                 my $src=$pagesources{$page};
1432
1433                 $index{page}{$src}={
1434                         ctime => $pagectime{$page},
1435                         mtime => $pagemtime{$page},
1436                         dest => $renderedfiles{$page},
1437                         links => $links{$page},
1438                 };
1439
1440                 if (exists $depends{$page}) {
1441                         $index{page}{$src}{depends} = $depends{$page};
1442                 }
1443
1444                 if (exists $pagestate{$page}) {
1445                         foreach my $id (@hookids) {
1446                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1447                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1448                                 }
1449                         }
1450                 }
1451         }
1452
1453         $index{state}={};
1454         foreach my $id (@hookids) {
1455                 foreach my $key (keys %{$wikistate{$id}}) {
1456                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1457                 }
1458         }
1459
1460         $index{version}="3";
1461         my $ret=Storable::nstore_fd(\%index, $out);
1462         return if ! defined $ret || ! $ret;
1463         close $out || error("failed saving to $newfile: $!", $cleanup);
1464         rename($newfile, "$config{wikistatedir}/indexdb") ||
1465                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1466
1467         return 1;
1468 } #}}}
1469
1470 sub template_file ($) { #{{{
1471         my $template=shift;
1472
1473         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
1474                 return "$dir/$template" if -e "$dir/$template";
1475         }
1476         return;
1477 } #}}}
1478
1479 sub template_params (@) { #{{{
1480         my $filename=template_file(shift);
1481
1482         if (! defined $filename) {
1483                 return if wantarray;
1484                 return "";
1485         }
1486
1487         my @ret=(
1488                 filter => sub {
1489                         my $text_ref = shift;
1490                         ${$text_ref} = decode_utf8(${$text_ref});
1491                 },
1492                 filename => $filename,
1493                 loop_context_vars => 1,
1494                 die_on_bad_params => 0,
1495                 @_
1496         );
1497         return wantarray ? @ret : {@ret};
1498 } #}}}
1499
1500 sub template ($;@) { #{{{
1501         require HTML::Template;
1502         return HTML::Template->new(template_params(@_));
1503 } #}}}
1504
1505 sub misctemplate ($$;@) { #{{{
1506         my $title=shift;
1507         my $pagebody=shift;
1508
1509         my $template=template("misc.tmpl");
1510         $template->param(
1511                 title => $title,
1512                 indexlink => indexlink(),
1513                 wikiname => $config{wikiname},
1514                 pagebody => $pagebody,
1515                 baseurl => baseurl(),
1516                 @_,
1517         );
1518         run_hooks(pagetemplate => sub {
1519                 shift->(page => "", destpage => "", template => $template);
1520         });
1521         return $template->output;
1522 }#}}}
1523
1524 sub hook (@) { # {{{
1525         my %param=@_;
1526
1527         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1528                 error 'hook requires type, call, and id parameters';
1529         }
1530
1531         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1532
1533         $hooks{$param{type}}{$param{id}}=\%param;
1534         return 1;
1535 } # }}}
1536
1537 sub run_hooks ($$) { # {{{
1538         # Calls the given sub for each hook of the given type,
1539         # passing it the hook function to call.
1540         my $type=shift;
1541         my $sub=shift;
1542
1543         if (exists $hooks{$type}) {
1544                 my @deferred;
1545                 foreach my $id (keys %{$hooks{$type}}) {
1546                         if ($hooks{$type}{$id}{last}) {
1547                                 push @deferred, $id;
1548                                 next;
1549                         }
1550                         $sub->($hooks{$type}{$id}{call});
1551                 }
1552                 foreach my $id (@deferred) {
1553                         $sub->($hooks{$type}{$id}{call});
1554                 }
1555         }
1556
1557         return 1;
1558 } #}}}
1559
1560 sub rcs_update () { #{{{
1561         $hooks{rcs}{rcs_update}{call}->(@_);
1562 } #}}}
1563
1564 sub rcs_prepedit ($) { #{{{
1565         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1566 } #}}}
1567
1568 sub rcs_commit ($$$;$$) { #{{{
1569         $hooks{rcs}{rcs_commit}{call}->(@_);
1570 } #}}}
1571
1572 sub rcs_commit_staged ($$$) { #{{{
1573         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
1574 } #}}}
1575
1576 sub rcs_add ($) { #{{{
1577         $hooks{rcs}{rcs_add}{call}->(@_);
1578 } #}}}
1579
1580 sub rcs_remove ($) { #{{{
1581         $hooks{rcs}{rcs_remove}{call}->(@_);
1582 } #}}}
1583
1584 sub rcs_rename ($$) { #{{{
1585         $hooks{rcs}{rcs_rename}{call}->(@_);
1586 } #}}}
1587
1588 sub rcs_recentchanges ($) { #{{{
1589         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
1590 } #}}}
1591
1592 sub rcs_diff ($) { #{{{
1593         $hooks{rcs}{rcs_diff}{call}->(@_);
1594 } #}}}
1595
1596 sub rcs_getctime ($) { #{{{
1597         $hooks{rcs}{rcs_getctime}{call}->(@_);
1598 } #}}}
1599
1600 sub rcs_receive () { #{{{
1601         $hooks{rcs}{rcs_receive}{call}->();
1602 } #}}}
1603
1604 sub globlist_to_pagespec ($) { #{{{
1605         my @globlist=split(' ', shift);
1606
1607         my (@spec, @skip);
1608         foreach my $glob (@globlist) {
1609                 if ($glob=~/^!(.*)/) {
1610                         push @skip, $glob;
1611                 }
1612                 else {
1613                         push @spec, $glob;
1614                 }
1615         }
1616
1617         my $spec=join(' or ', @spec);
1618         if (@skip) {
1619                 my $skip=join(' and ', @skip);
1620                 if (length $spec) {
1621                         $spec="$skip and ($spec)";
1622                 }
1623                 else {
1624                         $spec=$skip;
1625                 }
1626         }
1627         return $spec;
1628 } #}}}
1629
1630 sub is_globlist ($) { #{{{
1631         my $s=shift;
1632         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
1633 } #}}}
1634
1635 sub safequote ($) { #{{{
1636         my $s=shift;
1637         $s=~s/[{}]//g;
1638         return "q{$s}";
1639 } #}}}
1640
1641 sub add_depends ($$) { #{{{
1642         my $page=shift;
1643         my $pagespec=shift;
1644
1645         return unless pagespec_valid($pagespec);
1646
1647         if (! exists $depends{$page}) {
1648                 $depends{$page}=$pagespec;
1649         }
1650         else {
1651                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1652         }
1653
1654         return 1;
1655 } # }}}
1656
1657 sub file_pruned ($$) { #{{{
1658         require File::Spec;
1659         my $file=File::Spec->canonpath(shift);
1660         my $base=File::Spec->canonpath(shift);
1661         $file =~ s#^\Q$base\E/+##;
1662
1663         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1664         return $file =~ m/$regexp/ && $file ne $base;
1665 } #}}}
1666
1667 sub gettext { #{{{
1668         # Only use gettext in the rare cases it's needed.
1669         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1670             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1671             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1672                 if (! $gettext_obj) {
1673                         $gettext_obj=eval q{
1674                                 use Locale::gettext q{textdomain};
1675                                 Locale::gettext->domain('ikiwiki')
1676                         };
1677                         if ($@) {
1678                                 print STDERR "$@";
1679                                 $gettext_obj=undef;
1680                                 return shift;
1681                         }
1682                 }
1683                 return $gettext_obj->get(shift);
1684         }
1685         else {
1686                 return shift;
1687         }
1688 } #}}}
1689
1690 sub yesno ($) { #{{{
1691         my $val=shift;
1692
1693         return (defined $val && lc($val) eq gettext("yes"));
1694 } #}}}
1695
1696 sub inject { #{{{
1697         # Injects a new function into the symbol table to replace an
1698         # exported function.
1699         my %params=@_;
1700
1701         # This is deep ugly perl foo, beware.
1702         no strict;
1703         no warnings;
1704         if (! defined $params{parent}) {
1705                 $params{parent}='::';
1706                 $params{old}=\&{$params{name}};
1707                 $params{name}=~s/.*:://;
1708         }
1709         my $parent=$params{parent};
1710         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
1711                 $ns = $params{parent} . $ns;
1712                 inject(%params, parent => $ns) unless $ns eq '::main::';
1713                 *{$ns . $params{name}} = $params{call}
1714                         if exists ${$ns}{$params{name}} &&
1715                            \&{${$ns}{$params{name}}} == $params{old};
1716         }
1717         use strict;
1718         use warnings;
1719 } #}}}
1720
1721 sub pagespec_merge ($$) { #{{{
1722         my $a=shift;
1723         my $b=shift;
1724
1725         return $a if $a eq $b;
1726
1727         # Support for old-style GlobLists.
1728         if (is_globlist($a)) {
1729                 $a=globlist_to_pagespec($a);
1730         }
1731         if (is_globlist($b)) {
1732                 $b=globlist_to_pagespec($b);
1733         }
1734
1735         return "($a) or ($b)";
1736 } #}}}
1737
1738 sub pagespec_translate ($) { #{{{
1739         my $spec=shift;
1740
1741         # Support for old-style GlobLists.
1742         if (is_globlist($spec)) {
1743                 $spec=globlist_to_pagespec($spec);
1744         }
1745
1746         # Convert spec to perl code.
1747         my $code="";
1748         while ($spec=~m{
1749                 \s*             # ignore whitespace
1750                 (               # 1: match a single word
1751                         \!              # !
1752                 |
1753                         \(              # (
1754                 |
1755                         \)              # )
1756                 |
1757                         \w+\([^\)]*\)   # command(params)
1758                 |
1759                         [^\s()]+        # any other text
1760                 )
1761                 \s*             # ignore whitespace
1762         }igx) {
1763                 my $word=$1;
1764                 if (lc $word eq 'and') {
1765                         $code.=' &&';
1766                 }
1767                 elsif (lc $word eq 'or') {
1768                         $code.=' ||';
1769                 }
1770                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1771                         $code.=' '.$word;
1772                 }
1773                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1774                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1775                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@_)";
1776                         }
1777                         else {
1778                                 $code.=' 0';
1779                         }
1780                 }
1781                 else {
1782                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@_)";
1783                 }
1784         }
1785
1786         if (! length $code) {
1787                 $code=0;
1788         }
1789
1790         no warnings;
1791         return eval 'sub { my $page=shift; '.$code.' }';
1792 } #}}}
1793
1794 sub pagespec_match ($$;@) { #{{{
1795         my $page=shift;
1796         my $spec=shift;
1797         my @params=@_;
1798
1799         # Backwards compatability with old calling convention.
1800         if (@params == 1) {
1801                 unshift @params, 'location';
1802         }
1803
1804         my $sub=pagespec_translate($spec);
1805         return IkiWiki::FailReason->new("syntax error in pagespec \"$spec\"") if $@;
1806         return $sub->($page, @params);
1807 } #}}}
1808
1809 sub pagespec_valid ($) { #{{{
1810         my $spec=shift;
1811
1812         my $sub=pagespec_translate($spec);
1813         return ! $@;
1814 } #}}}
1815
1816 sub glob2re ($) { #{{{
1817         my $re=quotemeta(shift);
1818         $re=~s/\\\*/.*/g;
1819         $re=~s/\\\?/./g;
1820         return $re;
1821 } #}}}
1822
1823 package IkiWiki::FailReason;
1824
1825 use overload ( #{{{
1826         '""'    => sub { ${$_[0]} },
1827         '0+'    => sub { 0 },
1828         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1829         fallback => 1,
1830 ); #}}}
1831
1832 sub new { #{{{
1833         my $class = shift;
1834         my $value = shift;
1835         return bless \$value, $class;
1836 } #}}}
1837
1838 package IkiWiki::SuccessReason;
1839
1840 use overload ( #{{{
1841         '""'    => sub { ${$_[0]} },
1842         '0+'    => sub { 1 },
1843         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1844         fallback => 1,
1845 ); #}}}
1846
1847 sub new { #{{{
1848         my $class = shift;
1849         my $value = shift;
1850         return bless \$value, $class;
1851 }; #}}}
1852
1853 package IkiWiki::PageSpec;
1854
1855 sub match_glob ($$;@) { #{{{
1856         my $page=shift;
1857         my $glob=shift;
1858         my %params=@_;
1859
1860         my $from=exists $params{location} ? $params{location} : '';
1861
1862         # relative matching
1863         if ($glob =~ m!^\./!) {
1864                 $from=~s#/?[^/]+$##;
1865                 $glob=~s#^\./##;
1866                 $glob="$from/$glob" if length $from;
1867         }
1868
1869         my $regexp=IkiWiki::glob2re($glob);
1870         if ($page=~/^$regexp$/i) {
1871                 if (! IkiWiki::isinternal($page) || $params{internal}) {
1872                         return IkiWiki::SuccessReason->new("$glob matches $page");
1873                 }
1874                 else {
1875                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
1876                 }
1877         }
1878         else {
1879                 return IkiWiki::FailReason->new("$glob does not match $page");
1880         }
1881 } #}}}
1882
1883 sub match_internal ($$;@) { #{{{
1884         return match_glob($_[0], $_[1], @_, internal => 1)
1885 } #}}}
1886
1887 sub match_link ($$;@) { #{{{
1888         my $page=shift;
1889         my $link=lc(shift);
1890         my %params=@_;
1891
1892         my $from=exists $params{location} ? $params{location} : '';
1893
1894         # relative matching
1895         if ($link =~ m!^\.! && defined $from) {
1896                 $from=~s#/?[^/]+$##;
1897                 $link=~s#^\./##;
1898                 $link="$from/$link" if length $from;
1899         }
1900
1901         my $links = $IkiWiki::links{$page};
1902         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1903         my $bestlink = IkiWiki::bestlink($from, $link);
1904         foreach my $p (@{$links}) {
1905                 if (length $bestlink) {
1906                         return IkiWiki::SuccessReason->new("$page links to $link")
1907                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1908                 }
1909                 else {
1910                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1911                                 if match_glob($p, $link, %params);
1912                 }
1913         }
1914         return IkiWiki::FailReason->new("$page does not link to $link");
1915 } #}}}
1916
1917 sub match_backlink ($$;@) { #{{{
1918         return match_link($_[1], $_[0], @_);
1919 } #}}}
1920
1921 sub match_created_before ($$;@) { #{{{
1922         my $page=shift;
1923         my $testpage=shift;
1924
1925         if (exists $IkiWiki::pagectime{$testpage}) {
1926                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1927                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1928                 }
1929                 else {
1930                         return IkiWiki::FailReason->new("$page not created before $testpage");
1931                 }
1932         }
1933         else {
1934                 return IkiWiki::FailReason->new("$testpage has no ctime");
1935         }
1936 } #}}}
1937
1938 sub match_created_after ($$;@) { #{{{
1939         my $page=shift;
1940         my $testpage=shift;
1941
1942         if (exists $IkiWiki::pagectime{$testpage}) {
1943                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1944                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1945                 }
1946                 else {
1947                         return IkiWiki::FailReason->new("$page not created after $testpage");
1948                 }
1949         }
1950         else {
1951                 return IkiWiki::FailReason->new("$testpage has no ctime");
1952         }
1953 } #}}}
1954
1955 sub match_creation_day ($$;@) { #{{{
1956         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1957                 return IkiWiki::SuccessReason->new('creation_day matched');
1958         }
1959         else {
1960                 return IkiWiki::FailReason->new('creation_day did not match');
1961         }
1962 } #}}}
1963
1964 sub match_creation_month ($$;@) { #{{{
1965         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1966                 return IkiWiki::SuccessReason->new('creation_month matched');
1967         }
1968         else {
1969                 return IkiWiki::FailReason->new('creation_month did not match');
1970         }
1971 } #}}}
1972
1973 sub match_creation_year ($$;@) { #{{{
1974         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1975                 return IkiWiki::SuccessReason->new('creation_year matched');
1976         }
1977         else {
1978                 return IkiWiki::FailReason->new('creation_year did not match');
1979         }
1980 } #}}}
1981
1982 sub match_user ($$;@) { #{{{
1983         shift;
1984         my $user=shift;
1985         my %params=@_;
1986
1987         if (! exists $params{user}) {
1988                 return IkiWiki::FailReason->new("no user specified");
1989         }
1990
1991         if (defined $params{user} && lc $params{user} eq lc $user) {
1992                 return IkiWiki::SuccessReason->new("user is $user");
1993         }
1994         elsif (! defined $params{user}) {
1995                 return IkiWiki::FailReason->new("not logged in");
1996         }
1997         else {
1998                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
1999         }
2000 } #}}}
2001
2002 sub match_admin ($$;@) { #{{{
2003         shift;
2004         shift;
2005         my %params=@_;
2006
2007         if (! exists $params{user}) {
2008                 return IkiWiki::FailReason->new("no user specified");
2009         }
2010
2011         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2012                 return IkiWiki::SuccessReason->new("user is an admin");
2013         }
2014         elsif (! defined $params{user}) {
2015                 return IkiWiki::FailReason->new("not logged in");
2016         }
2017         else {
2018                 return IkiWiki::FailReason->new("user is not an admin");
2019         }
2020 } #}}}
2021
2022 sub match_ip ($$;@) { #{{{
2023         shift;
2024         my $ip=shift;
2025         my %params=@_;
2026
2027         if (! exists $params{ip}) {
2028                 return IkiWiki::FailReason->new("no IP specified");
2029         }
2030
2031         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2032                 return IkiWiki::SuccessReason->new("IP is $ip");
2033         }
2034         else {
2035                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2036         }
2037 } #}}}
2038
2039 1