ikiwiki.in

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3 delete @ENV{qw{IFS CDPATH ENV BASH_ENV}};
   4
   5 package IkiWiki;
   6
   7 use warnings;
   8 use strict;
   9 use lib '.'; # For use in nonstandard directory, munged by Makefile.
  10 use IkiWiki;
  11
  12 sub usage () { #{{{
  13         die gettext("usage: ikiwiki [options] source dest"), "\n";
  14 } #}}}
  15
  16 sub getconfig () { #{{{
  17         if (! exists $ENV{WRAPPED_OPTIONS}) {
  18                 %config=defaultconfig();
  19                 eval q{use Getopt::Long};
  20                 Getopt::Long::Configure('pass_through');
  21                 GetOptions(
  22                         "setup|s=s" => \$config{setup},
  23                         "dumpsetup|s=s" => \$config{dumpsetup},
  24                         "wikiname=s" => \$config{wikiname},
  25                         "verbose|v!" => \$config{verbose},
  26                         "syslog!" => \$config{syslog},
  27                         "rebuild!" => \$config{rebuild},
  28                         "refresh!" => \$config{refresh},
  29                         "post-commit" => \$config{post_commit},
  30                         "render=s" => \$config{render},
  31                         "wrappers!" => \$config{genwrappers},
  32                         "usedirs!" => \$config{usedirs},
  33                         "prefix-directives!" => \$config{prefix_directives},
  34                         "getctime" => \$config{getctime},
  35                         "numbacklinks=i" => \$config{numbacklinks},
  36                         "rcs=s" => \$config{rcs},
  37                         "no-rcs" => sub { $config{rcs}="" },
  38                         "cgi!" => \$config{cgi},
  39                         "discussion!" => \$config{discussion},
  40                         "w3mmode!" => \$config{w3mmode},
  41                         "url=s" => \$config{url},
  42                         "cgiurl=s" => \$config{cgiurl},
  43                         "historyurl=s" => \$config{historyurl},
  44                         "diffurl=s" => \$config{diffurl},
  45                         "svnpath" => \$config{svnpath},
  46                         "adminemail=s" => \$config{adminemail},
  47                         "timeformat=s" => \$config{timeformat},
  48                         "sslcookie!" => \$config{sslcookie},
  49                         "userdir=s" => \$config{userdir},
  50                         "htmlext=s" => \$config{htmlext},
  51                         "libdir=s" => \$config{libdir},
  52                         "exclude=s@" => sub {
  53                                 push @{$config{wiki_file_prune_regexps}}, $_[1];
  54                         },
  55                         "adminuser=s@" => sub {
  56                                 push @{$config{adminuser}}, $_[1]
  57                         },
  58                         "templatedir=s" => sub {
  59                                 $config{templatedir}=possibly_foolish_untaint($_[1])
  60                         },
  61                         "underlaydir=s" => sub {
  62                                 $config{underlaydir}=possibly_foolish_untaint($_[1])
  63                         },
  64                         "wrapper:s" => sub {
  65                                 $config{wrapper}=$_[1] ? possibly_foolish_untaint($_[1]) : "ikiwiki-wrap"
  66                         },
  67                         "wrappermode=i" => sub {
  68                                 $config{wrappermode}=possibly_foolish_untaint($_[1])
  69                         },
  70                         "plugin=s@" => sub {
  71                                 push @{$config{add_plugins}}, $_[1];
  72                         },
  73                         "disable-plugin=s@" => sub {
  74                                 push @{$config{disable_plugins}}, $_[1];
  75                         },
  76                         "set=s" => sub {
  77                                 my ($var, $val)=split('=', $_[1], 2);
  78                                 if (! defined $var || ! defined $val) {
  79                                         die gettext("usage: --set var=value"), "\n";
  80                                 }
  81                                 $config{$var}=$val;
  82                         },
  83                         "version" => sub {
  84                                 print "ikiwiki version $IkiWiki::version\n";
  85                                 exit;
  86                         },
  87                 ) || usage();
  88
  89                 if (! $config{setup} && ! $config{render}) {
  90                         loadplugins();
  91                         usage() unless @ARGV == 2;
  92                         $config{srcdir} = possibly_foolish_untaint(shift @ARGV);
  93                         $config{destdir} = possibly_foolish_untaint(shift @ARGV);
  94                         checkconfig();
  95                 }
  96         }
  97         else {
  98                 # wrapper passes a full config structure in the environment
  99                 # variable
 100                 eval possibly_foolish_untaint($ENV{WRAPPED_OPTIONS});
 101                 if ($@) {
 102                         error("WRAPPED_OPTIONS: $@");
 103                 }
 104                 loadplugins();
 105                 checkconfig();
 106         }
 107 } #}}}
 108
 109 sub main () { #{{{
 110         getconfig();
 111
 112         if ($config{setup}) {
 113                 require IkiWiki::Setup;
 114                 IkiWiki::Setup::load($config{setup});
 115                 if (@{$config{wrappers}} &&
 116                     ! $config{render} && ! $config{dumpsetup} &&
 117                     (! $config{refresh} || $config{genwrappers})) {
 118                         debug(gettext("generating wrappers.."));
 119                         require IkiWiki::Wrapper;
 120                         my %origconfig=(%config);
 121                         my @wrappers=@{$config{wrappers}};
 122                         delete $config{wrappers};
 123                         delete $config{genwrappers};
 124                         foreach my $wrapper (@wrappers) {
 125                                 %config=(%origconfig,
 126                                         rebuild => 0,
 127                                         verbose => 0,
 128                                         %{$wrapper},
 129                                 );
 130                                 checkconfig();
 131                                 if (! $config{cgi} && ! $config{post_commit}) {
 132                                         $config{post_commit}=1;
 133                                 }
 134                                 gen_wrapper();
 135                         }
 136                         %config=(%origconfig);
 137                 }
 138
 139                 # setup implies a wiki rebuild by default
 140                 if (! $config{refresh}) {
 141                         $config{rebuild}=1;
 142                 }
 143
 144                 # ignore syslog setting from setup file
 145                 # while doing initial setup
 146                 $config{syslog}=0 unless $config{dumpsetup};
 147
 148                 loadplugins();
 149                 checkconfig();
 150         }
 151
 152         if ($config{dumpsetup}) {
 153                 require IkiWiki::Setup;
 154                 IkiWiki::Setup::dump($config{dumpsetup});
 155         }
 156         elsif ($config{wrapper}) {
 157                 lockwiki();
 158                 require IkiWiki::Wrapper;
 159                 gen_wrapper();
 160         }
 161         elsif ($config{cgi}) {
 162                 require IkiWiki::CGI;
 163                 eval {cgi()};
 164                 if ($@) {
 165                         cgierror($@);
 166                 }
 167         }
 168         elsif ($config{render}) {
 169                 require IkiWiki::Render;
 170                 commandline_render();
 171         }
 172         elsif ($config{post_commit} && ! commit_hook_enabled()) {
 173                 # do nothing
 174         }
 175         else {
 176                 if (! $config{refresh}) {
 177                         debug(gettext("rebuilding wiki.."));
 178                 }
 179                 else {
 180                         debug(gettext("refreshing wiki.."));
 181                 }
 182                 lockwiki();
 183                 loadindex();
 184                 require IkiWiki::Render;
 185                 rcs_update();
 186                 refresh();
 187                 saveindex();
 188                 debug(gettext("done"));
 189         }
 190 } #}}}
 191
 192 main;