IkiWiki/Rcs/tla.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6
   7 package IkiWiki;
   8
   9 sub quiet_system (@) {
  10         # See Debian bug #385939.
  11         open (SAVEOUT, ">&STDOUT");
  12         close STDOUT;
  13         open (STDOUT, ">/dev/null");
  14         my $ret=system(@_);
  15         close STDOUT;
  16         open (STDOUT, ">&SAVEOUT");
  17         close SAVEOUT;
  18         return $ret;
  19 }
  20
  21 sub rcs_update () { #{{{
  22         if (-d "$config{srcdir}/{arch}") {
  23                 if (quiet_system("tla", "replay", "-d", $config{srcdir}) != 0) {
  24                         warn("tla replay failed\n");
  25                 }
  26         }
  27 } #}}}
  28
  29 sub rcs_prepedit ($) { #{{{
  30         my $file=shift;
  31
  32         if (-d "$config{srcdir}/{arch}") {
  33                 # For Arch, return the tree-id of archive when
  34                 # editing begins.
  35                 my $rev=`tla tree-id $config{srcdir}`;
  36                 return defined $rev ? $rev : "";
  37         }
  38 } #}}}
  39
  40 sub rcs_commit ($$$;$$) { #{{{
  41         my $file=shift;
  42         my $message=shift;
  43         my $rcstoken=shift;
  44         my $user=shift;
  45         my $ipaddr=shift;
  46
  47         if (defined $user) {
  48                 $message="web commit by $user".(length $message ? ": $message" : "");
  49         }
  50         elsif (defined $ipaddr) {
  51                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
  52         }
  53
  54         if (-d "$config{srcdir}/{arch}") {
  55                 # Check to see if the page has been changed by someone
  56                 # else since rcs_prepedit was called.
  57                 my ($oldrev)=$rcstoken=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
  58                 my $rev=`tla tree-id $config{srcdir}`;
  59                 if (defined $rev && defined $oldrev && $rev ne $oldrev) {
  60                         # Merge their changes into the file that we've
  61                         # changed.
  62                         if (quiet_system("tla", "update", "-d",
  63                                    "$config{srcdir}") != 0) {
  64                                 warn("tla update failed\n");
  65                         }
  66                 }
  67
  68                 if (quiet_system("tla", "commit",
  69                            "-L".possibly_foolish_untaint($message),
  70                            '-d', $config{srcdir}) != 0) {
  71                         my $conflict=readfile("$config{srcdir}/$file");
  72                         if (system("tla", "undo", "-n", "--quiet", "-d", "$config{srcdir}") != 0) {
  73                                 warn("tla undo failed\n");
  74                         }
  75                         return $conflict;
  76                 }
  77         }
  78         return undef # success
  79 } #}}}
  80
  81 sub rcs_add ($) { #{{{
  82         my $file=shift;
  83
  84         if (-d "$config{srcdir}/{arch}") {
  85                 if (quiet_system("tla", "add", "$config{srcdir}/$file") != 0) {
  86                         warn("tla add failed\n");
  87                 }
  88         }
  89 } #}}}
  90
  91 sub rcs_recentchanges ($) {
  92         my $num=shift;
  93         my @ret;
  94
  95         return unless -d "$config{srcdir}/{arch}";
  96
  97         eval q{use Date::Parse};
  98         error($@) if $@;
  99         eval q{use Mail::Header};
 100         error($@) if $@;
 101
 102         my $logs = `tla logs -d $config{srcdir}`;
 103         my @changesets = reverse split(/\n/, $logs);
 104
 105         for (my $i=0; $i<$num && $i<$#changesets; $i++) {
 106                 my ($change)=$changesets[$i]=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
 107
 108                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 109                 my $head = Mail::Header->new(\*LOG);
 110                 close(LOG);
 111
 112                 my $rev = $head->get("Revision");
 113                 my $summ = $head->get("Summary");
 114                 my $newfiles = $head->get("New-files");
 115                 my $modfiles = $head->get("Modified-files");
 116                 my $remfiles = $head->get("Removed-files");
 117                 my $user = $head->get("Creator");
 118
 119                 my @paths = grep { !/^(.*\/)?\.arch-ids\/.*\.id$/ }
 120                         split(/ /, "$newfiles $modfiles .arch-ids/fake.id");
 121
 122                 my $sdate = $head->get("Standard-date");
 123                 my $when = time - str2time($sdate, 'UTC');
 124
 125                 my $committype = "web";
 126                 if (defined $summ && $summ =~ /$config{web_commit_regexp}/) {
 127                         $user = defined $2 ? "$2" : "$3";
 128                         $summ = $4;
 129                 }
 130                 else {
 131                         $committype="tla";
 132                 }
 133
 134                 my @message;
 135                 push @message, { line => escapeHTML($summ) };
 136
 137                 my @pages;
 138
 139                 foreach my $file (@paths) {
 140                         my $diffurl=$config{diffurl};
 141                         $diffurl=~s/\[\[file\]\]/$file/g;
 142                         $diffurl=~s/\[\[rev\]\]/$change/g;
 143                         push @pages, {
 144                                 page => pagename($file),
 145                                 diffurl => $diffurl,
 146                         } if length $file;
 147                 }
 148                 push @ret, {
 149                         id => $change,
 150                         user => $user,
 151                         committype => $committype,
 152                         when => $when,
 153                         message => [@message],
 154                         pages => [@pages],
 155                 } if @pages;
 156
 157                 last if $i == $num;
 158         }
 159
 160         return @ret;
 161 }
 162
 163 sub rcs_notify () { #{{{
 164         # FIXME: Not set
 165         if (! exists $ENV{ARCH_VERSION}) {
 166                 error("ARCH_VERSION is not set, not running from tla post-commit hook, cannot send notifications");
 167         }
 168         my $rev=int(possibly_foolish_untaint($ENV{REV}));
 169
 170         eval q{use Mail::Header};
 171         error($@) if $@;
 172         open(LOG, $ENV{"ARCH_LOG"});
 173         my $head = Mail::Header->new(\*LOG);
 174         close(LOG);
 175
 176         my $user = $head->get("Creator");
 177
 178         my $newfiles = $head->get("New-files");
 179         my $modfiles = $head->get("Modified-files");
 180         my $remfiles = $head->get("Removed-files");
 181
 182         my @changed_pages = grep { !/(^.*\/)?\.arch-ids\/.*\.id$/ }
 183                 split(/ /, "$newfiles $modfiles $remfiles .arch-ids/fake.id");
 184
 185         require IkiWiki::UserInfo;
 186         send_commit_mails(
 187                 sub {
 188                         my $message = $head->get("Summary");
 189                         if ($message =~ /$config{web_commit_regexp}/) {
 190                                 $user=defined $2 ? "$2" : "$3";
 191                                 $message=$4;
 192                         }
 193                 },
 194                 sub {
 195                         my $logs = `tla logs -d $config{srcdir}`;
 196                         my @changesets = reverse split(/\n/, $logs);
 197                         my $i;
 198
 199                         for($i=0;$i<$#changesets;$i++) {
 200                                 last if $changesets[$i] eq $rev;
 201                         }
 202
 203                         my $revminusone = $changesets[$i+1];
 204                         `tla diff -d $ENV{ARCH_TREE_ROOT} $revminusone`;
 205                 }, $user, @changed_pages);
 206 } #}}}
 207
 208 sub rcs_getctime ($) { #{{{
 209         my $file=shift;
 210         eval q{use Date::Parse};
 211         error($@) if $@;
 212         eval q{use Mail::Header};
 213         error($@) if $@;
 214
 215         my $logs = `tla logs -d $config{srcdir}`;
 216         my @changesets = reverse split(/\n/, $logs);
 217         my $sdate;
 218
 219         for (my $i=0; $i<$#changesets; $i++) {
 220                 my $change = $changesets[$i];
 221
 222                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 223                 my $head = Mail::Header->new(\*LOG);
 224                 close(LOG);
 225
 226                 $sdate = $head->get("Standard-date");
 227                 my $newfiles = $head->get("New-files");
 228
 229                 my ($lastcreation) = grep {/^$file$/} split(/ /, "$newfiles");
 230                 last if defined($lastcreation);
 231         }
 232
 233         my $date=str2time($sdate, 'UTC');
 234         debug("found ctime ".localtime($date)." for $file");
 235         return $date;
 236 } #}}}
 237
 238 1