IkiWiki/Plugin/websetup.pm

   1 #!/usr/bin/perl
   2 package IkiWiki::Plugin::websetup;
   3
   4 use warnings;
   5 use strict;
   6 use IkiWiki 3.00;
   7
   8 sub import {
   9         hook(type => "getsetup", id => "websetup", call => \&getsetup);
  10         hook(type => "checkconfig", id => "websetup", call => \&checkconfig);
  11         hook(type => "sessioncgi", id => "websetup", call => \&sessioncgi);
  12         hook(type => "formbuilder_setup", id => "websetup",
  13              call => \&formbuilder_setup);
  14 }
  15
  16 sub getsetup () {
  17         return
  18                 plugin => {
  19                         safe => 1,
  20                         rebuild => 0,
  21                         section => "web",
  22                 },
  23                 websetup_force_plugins => {
  24                         type => "string",
  25                         example => [],
  26                         description => "list of plugins that cannot be enabled/disabled via the web interface",
  27                         safe => 0,
  28                         rebuild => 0,
  29                 },
  30                 websetup_unsafe => {
  31                         type => "string",
  32                         example => [],
  33                         description => "list of additional setup field keys to treat as unsafe",
  34                         safe => 0,
  35                         rebuild => 0,
  36                 },
  37                 websetup_show_unsafe => {
  38                         type => "boolean",
  39                         example => 1,
  40                         description => "show unsafe settings, read-only, in web interface?",
  41                         safe => 0,
  42                         rebuild => 0,
  43                 },
  44 }
  45
  46 sub checkconfig () {
  47         if (! exists $config{websetup_show_unsafe}) {
  48                 $config{websetup_show_unsafe}=1;
  49         }
  50 }
  51
  52 sub formatexample ($$) {
  53         my $example=shift;
  54         my $value=shift;
  55
  56         if (defined $value && length $value) {
  57                 return "";
  58         }
  59         elsif (defined $example && ! ref $example && length $example) {
  60                 return "<br/ ><small>Example: <tt>$example</tt></small>";
  61         }
  62         else {
  63                 return "";
  64         }
  65 }
  66
  67 sub issafe ($) {
  68         my $key=shift;
  69
  70         return ! grep { $_ eq $key } @{$config{websetup_unsafe}};
  71 }
  72
  73 sub showfields ($$$@) {
  74         my $form=shift;
  75         my $plugin=shift;
  76         my $enabled=shift;
  77
  78         my @show;
  79         my %plugininfo;
  80         while (@_) {
  81                 my $key=shift;
  82                 my %info=%{shift()};
  83
  84                 if ($key eq 'plugin') {
  85                         %plugininfo=%info;
  86                         next;
  87                 }
  88
  89                 # skip internal settings
  90                 next if defined $info{type} && $info{type} eq "internal";
  91                 # XXX hashes not handled yet
  92                 next if ref $config{$key} && ref $config{$key} eq 'HASH' || ref $info{example} eq 'HASH';
  93                 # maybe skip unsafe settings
  94                 next if ! ($config{websetup_show_unsafe} && $config{websetup_advanced}) &&
  95                         (! $info{safe} || ! issafe($key));
  96                 # maybe skip advanced settings
  97                 next if $info{advanced} && ! $config{websetup_advanced};
  98                 # these are handled specially, so don't show
  99                 next if $key eq 'add_plugins' || $key eq 'disable_plugins';
 100
 101                 push @show, $key, \%info;
 102         }
 103
 104         my $section=defined $plugin
 105                 ? sprintf(gettext("%s plugin:"), $plugininfo{section})." ".$plugin
 106                 : "main";
 107         my %enabledfields;
 108         my $shownfields=0;
 109
 110         my $plugin_forced=defined $plugin && (! $plugininfo{safe} ||
 111                 (exists $config{websetup_force_plugins} && grep { $_ eq $plugin } @{$config{websetup_force_plugins}}));
 112         if ($plugin_forced && ! $enabled) {
 113                 # plugin is forced disabled, so skip its settings
 114                 @show=();
 115         }
 116
 117         my $section_fieldset;
 118         if (defined $plugin) {
 119                 # Define the combined fieldset for the plugin's section.
 120                 # This ensures that this fieldset comes first.
 121                 $section_fieldset=sprintf(gettext("%s plugins"), $plugininfo{section});
 122                 $form->field(name => "placeholder.$plugininfo{section}",
 123                         type => "hidden",
 124                         fieldset => $section_fieldset);
 125         }
 126
 127         # show plugin toggle
 128         if (defined $plugin && (! $plugin_forced || $config{websetup_advanced})) {
 129                 my $name="enable.$plugin";
 130                 $form->field(
 131                         name => $name,
 132                         label => "",
 133                         type => "checkbox",
 134                         fieldset => $section,
 135                         options => [ [ 1 => sprintf(gettext("enable %s?"), $plugin) ]]
 136                 );
 137                 if (! $form->submitted) {
 138                         $form->field(name => $name, value => $enabled);
 139                 }
 140                 if ($plugin_forced) {
 141                         $form->field(name => $name, disabled => 1);
 142                 }
 143                 else {
 144                         $enabledfields{$name}=[$name, \%plugininfo];
 145                 }
 146         }
 147
 148         # show plugin settings
 149         while (@show) {
 150                 my $key=shift @show;
 151                 my %info=%{shift @show};
 152
 153                 my $description=$info{description};
 154                 if (exists $info{link} && length $info{link}) {
 155                         if ($info{link} =~ /^\w+:\/\//) {
 156                                 $description="<a href=\"$info{link}\">$description</a>";
 157                         }
 158                         else {
 159                                 $description=htmllink("", "", $info{link}, noimageinline => 1, linktext => $description);
 160                         }
 161                 }
 162
 163                 # multiple plugins can have the same field
 164                 my $name=defined $plugin ? $plugin.".".$key : $section.".".$key;
 165
 166                 my $value=$config{$key};
 167                 if (! defined $value) {
 168                         $value="";
 169                 }
 170
 171                 if (ref $value eq 'ARRAY' || ref $info{example} eq 'ARRAY') {
 172                         $value=[(ref $value eq 'ARRAY' ? map { Encode::encode_utf8($_) }  @{$value} : "")];
 173                         push @$value, "", "" if $info{safe} && issafe($key); # blank items for expansion
 174                 }
 175                 else {
 176                         $value=Encode::encode_utf8($value);
 177                 }
 178
 179                 if ($info{type} eq "string") {
 180                         $form->field(
 181                                 name => $name,
 182                                 label => $description,
 183                                 comment => formatexample($info{example}, $value),
 184                                 type => "text",
 185                                 value => $value,
 186                                 size => 60,
 187                                 fieldset => $section,
 188                         );
 189                 }
 190                 elsif ($info{type} eq "pagespec") {
 191                         $form->field(
 192                                 name => $name,
 193                                 label => $description,
 194                                 comment => formatexample($info{example}, $value),
 195                                 type => "text",
 196                                 value => $value,
 197                                 size => 60,
 198                                 validate => \&IkiWiki::pagespec_valid,
 199                                 fieldset => $section,
 200                         );
 201                 }
 202                 elsif ($info{type} eq "integer") {
 203                         $form->field(
 204                                 name => $name,
 205                                 label => $description,
 206                                 comment => formatexample($info{example}, $value),
 207                                 type => "text",
 208                                 value => $value,
 209                                 size => 5,
 210                                 validate => '/^[0-9]+$/',
 211                                 fieldset => $section,
 212                         );
 213                 }
 214                 elsif ($info{type} eq "boolean") {
 215                         $form->field(
 216                                 name => $name,
 217                                 label => "",
 218                                 type => "checkbox",
 219                                 options => [ [ 1 => $description ] ],
 220                                 fieldset => $section,
 221                         );
 222                         if (! $form->submitted ||
 223                             ($info{advanced} && $form->submitted eq 'Advanced Mode')) {
 224                                 $form->field(name => $name, value => $value);
 225                         }
 226                 }
 227
 228                 if (! $info{safe} || ! issafe($key)) {
 229                         $form->field(name => $name, disabled => 1);
 230                 }
 231                 else {
 232                         $enabledfields{$name}=[$key, \%info];
 233                 }
 234                 $shownfields++;
 235         }
 236
 237         # if no fields were shown for the plugin, drop it into a combined
 238         # fieldset for its section
 239         if (defined $plugin && (! $plugin_forced || $config{websetup_advanced}) &&
 240             ! $shownfields) {
 241                 $form->field(name => "enable.$plugin", fieldset => $section_fieldset);
 242         }
 243
 244         return %enabledfields;
 245 }
 246
 247 sub enable_plugin ($) {
 248         my $plugin=shift;
 249
 250         $config{disable_plugins}=[grep { $_ ne $plugin } @{$config{disable_plugins}}];
 251         push @{$config{add_plugins}}, $plugin;
 252 }
 253
 254 sub disable_plugin ($) {
 255         my $plugin=shift;
 256
 257         $config{add_plugins}=[grep { $_ ne $plugin } @{$config{add_plugins}}];
 258         push @{$config{disable_plugins}}, $plugin;
 259 }
 260
 261 sub showform ($$) {
 262         my $cgi=shift;
 263         my $session=shift;
 264
 265         IkiWiki::needsignin($cgi, $session);
 266
 267         if (! defined $session->param("name") ||
 268             ! IkiWiki::is_admin($session->param("name"))) {
 269                 error(gettext("you are not logged in as an admin"));
 270         }
 271
 272         if (! exists $config{setupfile}) {
 273                 error(gettext("setup file for this wiki is not known"));
 274         }
 275
 276         eval q{use CGI::FormBuilder};
 277         error($@) if $@;
 278
 279         my $form = CGI::FormBuilder->new(
 280                 title => "setup",
 281                 name => "setup",
 282                 header => 0,
 283                 charset => "utf-8",
 284                 method => 'POST',
 285                 javascript => 0,
 286                 reset => 1,
 287                 params => $cgi,
 288                 fieldsets => [
 289                         [main => gettext("main")],
 290                 ],
 291                 action => $config{cgiurl},
 292                 template => {type => 'div'},
 293                 stylesheet => 1,
 294         );
 295
 296         $form->field(name => "do", type => "hidden", value => "setup",
 297                 force => 1);
 298         $form->field(name => "rebuild_asked", type => "hidden");
 299         $form->field(name => "showadvanced", type => "hidden");
 300
 301         if ($form->submitted eq 'Basic Mode') {
 302                 $form->field(name => "showadvanced", type => "hidden",
 303                         value => 0, force => 1);
 304         }
 305         elsif ($form->submitted eq 'Advanced Mode') {
 306                 $form->field(name => "showadvanced", type => "hidden",
 307                         value => 1, force => 1);
 308         }
 309         my $advancedtoggle;
 310         if ($form->field("showadvanced")) {
 311                 $config{websetup_advanced}=1;
 312                 $advancedtoggle="Basic Mode";
 313         }
 314         else {
 315                 $config{websetup_advanced}=0;
 316                 $advancedtoggle="Advanced Mode";
 317         }
 318
 319         my $buttons=["Save Setup", $advancedtoggle, "Cancel"];
 320
 321         IkiWiki::decode_form_utf8($form);
 322         IkiWiki::run_hooks(formbuilder_setup => sub {
 323                 shift->(form => $form, cgi => $cgi, session => $session,
 324                         buttons => $buttons);
 325         });
 326
 327         my %fields=showfields($form, undef, undef, IkiWiki::getsetup());
 328
 329         # record all currently enabled plugins before all are loaded
 330         my %enabled_plugins=%IkiWiki::loaded_plugins;
 331
 332         # per-plugin setup
 333         require IkiWiki::Setup;
 334         foreach my $pair (IkiWiki::Setup::getsetup()) {
 335                 my $plugin=$pair->[0];
 336                 my $setup=$pair->[1];
 337
 338                 my %shown=showfields($form, $plugin, $enabled_plugins{$plugin}, @{$setup});
 339                 if (%shown) {
 340                         $fields{$_}=$shown{$_} foreach keys %shown;
 341                 }
 342         }
 343
 344         IkiWiki::decode_form_utf8($form);
 345
 346         if ($form->submitted eq "Cancel") {
 347                 IkiWiki::redirect($cgi, $config{url});
 348                 return;
 349         }
 350         elsif (($form->submitted eq 'Save Setup' || $form->submitted eq 'Rebuild Wiki') && $form->validate) {
 351                 # Push values from form into %config, avoiding unnecessary
 352                 # changes, and keeping track of which changes need a
 353                 # rebuild.
 354                 my %rebuild;
 355                 foreach my $field (keys %fields) {
 356                         my %info=%{$fields{$field}->[1]};
 357                         my $key=$fields{$field}->[0];
 358                         my @value=$form->field($field);
 359                         if (! @value) {
 360                                 @value=0;
 361                         }
 362
 363                         if (! $info{safe} || ! issafe($key)) {
 364                                 error("unsafe field $key"); # should never happen
 365                         }
 366
 367                         if (exists $info{rebuild} &&
 368                             ($info{rebuild} || ! defined $info{rebuild})) {
 369                                 $rebuild{$field}=$info{rebuild};
 370                         }
 371
 372                         if ($field=~/^enable\.(.*)/) {
 373                                 my $plugin=$1;
 374                                 $value[0]=0 if ! length $value[0];
 375                                 if ($value[0] != exists $enabled_plugins{$plugin}) {
 376                                         if ($value[0]) {
 377                                                 enable_plugin($plugin);
 378                                         }
 379                                         else {
 380                                                 disable_plugin($plugin);
 381
 382                                         }
 383                                 }
 384                                 else {
 385                                         delete $rebuild{$field};
 386                                 }
 387                                 next;
 388                         }
 389
 390                         if (ref $config{$key} eq "ARRAY" || ref $info{example} eq "ARRAY") {
 391                                 @value=sort grep { length $_ } @value;
 392                                 my @oldvalue=sort grep { length $_ }
 393                                         (defined $config{$key} ? @{$config{$key}} : ());
 394                                 my $same=(@oldvalue) == (@value);
 395                                 for (my $x=0; $same && $x < @value; $x++) {
 396                                         $same=0 if $value[$x] ne $oldvalue[$x];
 397                                 }
 398                                 if ($same) {
 399                                         delete $rebuild{$field};
 400                                 }
 401                                 else {
 402                                         $config{$key}=\@value;
 403                                 }
 404                         }
 405                         elsif (ref $config{$key} || ref $info{example}) {
 406                                 error("complex field $key"); # should never happen
 407                         }
 408                         else {
 409                                 if (defined $config{$key} && $config{$key} eq $value[0]) {
 410                                         delete $rebuild{$field};
 411                                 }
 412                                 elsif (! defined $config{$key} && ! length $value[0]) {
 413                                         delete $rebuild{$field};
 414                                 }
 415                                 elsif ((! defined $config{$key} || ! $config{$key}) &&
 416                                        ! $value[0] && $info{type} eq "boolean") {
 417                                         delete $rebuild{$field};
 418                                 }
 419                                 else {
 420                                         $config{$key}=$value[0];
 421                                 }
 422                         }
 423                 }
 424
 425                 if (%rebuild && ! $form->field("rebuild_asked")) {
 426                         my $required=0;
 427                         foreach my $field ($form->field) {
 428                                 $required=1 if $rebuild{$field};
 429                                 next if exists $rebuild{$field};
 430                                 $form->field(name => $field, type => "hidden");
 431                         }
 432                         if ($required) {
 433                                 $form->text(gettext("The configuration changes shown below require a wiki rebuild to take effect."));
 434                                 $buttons=["Rebuild Wiki", "Cancel"];
 435                         }
 436                         else {
 437                                 $form->text(gettext("For the configuration changes shown below to fully take effect, you may need to rebuild the wiki."));
 438                                 $buttons=["Rebuild Wiki", "Save Setup", "Cancel"];
 439                         }
 440                         $form->field(name => "rebuild_asked", value => 1, force => 1);
 441                         $form->reset(0); # doesn't really make sense here
 442                 }
 443                 else {
 444                         my $oldsetup=readfile($config{setupfile});
 445                         IkiWiki::Setup::dump($config{setupfile});
 446
 447                         IkiWiki::saveindex();
 448                         IkiWiki::unlockwiki();
 449
 450                         # Print the top part of a standard misctemplate,
 451                         # then show the rebuild or refresh, live.
 452                         my $divider="\0";
 453                         my $html=IkiWiki::misctemplate("setup", $divider);
 454                         IkiWiki::printheader($session);
 455                         my ($head, $tail)=split($divider, $html, 2);
 456                         print $head."<pre>\n";
 457
 458                         my @command;
 459                         if ($form->submitted eq 'Rebuild Wiki') {
 460                                 @command=("ikiwiki", "-setup", $config{setupfile},
 461                                         "-rebuild", "-v");
 462                         }
 463                         else {
 464                                 @command=("ikiwiki", "-setup", $config{setupfile},
 465                                         "-refresh", "-wrappers", "-v");
 466                         }
 467
 468                         close STDERR;
 469                         open(STDERR, ">&STDOUT");
 470                         my $ret=system(@command);
 471                         print "\n<\/pre>";
 472                         if ($ret != 0) {
 473                                 print '<p class="error">'.
 474                                         sprintf(gettext("Error: %s exited nonzero (%s). Discarding setup changes."),
 475                                                 join(" ", @command), $ret).
 476                                         '</p>';
 477                                 open(OUT, ">", $config{setupfile}) || error("$config{setupfile}: $!");
 478                                 print OUT Encode::encode_utf8($oldsetup);
 479                                 close OUT;
 480                         }
 481
 482                         print $tail;
 483                         exit 0;
 484                 }
 485         }
 486
 487         IkiWiki::showform($form, $buttons, $session, $cgi);
 488 }
 489
 490 sub sessioncgi ($$) {
 491         my $cgi=shift;
 492         my $session=shift;
 493
 494         if ($cgi->param("do") eq "setup") {
 495                 showform($cgi, $session);
 496                 exit;
 497         }
 498 }
 499
 500 sub formbuilder_setup (@) {
 501         my %params=@_;
 502
 503         my $form=$params{form};
 504         if ($form->title eq "preferences" &&
 505             IkiWiki::is_admin($params{session}->param("name"))) {
 506                 push @{$params{buttons}}, "Setup";
 507                 if ($form->submitted && $form->submitted eq "Setup") {
 508                         showform($params{cgi}, $params{session});
 509                         exit;
 510                 }
 511         }
 512 }
 513
 514 1