IkiWiki/Plugin/blogspam.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::blogspam;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 my $defaulturl='http://test.blogspam.net:8888/';
  10
  11 sub import {
  12         hook(type => "getsetup", id => "blogspam",  call => \&getsetup);
  13         hook(type => "checkconfig", id => "blogspam", call => \&checkconfig);
  14         hook(type => "checkcontent", id => "blogspam", call => \&checkcontent);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => 0,
  22                         section => "auth",
  23                 },
  24                 blogspam_pagespec => {
  25                         type => 'pagespec',
  26                         example => 'postcomment(*)',
  27                         description => 'PageSpec of pages to check for spam',
  28                         link => 'ikiwiki/PageSpec',
  29                         safe => 1,
  30                         rebuild => 0,
  31                 },
  32                 blogspam_options => {
  33                         type => "string",
  34                         example => "blacklist=1.2.3.4,blacklist=8.7.6.5,max-links=10",
  35                         description => "options to send to blogspam server",
  36                         link => "http://blogspam.net/api/testComment.html#options",
  37                         safe => 1,
  38                         rebuild => 0,
  39                 },
  40                 blogspam_server => {
  41                         type => "string",
  42                         default => $defaulturl,
  43                         description => "blogspam server XML-RPC url",
  44                         safe => 1,
  45                         rebuild => 0,
  46                 },
  47 }
  48
  49 sub checkconfig () {
  50         # This is done at checkconfig time because printing an error
  51         # if the module is missing when a spam is posted would not
  52         # let the admin know about the problem.
  53         eval q{
  54                 use RPC::XML;
  55                 use RPC::XML::Client;
  56         };
  57         error $@ if $@;
  58 }
  59
  60 sub checkcontent (@) {
  61         my %params=@_;
  62         my $session=$params{session};
  63
  64         if (exists $config{blogspam_pagespec}) {
  65                 return undef
  66                         if ! pagespec_match($params{page}, $config{blogspam_pagespec},
  67                                 location => $params{page});
  68         }
  69
  70         my $url=$defaulturl;
  71         $url = $config{blogspam_server} if exists $config{blogspam_server};
  72
  73         my $client = RPC::XML::Client->new($url);
  74
  75         my @options = split(",", $config{blogspam_options})
  76                 if exists $config{blogspam_options};
  77
  78         # Allow short comments and whitespace-only edits, unless the user
  79         # has overridden min-words themselves.
  80         push @options, "min-words=0"
  81                 unless grep /^min-words=/i, @options;
  82         # Wiki pages can have a lot of urls, unless the user specifically
  83         # wants to limit them.
  84         push @options, "exclude=lotsaurls"
  85                 unless grep /^max-links/i, @options;
  86         # Unless the user specified a size check, disable such checking.
  87         push @options, "exclude=size"
  88                 unless grep /^(?:max|min)-size/i, @options;
  89         # This test has absurd false positives on words like "alpha"
  90         # and "buy".
  91         push @options, "exclude=stopwords";
  92
  93         my %req=(
  94                 ip => $session->remote_addr(),
  95                 comment => encode_utf8(defined $params{diff} ? $params{diff} : $params{content}),
  96                 subject => encode_utf8(defined $params{subject} ? $params{subject} : ""),
  97                 name => encode_utf8(defined $params{author} ? $params{author} : ""),
  98                 link => encode_utf8(exists $params{url} ? $params{url} : ""),
  99                 options => join(",", @options),
 100                 site => encode_utf8($config{url}),
 101                 version => "ikiwiki ".$IkiWiki::version,
 102         );
 103         my $res = $client->send_request('testComment', \%req);
 104
 105         if (! ref $res || ! defined $res->value) {
 106                 debug("failed to get response from blogspam server ($url)");
 107                 return undef;
 108         }
 109         elsif ($res->value =~ /^SPAM:(.*)/) {
 110                 eval q{use Data::Dumper};
 111                 debug("blogspam server reports ".$res->value.": ".Dumper(\%req));
 112                 return gettext("Sorry, but that looks like spam to <a href=\"http://blogspam.net/\">blogspam</a>: ").$1;
 113         }
 114         elsif ($res->value ne 'OK') {
 115                 debug("blogspam server failure: ".$res->value);
 116                 return undef;
 117         }
 118         else {
 119                 return undef;
 120         }
 121 }
 122
 123 1