IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki;
   9 use Image::Magick;
  10
  11 my %imgdefaults;
  12
  13 sub import { #{{{
  14         hook(type => "preprocess", id => "img", call => \&preprocess);
  15 } #}}}
  16
  17 sub preprocess (@) { #{{{
  18         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  19         my %params=@_;
  20
  21         if (! exists $imgdefaults{$params{page}}) {
  22                 $imgdefaults{$params{page}} = {};
  23         }
  24         my $size = $params{size} || $imgdefaults{$params{page}}->{size} || 'full';
  25         my $alt = $params{alt} || $imgdefaults{$params{page}}->{alt} || '';
  26
  27         if ($image eq 'defaults') {
  28                 $imgdefaults{$params{page}} = {
  29                         size => $size,
  30                         alt => $alt,
  31                 };
  32                 return '';
  33         }
  34
  35         add_depends($params{page}, $image);
  36         my $file = bestlink($params{page}, $image) || return "[[img $image not found]]";
  37
  38         my $dir = IkiWiki::dirname($file);
  39         my $base = IkiWiki::basename($file);
  40         my $im = Image::Magick->new;
  41         my $imglink;
  42         my $r;
  43
  44         if ($size ne 'full') {
  45                 my ($w, $h) = ($size =~ /^(\d+)x(\d+)$/);
  46                 return "[[img bad size \"$size\"]]" unless (defined $w && defined $h);
  47
  48                 my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
  49                 $imglink = "$dir/${w}x${h}-$base";
  50                 will_render($params{page}, $imglink);
  51
  52                 if (-e $outfile && (-M srcfile($file) >= -M $outfile)) {
  53                         $r = $im->Read($outfile);
  54                         return "[[img failed to read $outfile: $r]]" if $r;
  55                 }
  56                 else {
  57                         $r = $im->Read(srcfile($file));
  58                         return "[[img failed to read $file: $r]]" if $r;
  59
  60                         $r = $im->Resize(geometry => "${w}x${h}");
  61                         return "[[img failed to resize: $r]]" if $r;
  62
  63                         my @blob = $im->ImageToBlob();
  64                         writefile($imglink, $config{destdir}, $blob[0], 1);
  65                 }
  66         }
  67         else {
  68                 $r = $im->Read(srcfile($file));
  69                 return "[[img failed to read $file: $r]]" if $r;
  70                 $imglink = $file;
  71         }
  72
  73         add_depends($imglink, $params{page});
  74
  75         return '<a href="'.
  76                 IkiWiki::abs2rel($file, IkiWiki::dirname($params{destpage})).
  77                 '"><img src="'.
  78                 IkiWiki::abs2rel($imglink, IkiWiki::dirname($params{destpage})).
  79                 '" alt="'.$alt.'" width="'.$im->Get("width").
  80                 '" height="'.$im->Get("height").'" /></a>';
  81 } #}}}
  82
  83 1;