IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                         section => "widget",
  23                 },
  24 }
  25
  26 sub preprocess (@) {
  27         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  28         my %params=@_;
  29
  30         if (! defined $image) {
  31                 error("bad image filename");
  32         }
  33
  34         if (exists $imgdefaults{$params{page}}) {
  35                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  36                         if (! exists $params{$key}) {
  37                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  38                         }
  39                 }
  40         }
  41
  42         if (! exists $params{size} || ! length $params{size}) {
  43                 $params{size}='full';
  44         }
  45
  46         if ($image eq 'defaults') {
  47                 $imgdefaults{$params{page}} = \%params;
  48                 return '';
  49         }
  50
  51         add_link($params{page}, $image);
  52         add_depends($params{page}, $image);
  53
  54         # optimisation: detect scan mode, and avoid generating the image
  55         if (! defined wantarray) {
  56                 return;
  57         }
  58
  59         my $file = bestlink($params{page}, $image);
  60         my $srcfile = srcfile($file, 1);
  61         if (! length $file || ! defined $srcfile) {
  62                 return htmllink($params{page}, $params{destpage}, $image);
  63         }
  64
  65         my $dir = $params{page};
  66         my $base = IkiWiki::basename($file);
  67         my $issvg = $base=~s/\.svg$/.png/i;
  68         my $ispdf = $base=~s/\.pdf$/.png/i;
  69         my $pagenumber = exists($params{pagenumber}) ? int($params{pagenumber}) : 0;
  70         if ($pagenumber != 0) {
  71                 $base = "p$pagenumber-$base";
  72         }
  73
  74         eval q{use Image::Magick};
  75         error gettext("Image::Magick is not installed") if $@;
  76         my $im = Image::Magick->new();
  77         my $imglink;
  78         my $imgdatalink;
  79         my $r = $im->Read(":$srcfile\[$pagenumber]");
  80         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
  81
  82         if (! defined $im->Get("width") || ! defined $im->Get("height")) {
  83                 error sprintf(gettext("failed to get dimensions of %s"), $file);
  84         }
  85
  86         my ($dwidth, $dheight);
  87
  88         if ($params{size} eq 'full') {
  89                 $dwidth = $im->Get("width");
  90                 $dheight = $im->Get("height");
  91         } else {
  92                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
  93                 error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
  94                         unless (defined $w && defined $h &&
  95                                 (length $w || length $h));
  96
  97                 if ($im->Get("width") == 0 || $im->Get("height") == 0) {
  98                         ($dwidth, $dheight)=(0, 0);
  99                 } elsif (! length $w || (length $h && $im->Get("height")*$w > $h * $im->Get("width"))) {
 100                         # using height because only height is given or ...
 101                         # because original image is more portrait than $w/$h
 102                         # ... slimness of $im > $h/w
 103                         # ... $im->Get("height")/$im->Get("width") > $h/$w
 104                         # ... $im->Get("height")*$w > $h * $im->Get("width")
 105
 106                         $dheight=$h;
 107                         $dwidth=$h / $im->Get("height") * $im->Get("width");
 108                 } else { # (! length $h) or $w is what determines the resized size
 109                         $dwidth=$w;
 110                         $dheight=$w / $im->Get("width") * $im->Get("height");
 111                 }
 112         }
 113
 114         if ($dwidth < $im->Get("width") || $ispdf) {
 115                 # resize down, or resize to pixels at all
 116
 117                 my $outfile = "$config{destdir}/$dir/$params{size}-$base";
 118                 $imglink = "$dir/$params{size}-$base";
 119
 120                 will_render($params{page}, $imglink);
 121
 122                 if (-e $outfile && (-M $srcfile >= -M $outfile)) {
 123                         $im = Image::Magick->new;
 124                         $r = $im->Read($outfile);
 125                         error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
 126                 }
 127                 else {
 128                         $r = $im->Resize(geometry => "${dwidth}x${dheight}");
 129                         error sprintf(gettext("failed to resize: %s"), $r) if $r;
 130
 131                         $im->set(($issvg || $ispdf) ? (magick => 'png') : ());
 132                         my @blob = $im->ImageToBlob();
 133                         # don't actually write resized file in preview mode;
 134                         # rely on width and height settings
 135                         if (! $params{preview}) {
 136                                 writefile($imglink, $config{destdir}, $blob[0], 1);
 137                         }
 138                         else {
 139                                 eval q{use MIME::Base64};
 140                                 error($@) if $@;
 141                                 $imgdatalink = "data:image/".$im->Get("magick").";base64,".encode_base64($blob[0]);
 142                         }
 143                 }
 144
 145                 # always get the true size of the resized image (it could be
 146                 # that imagemagick did its calculations differently)
 147                 $dwidth  = $im->Get("width");
 148                 $dheight = $im->Get("height");
 149         } else {
 150                 $imglink = $file;
 151         }
 152
 153         if (! defined($dwidth) || ! defined($dheight)) {
 154                 error sprintf(gettext("failed to determine size of image %s"), $file)
 155         }
 156
 157         my ($fileurl, $imgurl);
 158         my $urltobase = $params{preview} ? undef : $params{destpage};
 159         $fileurl=urlto($file, $urltobase);
 160         $imgurl=$imgdatalink ? $imgdatalink : urlto($imglink, $urltobase);
 161
 162         if (! exists $params{class}) {
 163                 $params{class}="img";
 164         }
 165
 166         my $attrs='';
 167         foreach my $attr (qw{alt title class id hspace vspace}) {
 168                 if (exists $params{$attr}) {
 169                         $attrs.=" $attr=\"$params{$attr}\"";
 170                 }
 171         }
 172
 173         my $imgtag='<img src="'.$imgurl.
 174                 '" width="'.$dwidth.
 175                 '" height="'.$dheight.'"'.
 176                 $attrs.
 177                 (exists $params{align} && ! exists $params{caption} ? ' align="'.$params{align}.'"' : '').
 178                 ' />';
 179
 180         my $link;
 181         if (! defined $params{link}) {
 182                 $link=$fileurl;
 183         }
 184         elsif ($params{link} =~ /^\w+:\/\//) {
 185                 $link=$params{link};
 186         }
 187
 188         if (defined $link) {
 189                 $imgtag='<a href="'.$link.'">'.$imgtag.'</a>';
 190         }
 191         else {
 192                 my $b = bestlink($params{page}, $params{link});
 193
 194                 if (length $b) {
 195                         add_depends($params{page}, $b, deptype("presence"));
 196                         $imgtag=htmllink($params{page}, $params{destpage},
 197                                 $params{link}, linktext => $imgtag,
 198                                 noimageinline => 1,
 199                         );
 200                 }
 201         }
 202
 203         if (exists $params{caption}) {
 204                 return '<table class="img'.
 205                         (exists $params{align} ? " align-$params{align}" : "").
 206                         '">'.
 207                         '<caption>'.$params{caption}.'</caption>'.
 208                         '<tr><td>'.$imgtag.'</td></tr>'.
 209                         '</table>';
 210         }
 211         else {
 212                 return $imgtag;
 213         }
 214 }
 215
 216 1