IkiWiki/Plugin/po.pm

   1 #!/usr/bin/perl
   2 # .po as a wiki page type
   3 # Licensed under GPL v2 or greater
   4 # Copyright (C) 2008 intrigeri <intrigeri@boum.org>
   5 # inspired by the GPL'd po4a-translate,
   6 # which is Copyright 2002, 2003, 2004 by Martin Quinson (mquinson#debian.org)
   7 package IkiWiki::Plugin::po;
   8
   9 use warnings;
  10 use strict;
  11 use IkiWiki 2.00;
  12 use Encode;
  13 use Locale::Po4a::Chooser;
  14 use Locale::Po4a::Po;
  15 use File::Basename;
  16 use File::Copy;
  17 use File::Spec;
  18 use File::Temp;
  19 use Memoize;
  20 use UNIVERSAL;
  21
  22 my %translations;
  23 my @origneedsbuild;
  24 my %origsubs;
  25
  26 memoize("_istranslation");
  27 memoize("percenttranslated");
  28
  29 sub import { #{{{
  30         hook(type => "getsetup", id => "po", call => \&getsetup);
  31         hook(type => "checkconfig", id => "po", call => \&checkconfig);
  32         hook(type => "needsbuild", id => "po", call => \&needsbuild);
  33         hook(type => "scan", id => "po", call => \&scan, last =>1);
  34         hook(type => "filter", id => "po", call => \&filter);
  35         hook(type => "htmlize", id => "po", call => \&htmlize);
  36         hook(type => "pagetemplate", id => "po", call => \&pagetemplate, last => 1);
  37         hook(type => "change", id => "po", call => \&change);
  38         hook(type => "editcontent", id => "po", call => \&editcontent);
  39
  40         $origsubs{'bestlink'}=\&IkiWiki::bestlink;
  41         inject(name => "IkiWiki::bestlink", call => \&mybestlink);
  42         $origsubs{'beautify_urlpath'}=\&IkiWiki::beautify_urlpath;
  43         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
  44         $origsubs{'targetpage'}=\&IkiWiki::targetpage;
  45         inject(name => "IkiWiki::targetpage", call => \&mytargetpage);
  46         $origsubs{'urlto'}=\&IkiWiki::urlto;
  47         inject(name => "IkiWiki::urlto", call => \&myurlto);
  48 } #}}}
  49
  50
  51 # ,----
  52 # | Table of contents
  53 # `----
  54
  55 # 1. Hooks
  56 # 2. Injected functions
  57 # 3. Blackboxes for private data
  58 # 4. Helper functions
  59 # 5. PageSpec's
  60
  61
  62 # ,----
  63 # | Hooks
  64 # `----
  65
  66 sub getsetup () { #{{{
  67         return
  68                 plugin => {
  69                         safe => 0,
  70                         rebuild => 1,
  71                 },
  72                 po_master_language => {
  73                         type => "string",
  74                         example => {
  75                                 'code' => 'en',
  76                                 'name' => 'English'
  77                         },
  78                         description => "master language (non-PO files)",
  79                         safe => 1,
  80                         rebuild => 1,
  81                 },
  82                 po_slave_languages => {
  83                         type => "string",
  84                         example => {
  85                                 'fr' => 'Français',
  86                                 'es' => 'Castellano',
  87                                 'de' => 'Deutsch'
  88                         },
  89                         description => "slave languages (PO files)",
  90                         safe => 1,
  91                         rebuild => 1,
  92                 },
  93                 po_translatable_pages => {
  94                         type => "pagespec",
  95                         example => "!*/Discussion",
  96                         description => "PageSpec controlling which pages are translatable",
  97                         link => "ikiwiki/PageSpec",
  98                         safe => 1,
  99                         rebuild => 1,
 100                 },
 101                 po_link_to => {
 102                         type => "string",
 103                         example => "current",
 104                         description => "internal linking behavior (default/current/negotiated)",
 105                         safe => 1,
 106                         rebuild => 1,
 107                 },
 108 } #}}}
 109
 110 sub checkconfig () { #{{{
 111         foreach my $field (qw{po_master_language po_slave_languages}) {
 112                 if (! exists $config{$field} || ! defined $config{$field}) {
 113                         error(sprintf(gettext("Must specify %s"), $field));
 114                 }
 115         }
 116         if (! (keys %{$config{po_slave_languages}})) {
 117                 error(gettext("At least one slave language must be defined in po_slave_languages"));
 118         }
 119         map {
 120                 islanguagecode($_)
 121                         or error(sprintf(gettext("%s is not a valid language code"), $_));
 122         } ($config{po_master_language}{code}, keys %{$config{po_slave_languages}});
 123         if (! exists $config{po_translatable_pages} ||
 124             ! defined $config{po_translatable_pages}) {
 125                 $config{po_translatable_pages}="";
 126         }
 127         if (! exists $config{po_link_to} ||
 128             ! defined $config{po_link_to}) {
 129                 $config{po_link_to}='default';
 130         }
 131         elsif (! grep {
 132                         $config{po_link_to} eq $_
 133                 } ('default', 'current', 'negotiated')) {
 134                 warn(sprintf(gettext('po_link_to=%s is not a valid setting, falling back to po_link_to=default'),
 135                                 $config{po_link_to}));
 136                 $config{po_link_to}='default';
 137         }
 138         elsif ($config{po_link_to} eq "negotiated" && ! $config{usedirs}) {
 139                 warn(gettext('po_link_to=negotiated requires usedirs to be enabled, falling back to po_link_to=default'));
 140                 $config{po_link_to}='default';
 141         }
 142         push @{$config{wiki_file_prune_regexps}}, qr/\.pot$/;
 143 } #}}}
 144
 145 sub needsbuild () { #{{{
 146         my $needsbuild=shift;
 147
 148         # backup @needsbuild content so that change() can know whether
 149         # a given master page was rendered because its source file was changed
 150         @origneedsbuild=(@$needsbuild);
 151
 152         buildtranslationscache();
 153
 154         # make existing translations depend on the corresponding master page
 155         foreach my $master (keys %translations) {
 156                 map add_depends($_, $master), values %{otherlanguages($master)};
 157         }
 158 } #}}}
 159
 160 # Massage the recorded state of internal links so that:
 161 # - it matches the actually generated links, rather than the links as written
 162 #   in the pages' source
 163 # - backlinks are consistent in all cases
 164 sub scan (@) { #{{{
 165         my %params=@_;
 166         my $page=$params{page};
 167         my $content=$params{content};
 168
 169         return unless UNIVERSAL::can("IkiWiki::Plugin::link", "import");
 170
 171         if (istranslation($page)) {
 172                 foreach my $destpage (@{$links{$page}}) {
 173                         if (istranslatable($destpage)) {
 174                                 # replace one occurence of $destpage in $links{$page}
 175                                 # (we only want to replace the one that was added by
 176                                 # IkiWiki::Plugin::link::scan, other occurences may be
 177                                 # there for other reasons)
 178                                 for (my $i=0; $i<@{$links{$page}}; $i++) {
 179                                         if (@{$links{$page}}[$i] eq $destpage) {
 180                                                 @{$links{$page}}[$i] = $destpage . '.' . lang($page);
 181                                                 last;
 182                                         }
 183                                 }
 184                         }
 185                 }
 186         }
 187         elsif (! istranslatable($page) && ! istranslation($page)) {
 188                 foreach my $destpage (@{$links{$page}}) {
 189                         if (istranslatable($destpage)) {
 190                                 # make sure any destpage's translations has
 191                                 # $page in its backlinks
 192                                 push @{$links{$page}},
 193                                         values %{otherlanguages($destpage)};
 194                         }
 195                 }
 196         }
 197 } #}}}
 198
 199 # We use filter to convert PO to the master page's format,
 200 # since the rest of ikiwiki should not work on PO files.
 201 sub filter (@) { #{{{
 202         my %params = @_;
 203
 204         my $page = $params{page};
 205         my $destpage = $params{destpage};
 206         my $content = decode_utf8(encode_utf8($params{content}));
 207
 208         return $content if ( ! istranslation($page)
 209                              || alreadyfiltered($page, $destpage) );
 210
 211         # CRLF line terminators make poor Locale::Po4a feel bad
 212         $content=~s/\r\n/\n/g;
 213
 214         # Implementation notes
 215         #
 216         # 1. Locale::Po4a reads/writes from/to files, and I'm too lazy
 217         #    to learn how to disguise a variable as a file.
 218         # 2. There are incompatibilities between some File::Temp versions
 219         #    (including 0.18, bundled with Lenny's perl-modules package)
 220         #    and others (e.g. 0.20, previously present in the archive as
 221         #    a standalone package): under certain circumstances, some
 222         #    return a relative filename, whereas others return an absolute one;
 223         #    we here use this module in a way that is at least compatible
 224         #    with 0.18 and 0.20. Beware, hit'n'run refactorers!
 225         my $infile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-in.XXXXXXXXXX",
 226                                     DIR => File::Spec->tmpdir,
 227                                     UNLINK => 1)->filename;
 228         my $outfile = new File::Temp(TEMPLATE => "ikiwiki-po-filter-out.XXXXXXXXXX",
 229                                      DIR => File::Spec->tmpdir,
 230                                      UNLINK => 1)->filename;
 231
 232         writefile(basename($infile), File::Spec->tmpdir, $content);
 233
 234         my $masterfile = srcfile($pagesources{masterpage($page)});
 235         my (@pos,@masters);
 236         push @pos,$infile;
 237         push @masters,$masterfile;
 238         my %options = (
 239                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 240         );
 241         my $doc=Locale::Po4a::Chooser::new('text',%options);
 242         $doc->process(
 243                 'po_in_name'    => \@pos,
 244                 'file_in_name'  => \@masters,
 245                 'file_in_charset'  => 'utf-8',
 246                 'file_out_charset' => 'utf-8',
 247         ) or error("[po/filter:$page]: failed to translate");
 248         $doc->write($outfile) or error("[po/filter:$page] could not write $outfile");
 249         $content = readfile($outfile) or error("[po/filter:$page] could not read $outfile");
 250
 251         # Unlinking should happen automatically, thanks to File::Temp,
 252         # but it does not work here, probably because of the way writefile()
 253         # and Locale::Po4a::write() work.
 254         unlink $infile, $outfile;
 255
 256         setalreadyfiltered($page, $destpage);
 257         return $content;
 258 } #}}}
 259
 260 sub htmlize (@) { #{{{
 261         my %params=@_;
 262
 263         my $page = $params{page};
 264         my $content = $params{content};
 265         my $masterfile = srcfile($pagesources{masterpage($page)});
 266
 267         # force content to be htmlize'd as if it was the same type as the master page
 268         return IkiWiki::htmlize($page, $page, pagetype($masterfile), $content);
 269 } #}}}
 270
 271 sub pagetemplate (@) { #{{{
 272         my %params=@_;
 273         my $page=$params{page};
 274         my $destpage=$params{destpage};
 275         my $template=$params{template};
 276
 277         my ($masterpage, $lang) = istranslation($page);
 278
 279         if (istranslation($page) && $template->query(name => "percenttranslated")) {
 280                 $template->param(percenttranslated => percenttranslated($page));
 281         }
 282         if ($template->query(name => "istranslation")) {
 283                 $template->param(istranslation => scalar istranslation($page));
 284         }
 285         if ($template->query(name => "istranslatable")) {
 286                 $template->param(istranslatable => istranslatable($page));
 287         }
 288         if ($template->query(name => "HOMEPAGEURL")) {
 289                 $template->param(homepageurl => homepageurl($page));
 290         }
 291         if ($template->query(name => "otherlanguages")) {
 292                 $template->param(otherlanguages => [otherlanguagesloop($page)]);
 293                 map add_depends($page, $_), (values %{otherlanguages($page)});
 294         }
 295         # Rely on IkiWiki::Render's genpage() to decide wether
 296         # a discussion link should appear on $page; this is not
 297         # totally accurate, though: some broken links may be generated
 298         # when cgiurl is disabled.
 299         # This compromise avoids some code duplication, and will probably
 300         # prevent future breakage when ikiwiki internals change.
 301         # Known limitations are preferred to future random bugs.
 302         if ($template->param('discussionlink') && istranslation($page)) {
 303                 $template->param('discussionlink' => htmllink(
 304                                                         $page,
 305                                                         $destpage,
 306                                                         $masterpage . '/' . gettext("Discussion"),
 307                                                         noimageinline => 1,
 308                                                         forcesubpage => 0,
 309                                                         linktext => gettext("Discussion"),
 310                                                         ));
 311         }
 312         # Remove broken parentlink to ./index.html on home page's translations.
 313         # It works because this hook has the "last" parameter set, to ensure it
 314         # runs after parentlinks' own pagetemplate hook.
 315         if ($template->param('parentlinks')
 316             && istranslation($page)
 317             && $masterpage eq "index") {
 318                 $template->param('parentlinks' => []);
 319         }
 320 } # }}}
 321
 322 sub change(@) { #{{{
 323         my @rendered=@_;
 324
 325         my $updated_po_files=0;
 326
 327         # Refresh/create POT and PO files as needed.
 328         foreach my $page (map pagename($_), @rendered) {
 329                 next unless istranslatable($page);
 330                 my $file=srcfile($pagesources{$page});
 331                 my $updated_pot_file=0;
 332                 # Only refresh Pot file if it does not exist, or if
 333                 # $pagesources{$page} was changed: don't if only the HTML was
 334                 # refreshed, e.g. because of a dependency.
 335                 if ((grep { $_ eq $pagesources{$page} } @origneedsbuild)
 336                     || ! -e potfile($file)) {
 337                         refreshpot($file);
 338                         $updated_pot_file=1;
 339                 }
 340                 my @pofiles;
 341                 map {
 342                         push @pofiles, $_ if ($updated_pot_file || ! -e $_);
 343                 } (pofiles($file));
 344                 if (@pofiles) {
 345                         refreshpofiles($file, @pofiles);
 346                         map { IkiWiki::rcs_add($_); } @pofiles if ($config{rcs});
 347                         $updated_po_files=1;
 348                 }
 349         }
 350
 351         if ($updated_po_files) {
 352                 # Check staged changes in.
 353                 if ($config{rcs}) {
 354                         IkiWiki::disable_commit_hook();
 355                         IkiWiki::rcs_commit_staged(gettext("updated PO files"),
 356                                 "IkiWiki::Plugin::po::change", "127.0.0.1");
 357                         IkiWiki::enable_commit_hook();
 358                         IkiWiki::rcs_update();
 359                 }
 360                 # Reinitialize module's private variables.
 361                 resetalreadyfiltered();
 362                 resettranslationscache();
 363                 # Trigger a wiki refresh.
 364                 require IkiWiki::Render;
 365                 # without preliminary saveindex/loadindex, refresh()
 366                 # complains about a lot of uninitialized variables
 367                 IkiWiki::saveindex();
 368                 IkiWiki::loadindex();
 369                 IkiWiki::refresh();
 370                 IkiWiki::saveindex();
 371         }
 372 } #}}}
 373
 374 # As we're previewing or saving a page, the content may have
 375 # changed, so tell the next filter() invocation it must not be lazy.
 376 sub editcontent () { #{{{
 377         my %params=@_;
 378
 379         unsetalreadyfiltered($params{page}, $params{page});
 380         return $params{content};
 381 } #}}}
 382
 383
 384 # ,----
 385 # | Injected functions
 386 # `----
 387
 388 # Implement po_link_to 'current' and 'negotiated' settings.
 389 sub mybestlink ($$) { #{{{
 390         my $page=shift;
 391         my $link=shift;
 392
 393         my $res=$origsubs{'bestlink'}->(masterpage($page), $link);
 394         if (length $res
 395             && ($config{po_link_to} eq "current" || $config{po_link_to} eq "negotiated")
 396             && istranslatable($res)
 397             && istranslation($page)) {
 398                 return $res . "." . lang($page);
 399         }
 400         return $res;
 401 } #}}}
 402
 403 sub mybeautify_urlpath ($) { #{{{
 404         my $url=shift;
 405
 406         my $res=$origsubs{'beautify_urlpath'}->($url);
 407         if ($config{po_link_to} eq "negotiated") {
 408                 $res =~ s!/\Qindex.$config{po_master_language}{code}.$config{htmlext}\E$!/!;
 409                 $res =~ s!/\Qindex.$config{htmlext}\E$!/!;
 410                 map {
 411                         $res =~ s!/\Qindex.$_.$config{htmlext}\E$!/!;
 412                 } (keys %{$config{po_slave_languages}});
 413         }
 414         return $res;
 415 } #}}}
 416
 417 sub mytargetpage ($$) { #{{{
 418         my $page=shift;
 419         my $ext=shift;
 420
 421         if (istranslation($page) || istranslatable($page)) {
 422                 my ($masterpage, $lang) = (masterpage($page), lang($page));
 423                 if (! $config{usedirs} || $masterpage eq 'index') {
 424                         return $masterpage . "." . $lang . "." . $ext;
 425                 }
 426                 else {
 427                         return $masterpage . "/index." . $lang . "." . $ext;
 428                 }
 429         }
 430         return $origsubs{'targetpage'}->($page, $ext);
 431 } #}}}
 432
 433 sub myurlto ($$;$) { #{{{
 434         my $to=shift;
 435         my $from=shift;
 436         my $absolute=shift;
 437
 438         # workaround hard-coded /index.$config{htmlext} in IkiWiki::urlto()
 439         if (! length $to
 440             && $config{po_link_to} eq "current"
 441             && istranslatable('index')) {
 442                 return IkiWiki::beautify_urlpath(IkiWiki::baseurl($from) . "index." . lang($from) . ".$config{htmlext}");
 443         }
 444         return $origsubs{'urlto'}->($to,$from,$absolute);
 445 } #}}}
 446
 447
 448 # ,----
 449 # | Blackboxes for private data
 450 # `----
 451
 452 {
 453         my %filtered;
 454
 455         sub alreadyfiltered($$) { #{{{
 456                 my $page=shift;
 457                 my $destpage=shift;
 458
 459                 return ( exists $filtered{$page}{$destpage}
 460                          && $filtered{$page}{$destpage} eq 1 );
 461         } #}}}
 462
 463         sub setalreadyfiltered($$) { #{{{
 464                 my $page=shift;
 465                 my $destpage=shift;
 466
 467                 $filtered{$page}{$destpage}=1;
 468         } #}}}
 469
 470         sub unsetalreadyfiltered($$) { #{{{
 471                 my $page=shift;
 472                 my $destpage=shift;
 473
 474                 if (exists $filtered{$page}{$destpage}) {
 475                         delete $filtered{$page}{$destpage};
 476                 }
 477         } #}}}
 478
 479         sub resetalreadyfiltered() { #{{{
 480                 undef %filtered;
 481         } #}}}
 482 }
 483
 484
 485 # ,----
 486 # | Helper functions
 487 # `----
 488
 489 sub maybe_add_leading_slash ($;$) { #{{{
 490         my $str=shift;
 491         my $add=shift;
 492         $add=1 unless defined $add;
 493         return '/' . $str if $add;
 494         return $str;
 495 } #}}}
 496
 497 sub istranslatable ($) { #{{{
 498         my $page=shift;
 499
 500         $page=~s#^/##;
 501         my $file=$pagesources{$page};
 502
 503         return 0 unless defined $file;
 504         return 0 if (defined pagetype($file) && pagetype($file) eq 'po');
 505         return 0 if $file =~ /\.pot$/;
 506         return pagespec_match($page, $config{po_translatable_pages});
 507 } #}}}
 508
 509 sub _istranslation ($) { #{{{
 510         my $page=shift;
 511
 512         my $hasleadingslash = ($page=~s#^/##);
 513         my $file=$pagesources{$page};
 514         return 0 unless (defined $file
 515                          && defined pagetype($file)
 516                          && pagetype($file) eq 'po');
 517         return 0 if $file =~ /\.pot$/;
 518
 519         my ($masterpage, $lang) = ($page =~ /(.*)[.]([a-z]{2})$/);
 520         return 0 unless (defined $masterpage && defined $lang
 521                          && length $masterpage && length $lang
 522                          && defined $pagesources{$masterpage}
 523                          && defined $config{po_slave_languages}{$lang});
 524
 525         return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 526 } #}}}
 527
 528 sub istranslation ($) { #{{{
 529         my $page=shift;
 530
 531         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 532                 my $hasleadingslash = ($masterpage=~s#^/##);
 533                 $translations{$masterpage}{$lang}=$page unless exists $translations{$masterpage}{$lang};
 534                 return (maybe_add_leading_slash($masterpage, $hasleadingslash), $lang);
 535         }
 536         return;
 537 } #}}}
 538
 539 sub masterpage ($) { #{{{
 540         my $page=shift;
 541
 542         if ( 1 < (my ($masterpage, $lang) = _istranslation($page))) {
 543                 return $masterpage;
 544         }
 545         return $page;
 546 } #}}}
 547
 548 sub lang ($) { #{{{
 549         my $page=shift;
 550
 551         if (1 < (my ($masterpage, $lang) = _istranslation($page))) {
 552                 return $lang;
 553         }
 554         return $config{po_master_language}{code};
 555 } #}}}
 556
 557 sub islanguagecode ($) { #{{{
 558         my $code=shift;
 559
 560         return ($code =~ /^[a-z]{2}$/);
 561 } #}}}
 562
 563 sub otherlanguages($) { #{{{
 564         my $page=shift;
 565
 566         my %ret;
 567         if (istranslatable($page)) {
 568                 %ret = %{$translations{$page}} if defined $translations{$page};
 569         }
 570         elsif (istranslation($page)) {
 571                 my $masterpage = masterpage($page);
 572                 $ret{$config{po_master_language}{code}} = $masterpage;
 573                 foreach my $lang (sort keys %{$translations{$masterpage}}) {
 574                         next if $lang eq lang($page);
 575                         $ret{$lang} = $translations{$masterpage}{$lang};
 576                 }
 577         }
 578         return \%ret;
 579 } #}}}
 580
 581 sub potfile ($) { #{{{
 582         my $masterfile=shift;
 583
 584         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 585         $dir='' if $dir eq './';
 586         return File::Spec->catpath('', $dir, $name . ".pot");
 587 } #}}}
 588
 589 sub pofile ($$) { #{{{
 590         my $masterfile=shift;
 591         my $lang=shift;
 592
 593         (my $name, my $dir, my $suffix) = fileparse($masterfile, qr/\.[^.]*/);
 594         $dir='' if $dir eq './';
 595         return File::Spec->catpath('', $dir, $name . "." . $lang . ".po");
 596 } #}}}
 597
 598 sub pofiles ($) { #{{{
 599         my $masterfile=shift;
 600
 601         return map pofile($masterfile, $_), (keys %{$config{po_slave_languages}});
 602 } #}}}
 603
 604 sub refreshpot ($) { #{{{
 605         my $masterfile=shift;
 606
 607         my $potfile=potfile($masterfile);
 608         my %options = ("markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0);
 609         my $doc=Locale::Po4a::Chooser::new('text',%options);
 610         $doc->{TT}{utf_mode} = 1;
 611         $doc->{TT}{file_in_charset} = 'utf-8';
 612         $doc->{TT}{file_out_charset} = 'utf-8';
 613         $doc->read($masterfile);
 614         # let's cheat a bit to force porefs option to be passed to Locale::Po4a::Po;
 615         # this is undocument use of internal Locale::Po4a::TransTractor's data,
 616         # compulsory since this module prevents us from using the porefs option.
 617         my %po_options = ('porefs' => 'none');
 618         $doc->{TT}{po_out}=Locale::Po4a::Po->new(\%po_options);
 619         $doc->{TT}{po_out}->set_charset('utf-8');
 620         # do the actual work
 621         $doc->parse;
 622         IkiWiki::prep_writefile(basename($potfile),dirname($potfile));
 623         $doc->writepo($potfile);
 624 } #}}}
 625
 626 sub refreshpofiles ($@) { #{{{
 627         my $masterfile=shift;
 628         my @pofiles=@_;
 629
 630         my $potfile=potfile($masterfile);
 631         error("[po/refreshpofiles] POT file ($potfile) does not exist") unless (-e $potfile);
 632
 633         foreach my $pofile (@pofiles) {
 634                 IkiWiki::prep_writefile(basename($pofile),dirname($pofile));
 635                 if (-e $pofile) {
 636                         system("msgmerge", "-U", "--backup=none", $pofile, $potfile) == 0
 637                                 or error("[po/refreshpofiles:$pofile] failed to update");
 638                 }
 639                 else {
 640                         File::Copy::syscopy($potfile,$pofile)
 641                                 or error("[po/refreshpofiles:$pofile] failed to copy the POT file");
 642                 }
 643         }
 644 } #}}}
 645
 646 sub buildtranslationscache() { #{{{
 647         # use istranslation's side-effect
 648         map istranslation($_), (keys %pagesources);
 649 } #}}}
 650
 651 sub resettranslationscache() { #{{{
 652         undef %translations;
 653 } #}}}
 654
 655 sub urlto_with_orig_beautiful_urlpath($$) { #{{{
 656         my $to=shift;
 657         my $from=shift;
 658
 659         inject(name => "IkiWiki::beautify_urlpath", call => $origsubs{'beautify_urlpath'});
 660         my $res=urlto($to, $from);
 661         inject(name => "IkiWiki::beautify_urlpath", call => \&mybeautify_urlpath);
 662
 663         return $res;
 664 } #}}}
 665
 666 sub percenttranslated ($) { #{{{
 667         my $page=shift;
 668
 669         return gettext("N/A") unless istranslation($page);
 670         my $file=srcfile($pagesources{$page});
 671         my $masterfile = srcfile($pagesources{masterpage($page)});
 672         my (@pos,@masters);
 673         push @pos,$file;
 674         push @masters,$masterfile;
 675         my %options = (
 676                 "markdown" => (pagetype($masterfile) eq 'mdwn') ? 1 : 0,
 677         );
 678         my $doc=Locale::Po4a::Chooser::new('text',%options);
 679         $doc->process(
 680                 'po_in_name'    => \@pos,
 681                 'file_in_name'  => \@masters,
 682                 'file_in_charset'  => 'utf-8',
 683                 'file_out_charset' => 'utf-8',
 684         ) or error("[po/percenttranslated:$page]: failed to translate");
 685         my ($percent,$hit,$queries) = $doc->stats();
 686         return $percent;
 687 } #}}}
 688
 689 sub languagename ($) { #{{{
 690         my $code=shift;
 691
 692         return $config{po_master_language}{name}
 693                 if $code eq $config{po_master_language}{code};
 694         return $config{po_slave_languages}{$code}
 695                 if defined $config{po_slave_languages}{$code};
 696         return;
 697 } #}}}
 698
 699 sub otherlanguagesloop ($) { #{{{
 700         my $page=shift;
 701
 702         my @ret;
 703         my %otherpages=%{otherlanguages($page)};
 704         while (my ($lang, $otherpage) = each %otherpages) {
 705                 if (istranslation($page) && masterpage($page) eq $otherpage) {
 706                         push @ret, {
 707                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 708                                 code => $lang,
 709                                 language => languagename($lang),
 710                                 master => 1,
 711                         };
 712                 }
 713                 else {
 714                         push @ret, {
 715                                 url => urlto_with_orig_beautiful_urlpath($otherpage, $page),
 716                                 code => $lang,
 717                                 language => languagename($lang),
 718                                 percent => percenttranslated($otherpage),
 719                         }
 720                 }
 721         }
 722         return sort {
 723                         return -1 if $a->{code} eq $config{po_master_language}{code};
 724                         return 1 if $b->{code} eq $config{po_master_language}{code};
 725                         return $a->{language} cmp $b->{language};
 726                 } @ret;
 727 } #}}}
 728
 729 sub homepageurl (;$) { #{{{
 730         my $page=shift;
 731
 732         return urlto('', $page);
 733 } #}}}
 734
 735 # ,----
 736 # | PageSpec's
 737 # `----
 738
 739 package IkiWiki::PageSpec;
 740 use warnings;
 741 use strict;
 742 use IkiWiki 2.00;
 743
 744 sub match_istranslation ($;@) { #{{{
 745         my $page=shift;
 746
 747         if (IkiWiki::Plugin::po::istranslation($page)) {
 748                 return IkiWiki::SuccessReason->new("is a translation page");
 749         }
 750         else {
 751                 return IkiWiki::FailReason->new("is not a translation page");
 752         }
 753 } #}}}
 754
 755 sub match_istranslatable ($;@) { #{{{
 756         my $page=shift;
 757
 758         if (IkiWiki::Plugin::po::istranslatable($page)) {
 759                 return IkiWiki::SuccessReason->new("is set as translatable in po_translatable_pages");
 760         }
 761         else {
 762                 return IkiWiki::FailReason->new("is not set as translatable in po_translatable_pages");
 763         }
 764 } #}}}
 765
 766 sub match_lang ($$;@) { #{{{
 767         my $page=shift;
 768         my $wanted=shift;
 769
 770         my $regexp=IkiWiki::glob2re($wanted);
 771         my $lang=IkiWiki::Plugin::po::lang($page);
 772         if ($lang!~/^$regexp$/i) {
 773                 return IkiWiki::FailReason->new("file language is $lang, not $wanted");
 774         }
 775         else {
 776                 return IkiWiki::SuccessReason->new("file language is $wanted");
 777         }
 778 } #}}}
 779
 780 sub match_currentlang ($$;@) { #{{{
 781         my $page=shift;
 782         shift;
 783         my %params=@_;
 784
 785         return IkiWiki::FailReason->new("no location provided") unless exists $params{location};
 786
 787         my $currentlang=IkiWiki::Plugin::po::lang($params{location});
 788         my $lang=IkiWiki::Plugin::po::lang($page);
 789
 790         if ($lang eq $currentlang) {
 791                 return IkiWiki::SuccessReason->new("file language is the same as current one, i.e. $currentlang");
 792         }
 793         else {
 794                 return IkiWiki::FailReason->new("file language is $lang, whereas current language is $currentlang");
 795         }
 796 } #}}}
 797
 798 1