IkiWiki/Plugin/autoindex.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::autoindex;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7 use Encode;
   8
   9 sub import {
  10         hook(type => "checkconfig", id => "autoindex", call => \&checkconfig);
  11         hook(type => "getsetup", id => "autoindex", call => \&getsetup);
  12         hook(type => "refresh", id => "autoindex", call => \&refresh);
  13         IkiWiki::loadplugin("transient");
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                 },
  22                 autoindex_commit => {
  23                         type => "boolean",
  24                         example => 1,
  25                         default => 1,
  26                         description => "commit autocreated index pages",
  27                         safe => 1,
  28                         rebuild => 0,
  29                 },
  30 }
  31
  32 sub checkconfig () {
  33         if (! defined $config{autoindex_commit}) {
  34                 $config{autoindex_commit} = 1;
  35         }
  36 }
  37
  38 sub genindex ($) {
  39         my $page=shift;
  40         my $file=newpagefile($page, $config{default_pageext});
  41
  42         add_autofile($file, "autoindex", sub {
  43                         my $message = sprintf(gettext("creating index page %s"),
  44                                 $page);
  45                         debug($message);
  46
  47                         my $dir = $config{srcdir};
  48                         if (! $config{autoindex_commit}) {
  49                                 $dir = $IkiWiki::Plugin::transient::transientdir;
  50                         }
  51
  52                         my $template = template("autoindex.tmpl");
  53                         $template->param(page => $page);
  54                         writefile($file, $dir, $template->output);
  55
  56                         if ($config{rcs} && $config{autoindex_commit}) {
  57                                 IkiWiki::disable_commit_hook();
  58                                 IkiWiki::rcs_add($file);
  59                                 IkiWiki::rcs_commit_staged(message => $message);
  60                                 IkiWiki::enable_commit_hook();
  61                         }
  62                 });
  63 }
  64
  65 sub refresh () {
  66         eval q{use File::Find};
  67         error($@) if $@;
  68         eval q{use Cwd};
  69         error($@) if $@;
  70         my $origdir=getcwd();
  71
  72         my (%pages, %dirs);
  73         foreach my $dir ($config{srcdir}, @{$config{underlaydirs}}, $config{underlaydir}) {
  74                 chdir($dir) || next;
  75
  76                 find({
  77                         no_chdir => 1,
  78                         wanted => sub {
  79                                 my $file=decode_utf8($_);
  80                                 $file=~s/^\.\/?//;
  81                                 return unless length $file;
  82                                 if (IkiWiki::file_pruned($file)) {
  83                                         $File::Find::prune=1;
  84                                 }
  85                                 elsif (! -l $_) {
  86                                         my ($f) = $file =~ /$config{wiki_file_regexp}/; # untaint
  87                                         return unless defined $f;
  88                                         return if $f =~ /\._([^.]+)$/; # skip internal page
  89                                         if (! -d _) {
  90                                                 $pages{pagename($f)}=1;
  91                                         }
  92                                         elsif ($dir eq $config{srcdir} || ! $config{autoindex_commit}) {
  93                                                 $dirs{$f}=1;
  94                                         }
  95                                 }
  96                         }
  97                 }, '.');
  98
  99                 chdir($origdir) || die "chdir $origdir: $!";
 100         }
 101
 102         # Compatibility code.
 103         #
 104         # {deleted} contains pages that have been deleted at some point.
 105         # This plugin used to delete from the hash sometimes, but no longer
 106         # does; in [[todo/autoindex_should_use_add__95__autofile]] Joey
 107         # thought the old behaviour was probably a bug.
 108         #
 109         # The effect of listing a page in {deleted} was to avoid re-creating
 110         # it; we migrate these pages to {autofile} which has the same effect.
 111         # However, {autofile} contains source filenames whereas {deleted}
 112         # contains page names.
 113         my %deleted;
 114         if (ref $wikistate{autoindex}{deleted}) {
 115                 %deleted=%{$wikistate{autoindex}{deleted}};
 116                 delete $wikistate{autoindex}{deleted};
 117         }
 118         elsif (ref $pagestate{index}{autoindex}{deleted}) {
 119                 # an even older version
 120                 %deleted=%{$pagestate{index}{autoindex}{deleted}};
 121                 delete $pagestate{index}{autoindex};
 122         }
 123
 124         if (keys %deleted) {
 125                 foreach my $dir (keys %deleted) {
 126                         my $file=newpagefile($dir, $config{default_pageext});
 127                         $wikistate{autoindex}{autofile}{$file} = 1;
 128                 }
 129         }
 130
 131         foreach my $dir (keys %dirs) {
 132                 if (! exists $pages{$dir} && grep /^$dir\/.*/, keys %pages) {
 133                         genindex($dir);
 134                 }
 135         }
 136 }
 137
 138 1