IkiWiki/Plugin/img.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki enhanced image handling plugin
   3 # Christian Mock cm@tahina.priv.at 20061002
   4 package IkiWiki::Plugin::img;
   5
   6 use warnings;
   7 use strict;
   8 use IkiWiki 3.00;
   9
  10 my %imgdefaults;
  11
  12 sub import {
  13         hook(type => "getsetup", id => "img", call => \&getsetup);
  14         hook(type => "preprocess", id => "img", call => \&preprocess, scan => 1);
  15 }
  16
  17 sub getsetup () {
  18         return
  19                 plugin => {
  20                         safe => 1,
  21                         rebuild => undef,
  22                 },
  23 }
  24
  25 sub preprocess (@) {
  26         my ($image) = $_[0] =~ /$config{wiki_file_regexp}/; # untaint
  27         my %params=@_;
  28
  29         if (exists $imgdefaults{$params{page}}) {
  30                 foreach my $key (keys %{$imgdefaults{$params{page}}}) {
  31                         if (! exists $params{$key}) {
  32                                 $params{$key}=$imgdefaults{$params{page}}->{$key};
  33                         }
  34                 }
  35         }
  36
  37         if (! exists $params{size}) {
  38                 $params{size}='full';
  39         }
  40
  41         if ($image eq 'defaults') {
  42                 $imgdefaults{$params{page}} = \%params;
  43                 return '';
  44         }
  45
  46         add_link($params{page}, $image);
  47
  48         # optimisation: detect scan mode, and avoid generating the image
  49         if (! defined wantarray) {
  50                 return;
  51         }
  52
  53         my $file = bestlink($params{page}, $image);
  54         my $srcfile = srcfile($file, 1);
  55         if (! length $file || ! defined $srcfile) {
  56                 return htmllink($params{page}, $params{destpage}, $image);
  57         }
  58
  59         my $dir = $params{page};
  60         my $base = IkiWiki::basename($file);
  61
  62         eval q{use Image::Magick};
  63         error gettext("Image::Magick is not installed") if $@;
  64         my $im = Image::Magick->new;
  65         my $imglink;
  66         my $r;
  67
  68         my ($dwidth, $dheight);
  69
  70         if ($params{size} ne 'full') {
  71                 add_depends($params{page}, $image);
  72
  73                 my ($w, $h) = ($params{size} =~ /^(\d*)x(\d*)$/);
  74                 error sprintf(gettext('wrong size format "%s" (should be WxH)'), $params{size})
  75                         unless (defined $w && defined $h &&
  76                                 (length $w || length $h));
  77
  78                 my $outfile = "$config{destdir}/$dir/${w}x${h}-$base";
  79                 $imglink = "$dir/${w}x${h}-$base";
  80
  81                 will_render($params{page}, $imglink);
  82
  83                 if (-e $outfile && (-M $srcfile >= -M $outfile)) {
  84                         $r = $im->Read($outfile);
  85                         error sprintf(gettext("failed to read %s: %s"), $outfile, $r) if $r;
  86                 }
  87                 else {
  88                         $r = $im->Read($srcfile);
  89                         error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
  90
  91                         # don't resize any larger
  92                         my ($rw, $rh) = ($w, $h);
  93                         if ((length $rw && $rw > $im->Get("width")) ||
  94                             (length $rh && $rh > $im->Get("height"))) {
  95                                 $rw=$im->Get("width");
  96                                 $rh=$im->Get("height");
  97                         }
  98
  99                         $r = $im->Resize(geometry => "${rw}x${rh}");
 100                         error sprintf(gettext("failed to resize: %s"), $r) if $r;
 101
 102                         # don't actually write file in preview mode
 103                         if (! $params{preview}) {
 104                                 my @blob = $im->ImageToBlob();
 105                                 writefile($imglink, $config{destdir}, $blob[0], 1);
 106                         }
 107                         else {
 108                                 $imglink = $file;
 109                         }
 110                 }
 111
 112                 # since we don't really resize larger, set the display
 113                 # size, so the browser can scale the image up if necessary
 114                 if (length $w && length $h) {
 115                         ($dwidth, $dheight)=($w, $h);
 116                 }
 117                 # avoid division by zero on 0x0 image
 118                 elsif ($im->Get("width") == 0 || $im->Get("height") == 0) {
 119                         ($dwidth, $dheight)=(0, 0);
 120                 }
 121                 # calculate unspecified size from the other one, preserving
 122                 # aspect ratio
 123                 elsif (length $w) {
 124                         $dwidth=$w;
 125                         $dheight=$w / $im->Get("width") * $im->Get("height");
 126                 }
 127                 elsif (length $h) {
 128                         $dheight=$h;
 129                         $dwidth=$h / $im->Get("height") * $im->Get("width");
 130                 }
 131
 132         }
 133         else {
 134                 $r = $im->Read($srcfile);
 135                 error sprintf(gettext("failed to read %s: %s"), $file, $r) if $r;
 136                 $imglink = $file;
 137                 $dwidth = $im->Get("width");
 138                 $dheight = $im->Get("height");
 139         }
 140
 141         my ($fileurl, $imgurl);
 142         if (! $params{preview}) {
 143                 $fileurl=urlto($file, $params{destpage});
 144                 $imgurl=urlto($imglink, $params{destpage});
 145         }
 146         else {
 147                 $fileurl="$config{url}/$file";
 148                 $imgurl="$config{url}/$imglink";
 149         }
 150
 151         if (! defined($im->Get("width")) || ! defined($im->Get("height"))) {
 152                 error sprintf(gettext("failed to determine size of image %s"), $file)
 153         }
 154
 155         my $imgtag='<img src="'.$imgurl.
 156                 '" width="'.$dwidth.
 157                 '" height="'.$dheight.'"'.
 158                 (exists $params{alt} ? ' alt="'.$params{alt}.'"' : '').
 159                 (exists $params{title} ? ' title="'.$params{title}.'"' : '').
 160                 (exists $params{align} ? ' align="'.$params{align}.'"' : '').
 161                 (exists $params{class} ? ' class="'.$params{class}.'"' : '').
 162                 (exists $params{id} ? ' id="'.$params{id}.'"' : '').
 163                 ' />';
 164
 165         if (! defined $params{link} || lc($params{link}) eq 'yes') {
 166                 $imgtag='<a href="'.$fileurl.'">'.$imgtag.'</a>';
 167         }
 168         elsif ($params{link} =~ /^\w+:\/\//) {
 169                 $imgtag='<a href="'.$params{link}.'">'.$imgtag.'</a>';
 170         }
 171         else {
 172                 my $b = bestlink($params{page}, $params{link});
 173
 174                 if (length $b) {
 175                         add_depends($params{page}, $b);
 176                         $imgtag=htmllink($params{page}, $params{destpage},
 177                                 $params{link}, linktext => $imgtag,
 178                                 noimageinline => 1);
 179                 }
 180         }
 181
 182         if (exists $params{caption}) {
 183                 return '<table class="img">'.
 184                         '<caption>'.$params{caption}.'</caption>'.
 185                         '<tr><td>'.$imgtag.'</td></tr>'.
 186                         '</table>';
 187         }
 188         else {
 189                 return $imgtag;
 190         }
 191 }
 192
 193 1