IkiWiki/Plugin/git.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::git;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki;
   7 use Encode;
   8 use open qw{:utf8 :std};
   9
  10 my $sha1_pattern     = qr/[0-9a-fA-F]{40}/; # pattern to validate Git sha1sums
  11 my $dummy_commit_msg = 'dummy commit';      # message to skip in recent changes
  12 my $no_chdir=0;
  13
  14 sub import {
  15         hook(type => "checkconfig", id => "git", call => \&checkconfig);
  16         hook(type => "getsetup", id => "git", call => \&getsetup);
  17         hook(type => "genwrapper", id => "git", call => \&genwrapper);
  18         hook(type => "rcs", id => "rcs_update", call => \&rcs_update);
  19         hook(type => "rcs", id => "rcs_prepedit", call => \&rcs_prepedit);
  20         hook(type => "rcs", id => "rcs_commit", call => \&rcs_commit);
  21         hook(type => "rcs", id => "rcs_commit_staged", call => \&rcs_commit_staged);
  22         hook(type => "rcs", id => "rcs_add", call => \&rcs_add);
  23         hook(type => "rcs", id => "rcs_remove", call => \&rcs_remove);
  24         hook(type => "rcs", id => "rcs_rename", call => \&rcs_rename);
  25         hook(type => "rcs", id => "rcs_recentchanges", call => \&rcs_recentchanges);
  26         hook(type => "rcs", id => "rcs_diff", call => \&rcs_diff);
  27         hook(type => "rcs", id => "rcs_getctime", call => \&rcs_getctime);
  28         hook(type => "rcs", id => "rcs_getmtime", call => \&rcs_getmtime);
  29         hook(type => "rcs", id => "rcs_receive", call => \&rcs_receive);
  30 }
  31
  32 sub checkconfig () {
  33         if (! defined $config{gitorigin_branch}) {
  34                 $config{gitorigin_branch}="origin";
  35         }
  36         if (! defined $config{gitmaster_branch}) {
  37                 $config{gitmaster_branch}="master";
  38         }
  39         if (defined $config{git_wrapper} &&
  40             length $config{git_wrapper}) {
  41                 push @{$config{wrappers}}, {
  42                         wrapper => $config{git_wrapper},
  43                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  44                 };
  45         }
  46
  47         if (defined $config{git_test_receive_wrapper} &&
  48             length $config{git_test_receive_wrapper}) {
  49                 push @{$config{wrappers}}, {
  50                         test_receive => 1,
  51                         wrapper => $config{git_test_receive_wrapper},
  52                         wrappermode => (defined $config{git_wrappermode} ? $config{git_wrappermode} : "06755"),
  53                 };
  54         }
  55
  56         # Avoid notes, parser does not handle and they only slow things down.
  57         $ENV{GIT_NOTES_REF}="";
  58
  59         # Run receive test only if being called by the wrapper, and not
  60         # when generating same.
  61         if ($config{test_receive} && ! exists $config{wrapper}) {
  62                 require IkiWiki::Receive;
  63                 IkiWiki::Receive::test();
  64         }
  65 }
  66
  67 sub getsetup () {
  68         return
  69                 plugin => {
  70                         safe => 0, # rcs plugin
  71                         rebuild => undef,
  72                         section => "rcs",
  73                 },
  74                 git_wrapper => {
  75                         type => "string",
  76                         example => "/git/wiki.git/hooks/post-update",
  77                         description => "git hook to generate",
  78                         safe => 0, # file
  79                         rebuild => 0,
  80                 },
  81                 git_wrappermode => {
  82                         type => "string",
  83                         example => '06755',
  84                         description => "mode for git_wrapper (can safely be made suid)",
  85                         safe => 0,
  86                         rebuild => 0,
  87                 },
  88                 git_test_receive_wrapper => {
  89                         type => "string",
  90                         example => "/git/wiki.git/hooks/pre-receive",
  91                         description => "git pre-receive hook to generate",
  92                         safe => 0, # file
  93                         rebuild => 0,
  94                 },
  95                 untrusted_committers => {
  96                         type => "string",
  97                         example => [],
  98                         description => "unix users whose commits should be checked by the pre-receive hook",
  99                         safe => 0,
 100                         rebuild => 0,
 101                 },
 102                 historyurl => {
 103                         type => "string",
 104                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=history;f=[[file]]",
 105                         description => "gitweb url to show file history ([[file]] substituted)",
 106                         safe => 1,
 107                         rebuild => 1,
 108                 },
 109                 diffurl => {
 110                         type => "string",
 111                         example => "http://git.example.com/gitweb.cgi?p=wiki.git;a=blobdiff;f=[[file]];h=[[sha1_to]];hp=[[sha1_from]];hb=[[sha1_commit]];hpb=[[sha1_parent]]",
 112                         description => "gitweb url to show a diff ([[file]], [[sha1_to]], [[sha1_from]], [[sha1_commit]], and [[sha1_parent]] substituted)",
 113                         safe => 1,
 114                         rebuild => 1,
 115                 },
 116                 gitorigin_branch => {
 117                         type => "string",
 118                         example => "origin",
 119                         description => "where to pull and push changes (set to empty string to disable)",
 120                         safe => 0, # paranoia
 121                         rebuild => 0,
 122                 },
 123                 gitmaster_branch => {
 124                         type => "string",
 125                         example => "master",
 126                         description => "branch that the wiki is stored in",
 127                         safe => 0, # paranoia
 128                         rebuild => 0,
 129                 },
 130 }
 131
 132 sub genwrapper {
 133         if ($config{test_receive}) {
 134                 require IkiWiki::Receive;
 135                 return IkiWiki::Receive::genwrapper();
 136         }
 137         else {
 138                 return "";
 139         }
 140 }
 141
 142 sub safe_git (&@) {
 143         # Start a child process safely without resorting /bin/sh.
 144         # Return command output or success state (in scalar context).
 145
 146         my ($error_handler, @cmdline) = @_;
 147
 148         my $pid = open my $OUT, "-|";
 149
 150         error("Cannot fork: $!") if !defined $pid;
 151
 152         if (!$pid) {
 153                 # In child.
 154                 # Git commands want to be in wc.
 155                 if (! $no_chdir) {
 156                         chdir $config{srcdir}
 157                             or error("Cannot chdir to $config{srcdir}: $!");
 158                 }
 159                 exec @cmdline or error("Cannot exec '@cmdline': $!");
 160         }
 161         # In parent.
 162
 163         # git output is probably utf-8 encoded, but may contain
 164         # other encodings or invalidly encoded stuff. So do not rely
 165         # on the normal utf-8 IO layer, decode it by hand.
 166         binmode($OUT);
 167
 168         my @lines;
 169         while (<$OUT>) {
 170                 $_=decode_utf8($_, 0);
 171
 172                 chomp;
 173
 174                 push @lines, $_;
 175         }
 176
 177         close $OUT;
 178
 179         $error_handler->("'@cmdline' failed: $!") if $? && $error_handler;
 180
 181         return wantarray ? @lines : ($? == 0);
 182 }
 183 # Convenient wrappers.
 184 sub run_or_die ($@) { safe_git(\&error, @_) }
 185 sub run_or_cry ($@) { safe_git(sub { warn @_ },  @_) }
 186 sub run_or_non ($@) { safe_git(undef,            @_) }
 187
 188
 189 sub merge_past ($$$) {
 190         # Unlike with Subversion, Git cannot make a 'svn merge -rN:M file'.
 191         # Git merge commands work with the committed changes, except in the
 192         # implicit case of '-m' of git checkout(1).  So we should invent a
 193         # kludge here.  In principle, we need to create a throw-away branch
 194         # in preparing for the merge itself.  Since branches are cheap (and
 195         # branching is fast), this shouldn't cost high.
 196         #
 197         # The main problem is the presence of _uncommitted_ local changes.  One
 198         # possible approach to get rid of this situation could be that we first
 199         # make a temporary commit in the master branch and later restore the
 200         # initial state (this is possible since Git has the ability to undo a
 201         # commit, i.e. 'git reset --soft HEAD^').  The method can be summarized
 202         # as follows:
 203         #
 204         #       - create a diff of HEAD:current-sha1
 205         #       - dummy commit
 206         #       - create a dummy branch and switch to it
 207         #       - rewind to past (reset --hard to the current-sha1)
 208         #       - apply the diff and commit
 209         #       - switch to master and do the merge with the dummy branch
 210         #       - make a soft reset (undo the last commit of master)
 211         #
 212         # The above method has some drawbacks: (1) it needs a redundant commit
 213         # just to get rid of local changes, (2) somewhat slow because of the
 214         # required system forks.  Until someone points a more straight method
 215         # (which I would be grateful) I have implemented an alternative method.
 216         # In this approach, we hide all the modified files from Git by renaming
 217         # them (using the 'rename' builtin) and later restore those files in
 218         # the throw-away branch (that is, we put the files themselves instead
 219         # of applying a patch).
 220
 221         my ($sha1, $file, $message) = @_;
 222
 223         my @undo;      # undo stack for cleanup in case of an error
 224         my $conflict;  # file content with conflict markers
 225
 226         eval {
 227                 # Hide local changes from Git by renaming the modified file.
 228                 # Relative paths must be converted to absolute for renaming.
 229                 my ($target, $hidden) = (
 230                     "$config{srcdir}/${file}", "$config{srcdir}/${file}.${sha1}"
 231                 );
 232                 rename($target, $hidden)
 233                     or error("rename '$target' to '$hidden' failed: $!");
 234                 # Ensure to restore the renamed file on error.
 235                 push @undo, sub {
 236                         return if ! -e "$hidden"; # already renamed
 237                         rename($hidden, $target)
 238                             or warn "rename '$hidden' to '$target' failed: $!";
 239                 };
 240
 241                 my $branch = "throw_away_${sha1}"; # supposed to be unique
 242
 243                 # Create a throw-away branch and rewind backward.
 244                 push @undo, sub { run_or_cry('git', 'branch', '-D', $branch) };
 245                 run_or_die('git', 'branch', $branch, $sha1);
 246
 247                 # Switch to throw-away branch for the merge operation.
 248                 push @undo, sub {
 249                         if (!run_or_cry('git', 'checkout', $config{gitmaster_branch})) {
 250                                 run_or_cry('git', 'checkout','-f',$config{gitmaster_branch});
 251                         }
 252                 };
 253                 run_or_die('git', 'checkout', $branch);
 254
 255                 # Put the modified file in _this_ branch.
 256                 rename($hidden, $target)
 257                     or error("rename '$hidden' to '$target' failed: $!");
 258
 259                 # _Silently_ commit all modifications in the current branch.
 260                 run_or_non('git', 'commit', '-m', $message, '-a');
 261                 # ... and re-switch to master.
 262                 run_or_die('git', 'checkout', $config{gitmaster_branch});
 263
 264                 # Attempt to merge without complaining.
 265                 if (!run_or_non('git', 'pull', '--no-commit', '.', $branch)) {
 266                         $conflict = readfile($target);
 267                         run_or_die('git', 'reset', '--hard');
 268                 }
 269         };
 270         my $failure = $@;
 271
 272         # Process undo stack (in reverse order).  By policy cleanup
 273         # actions should normally print a warning on failure.
 274         while (my $handle = pop @undo) {
 275                 $handle->();
 276         }
 277
 278         error("Git merge failed!\n$failure\n") if $failure;
 279
 280         return $conflict;
 281 }
 282
 283 {
 284 my $prefix;
 285 sub decode_git_file ($) {
 286         my $file=shift;
 287
 288         # git does not output utf-8 filenames, but instead
 289         # double-quotes them with the utf-8 characters
 290         # escaped as \nnn\nnn.
 291         if ($file =~ m/^"(.*)"$/) {
 292                 ($file=$1) =~ s/\\([0-7]{1,3})/chr(oct($1))/eg;
 293         }
 294
 295         # strip prefix if in a subdir
 296         if (! defined $prefix) {
 297                 ($prefix) = run_or_die('git', 'rev-parse', '--show-prefix');
 298                 if (! defined $prefix) {
 299                         $prefix="";
 300                 }
 301         }
 302         $file =~ s/^\Q$prefix\E//;
 303
 304         return decode("utf8", $file);
 305 }
 306 }
 307
 308 sub parse_diff_tree ($) {
 309         # Parse the raw diff tree chunk and return the info hash.
 310         # See git-diff-tree(1) for the syntax.
 311         my $dt_ref = shift;
 312
 313         # End of stream?
 314         return if !defined @{ $dt_ref } ||
 315                   !defined @{ $dt_ref }[0] || !length @{ $dt_ref }[0];
 316
 317         my %ci;
 318         # Header line.
 319         while (my $line = shift @{ $dt_ref }) {
 320                 return if $line !~ m/^(.+) ($sha1_pattern)/;
 321
 322                 my $sha1 = $2;
 323                 $ci{'sha1'} = $sha1;
 324                 last;
 325         }
 326
 327         # Identification lines for the commit.
 328         while (my $line = shift @{ $dt_ref }) {
 329                 # Regexps are semi-stolen from gitweb.cgi.
 330                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
 331                         $ci{'tree'} = $1;
 332                 }
 333                 elsif ($line =~ m/^parent ([0-9a-fA-F]{40})$/) {
 334                         # XXX: collecting in reverse order
 335                         push @{ $ci{'parents'} }, $1;
 336                 }
 337                 elsif ($line =~ m/^(author|committer) (.*) ([0-9]+) (.*)$/) {
 338                         my ($who, $name, $epoch, $tz) =
 339                            ($1,   $2,    $3,     $4 );
 340
 341                         $ci{  $who          } = $name;
 342                         $ci{ "${who}_epoch" } = $epoch;
 343                         $ci{ "${who}_tz"    } = $tz;
 344
 345                         if ($name =~ m/^([^<]+)\s+<([^@>]+)/) {
 346                                 $ci{"${who}_name"} = $1;
 347                                 $ci{"${who}_username"} = $2;
 348                         }
 349                         elsif ($name =~ m/^([^<]+)\s+<>$/) {
 350                                 $ci{"${who}_username"} = $1;
 351                         }
 352                         else {
 353                                 $ci{"${who}_username"} = $name;
 354                         }
 355                 }
 356                 elsif ($line =~ m/^$/) {
 357                         # Trailing empty line signals next section.
 358                         last;
 359                 }
 360         }
 361
 362         debug("No 'tree' seen in diff-tree output") if !defined $ci{'tree'};
 363
 364         if (defined $ci{'parents'}) {
 365                 $ci{'parent'} = @{ $ci{'parents'} }[0];
 366         }
 367         else {
 368                 $ci{'parent'} = 0 x 40;
 369         }
 370
 371         # Commit message (optional).
 372         while ($dt_ref->[0] =~ /^    /) {
 373                 my $line = shift @{ $dt_ref };
 374                 $line =~ s/^    //;
 375                 push @{ $ci{'comment'} }, $line;
 376         }
 377         shift @{ $dt_ref } if $dt_ref->[0] =~ /^$/;
 378
 379         # Modified files.
 380         while (my $line = shift @{ $dt_ref }) {
 381                 if ($line =~ m{^
 382                         (:+)       # number of parents
 383                         ([^\t]+)\t # modes, sha1, status
 384                         (.*)       # file names
 385                 $}xo) {
 386                         my $num_parents = length $1;
 387                         my @tmp = split(" ", $2);
 388                         my ($file, $file_to) = split("\t", $3);
 389                         my @mode_from = splice(@tmp, 0, $num_parents);
 390                         my $mode_to = shift(@tmp);
 391                         my @sha1_from = splice(@tmp, 0, $num_parents);
 392                         my $sha1_to = shift(@tmp);
 393                         my $status = shift(@tmp);
 394
 395                         if (length $file) {
 396                                 push @{ $ci{'details'} }, {
 397                                         'file'      => decode_git_file($file),
 398                                         'sha1_from' => $sha1_from[0],
 399                                         'sha1_to'   => $sha1_to,
 400                                         'mode_from' => $mode_from[0],
 401                                         'mode_to'   => $mode_to,
 402                                         'status'    => $status,
 403                                 };
 404                         }
 405                         next;
 406                 };
 407                 last;
 408         }
 409
 410         return \%ci;
 411 }
 412
 413 sub git_commit_info ($;$) {
 414         # Return an array of commit info hashes of num commits
 415         # starting from the given sha1sum.
 416         my ($sha1, $num) = @_;
 417
 418         my @opts;
 419         push @opts, "--max-count=$num" if defined $num;
 420
 421         my @raw_lines = run_or_die('git', 'log', @opts,
 422                 '--pretty=raw', '--raw', '--abbrev=40', '--always', '-c',
 423                 '-r', $sha1, '--', '.');
 424
 425         my @ci;
 426         while (my $parsed = parse_diff_tree(\@raw_lines)) {
 427                 push @ci, $parsed;
 428         }
 429
 430         warn "Cannot parse commit info for '$sha1' commit" if !@ci;
 431
 432         return wantarray ? @ci : $ci[0];
 433 }
 434
 435 sub git_sha1 (;$) {
 436         # Return head sha1sum (of given file).
 437         my $file = shift || q{--};
 438
 439         # Ignore error since a non-existing file might be given.
 440         my ($sha1) = run_or_non('git', 'rev-list', '--max-count=1', 'HEAD',
 441                 '--', $file);
 442         if ($sha1) {
 443                 ($sha1) = $sha1 =~ m/($sha1_pattern)/; # sha1 is untainted now
 444         }
 445         else {
 446                 debug("Empty sha1sum for '$file'.");
 447         }
 448         return defined $sha1 ? $sha1 : q{};
 449 }
 450
 451 sub rcs_update () {
 452         # Update working directory.
 453
 454         if (length $config{gitorigin_branch}) {
 455                 run_or_cry('git', 'pull', $config{gitorigin_branch});
 456         }
 457 }
 458
 459 sub rcs_prepedit ($) {
 460         # Return the commit sha1sum of the file when editing begins.
 461         # This will be later used in rcs_commit if a merge is required.
 462         my ($file) = @_;
 463
 464         return git_sha1($file);
 465 }
 466
 467 sub rcs_commit (@) {
 468         # Try to commit the page; returns undef on _success_ and
 469         # a version of the page with the rcs's conflict markers on
 470         # failure.
 471         my %params=@_;
 472
 473         # Check to see if the page has been changed by someone else since
 474         # rcs_prepedit was called.
 475         my $cur    = git_sha1($params{file});
 476         my ($prev) = $params{token} =~ /^($sha1_pattern)$/; # untaint
 477
 478         if (defined $cur && defined $prev && $cur ne $prev) {
 479                 my $conflict = merge_past($prev, $params{file}, $dummy_commit_msg);
 480                 return $conflict if defined $conflict;
 481         }
 482
 483         rcs_add($params{file});
 484         return rcs_commit_staged(
 485                 message => $params{message},
 486                 session => $params{session},
 487         );
 488 }
 489
 490 sub rcs_commit_staged (@) {
 491         # Commits all staged changes. Changes can be staged using rcs_add,
 492         # rcs_remove, and rcs_rename.
 493         my %params=@_;
 494
 495         my %env=%ENV;
 496
 497         if (defined $params{session}) {
 498                 # Set the commit author and email based on web session info.
 499                 my $u;
 500                 if (defined $params{session}->param("name")) {
 501                         $u=$params{session}->param("name");
 502                 }
 503                 elsif (defined $params{session}->remote_addr()) {
 504                         $u=$params{session}->remote_addr();
 505                 }
 506                 if (defined $u) {
 507                         $u=encode_utf8($u);
 508                         $ENV{GIT_AUTHOR_NAME}=$u;
 509                 }
 510                 if (defined $params{session}->param("username")) {
 511                         $u=encode_utf8($params{session}->param("username"));
 512                 }
 513                 if (defined $u) {
 514                         $ENV{GIT_AUTHOR_EMAIL}="$u\@web";
 515                 }
 516         }
 517
 518         $params{message} = IkiWiki::possibly_foolish_untaint($params{message});
 519         my @opts;
 520         if ($params{message} !~ /\S/) {
 521                 # Force git to allow empty commit messages.
 522                 # (If this version of git supports it.)
 523                 my ($version)=`git --version` =~ /git version (.*)/;
 524                 if ($version ge "1.5.4") {
 525                         push @opts, '--cleanup=verbatim';
 526                 }
 527                 else {
 528                         $params{message}.=".";
 529                 }
 530         }
 531         push @opts, '-q';
 532         # git commit returns non-zero if file has not been really changed.
 533         # so we should ignore its exit status (hence run_or_non).
 534         if (run_or_non('git', 'commit', @opts, '-m', $params{message})) {
 535                 if (length $config{gitorigin_branch}) {
 536                         run_or_cry('git', 'push', $config{gitorigin_branch});
 537                 }
 538         }
 539
 540         %ENV=%env;
 541         return undef; # success
 542 }
 543
 544 sub rcs_add ($) {
 545         # Add file to archive.
 546
 547         my ($file) = @_;
 548
 549         run_or_cry('git', 'add', $file);
 550 }
 551
 552 sub rcs_remove ($) {
 553         # Remove file from archive.
 554
 555         my ($file) = @_;
 556
 557         run_or_cry('git', 'rm', '-f', $file);
 558 }
 559
 560 sub rcs_rename ($$) {
 561         my ($src, $dest) = @_;
 562
 563         run_or_cry('git', 'mv', '-f', $src, $dest);
 564 }
 565
 566 sub rcs_recentchanges ($) {
 567         # List of recent changes.
 568
 569         my ($num) = @_;
 570
 571         eval q{use Date::Parse};
 572         error($@) if $@;
 573
 574         my @rets;
 575         foreach my $ci (git_commit_info('HEAD', $num || 1)) {
 576                 # Skip redundant commits.
 577                 next if ($ci->{'comment'} && @{$ci->{'comment'}}[0] eq $dummy_commit_msg);
 578
 579                 my ($sha1, $when) = (
 580                         $ci->{'sha1'},
 581                         $ci->{'author_epoch'}
 582                 );
 583
 584                 my @pages;
 585                 foreach my $detail (@{ $ci->{'details'} }) {
 586                         my $file = $detail->{'file'};
 587
 588                         my $diffurl = defined $config{'diffurl'} ? $config{'diffurl'} : "";
 589                         $diffurl =~ s/\[\[file\]\]/$file/go;
 590                         $diffurl =~ s/\[\[sha1_parent\]\]/$ci->{'parent'}/go;
 591                         $diffurl =~ s/\[\[sha1_from\]\]/$detail->{'sha1_from'}/go;
 592                         $diffurl =~ s/\[\[sha1_to\]\]/$detail->{'sha1_to'}/go;
 593                         $diffurl =~ s/\[\[sha1_commit\]\]/$sha1/go;
 594
 595                         push @pages, {
 596                                 page => pagename($file),
 597                                 diffurl => $diffurl,
 598                         };
 599                 }
 600
 601                 my @messages;
 602                 my $pastblank=0;
 603                 foreach my $line (@{$ci->{'comment'}}) {
 604                         $pastblank=1 if $line eq '';
 605                         next if $pastblank && $line=~m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i;
 606                         push @messages, { line => $line };
 607                 }
 608
 609                 my $user=$ci->{'author_username'};
 610                 my $web_commit = ($ci->{'author'} =~ /\@web>/);
 611                 my $nickname;
 612
 613                 # Set nickname only if a non-url author_username is available,
 614                 # and author_name is an url.
 615                 if ($user !~ /:\/\// && defined $ci->{'author_name'} &&
 616                     $ci->{'author_name'} =~ /:\/\//) {
 617                         $nickname=$user;
 618                         $user=$ci->{'author_name'};
 619                 }
 620
 621                 # compatability code for old web commit messages
 622                 if (! $web_commit &&
 623                       defined $messages[0] &&
 624                       $messages[0]->{line} =~ m/$config{web_commit_regexp}/) {
 625                         $user = defined $2 ? "$2" : "$3";
 626                         $messages[0]->{line} = $4;
 627                         $web_commit=1;
 628                 }
 629
 630                 push @rets, {
 631                         rev        => $sha1,
 632                         user       => $user,
 633                         nickname   => $nickname,
 634                         committype => $web_commit ? "web" : "git",
 635                         when       => $when,
 636                         message    => [@messages],
 637                         pages      => [@pages],
 638                 } if @pages;
 639
 640                 last if @rets >= $num;
 641         }
 642
 643         return @rets;
 644 }
 645
 646 sub rcs_diff ($) {
 647         my $rev=shift;
 648         my ($sha1) = $rev =~ /^($sha1_pattern)$/; # untaint
 649         my @lines;
 650         foreach my $line (run_or_non("git", "show", $sha1)) {
 651                 if (@lines || $line=~/^diff --git/) {
 652                         push @lines, $line."\n";
 653                 }
 654         }
 655         if (wantarray) {
 656                 return @lines;
 657         }
 658         else {
 659                 return join("", @lines);
 660         }
 661 }
 662
 663 {
 664 my %time_cache;
 665
 666 sub findtimes ($$) {
 667         my $file=shift;
 668         my $id=shift; # 0 = mtime ; 1 = ctime
 669
 670         if (! keys %time_cache) {
 671                 my $date;
 672                 foreach my $line (run_or_die('git', 'log',
 673                                 '--pretty=format:%ct',
 674                                 '--name-only', '--relative')) {
 675                         if (! defined $date && $line =~ /^(\d+)$/) {
 676                                 $date=$line;
 677                         }
 678                         elsif (! length $line) {
 679                                 $date=undef;
 680                         }
 681                         else {
 682                                 my $f=decode_git_file($line);
 683
 684                                 if (! $time_cache{$f}) {
 685                                         $time_cache{$f}[0]=$date; # mtime
 686                                 }
 687                                 $time_cache{$f}[1]=$date; # ctime
 688                         }
 689                 }
 690         }
 691
 692         return exists $time_cache{$file} ? $time_cache{$file}[$id] : 0;
 693 }
 694
 695 }
 696
 697 sub rcs_getctime ($) {
 698         my $file=shift;
 699
 700         return findtimes($file, 1);
 701 }
 702
 703 sub rcs_getmtime ($) {
 704         my $file=shift;
 705
 706         return findtimes($file, 0);
 707 }
 708
 709 sub rcs_receive () {
 710         # The wiki may not be the only thing in the git repo.
 711         # Determine if it is in a subdirectory by examining the srcdir,
 712         # and its parents, looking for the .git directory.
 713         my $subdir="";
 714         my $dir=$config{srcdir};
 715         while (! -d "$dir/.git") {
 716                 $subdir=IkiWiki::basename($dir)."/".$subdir;
 717                 $dir=IkiWiki::dirname($dir);
 718                 if (! length $dir) {
 719                         error("cannot determine root of git repo");
 720                 }
 721         }
 722
 723         my @rets;
 724         while (<>) {
 725                 chomp;
 726                 my ($oldrev, $newrev, $refname) = split(' ', $_, 3);
 727
 728                 # only allow changes to gitmaster_branch
 729                 if ($refname !~ /^refs\/heads\/\Q$config{gitmaster_branch}\E$/) {
 730                         error sprintf(gettext("you are not allowed to change %s"), $refname);
 731                 }
 732
 733                 # Avoid chdir when running git here, because the changes
 734                 # are in the master git repo, not the srcdir repo.
 735                 # The pre-recieve hook already puts us in the right place.
 736                 $no_chdir=1;
 737                 my @changes=git_commit_info($oldrev."..".$newrev);
 738                 $no_chdir=0;
 739
 740                 foreach my $ci (@changes) {
 741                         foreach my $detail (@{ $ci->{'details'} }) {
 742                                 my $file = $detail->{'file'};
 743
 744                                 # check that all changed files are in the
 745                                 # subdir
 746                                 if (length $subdir &&
 747                                     ! ($file =~ s/^\Q$subdir\E//)) {
 748                                         error sprintf(gettext("you are not allowed to change %s"), $file);
 749                                 }
 750
 751                                 my ($action, $mode, $path);
 752                                 if ($detail->{'status'} =~ /^[M]+\d*$/) {
 753                                         $action="change";
 754                                         $mode=$detail->{'mode_to'};
 755                                 }
 756                                 elsif ($detail->{'status'} =~ /^[AM]+\d*$/) {
 757                                         $action="add";
 758                                         $mode=$detail->{'mode_to'};
 759                                 }
 760                                 elsif ($detail->{'status'} =~ /^[DAM]+\d*/) {
 761                                         $action="remove";
 762                                         $mode=$detail->{'mode_from'};
 763                                 }
 764                                 else {
 765                                         error "unknown status ".$detail->{'status'};
 766                                 }
 767
 768                                 # test that the file mode is ok
 769                                 if ($mode !~ /^100[64][64][64]$/) {
 770                                         error sprintf(gettext("you cannot act on a file with mode %s"), $mode);
 771                                 }
 772                                 if ($action eq "change") {
 773                                         if ($detail->{'mode_from'} ne $detail->{'mode_to'}) {
 774                                                 error gettext("you are not allowed to change file modes");
 775                                         }
 776                                 }
 777
 778                                 # extract attachment to temp file
 779                                 if (($action eq 'add' || $action eq 'change') &&
 780                                      ! pagetype($file)) {
 781                                         eval q{use File::Temp};
 782                                         die $@ if $@;
 783                                         my $fh;
 784                                         ($fh, $path)=File::Temp::tempfile("XXXXXXXXXX", UNLINK => 1);
 785                                         if (system("git show ".$detail->{sha1_to}." > '$path'") != 0) {
 786                                                 error("failed writing temp file");
 787                                         }
 788                                 }
 789
 790                                 push @rets, {
 791                                         file => $file,
 792                                         action => $action,
 793                                         path => $path,
 794                                 };
 795                         }
 796                 }
 797         }
 798
 799         return reverse @rets;
 800 }
 801
 802 1