IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use Cwd q{abs_path};
   6 use Data::Dumper;
   7 use IkiWiki;
   8
   9 package IkiWiki;
  10
  11 sub gen_wrapper () { #{{{
  12         $config{srcdir}=abs_path($config{srcdir});
  13         $config{destdir}=abs_path($config{destdir});
  14         my $this=abs_path($0);
  15         if (! -x $this) {
  16                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  17         }
  18
  19         if ($config{setup}) {
  20                 error(gettext("cannot create a wrapper that uses a setup file"));
  21         }
  22         my $wrapper=possibly_foolish_untaint($config{wrapper});
  23         if (! defined $wrapper || ! length $wrapper) {
  24                 error(gettext("wrapper filename not specified"));
  25         }
  26         delete $config{wrapper};
  27
  28         my @envsave;
  29         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  30                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  31                        HTTP_COOKIE REMOTE_USER} if $config{cgi};
  32         my $envsave="";
  33         foreach my $var (@envsave) {
  34                 $envsave.=<<"EOF"
  35         if ((s=getenv("$var")))
  36                 asprintf(&newenviron[i++], "%s=%s", "$var", s);
  37 EOF
  38         }
  39         if ($config{rcs} eq "svn" && $config{notify}) {
  40                 # Support running directly as hooks/post-commit by passing
  41                 # $2 in REV in the environment.
  42                 $envsave.=<<"EOF"
  43         if (argc == 3)
  44                 asprintf(&newenviron[i++], "REV=%s", argv[2]);
  45         else if ((s=getenv("REV")))
  46                 asprintf(&newenviron[i++], "%s=%s", "REV", s);
  47 EOF
  48         }
  49         if ($config{rcs} eq "tla" && $config{notify}) {
  50                 $envsave.=<<"EOF"
  51         if ((s=getenv("ARCH_VERSION")))
  52                 asprintf(&newenviron[i++], "%s=%s", "ARCH_VERSION", s);
  53 EOF
  54         }
  55
  56         $Data::Dumper::Indent=0; # no newlines
  57         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
  58         $configstring=~s/\\/\\\\/g;
  59         $configstring=~s/"/\\"/g;
  60         $configstring=~s/\n/\\\n/g;
  61
  62         open(OUT, ">$wrapper.c") || error(sprintf(gettext("failed to write %s: %s"), "$wrapper.c", $!));;
  63         print OUT <<"EOF";
  64 /* A wrapper for ikiwiki, can be safely made suid. */
  65 #define _GNU_SOURCE
  66 #include <stdio.h>
  67 #include <sys/types.h>
  68 #include <unistd.h>
  69 #include <stdlib.h>
  70 #include <string.h>
  71
  72 extern char **environ;
  73
  74 int main (int argc, char **argv) {
  75         /* Sanitize environment. */
  76         char *s;
  77         char *newenviron[$#envsave+5];
  78         int i=0;
  79 $envsave
  80         newenviron[i++]="HOME=$ENV{HOME}";
  81         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
  82         newenviron[i]=NULL;
  83         environ=newenviron;
  84
  85         if (setregid(getegid(), -1) != 0 || setreuid(geteuid(), -1) != 0) {
  86                 perror("failed to drop real uid/gid");
  87                 exit(1);
  88         }
  89
  90         execl("$this", "$this", NULL);
  91         perror("failed to run $this");
  92         exit(1);
  93 }
  94 EOF
  95         close OUT;
  96         if (system("gcc", "$wrapper.c", "-o", $wrapper) != 0) {
  97                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
  98         }
  99         unlink("$wrapper.c");
 100         if (defined $config{wrappermode} &&
 101             ! chmod(oct($config{wrappermode}), $wrapper)) {
 102                 error("chmod $wrapper: $!");
 103         }
 104         printf(gettext("successfully generated %s\n"), $wrapper);
 105 } #}}}
 106
 107 1