ikiwiki-transition

   1 #!/usr/bin/perl
   2 use warnings;
   3 use strict;
   4 use IkiWiki;
   5 use HTML::Entities;
   6
   7 my $regex = qr{
   8         (\\?)           # 1: escape?
   9         \[\[(!?)        # directive open; 2: optional prefix
  10         ([-\w]+)        # 3: command
  11         (               # 4: the parameters (including initial whitespace)
  12         \s+
  13                 (?:
  14                         (?:[-\w]+=)?            # named parameter key?
  15                         (?:
  16                                 """.*?"""       # triple-quoted value
  17                                 |
  18                                 "[^"]+"         # single-quoted value
  19                                 |
  20                                 [^\s\]]+        # unquoted value
  21                         )
  22                         \s*                     # whitespace or end
  23                                                 # of directive
  24                 )
  25         *)              # 0 or more parameters
  26         \]\]            # directive closed
  27 }sx;
  28
  29 sub handle_directive {
  30         my $escape = shift;
  31         my $prefix = shift;
  32         my $directive = shift;
  33         my $args = shift;
  34
  35         if (length $escape) {
  36                 return "${escape}[[${prefix}${directive}${args}]]"
  37         }
  38         if ($directive =~ m/^(if|more|table|template|toggleable)$/) {
  39                 $args =~ s{$regex}{handle_directive($1, $2, $3, $4)}eg;
  40         }
  41         return "[[!${directive}${args}]]"
  42 }
  43
  44 sub prefix_directives {
  45         loadsetup(shift);
  46
  47         IkiWiki::loadplugins();
  48         IkiWiki::checkconfig();
  49         IkiWiki::loadindex();
  50
  51         if (! %pagesources) {
  52                 error "ikiwiki has not built this wiki yet, cannot transition";
  53         }
  54
  55         foreach my $page (values %pagesources) {
  56                 next unless defined pagetype($page) &&
  57                             -f $config{srcdir}."/".$page;
  58                 my $content=readfile($config{srcdir}."/".$page);
  59                 my $oldcontent=$content;
  60                 $content=~s{$regex}{handle_directive($1, $2, $3, $4)}eg;
  61                 if ($oldcontent ne $content) {
  62                         writefile($page, $config{srcdir}, $content);
  63                 }
  64         }
  65 }
  66
  67 sub indexdb {
  68         setstatedir(shift);
  69
  70         # Note: No lockwiki here because ikiwiki already locks it
  71         # before calling this.
  72         if (! IkiWiki::oldloadindex()) {
  73                 die "failed to load index\n";
  74         }
  75         if (! IkiWiki::saveindex()) {
  76                 die "failed to save indexdb\n"
  77         }
  78         if (! IkiWiki::loadindex()) {
  79                 die "transition failed, cannot load new indexdb\n";
  80         }
  81         if (! unlink("$config{wikistatedir}/index")) {
  82                 die "unlink failed: $!\n";
  83         }
  84 }
  85
  86 sub hashpassword {
  87         setstatedir(shift);
  88
  89         eval q{use IkiWiki::UserInfo};
  90         eval q{use Authen::Passphrase::BlowfishCrypt};
  91         if ($@) {
  92                 error("ikiwiki-transition hashpassword: failed to load Authen::Passphrase, passwords not hashed");
  93         }
  94
  95         IkiWiki::lockwiki();
  96         IkiWiki::loadplugin("passwordauth");
  97         my $userinfo = IkiWiki::userinfo_retrieve();
  98         foreach my $user (keys %{$userinfo}) {
  99                 if (ref $userinfo->{$user} &&
 100                     exists $userinfo->{$user}->{password} &&
 101                     length $userinfo->{$user}->{password} &&
 102                     ! exists $userinfo->{$user}->{cryptpassword}) {
 103                         IkiWiki::Plugin::passwordauth::setpassword($user, $userinfo->{$user}->{password});
 104                 }
 105         }
 106 }
 107
 108 sub aggregateinternal {
 109         loadsetup(shift);
 110         require IkiWiki::Plugin::aggregate;
 111         IkiWiki::checkconfig();
 112         IkiWiki::Plugin::aggregate::migrate_to_internal();
 113 }
 114
 115 sub setupformat {
 116         my $setup=shift;
 117
 118         loadsetup($setup);
 119         IkiWiki::checkconfig();
 120
 121         # unpack old-format wrappers setting into new fields
 122         my $cgi_seen=0;
 123         my $rcs_seen=0;
 124         foreach my $wrapper (@{$config{wrappers}}) {
 125                 if ($wrapper->{cgi}) {
 126                         if ($cgi_seen) {
 127                                 die "don't know what to do with second cgi wrapper ".$wrapper->{wrapper}."\n";
 128                         }
 129                         $cgi_seen++;
 130                         print "setting cgi_wrapper to ".$wrapper->{wrapper}."\n";
 131                         $config{cgi_wrapper}=$wrapper->{wrapper};
 132                         $config{cgi_wrappermode}=$wrapper->{wrappermode}
 133                                 if exists $wrapper->{wrappermode};
 134                 }
 135                 elsif ($config{rcs}) {
 136                         if ($rcs_seen) {
 137                                 die "don't know what to do with second rcs wrapper ".$wrapper->{wrapper}."\n";
 138                         }
 139                         $rcs_seen++;
 140                         print "setting $config{rcs}_wrapper to ".$wrapper->{wrapper}."\n";
 141                         $config{$config{rcs}."_wrapper"}=$wrapper->{wrapper};
 142                         $config{$config{rcs}."_wrappermode"}=$wrapper->{wrappermode}
 143                                 if exists $wrapper->{wrappermode};
 144                 }
 145                 else {
 146                         die "don't know what to do with wrapper ".$wrapper->{wrapper}."\n";
 147                 }
 148         }
 149
 150         IkiWiki::Setup::dump($setup);
 151 }
 152
 153 sub moveprefs {
 154         my $setup=shift;
 155
 156         loadsetup($setup);
 157         IkiWiki::checkconfig();
 158
 159         eval q{use IkiWiki::UserInfo};
 160         error $@ if $@;
 161
 162         foreach my $field (qw{allowed_attachments locked_pages}) {
 163                 my $orig=$config{$field};
 164                 foreach my $admin (@{$config{adminuser}}) {
 165                         my $a=IkiWiki::userinfo_get($admin, $field);
 166                         if (defined $a && length $a &&
 167                             # might already have been moved
 168                             (! defined $orig || $a ne $orig)) {
 169                                 if (defined $config{$field} &&
 170                                     length $config{$field}) {
 171                                         $config{$field}=IkiWiki::pagespec_merge($config{$field}, $a);
 172                                 }
 173                                 else {
 174                                         $config{$field}=$a;
 175                                 }
 176                         }
 177                 }
 178         }
 179
 180         my %banned=map { $_ => 1 } @{$config{banned_users}}, IkiWiki::get_banned_users();
 181         $config{banned_users}=[sort keys %banned];
 182
 183         IkiWiki::Setup::dump($setup);
 184 }
 185
 186 sub deduplinks {
 187         setstatdir(shift);
 188         IkiWiki::loadindex();
 189         foreach my $page (keys %links) {
 190                 my %l;
 191                 $l{$_}=1 foreach @{$links{$page}};
 192                 $links{$page}=[keys %l]
 193         }
 194         IkiWiki::saveindex();
 195 }
 196
 197 sub setstatedir {
 198         my $dirorsetup=shift;
 199
 200         if (! defined $dirorsetup) {
 201                 usage();
 202         }
 203
 204         if (-d $dirorsetup) {
 205                 $config{wikistatedir}=$dirorsetup."/.ikiwiki";
 206         }
 207         elsif (-f $dirorsetup) {
 208                 loadsetup($dirorsetup);
 209         }
 210         else {
 211                 error("ikiwiki-transition: $dirorsetup does not exist");
 212         }
 213
 214         if (! -d $config{wikistatedir}) {
 215                 error("ikiwiki-transition: $config{wikistatedir} does not exist");
 216         }
 217 }
 218
 219 sub loadsetup {
 220         my $setup=shift;
 221         if (! defined $setup) {
 222                 usage();
 223         }
 224
 225         require IkiWiki::Setup;
 226
 227         %config = IkiWiki::defaultconfig();
 228         IkiWiki::Setup::load($setup);
 229 }
 230
 231 sub usage {
 232         print STDERR "Usage: ikiwiki-transition type ...\n";
 233         print STDERR "Currently supported transition subcommands:\n";
 234         print STDERR "\tprefix_directives setupfile ...\n";
 235         print STDERR "\taggregateinternal setupfile\n";
 236         print STDERR "\tsetupformat setupfile\n";
 237         print STDERR "\tmoveprefs setupfile\n";
 238         print STDERR "\thashpassword setupfile|srcdir\n";
 239         print STDERR "\tindexdb setupfile|srcdir\n";
 240         print STDERR "\tdeduplinks setupfile|srcdir\n";
 241         exit 1;
 242 }
 243
 244 usage() unless @ARGV;
 245
 246 my $mode=shift;
 247 if ($mode eq 'prefix_directives') {
 248         prefix_directives(@ARGV);
 249 }
 250 elsif ($mode eq 'hashpassword') {
 251         hashpassword(@ARGV);
 252 }
 253 elsif ($mode eq 'indexdb') {
 254         indexdb(@ARGV);
 255 }
 256 elsif ($mode eq 'aggregateinternal') {
 257         aggregateinternal(@ARGV);
 258 }
 259 elsif ($mode eq 'setupformat') {
 260         setupformat(@ARGV);
 261 }
 262 elsif ($mode eq 'moveprefs') {
 263         moveprefs(@ARGV);
 264 }
 265 elsif ($mode eq 'deduplinks') {
 266         deduplinks(@ARGV);
 267 }
 268 else {
 269         usage();
 270 }
 271
 272 package IkiWiki;
 273
 274 # A slightly modified version of the old loadindex function.
 275 sub oldloadindex {
 276         %oldrenderedfiles=%pagectime=();
 277         if (! $config{rebuild}) {
 278                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
 279                         %destsources=%renderedfiles=%pagecase=%pagestate=();
 280         }
 281         open (my $in, "<", "$config{wikistatedir}/index") || return;
 282         while (<$in>) {
 283                 chomp;
 284                 my %items;
 285                 $items{link}=[];
 286                 $items{dest}=[];
 287                 foreach my $i (split(/ /, $_)) {
 288                         my ($item, $val)=split(/=/, $i, 2);
 289                         push @{$items{$item}}, decode_entities($val);
 290                 }
 291
 292                 next unless exists $items{src}; # skip bad lines for now
 293
 294                 my $page=pagename($items{src}[0]);
 295                 if (! $config{rebuild}) {
 296                         $pagesources{$page}=$items{src}[0];
 297                         $pagemtime{$page}=$items{mtime}[0];
 298                         $oldlinks{$page}=[@{$items{link}}];
 299                         $links{$page}=[@{$items{link}}];
 300                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 301                         $destsources{$_}=$page foreach @{$items{dest}};
 302                         $renderedfiles{$page}=[@{$items{dest}}];
 303                         $pagecase{lc $page}=$page;
 304                         foreach my $k (grep /_/, keys %items) {
 305                                 my ($id, $key)=split(/_/, $k, 2);
 306                                 $pagestate{$page}{decode_entities($id)}{decode_entities($key)}=$items{$k}[0];
 307                         }
 308                 }
 309                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 310                 $pagectime{$page}=$items{ctime}[0];
 311         }
 312
 313         # saveindex relies on %hooks being populated, else it won't save
 314         # the page state owned by a given hook. But no plugins are loaded
 315         # by this program, so populate %hooks with all hook ids that
 316         # currently have page state.
 317         foreach my $page (keys %pagemtime) {
 318                 foreach my $id (keys %{$pagestate{$page}}) {
 319                         $hooks{_dummy}{$id}=1;
 320                 }
 321         }
 322
 323         return close($in);
 324 }
 325
 326 # Used to be in IkiWiki/UserInfo, but only used here now.
 327 sub get_banned_users () {
 328         my @ret;
 329         my $userinfo=userinfo_retrieve();
 330         foreach my $user (keys %{$userinfo}) {
 331                 push @ret, $user if $userinfo->{$user}->{banned};
 332         }
 333         return @ret;
 334 }
 335
 336 1