ikiwiki

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3
   4 package IkiWiki;
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use HTML::Template;
   9 use lib '.'; # For use without installation, removed by Makefile.
  10
  11 use vars qw{%config %links %oldlinks %oldpagemtime %pagectime
  12             %renderedfiles %pagesources %inlinepages};
  13
  14 sub usage () { #{{{
  15         die "usage: ikiwiki [options] source dest\n";
  16 } #}}}
  17
  18 sub getconfig () { #{{{
  19         if (! exists $ENV{WRAPPED_OPTIONS}) {
  20                 %config=(
  21                         wiki_file_prune_regexp => qr{((^|/).svn/|\.\.|^\.|\/\.|\.html?$)},
  22                         wiki_link_regexp => qr/\[\[(?:([^\s\]\|]+)\|)?([^\s\]]+)\]\]/,
  23                         wiki_processor_regexp => qr/\[\[(\w+)\s+([^\]]+)\]\]/,
  24                         wiki_file_regexp => qr/(^[-A-Za-z0-9_.:\/+]+$)/,
  25                         verbose => 0,
  26                         wikiname => "wiki",
  27                         default_pageext => ".mdwn",
  28                         cgi => 0,
  29                         svn => 1,
  30                         url => '',
  31                         cgiurl => '',
  32                         historyurl => '',
  33                         diffurl => '',
  34                         anonok => 0,
  35                         rss => 0,
  36                         rebuild => 0,
  37                         refresh => 0,
  38                         getctime => 0,
  39                         wrapper => undef,
  40                         wrappermode => undef,
  41                         srcdir => undef,
  42                         destdir => undef,
  43                         templatedir => "/usr/share/ikiwiki/templates",
  44                         setup => undef,
  45                         adminuser => undef,
  46                 );
  47
  48                 eval q{use Getopt::Long};
  49                 GetOptions(
  50                         "setup|s=s" => \$config{setup},
  51                         "wikiname=s" => \$config{wikiname},
  52                         "verbose|v!" => \$config{verbose},
  53                         "rebuild!" => \$config{rebuild},
  54                         "refresh!" => \$config{refresh},
  55                         "getctime" => \$config{getctime},
  56                         "wrappermode=i" => \$config{wrappermode},
  57                         "svn!" => \$config{svn},
  58                         "anonok!" => \$config{anonok},
  59                         "rss!" => \$config{rss},
  60                         "cgi!" => \$config{cgi},
  61                         "url=s" => \$config{url},
  62                         "cgiurl=s" => \$config{cgiurl},
  63                         "historyurl=s" => \$config{historyurl},
  64                         "diffurl=s" => \$config{diffurl},
  65                         "exclude=s@" => sub {
  66                                 $config{wiki_file_prune_regexp}=qr/$config{wiki_file_prune_regexp}|$_[1]/;
  67                         },
  68                         "adminuser=s@" => sub {
  69                                 push @{$config{adminuser}}, $_[1]
  70                         },
  71                         "templatedir=s" => sub {
  72                                 $config{templatedir}=possibly_foolish_untaint($_[1])
  73                         },
  74                         "wrapper:s" => sub {
  75                                 $config{wrapper}=$_[1] ? $_[1] : "ikiwiki-wrap"
  76                         },
  77                 ) || usage();
  78
  79                 if (! $config{setup}) {
  80                         usage() unless @ARGV == 2;
  81                         $config{srcdir} = possibly_foolish_untaint(shift @ARGV);
  82                         $config{destdir} = possibly_foolish_untaint(shift @ARGV);
  83                         checkconfig();
  84                 }
  85         }
  86         else {
  87                 # wrapper passes a full config structure in the environment
  88                 # variable
  89                 eval possibly_foolish_untaint($ENV{WRAPPED_OPTIONS});
  90                 checkconfig();
  91         }
  92 } #}}}
  93
  94 sub checkconfig () { #{{{
  95         if ($config{cgi} && ! length $config{url}) {
  96                 error("Must specify url to wiki with --url when using --cgi\n");
  97         }
  98         if ($config{rss} && ! length $config{url}) {
  99                 error("Must specify url to wiki with --url when using --rss\n");
 100         }
 101
 102         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 103                 unless exists $config{wikistatedir};
 104
 105         if ($config{svn}) {
 106                 require IkiWiki::Rcs::SVN;
 107                 $config{rcs}=1;
 108         }
 109         else {
 110                 require IkiWiki::Rcs::Stub;
 111                 $config{rcs}=0;
 112         }
 113 } #}}}
 114
 115 sub error ($) { #{{{
 116         if ($config{cgi}) {
 117                 print "Content-type: text/html\n\n";
 118                 print misctemplate("Error", "<p>Error: @_</p>");
 119         }
 120         die @_;
 121 } #}}}
 122
 123 sub possibly_foolish_untaint ($) { #{{{
 124         my $tainted=shift;
 125         my ($untainted)=$tainted=~/(.*)/;
 126         return $untainted;
 127 } #}}}
 128
 129 sub debug ($) { #{{{
 130         return unless $config{verbose};
 131         if (! $config{cgi}) {
 132                 print "@_\n";
 133         }
 134         else {
 135                 print STDERR "@_\n";
 136         }
 137 } #}}}
 138
 139 sub basename ($) { #{{{
 140         my $file=shift;
 141
 142         $file=~s!.*/!!;
 143         return $file;
 144 } #}}}
 145
 146 sub dirname ($) { #{{{
 147         my $file=shift;
 148
 149         $file=~s!/?[^/]+$!!;
 150         return $file;
 151 } #}}}
 152
 153 sub pagetype ($) { #{{{
 154         my $page=shift;
 155
 156         if ($page =~ /\.mdwn$/) {
 157                 return ".mdwn";
 158         }
 159         else {
 160                 return "unknown";
 161         }
 162 } #}}}
 163
 164 sub pagename ($) { #{{{
 165         my $file=shift;
 166
 167         my $type=pagetype($file);
 168         my $page=$file;
 169         $page=~s/\Q$type\E*$// unless $type eq 'unknown';
 170         return $page;
 171 } #}}}
 172
 173 sub htmlpage ($) { #{{{
 174         my $page=shift;
 175
 176         return $page.".html";
 177 } #}}}
 178
 179 sub readfile ($) { #{{{
 180         my $file=shift;
 181
 182         if (-l $file) {
 183                 error("cannot read a symlink ($file)");
 184         }
 185
 186         local $/=undef;
 187         open (IN, "$file") || error("failed to read $file: $!");
 188         my $ret=<IN>;
 189         close IN;
 190         return $ret;
 191 } #}}}
 192
 193 sub writefile ($$) { #{{{
 194         my $file=shift;
 195         my $content=shift;
 196
 197         if (-l $file) {
 198                 error("cannot write to a symlink ($file)");
 199         }
 200
 201         my $dir=dirname($file);
 202         if (! -d $dir) {
 203                 my $d="";
 204                 foreach my $s (split(m!/+!, $dir)) {
 205                         $d.="$s/";
 206                         if (! -d $d) {
 207                                 mkdir($d) || error("failed to create directory $d: $!");
 208                         }
 209                 }
 210         }
 211
 212         open (OUT, ">$file") || error("failed to write $file: $!");
 213         print OUT $content;
 214         close OUT;
 215 } #}}}
 216
 217 sub bestlink ($$) { #{{{
 218         # Given a page and the text of a link on the page, determine which
 219         # existing page that link best points to. Prefers pages under a
 220         # subdirectory with the same name as the source page, failing that
 221         # goes down the directory tree to the base looking for matching
 222         # pages.
 223         my $page=shift;
 224         my $link=lc(shift);
 225
 226         my $cwd=$page;
 227         do {
 228                 my $l=$cwd;
 229                 $l.="/" if length $l;
 230                 $l.=$link;
 231
 232                 if (exists $links{$l}) {
 233                         #debug("for $page, \"$link\", use $l");
 234                         return $l;
 235                 }
 236         } while $cwd=~s!/?[^/]+$!!;
 237
 238         #print STDERR "warning: page $page, broken link: $link\n";
 239         return "";
 240 } #}}}
 241
 242 sub isinlinableimage ($) { #{{{
 243         my $file=shift;
 244
 245         $file=~/\.(png|gif|jpg|jpeg)$/i;
 246 } #}}}
 247
 248 sub pagetitle ($) { #{{{
 249         my $page=shift;
 250         $page=~s/__(\d+)__/&#$1;/g;
 251         $page=~y/_/ /;
 252         return $page;
 253 } #}}}
 254
 255 sub htmllink ($$;$$$) { #{{{
 256         my $page=shift;
 257         my $link=shift;
 258         my $noimageinline=shift; # don't turn links into inline html images
 259         my $forcesubpage=shift; # force a link to a subpage
 260         my $linktext=shift; # set to force the link text to something
 261
 262         my $bestlink;
 263         if (! $forcesubpage) {
 264                 $bestlink=bestlink($page, $link);
 265         }
 266         else {
 267                 $bestlink="$page/".lc($link);
 268         }
 269
 270         $linktext=pagetitle(basename($link)) unless defined $linktext;
 271
 272         return $linktext if length $bestlink && $page eq $bestlink;
 273
 274         # TODO BUG: %renderedfiles may not have it, if the linked to page
 275         # was also added and isn't yet rendered! Note that this bug is
 276         # masked by the bug mentioned below that makes all new files
 277         # be rendered twice.
 278         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 279                 $bestlink=htmlpage($bestlink);
 280         }
 281         if (! grep { $_ eq $bestlink } values %renderedfiles) {
 282                 return "<span><a href=\"$config{cgiurl}?do=create&page=$link&from=$page\">?</a>$linktext</span>"
 283         }
 284
 285         $bestlink=File::Spec->abs2rel($bestlink, dirname($page));
 286
 287         if (! $noimageinline && isinlinableimage($bestlink)) {
 288                 return "<img src=\"$bestlink\">";
 289         }
 290         return "<a href=\"$bestlink\">$linktext</a>";
 291 } #}}}
 292
 293 sub indexlink () { #{{{
 294         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 295 } #}}}
 296
 297 sub lockwiki () { #{{{
 298         # Take an exclusive lock on the wiki to prevent multiple concurrent
 299         # run issues. The lock will be dropped on program exit.
 300         if (! -d $config{wikistatedir}) {
 301                 mkdir($config{wikistatedir});
 302         }
 303         open(WIKILOCK, ">$config{wikistatedir}/lockfile") ||
 304                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 305         if (! flock(WIKILOCK, 2 | 4)) {
 306                 debug("wiki seems to be locked, waiting for lock");
 307                 my $wait=600; # arbitrary, but don't hang forever to
 308                               # prevent process pileup
 309                 for (1..600) {
 310                         return if flock(WIKILOCK, 2 | 4);
 311                         sleep 1;
 312                 }
 313                 error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 314         }
 315 } #}}}
 316
 317 sub unlockwiki () { #{{{
 318         close WIKILOCK;
 319 } #}}}
 320
 321 sub loadindex () { #{{{
 322         open (IN, "$config{wikistatedir}/index") || return;
 323         while (<IN>) {
 324                 $_=possibly_foolish_untaint($_);
 325                 chomp;
 326                 my %items;
 327                 $items{link}=[];
 328                 foreach my $i (split(/ /, $_)) {
 329                         my ($item, $val)=split(/=/, $i, 2);
 330                         push @{$items{$item}}, $val;
 331                 }
 332
 333                 next unless exists $items{src}; # skip bad lines for now
 334
 335                 my $page=pagename($items{src}[0]);
 336                 if (! $config{rebuild}) {
 337                         $pagesources{$page}=$items{src}[0];
 338                         $oldpagemtime{$page}=$items{mtime}[0];
 339                         $oldlinks{$page}=[@{$items{link}}];
 340                         $links{$page}=[@{$items{link}}];
 341                         $inlinepages{$page}=join(" ", @{$items{inlinepage}})
 342                                 if exists $items{inlinepage};
 343                         $renderedfiles{$page}=$items{dest}[0];
 344                 }
 345                 $pagectime{$page}=$items{ctime}[0];
 346         }
 347         close IN;
 348 } #}}}
 349
 350 sub saveindex () { #{{{
 351         if (! -d $config{wikistatedir}) {
 352                 mkdir($config{wikistatedir});
 353         }
 354         open (OUT, ">$config{wikistatedir}/index") ||
 355                 error("cannot write to $config{wikistatedir}/index: $!");
 356         foreach my $page (keys %oldpagemtime) {
 357                 next unless $oldpagemtime{$page};
 358                 my $line="mtime=$oldpagemtime{$page} ".
 359                         "ctime=$pagectime{$page} ".
 360                         "src=$pagesources{$page} ".
 361                         "dest=$renderedfiles{$page}";
 362                 $line.=" link=$_" foreach @{$links{$page}};
 363                 if (exists $inlinepages{$page}) {
 364                         $line.=" inlinepage=$_" foreach split " ", $inlinepages{$page};
 365                 }
 366                 print OUT $line."\n";
 367         }
 368         close OUT;
 369 } #}}}
 370
 371 sub misctemplate ($$) { #{{{
 372         my $title=shift;
 373         my $pagebody=shift;
 374
 375         my $template=HTML::Template->new(
 376                 filename => "$config{templatedir}/misc.tmpl"
 377         );
 378         $template->param(
 379                 title => $title,
 380                 indexlink => indexlink(),
 381                 wikiname => $config{wikiname},
 382                 pagebody => $pagebody,
 383         );
 384         return $template->output;
 385 }#}}}
 386
 387 sub userinfo_get ($$) { #{{{
 388         my $user=shift;
 389         my $field=shift;
 390
 391         eval q{use Storable};
 392         my $userdata=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
 393         if (! defined $userdata || ! ref $userdata ||
 394             ! exists $userdata->{$user} || ! ref $userdata->{$user} ||
 395             ! exists $userdata->{$user}->{$field}) {
 396                 return "";
 397         }
 398         return $userdata->{$user}->{$field};
 399 } #}}}
 400
 401 sub userinfo_set ($$$) { #{{{
 402         my $user=shift;
 403         my $field=shift;
 404         my $value=shift;
 405
 406         eval q{use Storable};
 407         my $userdata=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
 408         if (! defined $userdata || ! ref $userdata ||
 409             ! exists $userdata->{$user} || ! ref $userdata->{$user}) {
 410                 return "";
 411         }
 412
 413         $userdata->{$user}->{$field}=$value;
 414         my $oldmask=umask(077);
 415         my $ret=Storable::lock_store($userdata, "$config{wikistatedir}/userdb");
 416         umask($oldmask);
 417         return $ret;
 418 } #}}}
 419
 420 sub userinfo_setall ($$) { #{{{
 421         my $user=shift;
 422         my $info=shift;
 423
 424         eval q{use Storable};
 425         my $userdata=eval{ Storable::lock_retrieve("$config{wikistatedir}/userdb") };
 426         if (! defined $userdata || ! ref $userdata) {
 427                 $userdata={};
 428         }
 429         $userdata->{$user}=$info;
 430         my $oldmask=umask(077);
 431         my $ret=Storable::lock_store($userdata, "$config{wikistatedir}/userdb");
 432         umask($oldmask);
 433         return $ret;
 434 } #}}}
 435
 436 sub is_admin ($) { #{{{
 437         my $user_name=shift;
 438
 439         return grep { $_ eq $user_name } @{$config{adminuser}};
 440 } #}}}
 441
 442 sub glob_match ($$) { #{{{
 443         my $page=shift;
 444         my $glob=shift;
 445
 446         # turn glob into safe regexp
 447         $glob=quotemeta($glob);
 448         $glob=~s/\\\*/.*/g;
 449         $glob=~s/\\\?/./g;
 450         $glob=~s!\\/!/!g;
 451
 452         $page=~/^$glob$/i;
 453 } #}}}
 454
 455 sub globlist_match ($$) { #{{{
 456         my $page=shift;
 457         my @globlist=split(" ", shift);
 458
 459         # check any negated globs first
 460         foreach my $glob (@globlist) {
 461                 return 0 if $glob=~/^!(.*)/ && glob_match($page, $1);
 462         }
 463
 464         foreach my $glob (@globlist) {
 465                 return 1 if glob_match($page, $glob);
 466         }
 467
 468         return 0;
 469 } #}}}
 470
 471 sub main () { #{{{
 472         getconfig();
 473
 474         if ($config{cgi}) {
 475                 lockwiki();
 476                 loadindex();
 477                 require IkiWiki::CGI;
 478                 cgi();
 479         }
 480         elsif ($config{setup}) {
 481                 require IkiWiki::Setup;
 482                 setup();
 483         }
 484         elsif ($config{wrapper}) {
 485                 lockwiki();
 486                 require IkiWiki::Wrapper;
 487                 gen_wrapper();
 488         }
 489         else {
 490                 lockwiki();
 491                 loadindex();
 492                 require IkiWiki::Render;
 493                 rcs_update();
 494                 rcs_getctime() if $config{getctime};
 495                 refresh();
 496                 saveindex();
 497         }
 498 } #}}}
 499
 500 main;