IkiWiki/Plugin/remove.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::remove;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "remove", call => \&getsetup);
  10         hook(type => "formbuilder_setup", id => "remove", call => \&formbuilder_setup);
  11         hook(type => "formbuilder", id => "remove", call => \&formbuilder);
  12         hook(type => "sessioncgi", id => "remove", call => \&sessioncgi);
  13
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                         section => "web",
  22                 },
  23 }
  24
  25 sub check_canremove ($$$) {
  26         my $page=shift;
  27         my $q=shift;
  28         my $session=shift;
  29
  30         # Must be a known source file.
  31         if (! exists $pagesources{$page}) {
  32                 error(sprintf(gettext("%s does not exist"),
  33                         htmllink("", "", $page, noimageinline => 1)));
  34         }
  35
  36         # Must exist on disk, and be a regular file.
  37         my $file=$pagesources{$page};
  38         if (! -e "$config{srcdir}/$file") {
  39                 error(sprintf(gettext("%s is not in the srcdir, so it cannot be deleted"), $file));
  40         }
  41         elsif (-l "$config{srcdir}/$file" && ! -f _) {
  42                 error(sprintf(gettext("%s is not a file"), $file));
  43         }
  44
  45         # Must be editable.
  46         IkiWiki::check_canedit($page, $q, $session);
  47
  48         # If a user can't upload an attachment, don't let them delete it.
  49         # This is sorta overkill, but better safe than sorry.
  50         if (! defined pagetype($pagesources{$page})) {
  51                 if (IkiWiki::Plugin::attachment->can("check_canattach")) {
  52                         IkiWiki::Plugin::attachment::check_canattach($session, $page, "$config{srcdir}/$file");
  53                 }
  54                 else {
  55                         error("removal of attachments is not allowed");
  56                 }
  57         }
  58
  59         my $canremove;
  60         IkiWiki::run_hooks(canremove => sub {
  61                 return if defined $canremove;
  62                 my $ret=shift->(page => $page, cgi => $q, session => $session);
  63                 if (defined $ret) {
  64                         if ($ret eq "") {
  65                                 $canremove=1;
  66                         }
  67                         elsif (ref $ret eq 'CODE') {
  68                                 $ret->();
  69                                 $canremove=0;
  70                         }
  71                         elsif (defined $ret) {
  72                                 error($ret);
  73                                 $canremove=0;
  74                         }
  75                 }
  76         });
  77 }
  78
  79 sub formbuilder_setup (@) {
  80         my %params=@_;
  81         my $form=$params{form};
  82         my $q=$params{cgi};
  83
  84         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
  85             $form->field("do") eq "create")) {
  86                 # Removal button for the page, and also for attachments.
  87                 push @{$params{buttons}}, "Remove" if $form->field("do") eq "edit";
  88                 $form->tmpl_param("field-remove" => '<input name="_submit" type="submit" value="Remove Attachments" />');
  89         }
  90 }
  91
  92 sub confirmation_form ($$) {
  93         my $q=shift;
  94         my $session=shift;
  95
  96         eval q{use CGI::FormBuilder};
  97         error($@) if $@;
  98         my $f = CGI::FormBuilder->new(
  99                 name => "remove",
 100                 header => 0,
 101                 charset => "utf-8",
 102                 method => 'POST',
 103                 javascript => 0,
 104                 params => $q,
 105                 action => $config{cgiurl},
 106                 stylesheet => 1,
 107                 fields => [qw{do page}],
 108         );
 109
 110         $f->field(name => "sid", type => "hidden", value => $session->id,
 111                 force => 1);
 112         $f->field(name => "do", type => "hidden", value => "remove", force => 1);
 113
 114         return $f, ["Remove", "Cancel"];
 115 }
 116
 117 sub removal_confirm ($$@) {
 118         my $q=shift;
 119         my $session=shift;
 120         my $attachment=shift;
 121         my @pages=@_;
 122
 123         foreach my $page (@pages) {
 124                 check_canremove($page, $q, $session);
 125         }
 126
 127         # Save current form state to allow returning to it later
 128         # without losing any edits.
 129         # (But don't save what button was submitted, to avoid
 130         # looping back to here.)
 131         # Note: "_submit" is CGI::FormBuilder internals.
 132         $q->param(-name => "_submit", -value => "");
 133         $session->param(postremove => scalar $q->Vars);
 134         IkiWiki::cgi_savesession($session);
 135
 136         my ($f, $buttons)=confirmation_form($q, $session);
 137         $f->title(sprintf(gettext("confirm removal of %s"),
 138                 join(", ", map { pagetitle($_) } @pages)));
 139         $f->field(name => "page", type => "hidden", value => \@pages, force => 1);
 140         if (defined $attachment) {
 141                 $f->field(name => "attachment", type => "hidden",
 142                         value => $attachment, force => 1);
 143         }
 144
 145         IkiWiki::showform($f, $buttons, $session, $q);
 146         exit 0;
 147 }
 148
 149 sub postremove ($) {
 150         my $session=shift;
 151
 152         # Load saved form state and return to edit form.
 153         my $postremove=CGI->new($session->param("postremove"));
 154         $session->clear("postremove");
 155         IkiWiki::cgi_savesession($session);
 156         IkiWiki::cgi($postremove, $session);
 157 }
 158
 159 sub formbuilder (@) {
 160         my %params=@_;
 161         my $form=$params{form};
 162
 163         if (defined $form->field("do") && ($form->field("do") eq "edit" ||
 164             $form->field("do") eq "create")) {
 165                 my $q=$params{cgi};
 166                 my $session=$params{session};
 167
 168                 if ($form->submitted eq "Remove" && $form->field("do") eq "edit") {
 169                         removal_confirm($q, $session, 0, $form->field("page"));
 170                 }
 171                 elsif ($form->submitted eq "Remove Attachments") {
 172                         my @selected=map { Encode::decode_utf8($_) } $q->param("attachment_select");
 173                         if (! @selected) {
 174                                 error(gettext("Please select the attachments to remove."));
 175                         }
 176                         removal_confirm($q, $session, 1, @selected);
 177                 }
 178         }
 179 }
 180
 181 sub sessioncgi ($$) {
 182         my $q=shift;
 183
 184         if ($q->param("do") eq 'remove') {
 185                 my $session=shift;
 186                 my ($form, $buttons)=confirmation_form($q, $session);
 187                 IkiWiki::decode_form_utf8($form);
 188
 189                 if ($form->submitted eq 'Cancel') {
 190                         postremove($session);
 191                 }
 192                 elsif ($form->submitted eq 'Remove' && $form->validate) {
 193                         IkiWiki::checksessionexpiry($q, $session, $q->param('sid'));
 194
 195                         my @pages=$form->field("page");
 196
 197                         # Validate removal by checking that the page exists,
 198                         # and that the user is allowed to edit(/remove) it.
 199                         my @files;
 200                         foreach my $page (@pages) {
 201                                 check_canremove($page, $q, $session);
 202
 203                                 # This untaint is safe because of the
 204                                 # checks performed above, which verify the
 205                                 # page is a normal file, etc.
 206                                 push @files, IkiWiki::possibly_foolish_untaint($pagesources{$page});
 207                         }
 208
 209                         # Do removal, and update the wiki.
 210                         require IkiWiki::Render;
 211                         if ($config{rcs}) {
 212                                 IkiWiki::disable_commit_hook();
 213                                 foreach my $file (@files) {
 214                                         IkiWiki::rcs_remove($file);
 215                                 }
 216                                 IkiWiki::rcs_commit_staged(
 217                                         message => gettext("removed"),
 218                                         session => $session,
 219                                 );
 220                                 IkiWiki::enable_commit_hook();
 221                                 IkiWiki::rcs_update();
 222                         }
 223                         else {
 224                                 foreach my $file (@files) {
 225                                         IkiWiki::prune("$config{srcdir}/$file");
 226                                 }
 227                         }
 228                         IkiWiki::refresh();
 229                         IkiWiki::saveindex();
 230
 231                         if ($q->param("attachment")) {
 232                                 # Attachments were deleted, so redirect
 233                                 # back to the edit form.
 234                                 postremove($session);
 235                         }
 236                         else {
 237                                 # The page is gone, so redirect to parent
 238                                 # of the page.
 239                                 my $parent=IkiWiki::dirname($pages[0]);
 240                                 if (! exists $pagesources{$parent}) {
 241                                         $parent="index";
 242                                 }
 243                                 IkiWiki::redirect($q, urlto($parent, '/', 1));
 244                         }
 245                 }
 246                 else {
 247                         removal_confirm($q, $session, 0, $form->field("page"));
 248                 }
 249
 250                 exit 0;
 251         }
 252 }
 253
 254 1