IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                         section => "widget",
  23                 },
  24 }
  25
  26 sub preprocess (@) {
  27         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  28         my %params=@_;
  29
  30         if (! defined $image) {
  31                 error("bad image filename");
  32         }
  33
  34         if (exists $imgdefaults{$params{page}}) {
  35                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  36                         if (! exists $params{$key}) {
  37                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  38                         }
  39                 }
  40         }
  41
  42         if (! exists $params{size}) {
  43                 $params{size}='full';
  44         }
  45
  46         if ($image eq 'defaults') {
  47                 $imgdefaults{$params{page}} = \%params;
  48                 return '';
  49         }
  50
  51         add_link($params{page}, $image);
  52         add_depends($params{page}, $image);
  53
  54         # optimisation: detect scan mode, and avoid generating the image
  55         if (! defined wantarray) {
  56                 return;
  57         }
  58
  59         my $file = bestlink($params{page}, $image);
  60         my $srcfile = srcfile($file, 1);
  61         if (! length $file || ! defined $srcfile) {
  62                 return htmllink($params{page}, $params{destpage}, $image);
  63         }
  64
  65         my $dir = $params{page};
  66         my $base = IkiWiki::basename($file);
  67
  68         eval q{use Image::Magick};
  69         error gettext("Image::Magick is not installed") if $@;
  70         my $im = Image::Magick->new;
  71         my $imglink;
  72         my $r = $im->Read($srcfile);
  73         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
  74
  75         my ($dwidth, $dheight);
  76
  77         if ($params{size} ne 'full') {
  78                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
  79                 error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
  80                         unless (defined $w && defined $h &&
  81                                 (length $w || length $h));
  82
  83                 if ((length $w && $w > $im->Get("width")) ||
  84                     (length $h && $h > $im->Get("height"))) {
  85                         # resizing larger
  86                         $imglink = $file;
  87
  88                         # don't generate larger image, just set display size
  89                         if (length $w && length $h) {
  90                                 ($dwidth, $dheight)=($w, $h);
  91                         }
  92                         # avoid division by zero on 0x0 image
  93                         elsif ($im->Get("width") == 0 || $im->Get("height") == 0) {
  94                                 ($dwidth, $dheight)=(0, 0);
  95                         }
  96                         # calculate unspecified size from the other one, preserving
  97                         # aspect ratio
  98                         elsif (length $w) {
  99                                 $dwidth=$w;
 100                                 $dheight=$w / $im->Get("width") * $im->Get("height");
 101                         }
 102                         elsif (length $h) {
 103                                 $dheight=$h;
 104                                 $dwidth=$h / $im->Get("height") * $im->Get("width");
 105                         }
 106                 }
 107                 else {
 108                         # resizing smaller
 109                         my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
 110                         $imglink = "$dir/${w}x${h}-$base";
 111
 112                         will_render($params{page}, $imglink);
 113
 114                         if (-e $outfile && (-M $srcfile >= -M $outfile)) {
 115                                 $im = Image::Magick->new;
 116                                 $r = $im->Read($outfile);
 117                                 error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
 118
 119                                 $dwidth = $im->Get("width");
 120                                 $dheight = $im->Get("height");
 121                         }
 122                         else {
 123                                 ($dwidth, $dheight)=($w, $h);
 124                                 $r = $im->Resize(geometry => "${w}x${h}");
 125                                 error sprintf(gettext("failed to resize: %s"), $r) if $r;
 126
 127                                 # don't actually write file in preview mode
 128                                 if (! $params{preview}) {
 129                                         my @blob = $im->ImageToBlob();
 130                                         writefile($imglink, $config{destdir}, $blob[0], 1);
 131                                 }
 132                                 else {
 133                                         $imglink = $file;
 134                                 }
 135                         }
 136                 }
 137         }
 138         else {
 139                 $imglink = $file;
 140                 $dwidth = $im->Get("width");
 141                 $dheight = $im->Get("height");
 142         }
 143
 144         if (! defined($dwidth) || ! defined($dheight)) {
 145                 error sprintf(gettext("failed to determine size of image %s"), $file)
 146         }
 147
 148         my ($fileurl, $imgurl);
 149         if (! $params{preview}) {
 150                 $fileurl=urlto($file, $params{destpage});
 151                 $imgurl=urlto($imglink, $params{destpage});
 152         }
 153         else {
 154                 $fileurl="$config{url}/$file";
 155                 $imgurl="$config{url}/$imglink";
 156         }
 157
 158         my $imgtag='<img src="'.$imgurl.
 159                 '" width="'.$dwidth.
 160                 '" height="'.$dheight.'"'.
 161                 (exists $params{alt} ? ' alt="'.$params{alt}.'"' : '').
 162                 (exists $params{title} ? ' title="'.$params{title}.'"' : '').
 163                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 164                 (exists $params{align} && ! exists $params{caption} ? ' align="'.$params{align}.'"' : '').
 165                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 166                 ' />';
 167
 168         my $link;
 169         if (! defined $params{link}) {
 170                 $link=$fileurl;
 171         }
 172         elsif ($params{link} =~ /^\w+:\/\//) {
 173                 $link=$params{link};
 174         }
 175
 176         if (defined $link) {
 177                 $imgtag='<a href="'.$link.'">'.$imgtag.'</a>';
 178         }
 179         else {
 180                 my $b = bestlink($params{page}, $params{link});
 181
 182                 if (length $b) {
 183                         add_depends($params{page}, $b, deptype("presence"));
 184                         $imgtag=htmllink($params{page}, $params{destpage},
 185                                 $params{link}, linktext => $imgtag,
 186                                 noimageinline => 1,
 187                         );
 188                 }
 189         }
 190
 191         if (exists $params{caption}) {
 192                 return '<table class="img'.
 193                         (exists $params{align} ? " align-$params{align}" : "").
 194                         '">'.
 195                         '<caption>'.$params{caption}.'</caption>'.
 196                         '<tr><td>'.$imgtag.'</td></tr>'.
 197                         '</table>';
 198         }
 199         else {
 200                 return $imgtag;
 201         }
 202 }
 203
 204 1