IkiWiki/Render.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8
   9 my (%backlinks, %rendered, %scanned);
  10 our %brokenlinks;
  11 my $links_calculated=0;
  12
  13 sub calculate_links () {
  14         return if $links_calculated;
  15         %backlinks=%brokenlinks=();
  16         foreach my $page (keys %links) {
  17                 foreach my $link (@{$links{$page}}) {
  18                         my $bestlink=bestlink($page, $link);
  19                         if (length $bestlink) {
  20                                 $backlinks{$bestlink}{$page}=1
  21                                         if $bestlink ne $page;
  22                         }
  23                         else {
  24                                 push @{$brokenlinks{$link}}, $page;
  25                         }
  26                 }
  27         }
  28         $links_calculated=1;
  29 }
  30
  31 sub backlink_pages ($) {
  32         my $page=shift;
  33
  34         calculate_links();
  35
  36         return keys %{$backlinks{$page}};
  37 }
  38
  39 sub backlinks ($) {
  40         my $page=shift;
  41
  42         my @links;
  43         foreach my $p (backlink_pages($page)) {
  44                 my $href=urlto($p, $page);
  45
  46                 # Trim common dir prefixes from both pages.
  47                 my $p_trimmed=$p;
  48                 my $page_trimmed=$page;
  49                 my $dir;
  50                 1 while (($dir)=$page_trimmed=~m!^([^/]+/)!) &&
  51                         defined $dir &&
  52                         $p_trimmed=~s/^\Q$dir\E// &&
  53                         $page_trimmed=~s/^\Q$dir\E//;
  54
  55                 push @links, { url => $href, page => pagetitle($p_trimmed) };
  56         }
  57         return @links;
  58 }
  59
  60 sub genpage ($$) {
  61         my $page=shift;
  62         my $content=shift;
  63
  64         run_hooks(indexhtml => sub {
  65                 shift->(page => $page, destpage => $page, content => $content);
  66         });
  67
  68         my $templatefile;
  69         run_hooks(templatefile => sub {
  70                 return if defined $templatefile;
  71                 my $file=shift->(page => $page);
  72                 if (defined $file && defined template_file($file)) {
  73                         $templatefile=$file;
  74                 }
  75         });
  76         my $template;
  77         if (defined $templatefile) {
  78                 $template=template_depends($templatefile, $page,
  79                         blind_cache => 1);
  80         }
  81         else {
  82                 # no explicit depends as special case
  83                 $template=template('page.tmpl',
  84                         blind_cache => 1);
  85         }
  86
  87         my $actions=0;
  88         if (length $config{cgiurl}) {
  89                 if (IkiWiki->can("cgi_editpage")) {
  90                         $template->param(editurl => cgiurl(do => "edit", page => $page));
  91                         $actions++;
  92                 }
  93         }
  94         if (defined $config{historyurl} && length $config{historyurl}) {
  95                 my $u=$config{historyurl};
  96                 my $p=uri_escape_utf8($pagesources{$page}, '^A-Za-z0-9\-\._~/');
  97                 $u=~s/\[\[file\]\]/$p/g;
  98                 $template->param(historyurl => $u);
  99                 $actions++;
 100         }
 101         if ($config{discussion}) {
 102                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/i &&
 103                    (length $config{cgiurl} ||
 104                     exists $links{$page."/".$config{discussionpage}})) {
 105                         $template->param(discussionlink => htmllink($page, $page, $config{discussionpage}, noimageinline => 1, forcesubpage => 1));
 106                         $actions++;
 107                 }
 108         }
 109         if ($actions) {
 110                 $template->param(have_actions => 1);
 111         }
 112         templateactions($template, $page);
 113
 114         my @backlinks=sort { $a->{page} cmp $b->{page} || $a->{url} cmp $b->{url} } backlinks($page);
 115         my ($backlinks, $more_backlinks);
 116         if (@backlinks <= $config{numbacklinks} || ! $config{numbacklinks}) {
 117                 $backlinks=\@backlinks;
 118                 $more_backlinks=[];
 119         }
 120         else {
 121                 $backlinks=[@backlinks[0..$config{numbacklinks}-1]];
 122                 $more_backlinks=[@backlinks[$config{numbacklinks}..$#backlinks]];
 123         }
 124
 125         $template->param(
 126                 title => $page eq 'index'
 127                         ? $config{wikiname}
 128                         : pagetitle(basename($page)),
 129                 wikiname => $config{wikiname},
 130                 content => $content,
 131                 backlinks => $backlinks,
 132                 more_backlinks => $more_backlinks,
 133                 mtime => displaytime($pagemtime{$page}),
 134                 ctime => displaytime($pagectime{$page}, undef, 1),
 135                 baseurl => baseurl($page),
 136                 html5 => $config{html5},
 137                 responsive_layout => $config{responsive_layout},
 138         );
 139
 140         run_hooks(pagetemplate => sub {
 141                 shift->(page => $page, destpage => $page, template => $template);
 142         });
 143
 144         $content=$template->output;
 145
 146         run_hooks(format => sub {
 147                 $content=shift->(
 148                         page => $page,
 149                         content => $content,
 150                 );
 151         });
 152
 153         return $content;
 154 }
 155
 156 sub scan ($) {
 157         my $file=shift;
 158         return if ($config{rebuild} && $phase > PHASE_SCAN) || $scanned{$file};
 159         $scanned{$file}=1;
 160
 161         debug(sprintf(gettext("scanning %s"), $file));
 162
 163         my $type=pagetype($file);
 164         if (defined $type) {
 165                 my $srcfile=srcfile($file);
 166                 my $content=readfile($srcfile);
 167                 my $page=pagename($file);
 168                 will_render($page, htmlpage($page), 1);
 169
 170                 if ($config{discussion}) {
 171                         # Discussion links are a special case since they're
 172                         # not in the text of the page, but on its template.
 173                         $links{$page}=[ $page."/".lc($config{discussionpage}) ];
 174                 }
 175                 else {
 176                         $links{$page}=[];
 177                 }
 178                 delete $typedlinks{$page};
 179
 180                 # Preprocess in scan-only mode.
 181                 preprocess($page, $page, $content, 1);
 182
 183                 run_hooks(scan => sub {
 184                         shift->(
 185                                 page => $page,
 186                                 content => $content,
 187                         );
 188                 });
 189         }
 190         else {
 191                 will_render($file, $file, 1);
 192         }
 193 }
 194
 195 sub fast_file_copy (@) {
 196         my $srcfile=shift;
 197         my $destfile=shift;
 198         my $srcfd=shift;
 199         my $destfd=shift;
 200         my $cleanup=shift;
 201
 202         my $blksize = 16384;
 203         my ($len, $buf, $written);
 204         while ($len = sysread $srcfd, $buf, $blksize) {
 205                 if (! defined $len) {
 206                         next if $! =~ /^Interrupted/;
 207                         error("failed to read $srcfile: $!", $cleanup);
 208                 }
 209                 my $offset = 0;
 210                 while ($len) {
 211                         defined($written = syswrite $destfd, $buf, $len, $offset)
 212                                 or error("failed to write $destfile: $!", $cleanup);
 213                         $len -= $written;
 214                         $offset += $written;
 215                 }
 216         }
 217 }
 218
 219 sub render ($$) {
 220         my $file=shift;
 221         return if $rendered{$file};
 222         debug(shift);
 223         $rendered{$file}=1;
 224
 225         my $type=pagetype($file);
 226         my $srcfile=srcfile($file);
 227         if (defined $type) {
 228                 my $page=pagename($file);
 229                 delete $depends{$page};
 230                 delete $depends_simple{$page};
 231                 will_render($page, htmlpage($page), 1);
 232                 return if $type=~/^_/;
 233
 234                 my $content=htmlize($page, $page, $type,
 235                         linkify($page, $page,
 236                         preprocess($page, $page,
 237                         filter($page, $page,
 238                         readfile($srcfile)))));
 239
 240                 my $output=htmlpage($page);
 241                 writefile($output, $config{destdir}, genpage($page, $content));
 242         }
 243         else {
 244                 delete $depends{$file};
 245                 delete $depends_simple{$file};
 246                 will_render($file, $file, 1);
 247
 248                 if ($config{hardlink}) {
 249                         # only hardlink if owned by same user
 250                         my @stat=stat($srcfile);
 251                         if ($stat[4] == $>) {
 252                                 prep_writefile($file, $config{destdir});
 253                                 unlink($config{destdir}."/".$file);
 254                                 if (link($srcfile, $config{destdir}."/".$file)) {
 255                                         return;
 256                                 }
 257                         }
 258                         # if hardlink fails, fall back to copying
 259                 }
 260
 261                 my $srcfd=readfile($srcfile, 1, 1);
 262                 writefile($file, $config{destdir}, undef, 1, sub {
 263                         fast_file_copy($srcfile, $file, $srcfd, @_);
 264                 });
 265         }
 266 }
 267
 268 sub prune ($;$) {
 269         my $file=shift;
 270         my $up_to=shift;
 271
 272         unlink($file);
 273         my $dir=dirname($file);
 274         while ((! defined $up_to || $dir =~ m{^\Q$up_to\E\/}) && rmdir($dir)) {
 275                 $dir=dirname($dir);
 276         }
 277 }
 278
 279 sub srcdir_check () {
 280         # security check, avoid following symlinks in the srcdir path by default
 281         my $test=$config{srcdir};
 282         while (length $test) {
 283                 if (-l $test && ! $config{allow_symlinks_before_srcdir}) {
 284                         error(sprintf(gettext("symlink found in srcdir path (%s) -- set allow_symlinks_before_srcdir to allow this"), $test));
 285                 }
 286                 unless ($test=~s/\/+$//) {
 287                         $test=dirname($test);
 288                 }
 289         }
 290
 291 }
 292
 293 # Finds all files in the srcdir, and the underlaydirs.
 294 # Returns the files, and their corresponding pages.
 295 #
 296 # When run in only_underlay mode, adds only the underlay files to
 297 # the files and pages passed in.
 298 sub find_src_files (;$$$) {
 299         my $only_underlay=shift;
 300         my @files;
 301         if (defined $_[0]) {
 302                 @files=@{shift()};
 303         }
 304         my %pages;
 305         if (defined $_[0]) {
 306                 %pages=%{shift()};
 307         }
 308
 309         eval q{use File::Find};
 310         error($@) if $@;
 311
 312         eval q{use Cwd};
 313         die $@ if $@;
 314         my $origdir=getcwd();
 315         my $abssrcdir=Cwd::abs_path($config{srcdir});
 316
 317         @IkiWiki::underlayfiles=();
 318
 319         my ($page, $underlay);
 320         my $helper=sub {
 321                 my $file=decode_utf8($_);
 322
 323                 return if -l $file || -d _;
 324                 $file=~s/^\.\///;
 325                 return if ! length $file;
 326                 $page = pagename($file);
 327                 if (! exists $pagesources{$page} &&
 328                     file_pruned($file)) {
 329                         $File::Find::prune=1;
 330                         return;
 331                 }
 332
 333                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 334                 if (! defined $f) {
 335                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 336                         return;
 337                 }
 338
 339                 if ($underlay) {
 340                         # avoid underlaydir override attacks; see security.mdwn
 341                         if (! -l "$abssrcdir/$f" && ! -e _) {
 342                                 if (! $pages{$page}) {
 343                                         push @files, $f;
 344                                         push @IkiWiki::underlayfiles, $f;
 345                                         $pages{$page}=1;
 346                                 }
 347                         }
 348                 }
 349                 else {
 350                         push @files, $f;
 351                         if ($pages{$page}) {
 352                                 debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 353                         }
 354                         $pages{$page}=1;
 355                 }
 356         };
 357
 358         unless ($only_underlay) {
 359                 chdir($config{srcdir}) || die "chdir $config{srcdir}: $!";
 360                 find({
 361                         no_chdir => 1,
 362                         wanted => $helper,
 363                 }, '.');
 364                 chdir($origdir) || die "chdir $origdir: $!";
 365         }
 366
 367         $underlay=1;
 368         foreach (@{$config{underlaydirs}}, $config{underlaydir}) {
 369                 if (chdir($_)) {
 370                         find({
 371                                 no_chdir => 1,
 372                                 wanted => $helper,
 373                         }, '.');
 374                         chdir($origdir) || die "chdir: $!";
 375                 }
 376         };
 377
 378         return \@files, \%pages;
 379 }
 380
 381 # Given a hash of files that have changed, and a hash of files that were
 382 # deleted, should return the same results as find_src_files, with the same
 383 # sanity checks. But a lot faster!
 384 sub process_changed_files ($$) {
 385         my $changed_raw=shift;
 386         my $deleted_raw=shift;
 387
 388         my @files;
 389         my %pages;
 390
 391         foreach my $file (keys %$changed_raw) {
 392                 my $page = pagename($file);
 393                 next if ! exists $pagesources{$page} && file_pruned($file);
 394                 my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
 395                 if (! defined $f) {
 396                         warn(sprintf(gettext("skipping bad filename %s"), $file)."\n");
 397                         next;
 398                 }
 399                 push @files, $f;
 400                 if ($pages{$page}) {
 401                         debug(sprintf(gettext("%s has multiple possible source pages"), $page));
 402                 }
 403                 $pages{$page}=1;
 404         }
 405
 406         # So far, we only have the changed files. Now add in all the old
 407         # files that were not changed or deleted, excluding ones that came
 408         # from the underlay.
 409         my %old_underlay;
 410         foreach my $f (@IkiWiki::underlayfiles) {
 411                 $old_underlay{$f}=1;
 412         }
 413         foreach my $page (keys %pagesources) {
 414                 my $f=$pagesources{$page};
 415                 unless ($old_underlay{$f} || exists $pages{$page} || exists $deleted_raw->{$f}) {
 416                         $pages{$page}=1;
 417                         push @files, $f;
 418                 }
 419         }
 420
 421         # add in the underlay
 422         find_src_files(1, \@files, \%pages);
 423 }
 424
 425 sub find_new_files ($) {
 426         my $files=shift;
 427         my @new;
 428         my @internal_new;
 429
 430         my $times_noted;
 431
 432         foreach my $file (@$files) {
 433                 my $page=pagename($file);
 434
 435                 if ($config{rcs} && $config{gettime} &&
 436                     -e "$config{srcdir}/$file") {
 437                         if (! $times_noted) {
 438                                 debug(sprintf(gettext("querying %s for file creation and modification times.."), $config{rcs}));
 439                                 $times_noted=1;
 440                         }
 441
 442                         eval {
 443                                 my $ctime=rcs_getctime($file);
 444                                 if ($ctime > 0) {
 445                                         $pagectime{$page}=$ctime;
 446                                 }
 447                         };
 448                         if ($@) {
 449                                 print STDERR $@;
 450                         }
 451                         my $mtime;
 452                         eval {
 453                                 $mtime=rcs_getmtime($file);
 454                         };
 455                         if ($@) {
 456                                 print STDERR $@;
 457                         }
 458                         elsif ($mtime > 0) {
 459                                 utime($mtime, $mtime, "$config{srcdir}/$file");
 460                         }
 461                 }
 462
 463                 if (exists $pagesources{$page} && $pagesources{$page} ne $file) {
 464                         # the page has changed its type
 465                         $forcerebuild{$page}=1;
 466                 }
 467                 $pagesources{$page}=$file;
 468                 if (! $pagemtime{$page}) {
 469                         if (isinternal($page)) {
 470                                 push @internal_new, $file;
 471                         }
 472                         else {
 473                                 push @new, $file;
 474                         }
 475                         $pagecase{lc $page}=$page;
 476                         if (! exists $pagectime{$page}) {
 477                                 my @stat=srcfile_stat($file, 1);
 478                                 # For the creation time of the page, take the
 479                                 # inode change time (not creation time!) or
 480                                 # the modification time, whichever is older.
 481                                 my $ctime=($stat[10] < $stat[9] ? $stat[10] : $stat[9]);
 482                                 $pagectime{$page}=$ctime if defined $ctime;
 483                         }
 484                 }
 485         }
 486
 487         return \@new, \@internal_new;
 488 }
 489
 490 sub find_del_files ($) {
 491         my $pages=shift;
 492         my @del;
 493         my @internal_del;
 494
 495         foreach my $page (keys %pagesources) {
 496                 if (! $pages->{$page}) {
 497                         if (isinternal($page)) {
 498                                 push @internal_del, $pagesources{$page};
 499                         }
 500                         else {
 501                                 push @del, $pagesources{$page};
 502                         }
 503                         $links{$page}=[];
 504                         delete $typedlinks{$page};
 505                         $renderedfiles{$page}=[];
 506                         $pagemtime{$page}=0;
 507                 }
 508         }
 509
 510         return \@del, \@internal_del;
 511 }
 512
 513 sub remove_del (@) {
 514         foreach my $file (@_) {
 515                 my $page=pagename($file);
 516                 if (! isinternal($page)) {
 517                         debug(sprintf(gettext("removing obsolete %s"), $page));
 518                 }
 519
 520                 foreach my $old (@{$oldrenderedfiles{$page}}) {
 521                         prune($config{destdir}."/".$old, $config{destdir});
 522                 }
 523
 524                 foreach my $source (keys %destsources) {
 525                         if ($destsources{$source} eq $page) {
 526                                 delete $destsources{$source};
 527                         }
 528                 }
 529
 530                 delete $pagecase{lc $page};
 531                 $delpagesources{$page}=$pagesources{$page};
 532                 delete $pagesources{$page};
 533         }
 534 }
 535
 536 sub find_changed ($) {
 537         my $files=shift;
 538         my @changed;
 539         my @internal_changed;
 540         foreach my $file (@$files) {
 541                 my $page=pagename($file);
 542                 my ($srcfile, @stat)=srcfile_stat($file, 1);
 543                 if (defined $srcfile &&
 544                     (! exists $pagemtime{$page} ||
 545                      $stat[9] > $pagemtime{$page} ||
 546                      $forcerebuild{$page})) {
 547                         $pagemtime{$page}=$stat[9];
 548
 549                         if (isinternal($page)) {
 550                                 my $content = readfile($srcfile);
 551
 552                                 # Preprocess internal page in scan-only mode.
 553                                 preprocess($page, $page, $content, 1);
 554
 555                                 run_hooks(scan => sub {
 556                                         shift->(
 557                                                 page => $page,
 558                                                 content => $content,
 559                                         );
 560                                 });
 561
 562                                 push @internal_changed, $file;
 563                         }
 564                         else {
 565                                 push @changed, $file;
 566                         }
 567                 }
 568         }
 569         return \@changed, \@internal_changed;
 570 }
 571
 572 sub calculate_old_links ($$) {
 573         my ($changed, $del)=@_;
 574         my %oldlink_targets;
 575         foreach my $file (@$changed, @$del) {
 576                 my $page=pagename($file);
 577                 if (exists $oldlinks{$page}) {
 578                         foreach my $l (@{$oldlinks{$page}}) {
 579                                 $oldlink_targets{$page}{$l}=bestlink($page, $l);
 580                         }
 581                 }
 582         }
 583         return \%oldlink_targets;
 584 }
 585
 586 sub derender_internal ($) {
 587         my $file=shift;
 588         my $page=pagename($file);
 589         delete $depends{$page};
 590         delete $depends_simple{$page};
 591         foreach my $old (@{$renderedfiles{$page}}) {
 592                 delete $destsources{$old};
 593         }
 594         $renderedfiles{$page}=[];
 595 }
 596
 597 sub render_linkers ($) {
 598         my $f=shift;
 599         my $p=pagename($f);
 600         foreach my $page (keys %{$backlinks{$p}}) {
 601                 my $file=$pagesources{$page};
 602                 render($file, sprintf(gettext("building %s, which links to %s"), $file, $p));
 603         }
 604 }
 605
 606 sub remove_unrendered () {
 607         foreach my $src (keys %rendered) {
 608                 my $page=pagename($src);
 609                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 610                         if (! grep { $_ eq $file } @{$renderedfiles{$page}}) {
 611                                 debug(sprintf(gettext("removing %s, no longer built by %s"), $file, $page));
 612                                 prune($config{destdir}."/".$file, $config{destdir});
 613                         }
 614                 }
 615         }
 616 }
 617
 618 sub link_types_changed ($$) {
 619         # each is of the form { type => { link => 1 } }
 620         my $new = shift;
 621         my $old = shift;
 622
 623         return 0 if !defined $new && !defined $old;
 624         return 1 if (!defined $new && %$old) || (!defined $old && %$new);
 625
 626         while (my ($type, $links) = each %$new) {
 627                 foreach my $link (keys %$links) {
 628                         return 1 unless exists $old->{$type}{$link};
 629                 }
 630         }
 631
 632         while (my ($type, $links) = each %$old) {
 633                 foreach my $link (keys %$links) {
 634                         return 1 unless exists $new->{$type}{$link};
 635                 }
 636         }
 637
 638         return 0;
 639 }
 640
 641 sub calculate_changed_links ($$$) {
 642         my ($changed, $del, $oldlink_targets)=@_;
 643
 644         my (%backlinkchanged, %linkchangers);
 645
 646         foreach my $file (@$changed, @$del) {
 647                 my $page=pagename($file);
 648
 649                 if (exists $links{$page}) {
 650                         foreach my $l (@{$links{$page}}) {
 651                                 my $target=bestlink($page, $l);
 652                                 if (! exists $oldlink_targets->{$page}{$l} ||
 653                                     $target ne $oldlink_targets->{$page}{$l}) {
 654                                         $backlinkchanged{$target}=1;
 655                                         $linkchangers{lc($page)}=1;
 656                                 }
 657                                 delete $oldlink_targets->{$page}{$l};
 658                         }
 659                 }
 660                 if (exists $oldlink_targets->{$page} &&
 661                     %{$oldlink_targets->{$page}}) {
 662                         foreach my $target (values %{$oldlink_targets->{$page}}) {
 663                                 $backlinkchanged{$target}=1;
 664                         }
 665                         $linkchangers{lc($page)}=1;
 666                 }
 667
 668                 # we currently assume that changing the type of a link doesn't
 669                 # change backlinks
 670                 if (!exists $linkchangers{lc($page)}) {
 671                         if (link_types_changed($typedlinks{$page}, $oldtypedlinks{$page})) {
 672                                 $linkchangers{lc($page)}=1;
 673                         }
 674                 }
 675         }
 676
 677         return \%backlinkchanged, \%linkchangers;
 678 }
 679
 680 sub render_dependent ($$$$$$$) {
 681         my ($files, $new, $internal_new, $del, $internal_del,
 682                 $internal_changed, $linkchangers)=@_;
 683
 684         my @changed=(keys %rendered, @$del);
 685         my @exists_changed=(@$new, @$del);
 686
 687         my %lc_changed = map { lc(pagename($_)) => 1 } @changed;
 688         my %lc_exists_changed = map { lc(pagename($_)) => 1 } @exists_changed;
 689
 690         foreach my $p ("templates/page.tmpl", keys %{$depends_simple{""}}) {
 691                 if ($rendered{$p} || grep { $_ eq $p } @$del) {
 692                         foreach my $f (@$files) {
 693                                 next if $rendered{$f};
 694                                 render($f, sprintf(gettext("building %s, which depends on %s"), $f, $p));
 695                         }
 696                         return 0;
 697                 }
 698         }
 699
 700         foreach my $f (@$files) {
 701                 next if $rendered{$f};
 702                 my $p=pagename($f);
 703                 my $reason = undef;
 704
 705                 if (exists $depends_simple{$p} && ! defined $reason) {
 706                         foreach my $d (keys %{$depends_simple{$p}}) {
 707                                 if (($depends_simple{$p}{$d} & $IkiWiki::DEPEND_CONTENT &&
 708                                      $lc_changed{$d})
 709                                     ||
 710                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_PRESENCE &&
 711                                      $lc_exists_changed{$d})
 712                                     ||
 713                                     ($depends_simple{$p}{$d} & $IkiWiki::DEPEND_LINKS &&
 714                                      $linkchangers->{$d})
 715                                 ) {
 716                                         $reason = $d;
 717                                         last;
 718                                 }
 719                         }
 720                 }
 721
 722                 if (exists $depends{$p} && ! defined $reason) {
 723                         foreach my $dep (keys %{$depends{$p}}) {
 724                                 my $sub=pagespec_translate($dep);
 725                                 next unless defined $sub;
 726
 727                                 # only consider internal files
 728                                 # if the page explicitly depends
 729                                 # on such files
 730                                 my $internal_dep=$dep =~ /(?:internal|comment|comment_pending)\(/;
 731
 732                                 my $in=sub {
 733                                         my $list=shift;
 734                                         my $type=shift;
 735                                         foreach my $file (@$list) {
 736                                                 next if $file eq $f;
 737                                                 my $page=pagename($file);
 738                                                 if ($sub->($page, location => $p)) {
 739                                                         if ($type == $IkiWiki::DEPEND_LINKS) {
 740                                                                 next unless $linkchangers->{lc($page)};
 741                                                         }
 742                                                         $reason=$page;
 743                                                         return 1;
 744                                                 }
 745                                         }
 746                                         return undef;
 747                                 };
 748
 749                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_CONTENT) {
 750                                         last if $in->(\@changed, $IkiWiki::DEPEND_CONTENT);
 751                                         last if $internal_dep && (
 752                                                 $in->($internal_new, $IkiWiki::DEPEND_CONTENT) ||
 753                                                 $in->($internal_del, $IkiWiki::DEPEND_CONTENT) ||
 754                                                 $in->($internal_changed, $IkiWiki::DEPEND_CONTENT)
 755                                         );
 756                                 }
 757                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_PRESENCE) {
 758                                         last if $in->(\@exists_changed, $IkiWiki::DEPEND_PRESENCE);
 759                                         last if $internal_dep && (
 760                                                 $in->($internal_new, $IkiWiki::DEPEND_PRESENCE) ||
 761                                                 $in->($internal_del, $IkiWiki::DEPEND_PRESENCE)
 762                                         );
 763                                 }
 764                                 if ($depends{$p}{$dep} & $IkiWiki::DEPEND_LINKS) {
 765                                         last if $in->(\@changed, $IkiWiki::DEPEND_LINKS);
 766                                         last if $internal_dep && (
 767                                                 $in->($internal_new, $IkiWiki::DEPEND_LINKS) ||
 768                                                 $in->($internal_del, $IkiWiki::DEPEND_LINKS) ||
 769                                                 $in->($internal_changed, $IkiWiki::DEPEND_LINKS)
 770                                         );
 771                                 }
 772                         }
 773                 }
 774
 775                 if (defined $reason) {
 776                         render($f, sprintf(gettext("building %s, which depends on %s"), $f, $reason));
 777                         return 1;
 778                 }
 779         }
 780
 781         return 0;
 782 }
 783
 784 sub render_backlinks ($) {
 785         my $backlinkchanged=shift;
 786         foreach my $link (keys %$backlinkchanged) {
 787                 my $linkfile=$pagesources{$link};
 788                 if (defined $linkfile) {
 789                         render($linkfile, sprintf(gettext("building %s, to update its backlinks"), $linkfile));
 790                 }
 791         }
 792 }
 793
 794 sub gen_autofile ($$$) {
 795         my $autofile=shift;
 796         my $pages=shift;
 797         my $del=shift;
 798
 799         if (file_pruned($autofile)) {
 800                 return;
 801         }
 802
 803         my ($file)="$config{srcdir}/$autofile" =~ /$config{wiki_file_regexp}/; # untaint
 804         if (! defined $file) {
 805                 return;
 806         }
 807
 808         # Remember autofiles that were tried, and never try them again later.
 809         if (exists $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}) {
 810                 return;
 811         }
 812         $wikistate{$autofiles{$autofile}{plugin}}{autofile}{$autofile}=1;
 813
 814         if (srcfile($autofile, 1) || file_pruned($autofile)) {
 815                 return;
 816         }
 817
 818         if (-l $file || -d _ || -e _) {
 819                 return;
 820         }
 821
 822         my $page = pagename($file);
 823         if ($pages->{$page}) {
 824                 return;
 825         }
 826
 827         if (grep { $_ eq $autofile } @$del) {
 828                 return;
 829         }
 830
 831         $autofiles{$autofile}{generator}->();
 832         $pages->{$page}=1;
 833         return 1;
 834 }
 835
 836 sub refresh () {
 837         $phase = PHASE_SCAN;
 838
 839         srcdir_check();
 840         run_hooks(refresh => sub { shift->() });
 841         my ($files, $pages, $new, $internal_new, $del, $internal_del, $changed, $internal_changed);
 842         my $want_find_changes=$config{only_committed_changes} &&
 843                 exists $IkiWiki::hooks{rcs}{rcs_find_changes} &&
 844                 exists $IkiWiki::hooks{rcs}{rcs_get_current_rev};
 845         if (! $config{rebuild} && $want_find_changes && defined $IkiWiki::lastrev && length $IkiWiki::lastrev) {
 846                 my ($changed_raw, $del_raw);
 847                 ($changed_raw, $del_raw, $IkiWiki::lastrev) = $IkiWiki::hooks{rcs}{rcs_find_changes}{call}->($IkiWiki::lastrev);
 848                 ($files, $pages)=process_changed_files($changed_raw, $del_raw);
 849         }
 850         else {
 851                 ($files, $pages)=find_src_files();
 852         }
 853         if ($want_find_changes) {
 854                 if (! defined($IkiWiki::lastrev) || ! length $IkiWiki::lastrev) {
 855                         $IkiWiki::lastrev=$IkiWiki::hooks{rcs}{rcs_get_current_rev}{call}->();
 856                 }
 857         }
 858         ($new, $internal_new)=find_new_files($files);
 859         ($del, $internal_del)=find_del_files($pages);
 860         ($changed, $internal_changed)=find_changed($files);
 861         my %existingfiles;
 862         run_hooks(needsbuild => sub {
 863                 my $ret=shift->($changed, [@$del, @$internal_del]);
 864                 if (ref $ret eq 'ARRAY' && $ret != $changed) {
 865                         if (! %existingfiles) {
 866                                 foreach my $f (@$files) {
 867                                         $existingfiles{$f}=1;
 868                                 }
 869                         }
 870                         @$changed=grep $existingfiles{$_}, @$ret;
 871                 }
 872         });
 873         my $oldlink_targets=calculate_old_links($changed, $del);
 874
 875         foreach my $file (@$changed) {
 876                 scan($file);
 877         }
 878
 879         foreach my $autofile (keys %autofiles) {
 880                 if (gen_autofile($autofile, $pages, $del)) {
 881                         push @{$files}, $autofile;
 882                         push @{$new}, $autofile if find_new_files([$autofile]);
 883                         push @{$changed}, $autofile if find_changed([$autofile]);
 884
 885                         scan($autofile);
 886                 }
 887         }
 888
 889         calculate_links();
 890
 891         # At this point it becomes OK to start matching pagespecs.
 892         $phase = PHASE_RENDER;
 893         # Save some memory in full rebuilds: we no longer need to keep
 894         # track of which pages we've scanned, because we can assume the
 895         # answer is "all of them".
 896         %scanned = () if $config{rebuild};
 897
 898         remove_del(@$del, @$internal_del);
 899
 900         foreach my $file (@$changed) {
 901                 render($file, sprintf(gettext("building %s"), $file));
 902         }
 903         foreach my $file (@$internal_new, @$internal_del, @$internal_changed) {
 904                 derender_internal($file);
 905         }
 906
 907         run_hooks(build_affected => sub {
 908                 my %affected = shift->();
 909                 while (my ($page, $message) = each %affected) {
 910                         next unless exists $pagesources{$page};
 911                         render($pagesources{$page}, $message);
 912                 }
 913         });
 914
 915         my ($backlinkchanged, $linkchangers)=calculate_changed_links($changed,
 916                 $del, $oldlink_targets);
 917
 918         foreach my $file (@$new, @$del) {
 919                 render_linkers($file);
 920         }
 921
 922         if (@$changed || @$internal_changed ||
 923             @$del || @$internal_del || @$internal_new) {
 924                 1 while render_dependent($files, $new, $internal_new,
 925                         $del, $internal_del, $internal_changed,
 926                         $linkchangers);
 927         }
 928
 929         render_backlinks($backlinkchanged);
 930         remove_unrendered();
 931
 932         if (@$del || @$internal_del) {
 933                 run_hooks(delete => sub { shift->(@$del, @$internal_del) });
 934         }
 935         if (%rendered) {
 936                 run_hooks(rendered => sub { shift->(keys %rendered) });
 937                 run_hooks(change => sub { shift->(keys %rendered) }); # back-compat
 938         }
 939         my %all_changed = map { $_ => 1 }
 940                 @$new, @$changed, @$del,
 941                 @$internal_new, @$internal_changed, @$internal_del;
 942         run_hooks(changes => sub { shift->(keys %all_changed) });
 943 }
 944
 945 sub clean_rendered {
 946         lockwiki();
 947         loadindex();
 948         remove_unrendered();
 949         foreach my $page (keys %oldrenderedfiles) {
 950                 foreach my $file (@{$oldrenderedfiles{$page}}) {
 951                         prune($config{destdir}."/".$file, $config{destdir});
 952                 }
 953         }
 954 }
 955
 956 sub commandline_render () {
 957         lockwiki();
 958         loadindex();
 959         unlockwiki();
 960
 961         # This function behaves as though it's in the render phase;
 962         # all other files are assumed to have been scanned last time.
 963         $phase = PHASE_RENDER;
 964
 965         my $srcfile=possibly_foolish_untaint($config{render});
 966         my $file=$srcfile;
 967         $file=~s/\Q$config{srcdir}\E\/?//;
 968
 969         my $type=pagetype($file);
 970         die sprintf(gettext("ikiwiki: cannot build %s"), $srcfile)."\n" unless defined $type;
 971         my $content=readfile($srcfile);
 972         my $page=pagename($file);
 973         $pagesources{$page}=$file;
 974         $content=filter($page, $page, $content);
 975         $content=preprocess($page, $page, $content);
 976         $content=linkify($page, $page, $content);
 977         $content=htmlize($page, $page, $type, $content);
 978         $pagemtime{$page}=(stat($srcfile))[9];
 979         $pagectime{$page}=$pagemtime{$page} if ! exists $pagectime{$page};
 980
 981         print genpage($page, $content);
 982         exit 0;
 983 }
 984
 985 1