IkiWiki/Plugin/tla.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::tla;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7
   8 sub import {
   9         hook(type => "checkconfig", id => "tla", call => \&checkconfig);
  10         hook(type => "getsetup", id => "tla", call => \&getsetup);
  11         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  12         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  13         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  14         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  15         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  16         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  17         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  18         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  19         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  20         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  21 }
  22
  23 sub checkconfig () {
  24         if (defined $config{tla_wrapper} && length $config{tla_wrapper}) {
  25                 push @{$config{wrappers}}, {
  26                         wrapper => $config{tla_wrapper},
  27                         wrappermode => (defined $config{tla_wrappermode} ? $config{tla_wrappermode} : "06755"),
  28                 };
  29         }
  30 }
  31
  32 sub getsetup () {
  33         return
  34                 plugin => {
  35                         safe => 0, # rcs plugin
  36                         rebuild => undef,
  37                         section => "rcs",
  38                 },
  39                 tla_wrapper => {
  40                         type => "string",
  41                         #example => "", # TODO example
  42                         description => "tla post-commit hook to generate",
  43                         safe => 0, # file
  44                         rebuild => 0,
  45                 },
  46                 tla_wrappermode => {
  47                         type => "string",
  48                         example => '06755',
  49                         description => "mode for tla_wrapper (can safely be made suid)",
  50                         safe => 0,
  51                         rebuild => 0,
  52                 },
  53                 historyurl => {
  54                         type => "string",
  55                         #example => "", # TODO example
  56                         description => "url to show file history ([[file]] substituted)",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 diffurl => {
  61                         type => "string",
  62                         #example => "", # TODO example
  63                         description => "url to show a diff ([[file]] and [[rev]] substituted)",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67 }
  68
  69 sub quiet_system (@) {
  70         # See Debian bug #385939.
  71         open (SAVEOUT, ">&STDOUT");
  72         close STDOUT;
  73         open (STDOUT, ">/dev/null");
  74         my $ret=system(@_);
  75         close STDOUT;
  76         open (STDOUT, ">&SAVEOUT");
  77         close SAVEOUT;
  78         return $ret;
  79 }
  80
  81 sub rcs_update () {
  82         if (-d "$config{srcdir}/{arch}") {
  83                 if (quiet_system("tla", "replay", "-d", $config{srcdir}) != 0) {
  84                         warn("tla replay failed\n");
  85                 }
  86         }
  87 }
  88
  89 sub rcs_prepedit ($) {
  90         my $file=shift;
  91
  92         if (-d "$config{srcdir}/{arch}") {
  93                 # For Arch, return the tree-id of archive when
  94                 # editing begins.
  95                 my $rev=`tla tree-id $config{srcdir}`;
  96                 return defined $rev ? $rev : "";
  97         }
  98 }
  99
 100 sub rcs_commit ($$$;$$) {
 101         my $file=shift;
 102         my $message=shift;
 103         my $rcstoken=shift;
 104         my $user=shift;
 105         my $ipaddr=shift;
 106
 107         if (defined $user) {
 108                 $message="web commit by $user".(length $message ? ": $message" : "");
 109         }
 110         elsif (defined $ipaddr) {
 111                 $message="web commit from $ipaddr".(length $message ? ": $message" : "");
 112         }
 113
 114         if (-d "$config{srcdir}/{arch}") {
 115                 # Check to see if the page has been changed by someone
 116                 # else since rcs_prepedit was called.
 117                 my ($oldrev)=$rcstoken=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
 118                 my $rev=`tla tree-id $config{srcdir}`;
 119                 if (defined $rev && defined $oldrev && $rev ne $oldrev) {
 120                         # Merge their changes into the file that we've
 121                         # changed.
 122                         if (quiet_system("tla", "update", "-d",
 123                                    "$config{srcdir}") != 0) {
 124                                 warn("tla update failed\n");
 125                         }
 126                 }
 127
 128                 if (quiet_system("tla", "commit",
 129                            "-L".IkiWiki::possibly_foolish_untaint($message),
 130                            '-d', $config{srcdir}) != 0) {
 131                         my $conflict=readfile("$config{srcdir}/$file");
 132                         if (system("tla", "undo", "-n", "--quiet", "-d", "$config{srcdir}") != 0) {
 133                                 warn("tla undo failed\n");
 134                         }
 135                         return $conflict;
 136                 }
 137         }
 138         return undef # success
 139 }
 140
 141 sub rcs_commit_staged ($$$) {
 142         # Commits all staged changes. Changes can be staged using rcs_add,
 143         # rcs_remove, and rcs_rename.
 144         my ($message, $user, $ipaddr)=@_;
 145
 146         error("rcs_commit_staged not implemented for tla"); # TODO
 147 }
 148
 149 sub rcs_add ($) {
 150         my $file=shift;
 151
 152         if (-d "$config{srcdir}/{arch}") {
 153                 if (quiet_system("tla", "add", "$config{srcdir}/$file") != 0) {
 154                         warn("tla add failed\n");
 155                 }
 156         }
 157 }
 158
 159 sub rcs_remove ($) {
 160         my $file = shift;
 161
 162         error("rcs_remove not implemented for tla"); # TODO
 163 }
 164
 165 sub rcs_rename ($$) { # {{{a
 166         my ($src, $dest) = @_;
 167
 168         error("rcs_rename not implemented for tla"); # TODO
 169 }
 170
 171 sub rcs_recentchanges ($) {
 172         my $num=shift;
 173         my @ret;
 174
 175         return unless -d "$config{srcdir}/{arch}";
 176
 177         eval q{use Date::Parse};
 178         error($@) if $@;
 179         eval q{use Mail::Header};
 180         error($@) if $@;
 181
 182         my $logs = `tla logs -d $config{srcdir}`;
 183         my @changesets = reverse split(/\n/, $logs);
 184
 185         for (my $i=0; $i<$num && $i<$#changesets; $i++) {
 186                 my ($change)=$changesets[$i]=~/^([A-Za-z0-9@\/._-]+)$/; # untaint
 187
 188                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 189                 my $head = Mail::Header->new(\*LOG);
 190                 close(LOG);
 191
 192                 my $rev = $head->get("Revision");
 193                 my $summ = $head->get("Summary");
 194                 my $newfiles = $head->get("New-files");
 195                 my $modfiles = $head->get("Modified-files");
 196                 my $remfiles = $head->get("Removed-files");
 197                 my $user = $head->get("Creator");
 198
 199                 my @paths = grep { !/^(.*\/)?\.arch-ids\/.*\.id$/ }
 200                         split(/ /, "$newfiles $modfiles .arch-ids/fake.id");
 201
 202                 my $sdate = $head->get("Standard-date");
 203                 my $when = str2time($sdate, 'UTC');
 204
 205                 my $committype = "web";
 206                 if (defined $summ && $summ =~ /$config{web_commit_regexp}/) {
 207                         $user = defined $2 ? "$2" : "$3";
 208                         $summ = $4;
 209                 }
 210                 else {
 211                         $committype="tla";
 212                 }
 213
 214                 my @message;
 215                 push @message, { line => $summ };
 216
 217                 my @pages;
 218
 219                 foreach my $file (@paths) {
 220                         my $diffurl=defined $config{diffurl} ? $config{diffurl} : "";
 221                         $diffurl=~s/\[\[file\]\]/$file/g;
 222                         $diffurl=~s/\[\[rev\]\]/$change/g;
 223                         push @pages, {
 224                                 page => pagename($file),
 225                                 diffurl => $diffurl,
 226                         } if length $file;
 227                 }
 228                 push @ret, {
 229                         rev => $change,
 230                         user => $user,
 231                         committype => $committype,
 232                         when => $when,
 233                         message => [@message],
 234                         pages => [@pages],
 235                 } if @pages;
 236
 237                 last if $i == $num;
 238         }
 239
 240         return @ret;
 241 }
 242
 243 sub rcs_diff ($) {
 244         my $rev=shift;
 245         my $logs = `tla logs -d $config{srcdir}`;
 246         my @changesets = reverse split(/\n/, $logs);
 247         my $i;
 248
 249         for($i=0;$i<$#changesets;$i++) {
 250                 last if $changesets[$i] eq $rev;
 251         }
 252
 253         my $revminusone = $changesets[$i+1];
 254         return `tla diff -d $config{srcdir} $revminusone`;
 255 }
 256
 257 sub rcs_getctime ($) {
 258         my $file=shift;
 259         eval q{use Date::Parse};
 260         error($@) if $@;
 261         eval q{use Mail::Header};
 262         error($@) if $@;
 263
 264         my $logs = `tla logs -d $config{srcdir}`;
 265         my @changesets = reverse split(/\n/, $logs);
 266         my $sdate;
 267
 268         for (my $i=0; $i<$#changesets; $i++) {
 269                 my $change = $changesets[$i];
 270
 271                 open(LOG, "tla cat-log -d $config{srcdir} $change|");
 272                 my $head = Mail::Header->new(\*LOG);
 273                 close(LOG);
 274
 275                 $sdate = $head->get("Standard-date");
 276                 my $newfiles = $head->get("New-files");
 277
 278                 my ($lastcreation) = grep {/^$file$/} split(/ /, "$newfiles");
 279                 last if defined($lastcreation);
 280         }
 281
 282         my $date=str2time($sdate, 'UTC');
 283         debug("found ctime ".localtime($date)." for $file");
 284         return $date;
 285 }
 286
 287 1