IkiWiki/Rcs/git.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki;
   8 use Encode;
   9 use open qw{:utf8 :std};
  10
  11 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  12 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  13
  14 sub _safe_git (&@) { #{{{
  15         # Start a child process safely without resorting /bin/sh.
  16         # Return command output or success state (in scalar context).
  17
  18         my ($error_handler, @cmdline) = @_;
  19
  20         my $pid = open my $OUT, "-|";
  21
  22         error("Cannot fork: $!") if !defined $pid;
  23
  24         if (!$pid) {
  25                 # In child.
  26                 # Git commands want to be in wc.
  27                 chdir $config{srcdir}
  28                     or error("Cannot chdir to $config{srcdir}: $!");
  29                 exec @cmdline or error("Cannot exec '@cmdline': $!");
  30         }
  31         # In parent.
  32
  33         my @lines;
  34         while (<$OUT>) {
  35                 chomp;
  36                 push @lines, $_;
  37         }
  38
  39         close $OUT;
  40
  41         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
  42
  43         return wantarray ? @lines : ($? == 0);
  44 }
  45 # Convenient wrappers.
  46 sub run_or_die ($@) { _safe_git(\&error, @_) }
  47 sub run_or_cry ($@) { _safe_git(sub { warn @_ },  @_) }
  48 sub run_or_non ($@) { _safe_git(undef,            @_) }
  49 #}}}
  50
  51 sub _merge_past ($$$) { #{{{
  52         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
  53         # Git merge commands work with the committed changes, except in the
  54         # implicit case of '-m' of git checkout(1).  So we should invent a
  55         # kludge here.  In principle, we need to create a throw-away branch
  56         # in preparing for the merge itself.  Since branches are cheap (and
  57         # branching is fast), this shouldn't cost high.
  58         #
  59         # The main problem is the presence of _uncommitted_ local changes.  One
  60         # possible approach to get rid of this situation could be that we first
  61         # make a temporary commit in the master branch and later restore the
  62         # initial state (this is possible since Git has the ability to undo a
  63         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
  64         # as follows:
  65         #
  66         #       - create a diff of HEAD:current-sha1
  67         #       - dummy commit
  68         #       - create a dummy branch and switch to it
  69         #       - rewind to past (reset --hard to the current-sha1)
  70         #       - apply the diff and commit
  71         #       - switch to master and do the merge with the dummy branch
  72         #       - make a soft reset (undo the last commit of master)
  73         #
  74         # The above method has some drawbacks: (1) it needs a redundant commit
  75         # just to get rid of local changes, (2) somewhat slow because of the
  76         # required system forks.  Until someone points a more straight method
  77         # (which I would be grateful) I have implemented an alternative method.
  78         # In this approach, we hide all the modified files from Git by renaming
  79         # them (using the 'rename' builtin) and later restore those files in
  80         # the throw-away branch (that is, we put the files themselves instead
  81         # of applying a patch).
  82
  83         my ($sha1, $file, $message) = @_;
  84
  85         my @undo;      # undo stack for cleanup in case of an error
  86         my $conflict;  # file content with conflict markers
  87
  88         eval {
  89                 # Hide local changes from Git by renaming the modified file.
  90                 # Relative paths must be converted to absolute for renaming.
  91                 my ($target, $hidden) = (
  92                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
  93                 );
  94                 rename($target, $hidden)
  95                     or error("rename '$target' to '$hidden' failed: $!");
  96                 # Ensure to restore the renamed file on error.
  97                 push @undo, sub {
  98                         return if ! -e "$hidden"; # already renamed
  99                         rename($hidden, $target)
 100                             or warn "rename '$hidden' to '$target' failed: $!";
 101                 };
 102
 103                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 104
 105                 # Create a throw-away branch and rewind backward.
 106                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 107                 run_or_die('git', 'branch', $branch, $sha1);
 108
 109                 # Switch to throw-away branch for the merge operation.
 110                 push @undo, sub {
 111                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 112                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 113                         }
 114                 };
 115                 run_or_die('git', 'checkout', $branch);
 116
 117                 # Put the modified file in _this_ branch.
 118                 rename($hidden, $target)
 119                     or error("rename '$hidden' to '$target' failed: $!");
 120
 121                 # _Silently_ commit all modifications in the current branch.
 122                 run_or_non('git', 'commit', '-m', $message, '-a');
 123                 # ... and re-switch to master.
 124                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 125
 126                 # Attempt to merge without complaining.
 127                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 128                         $conflict = readfile($target);
 129                         run_or_die('git', 'reset', '--hard');
 130                 }
 131         };
 132         my $failure = $@;
 133
 134         # Process undo stack (in reverse order).  By policy cleanup
 135         # actions should normally print a warning on failure.
 136         while (my $handle = pop @undo) {
 137                 $handle->();
 138         }
 139
 140         error("Git merge failed!\n$failure\n") if $failure;
 141
 142         return $conflict;
 143 } #}}}
 144
 145 sub _parse_diff_tree ($@) { #{{{
 146         # Parse the raw diff tree chunk and return the info hash.
 147         # See git-diff-tree(1) for the syntax.
 148
 149         my ($prefix, $dt_ref) = @_;
 150
 151         # End of stream?
 152         return if !defined @{ $dt_ref } ||
 153                   !defined @{ $dt_ref }[0] || !length @{ $dt_ref }[0];
 154
 155         my %ci;
 156         # Header line.
 157         while (my $line = shift @{ $dt_ref }) {
 158                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 159
 160                 my $sha1 = $2;
 161                 $ci{'sha1'} = $sha1;
 162                 last;
 163         }
 164
 165         # Identification lines for the commit.
 166         while (my $line = shift @{ $dt_ref }) {
 167                 # Regexps are semi-stolen from gitweb.cgi.
 168                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 169                         $ci{'tree'} = $1;
 170                 }
 171                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 172                         # XXX: collecting in reverse order
 173                         push @{ $ci{'parents'} }, $1;
 174                 }
 175                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 176                         my ($who, $name, $epoch, $tz) =
 177                            ($1,   $2,    $3,     $4 );
 178
 179                         $ci{  $who          } = $name;
 180                         $ci{ "${who}_epoch" } = $epoch;
 181                         $ci{ "${who}_tz"    } = $tz;
 182
 183                         if ($name =~ m/^[^<]+\s+<([^@>]+)/) {
 184                                 $ci{"${who}_username"} = $1;
 185                         }
 186                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 187                                 $ci{"${who}_username"} = $1;
 188                         }
 189                         else {
 190                                 $ci{"${who}_username"} = $name;
 191                         }
 192                 }
 193                 elsif ($line =~ m/^$/) {
 194                         # Trailing empty line signals next section.
 195                         last;
 196                 }
 197         }
 198
 199         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 200
 201         if (defined $ci{'parents'}) {
 202                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 203         }
 204         else {
 205                 $ci{'parent'} = 0 x 40;
 206         }
 207
 208         # Commit message.
 209         while (my $line = shift @{ $dt_ref }) {
 210                 if ($line =~ m/^$/) {
 211                         # Trailing empty line signals next section.
 212                         last;
 213                 };
 214                 $line =~ s/^    //;
 215                 push @{ $ci{'comment'} }, $line;
 216         }
 217
 218         # Modified files.
 219         while (my $line = shift @{ $dt_ref }) {
 220                 if ($line =~ m{^
 221                         (:+)       # number of parents
 222                         ([^\t]+)\t # modes, sha1, status
 223                         (.*)       # file names
 224                 $}xo) {
 225                         my $num_parents = length $1;
 226                         my @tmp = split(" ", $2);
 227                         my ($file, $file_to) = split("\t", $3);
 228                         my @mode_from = splice(@tmp, 0, $num_parents);
 229                         my $mode_to = shift(@tmp);
 230                         my @sha1_from = splice(@tmp, 0, $num_parents);
 231                         my $sha1_to = shift(@tmp);
 232                         my $status = shift(@tmp);
 233
 234                         if ($file =~ m/^"(.*)"$/) {
 235                                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 236                         }
 237                         $file =~ s/^\Q$prefix\E//;
 238                         if (length $file) {
 239                                 push @{ $ci{'details'} }, {
 240                                         'file'      => decode_utf8($file),
 241                                         'sha1_from' => $sha1_from[0],
 242                                         'sha1_to'   => $sha1_to,
 243                                 };
 244                         }
 245                         next;
 246                 };
 247                 last;
 248         }
 249
 250         return \%ci;
 251 } #}}}
 252
 253 sub git_commit_info ($;$) { #{{{
 254         # Return an array of commit info hashes of num commits (default: 1)
 255         # starting from the given sha1sum.
 256
 257         my ($sha1, $num) = @_;
 258
 259         $num ||= 1;
 260
 261         my @raw_lines = run_or_die('git', 'log', "--max-count=$num",
 262                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 263                 '-r', $sha1, '--', '.');
 264         my ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 265
 266         my @ci;
 267         while (my $parsed = _parse_diff_tree(($prefix or ""), \@raw_lines)) {
 268                 push @ci, $parsed;
 269         }
 270
 271         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 272
 273         return wantarray ? @ci : $ci[0];
 274 } #}}}
 275
 276 sub git_sha1 (;$) { #{{{
 277         # Return head sha1sum (of given file).
 278
 279         my $file = shift || q{--};
 280
 281         # Ignore error since a non-existing file might be given.
 282         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 283                 '--', $file);
 284         if ($sha1) {
 285                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 286         } else { debug("Empty sha1sum for '$file'.") }
 287         return defined $sha1 ? $sha1 : q{};
 288 } #}}}
 289
 290 sub rcs_update () { #{{{
 291         # Update working directory.
 292
 293         if (length $config{gitorigin_branch}) {
 294                 run_or_cry('git', 'pull', $config{gitorigin_branch});
 295         }
 296 } #}}}
 297
 298 sub rcs_prepedit ($) { #{{{
 299         # Return the commit sha1sum of the file when editing begins.
 300         # This will be later used in rcs_commit if a merge is required.
 301
 302         my ($file) = @_;
 303
 304         return git_sha1($file);
 305 } #}}}
 306
 307 sub rcs_commit ($$$;$$) { #{{{
 308         # Try to commit the page; returns undef on _success_ and
 309         # a version of the page with the rcs's conflict markers on
 310         # failure.
 311
 312         my ($file, $message, $rcstoken, $user, $ipaddr) = @_;
 313
 314         # Check to see if the page has been changed by someone else since
 315         # rcs_prepedit was called.
 316         my $cur    = git_sha1($file);
 317         my ($prev) = $rcstoken =~ /^($sha1_pattern)$/; # untaint
 318
 319         if (defined $cur && defined $prev && $cur ne $prev) {
 320                 my $conflict = _merge_past($prev, $file, $dummy_commit_msg);
 321                 return $conflict if defined $conflict;
 322         }
 323
 324         # Set the commit author to the web committer.
 325         my %env=%ENV;
 326         if (defined $user || defined $ipaddr) {
 327                 $ENV{GIT_AUTHOR_NAME}=defined $user ? $user : $ipaddr;
 328                 $ENV{GIT_AUTHOR_EMAIL}="";
 329                 $message.="\n\nWeb-commit: true\n";
 330         }
 331
 332         # git commit returns non-zero if file has not been really changed.
 333         # so we should ignore its exit status (hence run_or_non).
 334         $message = possibly_foolish_untaint($message);
 335         if (run_or_non('git', 'commit', '-q', '-m', $message, '-i', $file)) {
 336                 if (length $config{gitorigin_branch}) {
 337                         run_or_cry('git', 'push', $config{gitorigin_branch});
 338                 }
 339         }
 340
 341         %ENV=%env;
 342         return undef; # success
 343 } #}}}
 344
 345 sub rcs_add ($) { # {{{
 346         # Add file to archive.
 347
 348         my ($file) = @_;
 349
 350         run_or_cry('git', 'add', $file);
 351 } #}}}
 352
 353 sub rcs_recentchanges ($) { #{{{
 354         # List of recent changes.
 355
 356         my ($num) = @_;
 357
 358         eval q{use Date::Parse};
 359         error($@) if $@;
 360
 361         my @rets;
 362         foreach my $ci (git_commit_info('HEAD', $num)) {
 363                 # Skip redundant commits.
 364                 next if (@{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 365
 366                 my ($sha1, $when) = (
 367                         $ci->{'sha1'},
 368                         $ci->{'author_epoch'}
 369                 );
 370
 371                 my @pages;
 372                 foreach my $detail (@{ $ci->{'details'} }) {
 373                         my $file = $detail->{'file'};
 374
 375                         my $diffurl = $config{'diffurl'};
 376                         $diffurl =~ s/\[\[file\]\]/$file/go;
 377                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 378                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 379                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 380
 381                         push @pages, {
 382                                 page => pagename($file),
 383                                 diffurl => $diffurl,
 384                         };
 385                 }
 386
 387                 my $web_commit=0;
 388                 my @messages;
 389                 my $pastblank=0;
 390                 foreach my $line (@{$ci->{'comment'}}) {
 391                         $pastblank=1 if $line eq '';
 392                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 393                         if ($pastblank && $line=~m/^ *web-commit: true$/i) {
 394                                 $web_commit=1;
 395                                 next;
 396                         }
 397                         push @messages, { line => $line };
 398                 }
 399
 400                 my $user;
 401                 # compatability code for old web commit messages
 402                 if (! $web_commit && defined $messages[0] &&
 403                     $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 404                         $user = defined $2 ? "$2" : "$3";
 405                         $messages[0]->{line} = $4;
 406                 }
 407                 else {
 408                         $user = $ci->{'author_username'};
 409                 }
 410
 411                 push @rets, {
 412                         rev        => $sha1,
 413                         user       => $user,
 414                         committype => $web_commit ? "web" : "git",
 415                         when       => $when,
 416                         message    => [@messages],
 417                         pages      => [@pages],
 418                 } if @pages;
 419
 420                 last if @rets >= $num;
 421         }
 422
 423         return @rets;
 424 } #}}}
 425
 426 sub rcs_diff ($) { #{{{
 427         my $rev=shift;
 428         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 429         my @lines;
 430         foreach my $line (run_or_non("git", "show", $sha1)) {
 431                 if (@lines || $line=~/^diff --git/) {
 432                         push @lines, $line."\n";
 433                 }
 434         }
 435         if (wantarray) {
 436                 return @lines;
 437         }
 438         else {
 439                 return join("", @lines);
 440         }
 441 } #}}}
 442
 443 sub rcs_getctime ($) { #{{{
 444         my $file=shift;
 445         # Remove srcdir prefix
 446         $file =~ s/^\Q$config{srcdir}\E\/?//;
 447
 448         my $sha1  = git_sha1($file);
 449         my $ci    = git_commit_info($sha1);
 450         my $ctime = $ci->{'author_epoch'};
 451         debug("ctime for '$file': ". localtime($ctime));
 452
 453         return $ctime;
 454 } #}}}
 455
 456 1