IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use open qw{:utf8 :std};
   9
  10 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime %pagecase
  11             %renderedfiles %oldrenderedfiles %pagesources %depends %hooks
  12             %forcerebuild};
  13
  14 use Exporter q{import};
  15 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  16                  bestlink htmllink readfile writefile pagetype srcfile pagename
  17                  displaytime will_render
  18                  %config %links %renderedfiles %pagesources);
  19 our $VERSION = 1.01; # plugin interface version
  20
  21 # Optimisation.
  22 use Memoize;
  23 memoize("abs2rel");
  24 memoize("pagespec_translate");
  25
  26 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  27 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  28
  29 sub defaultconfig () { #{{{
  30         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.x?html?$|\.rss$|\.atom$|.arch-ids/|{arch}/)},
  31         wiki_link_regexp => qr/\[\[(?:([^\]\|]+)\|)?([^\s\]]+)\]\]/,
  32         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  33         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  34         verbose => 0,
  35         syslog => 0,
  36         wikiname => "wiki",
  37         default_pageext => "mdwn",
  38         cgi => 0,
  39         rcs => 'svn',
  40         notify => 0,
  41         url => '',
  42         cgiurl => '',
  43         historyurl => '',
  44         diffurl => '',
  45         anonok => 0,
  46         rss => 0,
  47         atom => 0,
  48         discussion => 1,
  49         rebuild => 0,
  50         refresh => 0,
  51         getctime => 0,
  52         w3mmode => 0,
  53         wrapper => undef,
  54         wrappermode => undef,
  55         svnrepo => undef,
  56         svnpath => "trunk",
  57         srcdir => undef,
  58         destdir => undef,
  59         pingurl => [],
  60         templatedir => "$installdir/share/ikiwiki/templates",
  61         underlaydir => "$installdir/share/ikiwiki/basewiki",
  62         setup => undef,
  63         adminuser => undef,
  64         adminemail => undef,
  65         plugin => [qw{mdwn inline htmlscrubber passwordauth}],
  66         timeformat => '%c',
  67         locale => undef,
  68         sslcookie => 0,
  69         httpauth => 0,
  70 } #}}}
  71
  72 sub checkconfig () { #{{{
  73         # locale stuff; avoid LC_ALL since it overrides everything
  74         if (defined $ENV{LC_ALL}) {
  75                 $ENV{LANG} = $ENV{LC_ALL};
  76                 delete $ENV{LC_ALL};
  77         }
  78         if (defined $config{locale}) {
  79                 eval q{use POSIX};
  80                 error($@) if $@;
  81                 $ENV{LANG} = $config{locale}
  82                         if POSIX::setlocale(&POSIX::LC_TIME, $config{locale});
  83         }
  84
  85         if ($config{w3mmode}) {
  86                 eval q{use Cwd q{abs_path}};
  87                 error($@) if $@;
  88                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
  89                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
  90                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
  91                         unless $config{cgiurl} =~ m!file:///!;
  92                 $config{url}="file://".$config{destdir};
  93         }
  94
  95         if ($config{cgi} && ! length $config{url}) {
  96                 error("Must specify url to wiki with --url when using --cgi\n");
  97         }
  98         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  99                 error("Must specify url to wiki with --url when using --rss or --atom\n");
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{rcs}) {
 106                 eval qq{require IkiWiki::Rcs::$config{rcs}};
 107                 if ($@) {
 108                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 109                 }
 110         }
 111         else {
 112                 require IkiWiki::Rcs::Stub;
 113         }
 114
 115         run_hooks(checkconfig => sub { shift->() });
 116 } #}}}
 117
 118 sub loadplugins () { #{{{
 119         loadplugin($_) foreach @{$config{plugin}};
 120
 121         run_hooks(getopt => sub { shift->() });
 122         if (grep /^-/, @ARGV) {
 123                 print STDERR "Unknown option: $_\n"
 124                         foreach grep /^-/, @ARGV;
 125                 usage();
 126         }
 127 } #}}}
 128
 129 sub loadplugin ($) { #{{{
 130         my $plugin=shift;
 131
 132         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 133         eval qq{use $mod};
 134         if ($@) {
 135                 error("Failed to load plugin $mod: $@");
 136         }
 137 } #}}}
 138
 139 sub error ($) { #{{{
 140         if ($config{cgi}) {
 141                 print "Content-type: text/html\n\n";
 142                 print misctemplate("Error", "<p>Error: @_</p>");
 143         }
 144         log_message(error => @_);
 145         exit(1);
 146 } #}}}
 147
 148 sub debug ($) { #{{{
 149         return unless $config{verbose};
 150         log_message(debug => @_);
 151 } #}}}
 152
 153 my $log_open=0;
 154 sub log_message ($$) { #{{{
 155         my $type=shift;
 156
 157         if ($config{syslog}) {
 158                 require Sys::Syslog;
 159                 unless ($log_open) {
 160                         Sys::Syslog::setlogsock('unix');
 161                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 162                         $log_open=1;
 163                 }
 164                 eval {
 165                         Sys::Syslog::syslog($type, join(" ", @_));
 166                 }
 167         }
 168         elsif (! $config{cgi}) {
 169                 print "@_\n";
 170         }
 171         else {
 172                 print STDERR "@_\n";
 173         }
 174 } #}}}
 175
 176 sub possibly_foolish_untaint ($) { #{{{
 177         my $tainted=shift;
 178         my ($untainted)=$tainted=~/(.*)/;
 179         return $untainted;
 180 } #}}}
 181
 182 sub basename ($) { #{{{
 183         my $file=shift;
 184
 185         $file=~s!.*/+!!;
 186         return $file;
 187 } #}}}
 188
 189 sub dirname ($) { #{{{
 190         my $file=shift;
 191
 192         $file=~s!/*[^/]+$!!;
 193         return $file;
 194 } #}}}
 195
 196 sub pagetype ($) { #{{{
 197         my $page=shift;
 198
 199         if ($page =~ /\.([^.]+)$/) {
 200                 return $1 if exists $hooks{htmlize}{$1};
 201         }
 202         return undef;
 203 } #}}}
 204
 205 sub pagename ($) { #{{{
 206         my $file=shift;
 207
 208         my $type=pagetype($file);
 209         my $page=$file;
 210         $page=~s/\Q.$type\E*$// if defined $type;
 211         return $page;
 212 } #}}}
 213
 214 sub htmlpage ($) { #{{{
 215         my $page=shift;
 216
 217         return $page.".html";
 218 } #}}}
 219
 220 sub srcfile ($) { #{{{
 221         my $file=shift;
 222
 223         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 224         return "$config{underlaydir}/$file" if -e "$config{underlaydir}/$file";
 225         error("internal error: $file cannot be found");
 226 } #}}}
 227
 228 sub readfile ($;$) { #{{{
 229         my $file=shift;
 230         my $binary=shift;
 231
 232         if (-l $file) {
 233                 error("cannot read a symlink ($file)");
 234         }
 235
 236         local $/=undef;
 237         open (IN, $file) || error("failed to read $file: $!");
 238         binmode(IN) if ($binary);
 239         my $ret=<IN>;
 240         close IN;
 241         return $ret;
 242 } #}}}
 243
 244 sub writefile ($$$;$) { #{{{
 245         my $file=shift; # can include subdirs
 246         my $destdir=shift; # directory to put file in
 247         my $content=shift;
 248         my $binary=shift;
 249
 250         my $test=$file;
 251         while (length $test) {
 252                 if (-l "$destdir/$test") {
 253                         error("cannot write to a symlink ($test)");
 254                 }
 255                 $test=dirname($test);
 256         }
 257
 258         my $dir=dirname("$destdir/$file");
 259         if (! -d $dir) {
 260                 my $d="";
 261                 foreach my $s (split(m!/+!, $dir)) {
 262                         $d.="$s/";
 263                         if (! -d $d) {
 264                                 mkdir($d) || error("failed to create directory $d: $!");
 265                         }
 266                 }
 267         }
 268
 269         open (OUT, ">$destdir/$file") || error("failed to write $destdir/$file: $!");
 270         binmode(OUT) if ($binary);
 271         print OUT $content;
 272         close OUT;
 273 } #}}}
 274
 275 my %cleared;
 276 sub will_render ($$;$) { #{{{
 277         my $page=shift;
 278         my $dest=shift;
 279         my $clear=shift;
 280
 281         # Important security check.
 282         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 283             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 284                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 285         }
 286
 287         if (! $clear || $cleared{$page}) {
 288                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 289         }
 290         else {
 291                 $renderedfiles{$page}=[$dest];
 292                 $cleared{$page}=1;
 293         }
 294 } #}}}
 295
 296 sub bestlink ($$) { #{{{
 297         my $page=shift;
 298         my $link=shift;
 299
 300         my $cwd=$page;
 301         do {
 302                 my $l=$cwd;
 303                 $l.="/" if length $l;
 304                 $l.=$link;
 305
 306                 if (exists $links{$l}) {
 307                         return $l;
 308                 }
 309                 elsif (exists $pagecase{lc $l}) {
 310                         return $pagecase{lc $l};
 311                 }
 312         } while $cwd=~s!/?[^/]+$!!;
 313
 314         #print STDERR "warning: page $page, broken link: $link\n";
 315         return "";
 316 } #}}}
 317
 318 sub isinlinableimage ($) { #{{{
 319         my $file=shift;
 320
 321         $file=~/\.(png|gif|jpg|jpeg)$/i;
 322 } #}}}
 323
 324 sub pagetitle ($) { #{{{
 325         my $page=shift;
 326         $page=~s/__(\d+)__/&#$1;/g;
 327         $page=~y/_/ /;
 328         return $page;
 329 } #}}}
 330
 331 sub titlepage ($) { #{{{
 332         my $title=shift;
 333         $title=~y/ /_/;
 334         $title=~s/([^-[:alnum:]_:+\/.])/"__".ord($1)."__"/eg;
 335         return $title;
 336 } #}}}
 337
 338 sub cgiurl (@) { #{{{
 339         my %params=@_;
 340
 341         return $config{cgiurl}."?".join("&amp;", map "$_=$params{$_}", keys %params);
 342 } #}}}
 343
 344 sub baseurl (;$) { #{{{
 345         my $page=shift;
 346
 347         return "$config{url}/" if ! defined $page;
 348
 349         $page=~s/[^\/]+$//;
 350         $page=~s/[^\/]+\//..\//g;
 351         return $page;
 352 } #}}}
 353
 354 sub abs2rel ($$) { #{{{
 355         # Work around very innefficient behavior in File::Spec if abs2rel
 356         # is passed two relative paths. It's much faster if paths are
 357         # absolute! (Debian bug #376658)
 358         my $path="/".shift;
 359         my $base="/".shift;
 360
 361         require File::Spec;
 362         my $ret=File::Spec->abs2rel($path, $base);
 363         $ret=~s/^// if defined $ret;
 364         return $ret;
 365 } #}}}
 366
 367 sub displaytime ($) { #{{{
 368         my $time=shift;
 369
 370         eval q{use POSIX};
 371         error($@) if $@;
 372         # strftime doesn't know about encodings, so make sure
 373         # its output is properly treated as utf8
 374         return decode_utf8(POSIX::strftime(
 375                         $config{timeformat}, localtime($time)));
 376 } #}}}
 377
 378 sub htmllink ($$$;$$$) { #{{{
 379         my $lpage=shift; # the page doing the linking
 380         my $page=shift; # the page that will contain the link (different for inline)
 381         my $link=shift;
 382         my $noimageinline=shift; # don't turn links into inline html images
 383         my $forcesubpage=shift; # force a link to a subpage
 384         my $linktext=shift; # set to force the link text to something
 385
 386         my $bestlink;
 387         if (! $forcesubpage) {
 388                 $bestlink=bestlink($lpage, $link);
 389         }
 390         else {
 391                 $bestlink="$lpage/".lc($link);
 392         }
 393
 394         $linktext=pagetitle(basename($link)) unless defined $linktext;
 395
 396         return "<span class=\"selflink\">$linktext</span>"
 397                 if length $bestlink && $page eq $bestlink;
 398
 399         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 400                 $bestlink=htmlpage($bestlink);
 401         }
 402         if (! grep { $_ eq $bestlink } map { @{$_} } values %renderedfiles) {
 403                 return "<span><a href=\"".
 404                         cgiurl(do => "create", page => lc($link), from => $page).
 405                         "\">?</a>$linktext</span>"
 406         }
 407
 408         $bestlink=abs2rel($bestlink, dirname($page));
 409
 410         if (! $noimageinline && isinlinableimage($bestlink)) {
 411                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 412         }
 413         return "<a href=\"$bestlink\">$linktext</a>";
 414 } #}}}
 415
 416 sub htmlize ($$$) { #{{{
 417         my $page=shift;
 418         my $type=shift;
 419         my $content=shift;
 420
 421         if (exists $hooks{htmlize}{$type}) {
 422                 $content=$hooks{htmlize}{$type}{call}->(
 423                         page => $page,
 424                         content => $content,
 425                 );
 426         }
 427         else {
 428                 error("htmlization of $type not supported");
 429         }
 430
 431         run_hooks(sanitize => sub {
 432                 $content=shift->(
 433                         page => $page,
 434                         content => $content,
 435                 );
 436         });
 437
 438         return $content;
 439 } #}}}
 440
 441 sub linkify ($$$) { #{{{
 442         my $lpage=shift; # the page containing the links
 443         my $page=shift; # the page the link will end up on (different for inline)
 444         my $content=shift;
 445
 446         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 447                 $2 ? ( $1 ? "[[$2|$3]]" : htmllink($lpage, $page, titlepage($3), 0, 0, pagetitle($2)))
 448                    : ( $1 ? "[[$3]]" :    htmllink($lpage, $page, titlepage($3)))
 449         }eg;
 450
 451         return $content;
 452 } #}}}
 453
 454 my %preprocessing;
 455 sub preprocess ($$$;$) { #{{{
 456         my $page=shift; # the page the data comes from
 457         my $destpage=shift; # the page the data will appear in (different for inline)
 458         my $content=shift;
 459         my $scan=shift;
 460
 461         my $handle=sub {
 462                 my $escape=shift;
 463                 my $command=shift;
 464                 my $params=shift;
 465                 if (length $escape) {
 466                         return "[[$command $params]]";
 467                 }
 468                 elsif (exists $hooks{preprocess}{$command}) {
 469                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 470                         # Note: preserve order of params, some plugins may
 471                         # consider it significant.
 472                         my @params;
 473                         while ($params =~ /(?:(\w+)=)?(?:"""(.*?)"""|"([^"]+)"|(\S+))(?:\s+|$)/sg) {
 474                                 my $key=$1;
 475                                 my $val;
 476                                 if (defined $2) {
 477                                         $val=$2;
 478                                         $val=~s/\r\n/\n/mg;
 479                                         $val=~s/^\n+//g;
 480                                         $val=~s/\n+$//g;
 481                                 }
 482                                 elsif (defined $3) {
 483                                         $val=$3;
 484                                 }
 485                                 elsif (defined $4) {
 486                                         $val=$4;
 487                                 }
 488
 489                                 if (defined $key) {
 490                                         push @params, $key, $val;
 491                                 }
 492                                 else {
 493                                         push @params, $val, '';
 494                                 }
 495                         }
 496                         if ($preprocessing{$page}++ > 3) {
 497                                 # Avoid loops of preprocessed pages preprocessing
 498                                 # other pages that preprocess them, etc.
 499                                 return "[[$command preprocessing loop detected on $page at depth $preprocessing{$page}]]";
 500                         }
 501                         my $ret=$hooks{preprocess}{$command}{call}->(
 502                                 @params,
 503                                 page => $page,
 504                                 destpage => $destpage,
 505                         );
 506                         $preprocessing{$page}--;
 507                         return $ret;
 508                 }
 509                 else {
 510                         return "[[$command $params]]";
 511                 }
 512         };
 513
 514         $content =~ s{(\\?)\[\[(\w+)\s+((?:(?:\w+=)?(?:""".*?"""|"[^"]+"|[^\s\]]+)\s*)*)\]\]}{$handle->($1, $2, $3)}seg;
 515         return $content;
 516 } #}}}
 517
 518 sub filter ($$) { #{{{
 519         my $page=shift;
 520         my $content=shift;
 521
 522         run_hooks(filter => sub {
 523                 $content=shift->(page => $page, content => $content);
 524         });
 525
 526         return $content;
 527 } #}}}
 528
 529 sub indexlink () { #{{{
 530         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 531 } #}}}
 532
 533 sub lockwiki () { #{{{
 534         # Take an exclusive lock on the wiki to prevent multiple concurrent
 535         # run issues. The lock will be dropped on program exit.
 536         if (! -d $config{wikistatedir}) {
 537                 mkdir($config{wikistatedir});
 538         }
 539         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 540                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 541         if (! flock(WIKILOCK, 2 | 4)) {
 542                 debug("wiki seems to be locked, waiting for lock");
 543                 my $wait=600; # arbitrary, but don't hang forever to
 544                               # prevent process pileup
 545                 for (1..600) {
 546                         return if flock(WIKILOCK, 2 | 4);
 547                         sleep 1;
 548                 }
 549                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 550         }
 551 } #}}}
 552
 553 sub unlockwiki () { #{{{
 554         close WIKILOCK;
 555 } #}}}
 556
 557 sub loadindex () { #{{{
 558         open (IN, "$config{wikistatedir}/index") || return;
 559         while (<IN>) {
 560                 $_=possibly_foolish_untaint($_);
 561                 chomp;
 562                 my %items;
 563                 $items{link}=[];
 564                 $items{dest}=[];
 565                 foreach my $i (split(/ /, $_)) {
 566                         my ($item, $val)=split(/=/, $i, 2);
 567                         push @{$items{$item}}, decode_entities($val);
 568                 }
 569
 570                 next unless exists $items{src}; # skip bad lines for now
 571
 572                 my $page=pagename($items{src}[0]);
 573                 if (! $config{rebuild}) {
 574                         $pagesources{$page}=$items{src}[0];
 575                         $oldpagemtime{$page}=$items{mtime}[0];
 576                         $oldlinks{$page}=[@{$items{link}}];
 577                         $links{$page}=[@{$items{link}}];
 578                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 579                         $renderedfiles{$page}=[@{$items{dest}}];
 580                         $oldrenderedfiles{$page}=[@{$items{dest}}];
 581                         $pagecase{lc $page}=$page;
 582                 }
 583                 $pagectime{$page}=$items{ctime}[0];
 584         }
 585         close IN;
 586 } #}}}
 587
 588 sub saveindex () { #{{{
 589         run_hooks(savestate => sub { shift->() });
 590
 591         if (! -d $config{wikistatedir}) {
 592                 mkdir($config{wikistatedir});
 593         }
 594         open (OUT, ">$config{wikistatedir}/index") ||
 595                 error("cannot write to $config{wikistatedir}/index: $!");
 596         foreach my $page (keys %oldpagemtime) {
 597                 next unless $oldpagemtime{$page};
 598                 my $line="mtime=$oldpagemtime{$page} ".
 599                         "ctime=$pagectime{$page} ".
 600                         "src=$pagesources{$page}";
 601                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 602                 my %count;
 603                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 604                 if (exists $depends{$page}) {
 605                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 606                 }
 607                 print OUT $line."\n";
 608         }
 609         close OUT;
 610 } #}}}
 611
 612 sub template_params (@) { #{{{
 613         my $filename=shift;
 614
 615         require HTML::Template;
 616         return filter => sub {
 617                         my $text_ref = shift;
 618                         $$text_ref=&Encode::decode_utf8($$text_ref);
 619                 },
 620                 filename => "$config{templatedir}/$filename",
 621                 loop_context_vars => 1,
 622                 die_on_bad_params => 0,
 623                 @_;
 624 } #}}}
 625
 626 sub template ($;@) { #{{{
 627         HTML::Template->new(template_params(@_));
 628 } #}}}
 629
 630 sub misctemplate ($$;@) { #{{{
 631         my $title=shift;
 632         my $pagebody=shift;
 633
 634         my $template=template("misc.tmpl");
 635         $template->param(
 636                 title => $title,
 637                 indexlink => indexlink(),
 638                 wikiname => $config{wikiname},
 639                 pagebody => $pagebody,
 640                 baseurl => baseurl(),
 641                 @_,
 642         );
 643         run_hooks(pagetemplate => sub {
 644                 shift->(page => "", destpage => "", template => $template);
 645         });
 646         return $template->output;
 647 }#}}}
 648
 649 sub hook (@) { # {{{
 650         my %param=@_;
 651
 652         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 653                 error "hook requires type, call, and id parameters";
 654         }
 655
 656         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 657
 658         $hooks{$param{type}}{$param{id}}=\%param;
 659 } # }}}
 660
 661 sub run_hooks ($$) { # {{{
 662         # Calls the given sub for each hook of the given type,
 663         # passing it the hook function to call.
 664         my $type=shift;
 665         my $sub=shift;
 666
 667         if (exists $hooks{$type}) {
 668                 my @deferred;
 669                 foreach my $id (keys %{$hooks{$type}}) {
 670                         if ($hooks{$type}{$id}{last}) {
 671                                 push @deferred, $id;
 672                                 next;
 673                         }
 674                         $sub->($hooks{$type}{$id}{call});
 675                 }
 676                 foreach my $id (@deferred) {
 677                         $sub->($hooks{$type}{$id}{call});
 678                 }
 679         }
 680 } #}}}
 681
 682 sub globlist_to_pagespec ($) { #{{{
 683         my @globlist=split(' ', shift);
 684
 685         my (@spec, @skip);
 686         foreach my $glob (@globlist) {
 687                 if ($glob=~/^!(.*)/) {
 688                         push @skip, $glob;
 689                 }
 690                 else {
 691                         push @spec, $glob;
 692                 }
 693         }
 694
 695         my $spec=join(" or ", @spec);
 696         if (@skip) {
 697                 my $skip=join(" and ", @skip);
 698                 if (length $spec) {
 699                         $spec="$skip and ($spec)";
 700                 }
 701                 else {
 702                         $spec=$skip;
 703                 }
 704         }
 705         return $spec;
 706 } #}}}
 707
 708 sub is_globlist ($) { #{{{
 709         my $s=shift;
 710         $s=~/[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or";
 711 } #}}}
 712
 713 sub safequote ($) { #{{{
 714         my $s=shift;
 715         $s=~s/[{}]//g;
 716         return "q{$s}";
 717 } #}}}
 718
 719 sub pagespec_merge ($$) { #{{{
 720         my $a=shift;
 721         my $b=shift;
 722
 723         return $a if $a eq $b;
 724
 725         # Support for old-style GlobLists.
 726         if (is_globlist($a)) {
 727                 $a=globlist_to_pagespec($a);
 728         }
 729         if (is_globlist($b)) {
 730                 $b=globlist_to_pagespec($b);
 731         }
 732
 733         return "($a) or ($b)";
 734 } #}}}
 735
 736 sub pagespec_translate ($) { #{{{
 737         # This assumes that $page is in scope in the function
 738         # that evalulates the translated pagespec code.
 739         my $spec=shift;
 740
 741         # Support for old-style GlobLists.
 742         if (is_globlist($spec)) {
 743                 $spec=globlist_to_pagespec($spec);
 744         }
 745
 746         # Convert spec to perl code.
 747         my $code="";
 748         while ($spec=~m/\s*(\!|\(|\)|\w+\([^\)]+\)|[^\s()]+)\s*/ig) {
 749                 my $word=$1;
 750                 if (lc $word eq "and") {
 751                         $code.=" &&";
 752                 }
 753                 elsif (lc $word eq "or") {
 754                         $code.=" ||";
 755                 }
 756                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
 757                         $code.=" ".$word;
 758                 }
 759                 elsif ($word =~ /^(link|backlink|created_before|created_after|creation_month|creation_year|creation_day)\((.+)\)$/) {
 760                         $code.=" match_$1(\$page, ".safequote($2).")";
 761                 }
 762                 else {
 763                         $code.=" match_glob(\$page, ".safequote($word).")";
 764                 }
 765         }
 766
 767         return $code;
 768 } #}}}
 769
 770 sub add_depends ($$) { #{{{
 771         my $page=shift;
 772         my $pagespec=shift;
 773
 774         if (! exists $depends{$page}) {
 775                 $depends{$page}=$pagespec;
 776         }
 777         else {
 778                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
 779         }
 780 } # }}}
 781
 782 sub pagespec_match ($$) { #{{{
 783         my $page=shift;
 784         my $spec=shift;
 785
 786         return eval pagespec_translate($spec);
 787 } #}}}
 788
 789 sub match_glob ($$) { #{{{
 790         my $page=shift;
 791         my $glob=shift;
 792
 793         # turn glob into safe regexp
 794         $glob=quotemeta($glob);
 795         $glob=~s/\\\*/.*/g;
 796         $glob=~s/\\\?/./g;
 797
 798         return $page=~/^$glob$/i;
 799 } #}}}
 800
 801 sub match_link ($$) { #{{{
 802         my $page=shift;
 803         my $link=lc(shift);
 804
 805         my $links = $links{$page} or return undef;
 806         foreach my $p (@$links) {
 807                 return 1 if lc $p eq $link;
 808         }
 809         return 0;
 810 } #}}}
 811
 812 sub match_backlink ($$) { #{{{
 813         match_link(pop, pop);
 814 } #}}}
 815
 816 sub match_created_before ($$) { #{{{
 817         my $page=shift;
 818         my $testpage=shift;
 819
 820         if (exists $pagectime{$testpage}) {
 821                 return $pagectime{$page} < $pagectime{$testpage};
 822         }
 823         else {
 824                 return 0;
 825         }
 826 } #}}}
 827
 828 sub match_created_after ($$) { #{{{
 829         my $page=shift;
 830         my $testpage=shift;
 831
 832         if (exists $pagectime{$testpage}) {
 833                 return $pagectime{$page} > $pagectime{$testpage};
 834         }
 835         else {
 836                 return 0;
 837         }
 838 } #}}}
 839
 840 sub match_creation_day ($$) { #{{{
 841         return ((gmtime($pagectime{shift()}))[3] == shift);
 842 } #}}}
 843
 844 sub match_creation_month ($$) { #{{{
 845         return ((gmtime($pagectime{shift()}))[4] + 1 == shift);
 846 } #}}}
 847
 848 sub match_creation_year ($$) { #{{{
 849         return ((gmtime($pagectime{shift()}))[5] + 1900 == shift);
 850 } #}}}
 851
 852 1