IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4 use warnings;
   5 use strict;
   6 use Encode;
   7 use HTML::Entities;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX;
  10 use open qw{:utf8 :std};
  11
  12 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  13             %renderedfiles %oldrenderedfiles %pagesources %destsources
  14             %depends %hooks %forcerebuild $gettext_obj};
  15
  16 use Exporter q{import};
  17 our @EXPORT = qw(hook debug error template htmlpage add_depends pagespec_match
  18                  bestlink htmllink readfile writefile pagetype srcfile pagename
  19                  displaytime will_render gettext urlto targetpage
  20                  add_underlay
  21                  %config %links %renderedfiles %pagesources %destsources);
  22 our $VERSION = 2.00; # plugin interface version, next is ikiwiki version
  23 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  24 my $installdir=''; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  25
  26 # Optimisation.
  27 use Memoize;
  28 memoize("abs2rel");
  29 memoize("pagespec_translate");
  30 memoize("file_pruned");
  31
  32 sub defaultconfig () { #{{{
  33         return
  34         wiki_file_prune_regexps => [qr/\.\./, qr/^\./, qr/\/\./,
  35                 qr/\.x?html?$/, qr/\.ikiwiki-new$/,
  36                 qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
  37                 qr/(^|\/)_MTN\//,
  38                 qr/\.dpkg-tmp$/],
  39         wiki_link_regexp => qr{
  40                 \[\[                    # beginning of link
  41                 (?:
  42                         ([^\]\|\n\s]+)  # 1: link text
  43                         \|              # followed by '|'
  44                 )?                      # optional
  45
  46                 ([^\s\]#]+)             # 2: page to link to
  47                 (?:
  48                         \#              # '#', beginning of anchor
  49                         ([^\s\]]+)      # 3: anchor text
  50                 )?                      # optional
  51
  52                 \]\]                    # end of link
  53         }x,
  54         wiki_file_regexp => qr/(^[-[:alnum:]_.:\/+]+$)/,
  55         web_commit_regexp => qr/^web commit (by (.*?(?=: |$))|from (\d+\.\d+\.\d+\.\d+)):?(.*)/,
  56         verbose => 0,
  57         syslog => 0,
  58         wikiname => "wiki",
  59         default_pageext => "mdwn",
  60         htmlext => "html",
  61         cgi => 0,
  62         post_commit => 0,
  63         rcs => '',
  64         notify => 0,
  65         url => '',
  66         cgiurl => '',
  67         historyurl => '',
  68         diffurl => '',
  69         rss => 0,
  70         atom => 0,
  71         discussion => 1,
  72         rebuild => 0,
  73         refresh => 0,
  74         getctime => 0,
  75         w3mmode => 0,
  76         wrapper => undef,
  77         wrappermode => undef,
  78         svnrepo => undef,
  79         svnpath => "trunk",
  80         gitorigin_branch => "origin",
  81         gitmaster_branch => "master",
  82         srcdir => undef,
  83         destdir => undef,
  84         pingurl => [],
  85         templatedir => "$installdir/share/ikiwiki/templates",
  86         underlaydir => "$installdir/share/ikiwiki/basewiki",
  87         underlaydirs => [],
  88         setup => undef,
  89         adminuser => undef,
  90         adminemail => undef,
  91         plugin => [qw{mdwn inline htmlscrubber passwordauth openid signinedit
  92                       lockedit conditional}],
  93         libdir => undef,
  94         timeformat => '%c',
  95         locale => undef,
  96         sslcookie => 0,
  97         httpauth => 0,
  98         userdir => "",
  99         usedirs => 1,
 100         numbacklinks => 10,
 101         account_creation_password => "",
 102 } #}}}
 103
 104 sub checkconfig () { #{{{
 105         # locale stuff; avoid LC_ALL since it overrides everything
 106         if (defined $ENV{LC_ALL}) {
 107                 $ENV{LANG} = $ENV{LC_ALL};
 108                 delete $ENV{LC_ALL};
 109         }
 110         if (defined $config{locale}) {
 111                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 112                         $ENV{LANG}=$config{locale};
 113                         $gettext_obj=undef;
 114                 }
 115         }
 116
 117         if ($config{w3mmode}) {
 118                 eval q{use Cwd q{abs_path}};
 119                 error($@) if $@;
 120                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 121                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 122                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 123                         unless $config{cgiurl} =~ m!file:///!;
 124                 $config{url}="file://".$config{destdir};
 125         }
 126
 127         if ($config{cgi} && ! length $config{url}) {
 128                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 129         }
 130
 131         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 132                 unless exists $config{wikistatedir};
 133
 134         if ($config{rcs}) {
 135                 eval qq{use IkiWiki::Rcs::$config{rcs}};
 136                 if ($@) {
 137                         error("Failed to load RCS module IkiWiki::Rcs::$config{rcs}: $@");
 138                 }
 139         }
 140         else {
 141                 require IkiWiki::Rcs::Stub;
 142         }
 143
 144         run_hooks(checkconfig => sub { shift->() });
 145
 146         return 1;
 147 } #}}}
 148
 149 sub loadplugins () { #{{{
 150         if (defined $config{libdir}) {
 151                 unshift @INC, possibly_foolish_untaint($config{libdir});
 152         }
 153
 154         loadplugin($_) foreach @{$config{plugin}};
 155
 156         run_hooks(getopt => sub { shift->() });
 157         if (grep /^-/, @ARGV) {
 158                 print STDERR "Unknown option: $_\n"
 159                         foreach grep /^-/, @ARGV;
 160                 usage();
 161         }
 162
 163         return 1;
 164 } #}}}
 165
 166 sub loadplugin ($) { #{{{
 167         my $plugin=shift;
 168
 169         return if grep { $_ eq $plugin} @{$config{disable_plugins}};
 170
 171         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 172                          "$installdir/lib/ikiwiki") {
 173                 if (defined $dir && -x "$dir/plugins/$plugin") {
 174                         require IkiWiki::Plugin::external;
 175                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 176                         return 1;
 177                 }
 178         }
 179
 180         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 181         eval qq{use $mod};
 182         if ($@) {
 183                 error("Failed to load plugin $mod: $@");
 184         }
 185         return 1;
 186 } #}}}
 187
 188 sub error ($;$) { #{{{
 189         my $message=shift;
 190         my $cleaner=shift;
 191         if ($config{cgi}) {
 192                 print "Content-type: text/html\n\n";
 193                 print misctemplate(gettext("Error"),
 194                         "<p>".gettext("Error").": $message</p>");
 195         }
 196         log_message('err' => $message) if $config{syslog};
 197         if (defined $cleaner) {
 198                 $cleaner->();
 199         }
 200         die $message."\n";
 201 } #}}}
 202
 203 sub debug ($) { #{{{
 204         return unless $config{verbose};
 205         return log_message(debug => @_);
 206 } #}}}
 207
 208 my $log_open=0;
 209 sub log_message ($$) { #{{{
 210         my $type=shift;
 211
 212         if ($config{syslog}) {
 213                 require Sys::Syslog;
 214                 if (! $log_open) {
 215                         Sys::Syslog::setlogsock('unix');
 216                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 217                         $log_open=1;
 218                 }
 219                 return eval {
 220                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 221                 };
 222         }
 223         elsif (! $config{cgi}) {
 224                 return print "@_\n";
 225         }
 226         else {
 227                 return print STDERR "@_\n";
 228         }
 229 } #}}}
 230
 231 sub possibly_foolish_untaint ($) { #{{{
 232         my $tainted=shift;
 233         my ($untainted)=$tainted=~/(.*)/s;
 234         return $untainted;
 235 } #}}}
 236
 237 sub basename ($) { #{{{
 238         my $file=shift;
 239
 240         $file=~s!.*/+!!;
 241         return $file;
 242 } #}}}
 243
 244 sub dirname ($) { #{{{
 245         my $file=shift;
 246
 247         $file=~s!/*[^/]+$!!;
 248         return $file;
 249 } #}}}
 250
 251 sub pagetype ($) { #{{{
 252         my $page=shift;
 253
 254         if ($page =~ /\.([^.]+)$/) {
 255                 return $1 if exists $hooks{htmlize}{$1};
 256         }
 257         return;
 258 } #}}}
 259
 260 sub pagename ($) { #{{{
 261         my $file=shift;
 262
 263         my $type=pagetype($file);
 264         my $page=$file;
 265         $page=~s/\Q.$type\E*$// if defined $type;
 266         return $page;
 267 } #}}}
 268
 269 sub targetpage ($$) { #{{{
 270         my $page=shift;
 271         my $ext=shift;
 272
 273         if (! $config{usedirs} || $page =~ /^index$/ ) {
 274                 return $page.".".$ext;
 275         } else {
 276                 return $page."/index.".$ext;
 277         }
 278 } #}}}
 279
 280 sub htmlpage ($) { #{{{
 281         my $page=shift;
 282
 283         return targetpage($page, $config{htmlext});
 284 } #}}}
 285
 286 sub srcfile ($) { #{{{
 287         my $file=shift;
 288
 289         return "$config{srcdir}/$file" if -e "$config{srcdir}/$file";
 290         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 291                 return "$dir/$file" if -e "$dir/$file";
 292         }
 293         error("internal error: $file cannot be found in $config{srcdir} or underlay");
 294         return;
 295 } #}}}
 296
 297 sub add_underlay ($) { #{{{
 298         my $dir=shift;
 299
 300         if ($dir=~/^\//) {
 301                 unshift @{$config{underlaydirs}}, $dir;
 302         }
 303         else {
 304                 unshift @{$config{underlaydirs}}, "$config{underlaydir}/../$dir";
 305         }
 306
 307         return 1;
 308 } #}}}
 309
 310 sub readfile ($;$$) { #{{{
 311         my $file=shift;
 312         my $binary=shift;
 313         my $wantfd=shift;
 314
 315         if (-l $file) {
 316                 error("cannot read a symlink ($file)");
 317         }
 318
 319         local $/=undef;
 320         open (my $in, "<", $file) || error("failed to read $file: $!");
 321         binmode($in) if ($binary);
 322         return \*$in if $wantfd;
 323         my $ret=<$in>;
 324         close $in || error("failed to read $file: $!");
 325         return $ret;
 326 } #}}}
 327
 328 sub writefile ($$$;$$) { #{{{
 329         my $file=shift; # can include subdirs
 330         my $destdir=shift; # directory to put file in
 331         my $content=shift;
 332         my $binary=shift;
 333         my $writer=shift;
 334
 335         my $test=$file;
 336         while (length $test) {
 337                 if (-l "$destdir/$test") {
 338                         error("cannot write to a symlink ($test)");
 339                 }
 340                 $test=dirname($test);
 341         }
 342         my $newfile="$destdir/$file.ikiwiki-new";
 343         if (-l $newfile) {
 344                 error("cannot write to a symlink ($newfile)");
 345         }
 346
 347         my $dir=dirname($newfile);
 348         if (! -d $dir) {
 349                 my $d="";
 350                 foreach my $s (split(m!/+!, $dir)) {
 351                         $d.="$s/";
 352                         if (! -d $d) {
 353                                 mkdir($d) || error("failed to create directory $d: $!");
 354                         }
 355                 }
 356         }
 357
 358         my $cleanup = sub { unlink($newfile) };
 359         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 360         binmode($out) if ($binary);
 361         if ($writer) {
 362                 $writer->(\*$out, $cleanup);
 363         }
 364         else {
 365                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 366         }
 367         close $out || error("failed saving $newfile: $!", $cleanup);
 368         rename($newfile, "$destdir/$file") ||
 369                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 370
 371         return 1;
 372 } #}}}
 373
 374 my %cleared;
 375 sub will_render ($$;$) { #{{{
 376         my $page=shift;
 377         my $dest=shift;
 378         my $clear=shift;
 379
 380         # Important security check.
 381         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 382             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}})) {
 383                 error("$config{destdir}/$dest independently created, not overwriting with version from $page");
 384         }
 385
 386         if (! $clear || $cleared{$page}) {
 387                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 388         }
 389         else {
 390                 foreach my $old (@{$renderedfiles{$page}}) {
 391                         delete $destsources{$old};
 392                 }
 393                 $renderedfiles{$page}=[$dest];
 394                 $cleared{$page}=1;
 395         }
 396         $destsources{$dest}=$page;
 397
 398         return 1;
 399 } #}}}
 400
 401 sub bestlink ($$) { #{{{
 402         my $page=shift;
 403         my $link=shift;
 404
 405         my $cwd=$page;
 406         if ($link=~s/^\/+//) {
 407                 # absolute links
 408                 $cwd="";
 409         }
 410
 411         do {
 412                 my $l=$cwd;
 413                 $l.="/" if length $l;
 414                 $l.=$link;
 415
 416                 if (exists $links{$l}) {
 417                         return $l;
 418                 }
 419                 elsif (exists $pagecase{lc $l}) {
 420                         return $pagecase{lc $l};
 421                 }
 422         } while $cwd=~s!/?[^/]+$!!;
 423
 424         if (length $config{userdir}) {
 425                 my $l = "$config{userdir}/".lc($link);
 426                 if (exists $links{$l}) {
 427                         return $l;
 428                 }
 429                 elsif (exists $pagecase{lc $l}) {
 430                         return $pagecase{lc $l};
 431                 }
 432         }
 433
 434         #print STDERR "warning: page $page, broken link: $link\n";
 435         return "";
 436 } #}}}
 437
 438 sub isinlinableimage ($) { #{{{
 439         my $file=shift;
 440
 441         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 442 } #}}}
 443
 444 sub pagetitle ($;$) { #{{{
 445         my $page=shift;
 446         my $unescaped=shift;
 447
 448         if ($unescaped) {
 449                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 450         }
 451         else {
 452                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 453         }
 454
 455         return $page;
 456 } #}}}
 457
 458 sub titlepage ($) { #{{{
 459         my $title=shift;
 460         $title=~s/([^-[:alnum:]:+\/.])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 461         return $title;
 462 } #}}}
 463
 464 sub linkpage ($) { #{{{
 465         my $link=shift;
 466         $link=~s/([^-[:alnum:]:+\/._])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
 467         return $link;
 468 } #}}}
 469
 470 sub cgiurl (@) { #{{{
 471         my %params=@_;
 472
 473         return $config{cgiurl}."?".
 474                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
 475 } #}}}
 476
 477 sub baseurl (;$) { #{{{
 478         my $page=shift;
 479
 480         return "$config{url}/" if ! defined $page;
 481
 482         $page=htmlpage($page);
 483         $page=~s/[^\/]+$//;
 484         $page=~s/[^\/]+\//..\//g;
 485         return $page;
 486 } #}}}
 487
 488 sub abs2rel ($$) { #{{{
 489         # Work around very innefficient behavior in File::Spec if abs2rel
 490         # is passed two relative paths. It's much faster if paths are
 491         # absolute! (Debian bug #376658; fixed in debian unstable now)
 492         my $path="/".shift;
 493         my $base="/".shift;
 494
 495         require File::Spec;
 496         my $ret=File::Spec->abs2rel($path, $base);
 497         $ret=~s/^// if defined $ret;
 498         return $ret;
 499 } #}}}
 500
 501 sub displaytime ($;$) { #{{{
 502         my $time=shift;
 503         my $format=shift;
 504         if (! defined $format) {
 505                 $format=$config{timeformat};
 506         }
 507
 508         # strftime doesn't know about encodings, so make sure
 509         # its output is properly treated as utf8
 510         return decode_utf8(POSIX::strftime($format, localtime($time)));
 511 } #}}}
 512
 513 sub beautify_url ($) { #{{{
 514         my $url=shift;
 515
 516         $url =~ s!/index.$config{htmlext}$!/!;
 517         $url =~ s!^$!./!; # Browsers don't like empty links...
 518
 519         return $url;
 520 } #}}}
 521
 522 sub urlto ($$) { #{{{
 523         my $to=shift;
 524         my $from=shift;
 525
 526         if (! length $to) {
 527                 return beautify_url(baseurl($from));
 528         }
 529
 530         if (! $destsources{$to}) {
 531                 $to=htmlpage($to);
 532         }
 533
 534         my $link = abs2rel($to, dirname(htmlpage($from)));
 535
 536         return beautify_url($link);
 537 } #}}}
 538
 539 sub htmllink ($$$;@) { #{{{
 540         my $lpage=shift; # the page doing the linking
 541         my $page=shift; # the page that will contain the link (different for inline)
 542         my $link=shift;
 543         my %opts=@_;
 544
 545         my $bestlink;
 546         if (! $opts{forcesubpage}) {
 547                 $bestlink=bestlink($lpage, $link);
 548         }
 549         else {
 550                 $bestlink="$lpage/".lc($link);
 551         }
 552
 553         my $linktext;
 554         if (defined $opts{linktext}) {
 555                 $linktext=$opts{linktext};
 556         }
 557         else {
 558                 $linktext=pagetitle(basename($link));
 559         }
 560
 561         return "<span class=\"selflink\">$linktext</span>"
 562                 if length $bestlink && $page eq $bestlink;
 563
 564         if (! $destsources{$bestlink}) {
 565                 $bestlink=htmlpage($bestlink);
 566
 567                 if (! $destsources{$bestlink}) {
 568                         return $linktext unless length $config{cgiurl};
 569                         return "<span class=\"createlink\"><a href=\"".
 570                                 cgiurl(
 571                                         do => "create",
 572                                         page => pagetitle(lc($link), 1),
 573                                         from => $lpage
 574                                 ).
 575                                 "\">?</a>$linktext</span>"
 576                 }
 577         }
 578
 579         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
 580         $bestlink=beautify_url($bestlink);
 581
 582         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
 583                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
 584         }
 585
 586         if (defined $opts{anchor}) {
 587                 $bestlink.="#".$opts{anchor};
 588         }
 589
 590         my @attrs;
 591         if (defined $opts{rel}) {
 592                 push @attrs, ' rel="'.$opts{rel}.'"';
 593         }
 594         if (defined $opts{class}) {
 595                 push @attrs, ' class="'.$opts{class}.'"';
 596         }
 597
 598         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
 599 } #}}}
 600
 601 sub htmlize ($$$) { #{{{
 602         my $page=shift;
 603         my $type=shift;
 604         my $content=shift;
 605
 606         if (exists $hooks{htmlize}{$type}) {
 607                 $content=$hooks{htmlize}{$type}{call}->(
 608                         page => $page,
 609                         content => $content,
 610                 );
 611         }
 612         else {
 613                 error("htmlization of $type not supported");
 614         }
 615
 616         run_hooks(sanitize => sub {
 617                 $content=shift->(
 618                         page => $page,
 619                         content => $content,
 620                 );
 621         });
 622
 623         return $content;
 624 } #}}}
 625
 626 sub linkify ($$$) { #{{{
 627         my $lpage=shift; # the page containing the links
 628         my $page=shift; # the page the link will end up on (different for inline)
 629         my $content=shift;
 630
 631         $content =~ s{(\\?)$config{wiki_link_regexp}}{
 632                 defined $2
 633                         ? ( $1
 634                                 ? "[[$2|$3".($4 ? "#$4" : "")."]]"
 635                                 : htmllink($lpage, $page, linkpage($3),
 636                                         anchor => $4, linktext => pagetitle($2)))
 637                         : ( $1
 638                                 ? "[[$3".($4 ? "#$4" : "")."]]"
 639                                 : htmllink($lpage, $page, linkpage($3),
 640                                         anchor => $4))
 641         }eg;
 642
 643         return $content;
 644 } #}}}
 645
 646 my %preprocessing;
 647 our $preprocess_preview=0;
 648 sub preprocess ($$$;$$) { #{{{
 649         my $page=shift; # the page the data comes from
 650         my $destpage=shift; # the page the data will appear in (different for inline)
 651         my $content=shift;
 652         my $scan=shift;
 653         my $preview=shift;
 654
 655         # Using local because it needs to be set within any nested calls
 656         # of this function.
 657         local $preprocess_preview=$preview if defined $preview;
 658
 659         my $handle=sub {
 660                 my $escape=shift;
 661                 my $command=shift;
 662                 my $params=shift;
 663                 if (length $escape) {
 664                         return "[[$command $params]]";
 665                 }
 666                 elsif (exists $hooks{preprocess}{$command}) {
 667                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
 668                         # Note: preserve order of params, some plugins may
 669                         # consider it significant.
 670                         my @params;
 671                         while ($params =~ m{
 672                                 (?:(\w+)=)?             # 1: named parameter key?
 673                                 (?:
 674                                         """(.*?)"""     # 2: triple-quoted value
 675                                 |
 676                                         "([^"]+)"       # 3: single-quoted value
 677                                 |
 678                                         (\S+)           # 4: unquoted value
 679                                 )
 680                                 (?:\s+|$)               # delimiter to next param
 681                         }sgx) {
 682                                 my $key=$1;
 683                                 my $val;
 684                                 if (defined $2) {
 685                                         $val=$2;
 686                                         $val=~s/\r\n/\n/mg;
 687                                         $val=~s/^\n+//g;
 688                                         $val=~s/\n+$//g;
 689                                 }
 690                                 elsif (defined $3) {
 691                                         $val=$3;
 692                                 }
 693                                 elsif (defined $4) {
 694                                         $val=$4;
 695                                 }
 696
 697                                 if (defined $key) {
 698                                         push @params, $key, $val;
 699                                 }
 700                                 else {
 701                                         push @params, $val, '';
 702                                 }
 703                         }
 704                         if ($preprocessing{$page}++ > 3) {
 705                                 # Avoid loops of preprocessed pages preprocessing
 706                                 # other pages that preprocess them, etc.
 707                                 #translators: The first parameter is a
 708                                 #translators: preprocessor directive name,
 709                                 #translators: the second a page name, the
 710                                 #translators: third a number.
 711                                 return "[[".sprintf(gettext("%s preprocessing loop detected on %s at depth %i"),
 712                                         $command, $page, $preprocessing{$page}).
 713                                 "]]";
 714                         }
 715                         my $ret=$hooks{preprocess}{$command}{call}->(
 716                                 @params,
 717                                 page => $page,
 718                                 destpage => $destpage,
 719                                 preview => $preprocess_preview,
 720                         );
 721                         $preprocessing{$page}--;
 722                         return $ret;
 723                 }
 724                 else {
 725                         return "[[$command $params]]";
 726                 }
 727         };
 728
 729         $content =~ s{
 730                 (\\?)           # 1: escape?
 731                 \[\[            # directive open
 732                 (\w+)           # 2: command
 733                 \s+
 734                 (               # 3: the parameters..
 735                         (?:
 736                                 (?:\w+=)?               # named parameter key?
 737                                 (?:
 738                                         """.*?"""       # triple-quoted value
 739                                         |
 740                                         "[^"]+"         # single-quoted value
 741                                         |
 742                                         [^\s\]]+        # unquoted value
 743                                 )
 744                                 \s*                     # whitespace or end
 745                                                         # of directive
 746                         )
 747                 *)              # 0 or more parameters
 748                 \]\]            # directive closed
 749         }{$handle->($1, $2, $3)}sexg;
 750         return $content;
 751 } #}}}
 752
 753 sub filter ($$$) { #{{{
 754         my $page=shift;
 755         my $destpage=shift;
 756         my $content=shift;
 757
 758         run_hooks(filter => sub {
 759                 $content=shift->(page => $page, destpage => $destpage,
 760                         content => $content);
 761         });
 762
 763         return $content;
 764 } #}}}
 765
 766 sub indexlink () { #{{{
 767         return "<a href=\"$config{url}\">$config{wikiname}</a>";
 768 } #}}}
 769
 770 my $wikilock;
 771
 772 sub lockwiki (;$) { #{{{
 773         my $wait=@_ ? shift : 1;
 774         # Take an exclusive lock on the wiki to prevent multiple concurrent
 775         # run issues. The lock will be dropped on program exit.
 776         if (! -d $config{wikistatedir}) {
 777                 mkdir($config{wikistatedir});
 778         }
 779         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
 780                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
 781         if (! flock($wikilock, 2 | 4)) { # LOCK_EX | LOCK_NB
 782                 if ($wait) {
 783                         debug("wiki seems to be locked, waiting for lock");
 784                         my $wait=600; # arbitrary, but don't hang forever to
 785                                       # prevent process pileup
 786                         for (1..$wait) {
 787                                 return if flock($wikilock, 2 | 4);
 788                                 sleep 1;
 789                         }
 790                         error("wiki is locked; waited $wait seconds without lock being freed (possible stuck process or stale lock?)");
 791                 }
 792                 else {
 793                         return 0;
 794                 }
 795         }
 796         return 1;
 797 } #}}}
 798
 799 sub unlockwiki () { #{{{
 800         return close($wikilock) if $wikilock;
 801         return;
 802 } #}}}
 803
 804 my $commitlock;
 805
 806 sub commit_hook_enabled () { #{{{
 807         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
 808                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 809         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
 810                 close($commitlock) || error("failed closing commitlock: $!");
 811                 return 0;
 812         }
 813         close($commitlock) || error("failed closing commitlock: $!");
 814         return 1;
 815 } #}}}
 816
 817 sub disable_commit_hook () { #{{{
 818         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
 819                 error("cannot write to $config{wikistatedir}/commitlock: $!");
 820         if (! flock($commitlock, 2)) { # LOCK_EX
 821                 error("failed to get commit lock");
 822         }
 823         return 1;
 824 } #}}}
 825
 826 sub enable_commit_hook () { #{{{
 827         return close($commitlock) if $commitlock;
 828         return;
 829 } #}}}
 830
 831 sub loadindex () { #{{{
 832         %oldrenderedfiles=%pagectime=();
 833         if (! $config{rebuild}) {
 834                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
 835                         %destsources=%renderedfiles=%pagecase=();
 836         }
 837         open (my $in, "<", "$config{wikistatedir}/index") || return;
 838         while (<$in>) {
 839                 $_=possibly_foolish_untaint($_);
 840                 chomp;
 841                 my %items;
 842                 $items{link}=[];
 843                 $items{dest}=[];
 844                 foreach my $i (split(/ /, $_)) {
 845                         my ($item, $val)=split(/=/, $i, 2);
 846                         push @{$items{$item}}, decode_entities($val);
 847                 }
 848
 849                 next unless exists $items{src}; # skip bad lines for now
 850
 851                 my $page=pagename($items{src}[0]);
 852                 if (! $config{rebuild}) {
 853                         $pagesources{$page}=$items{src}[0];
 854                         $pagemtime{$page}=$items{mtime}[0];
 855                         $oldlinks{$page}=[@{$items{link}}];
 856                         $links{$page}=[@{$items{link}}];
 857                         $depends{$page}=$items{depends}[0] if exists $items{depends};
 858                         $destsources{$_}=$page foreach @{$items{dest}};
 859                         $renderedfiles{$page}=[@{$items{dest}}];
 860                         $pagecase{lc $page}=$page;
 861                 }
 862                 $oldrenderedfiles{$page}=[@{$items{dest}}];
 863                 $pagectime{$page}=$items{ctime}[0];
 864         }
 865         return close($in);
 866 } #}}}
 867
 868 sub saveindex () { #{{{
 869         run_hooks(savestate => sub { shift->() });
 870
 871         if (! -d $config{wikistatedir}) {
 872                 mkdir($config{wikistatedir});
 873         }
 874         my $newfile="$config{wikistatedir}/index.new";
 875         my $cleanup = sub { unlink($newfile) };
 876         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
 877         foreach my $page (keys %pagemtime) {
 878                 next unless $pagemtime{$page};
 879                 my $line="mtime=$pagemtime{$page} ".
 880                         "ctime=$pagectime{$page} ".
 881                         "src=$pagesources{$page}";
 882                 $line.=" dest=$_" foreach @{$renderedfiles{$page}};
 883                 my %count;
 884                 $line.=" link=$_" foreach grep { ++$count{$_} == 1 } @{$links{$page}};
 885                 if (exists $depends{$page}) {
 886                         $line.=" depends=".encode_entities($depends{$page}, " \t\n");
 887                 }
 888                 print $out $line."\n" || error("failed writing to $newfile: $!", $cleanup);
 889         }
 890         close $out || error("failed saving to $newfile: $!", $cleanup);
 891         rename($newfile, "$config{wikistatedir}/index") ||
 892                 error("failed renaming $newfile to $config{wikistatedir}/index", $cleanup);
 893
 894         return 1;
 895 } #}}}
 896
 897 sub template_file ($) { #{{{
 898         my $template=shift;
 899
 900         foreach my $dir ($config{templatedir}, "$installdir/share/ikiwiki/templates") {
 901                 return "$dir/$template" if -e "$dir/$template";
 902         }
 903         return;
 904 } #}}}
 905
 906 sub template_params (@) { #{{{
 907         my $filename=template_file(shift);
 908
 909         if (! defined $filename) {
 910                 return if wantarray;
 911                 return "";
 912         }
 913
 914         my @ret=(
 915                 filter => sub {
 916                         my $text_ref = shift;
 917                         ${$text_ref} = decode_utf8(${$text_ref});
 918                 },
 919                 filename => $filename,
 920                 loop_context_vars => 1,
 921                 die_on_bad_params => 0,
 922                 @_
 923         );
 924         return wantarray ? @ret : {@ret};
 925 } #}}}
 926
 927 sub template ($;@) { #{{{
 928         require HTML::Template;
 929         return HTML::Template->new(template_params(@_));
 930 } #}}}
 931
 932 sub misctemplate ($$;@) { #{{{
 933         my $title=shift;
 934         my $pagebody=shift;
 935
 936         my $template=template("misc.tmpl");
 937         $template->param(
 938                 title => $title,
 939                 indexlink => indexlink(),
 940                 wikiname => $config{wikiname},
 941                 pagebody => $pagebody,
 942                 baseurl => baseurl(),
 943                 @_,
 944         );
 945         run_hooks(pagetemplate => sub {
 946                 shift->(page => "", destpage => "", template => $template);
 947         });
 948         return $template->output;
 949 }#}}}
 950
 951 sub hook (@) { # {{{
 952         my %param=@_;
 953
 954         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
 955                 error 'hook requires type, call, and id parameters';
 956         }
 957
 958         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
 959
 960         $hooks{$param{type}}{$param{id}}=\%param;
 961         return 1;
 962 } # }}}
 963
 964 sub run_hooks ($$) { # {{{
 965         # Calls the given sub for each hook of the given type,
 966         # passing it the hook function to call.
 967         my $type=shift;
 968         my $sub=shift;
 969
 970         if (exists $hooks{$type}) {
 971                 my @deferred;
 972                 foreach my $id (keys %{$hooks{$type}}) {
 973                         if ($hooks{$type}{$id}{last}) {
 974                                 push @deferred, $id;
 975                                 next;
 976                         }
 977                         $sub->($hooks{$type}{$id}{call});
 978                 }
 979                 foreach my $id (@deferred) {
 980                         $sub->($hooks{$type}{$id}{call});
 981                 }
 982         }
 983
 984         return 1;
 985 } #}}}
 986
 987 sub globlist_to_pagespec ($) { #{{{
 988         my @globlist=split(' ', shift);
 989
 990         my (@spec, @skip);
 991         foreach my $glob (@globlist) {
 992                 if ($glob=~/^!(.*)/) {
 993                         push @skip, $glob;
 994                 }
 995                 else {
 996                         push @spec, $glob;
 997                 }
 998         }
 999
1000         my $spec=join(' or ', @spec);
1001         if (@skip) {
1002                 my $skip=join(' and ', @skip);
1003                 if (length $spec) {
1004                         $spec="$skip and ($spec)";
1005                 }
1006                 else {
1007                         $spec=$skip;
1008                 }
1009         }
1010         return $spec;
1011 } #}}}
1012
1013 sub is_globlist ($) { #{{{
1014         my $s=shift;
1015         return ( $s =~ /[^\s]+\s+([^\s]+)/ && $1 ne "and" && $1 ne "or" );
1016 } #}}}
1017
1018 sub safequote ($) { #{{{
1019         my $s=shift;
1020         $s=~s/[{}]//g;
1021         return "q{$s}";
1022 } #}}}
1023
1024 sub add_depends ($$) { #{{{
1025         my $page=shift;
1026         my $pagespec=shift;
1027
1028         if (! exists $depends{$page}) {
1029                 $depends{$page}=$pagespec;
1030         }
1031         else {
1032                 $depends{$page}=pagespec_merge($depends{$page}, $pagespec);
1033         }
1034
1035         return 1;
1036 } # }}}
1037
1038 sub file_pruned ($$) { #{{{
1039         require File::Spec;
1040         my $file=File::Spec->canonpath(shift);
1041         my $base=File::Spec->canonpath(shift);
1042         $file =~ s#^\Q$base\E/*##;
1043
1044         my $regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1045         return $file =~ m/$regexp/;
1046 } #}}}
1047
1048 sub gettext { #{{{
1049         # Only use gettext in the rare cases it's needed.
1050         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
1051             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
1052             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
1053                 if (! $gettext_obj) {
1054                         $gettext_obj=eval q{
1055                                 use Locale::gettext q{textdomain};
1056                                 Locale::gettext->domain('ikiwiki')
1057                         };
1058                         if ($@) {
1059                                 print STDERR "$@";
1060                                 $gettext_obj=undef;
1061                                 return shift;
1062                         }
1063                 }
1064                 return $gettext_obj->get(shift);
1065         }
1066         else {
1067                 return shift;
1068         }
1069 } #}}}
1070
1071 sub pagespec_merge ($$) { #{{{
1072         my $a=shift;
1073         my $b=shift;
1074
1075         return $a if $a eq $b;
1076
1077         # Support for old-style GlobLists.
1078         if (is_globlist($a)) {
1079                 $a=globlist_to_pagespec($a);
1080         }
1081         if (is_globlist($b)) {
1082                 $b=globlist_to_pagespec($b);
1083         }
1084
1085         return "($a) or ($b)";
1086 } #}}}
1087
1088 sub pagespec_translate ($) { #{{{
1089         # This assumes that $page is in scope in the function
1090         # that evalulates the translated pagespec code.
1091         my $spec=shift;
1092
1093         # Support for old-style GlobLists.
1094         if (is_globlist($spec)) {
1095                 $spec=globlist_to_pagespec($spec);
1096         }
1097
1098         # Convert spec to perl code.
1099         my $code="";
1100         while ($spec=~m{
1101                 \s*             # ignore whitespace
1102                 (               # 1: match a single word
1103                         \!              # !
1104                 |
1105                         \(              # (
1106                 |
1107                         \)              # )
1108                 |
1109                         \w+\([^\)]*\)   # command(params)
1110                 |
1111                         [^\s()]+        # any other text
1112                 )
1113                 \s*             # ignore whitespace
1114         }igx) {
1115                 my $word=$1;
1116                 if (lc $word eq 'and') {
1117                         $code.=' &&';
1118                 }
1119                 elsif (lc $word eq 'or') {
1120                         $code.=' ||';
1121                 }
1122                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
1123                         $code.=' '.$word;
1124                 }
1125                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
1126                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
1127                                 $code.="IkiWiki::PageSpec::match_$1(\$page, ".safequote($2).", \@params)";
1128                         }
1129                         else {
1130                                 $code.=' 0';
1131                         }
1132                 }
1133                 else {
1134                         $code.=" IkiWiki::PageSpec::match_glob(\$page, ".safequote($word).", \@params)";
1135                 }
1136         }
1137
1138         return $code;
1139 } #}}}
1140
1141 sub pagespec_match ($$;@) { #{{{
1142         my $page=shift;
1143         my $spec=shift;
1144         my @params=@_;
1145
1146         # Backwards compatability with old calling convention.
1147         if (@params == 1) {
1148                 unshift @params, 'location';
1149         }
1150
1151         my $ret=eval pagespec_translate($spec);
1152         return IkiWiki::FailReason->new('syntax error') if $@;
1153         return $ret;
1154 } #}}}
1155
1156 package IkiWiki::FailReason;
1157
1158 use overload ( #{{{
1159         '""'    => sub { ${$_[0]} },
1160         '0+'    => sub { 0 },
1161         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
1162         fallback => 1,
1163 ); #}}}
1164
1165 sub new { #{{{
1166         return bless \$_[1], $_[0];
1167 } #}}}
1168
1169 package IkiWiki::SuccessReason;
1170
1171 use overload ( #{{{
1172         '""'    => sub { ${$_[0]} },
1173         '0+'    => sub { 1 },
1174         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
1175         fallback => 1,
1176 ); #}}}
1177
1178 sub new { #{{{
1179         return bless \$_[1], $_[0];
1180 }; #}}}
1181
1182 package IkiWiki::PageSpec;
1183
1184 sub match_glob ($$;@) { #{{{
1185         my $page=shift;
1186         my $glob=shift;
1187         my %params=@_;
1188
1189         my $from=exists $params{location} ? $params{location} : '';
1190
1191         # relative matching
1192         if ($glob =~ m!^\./!) {
1193                 $from=~s#/?[^/]+$##;
1194                 $glob=~s#^\./##;
1195                 $glob="$from/$glob" if length $from;
1196         }
1197
1198         # turn glob into safe regexp
1199         $glob=quotemeta($glob);
1200         $glob=~s/\\\*/.*/g;
1201         $glob=~s/\\\?/./g;
1202
1203         if ($page=~/^$glob$/i) {
1204                 return IkiWiki::SuccessReason->new("$glob matches $page");
1205         }
1206         else {
1207                 return IkiWiki::FailReason->new("$glob does not match $page");
1208         }
1209 } #}}}
1210
1211 sub match_link ($$;@) { #{{{
1212         my $page=shift;
1213         my $link=lc(shift);
1214         my %params=@_;
1215
1216         my $from=exists $params{location} ? $params{location} : '';
1217
1218         # relative matching
1219         if ($link =~ m!^\.! && defined $from) {
1220                 $from=~s#/?[^/]+$##;
1221                 $link=~s#^\./##;
1222                 $link="$from/$link" if length $from;
1223         }
1224
1225         my $links = $IkiWiki::links{$page};
1226         return IkiWiki::FailReason->new("$page has no links") unless $links && @{$links};
1227         my $bestlink = IkiWiki::bestlink($from, $link);
1228         foreach my $p (@{$links}) {
1229                 if (length $bestlink) {
1230                         return IkiWiki::SuccessReason->new("$page links to $link")
1231                                 if $bestlink eq IkiWiki::bestlink($page, $p);
1232                 }
1233                 else {
1234                         return IkiWiki::SuccessReason->new("$page links to page $p matching $link")
1235                                 if match_glob($p, $link, %params);
1236                 }
1237         }
1238         return IkiWiki::FailReason->new("$page does not link to $link");
1239 } #}}}
1240
1241 sub match_backlink ($$;@) { #{{{
1242         return match_link($_[1], $_[0], @_);
1243 } #}}}
1244
1245 sub match_created_before ($$;@) { #{{{
1246         my $page=shift;
1247         my $testpage=shift;
1248
1249         if (exists $IkiWiki::pagectime{$testpage}) {
1250                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
1251                         return IkiWiki::SuccessReason->new("$page created before $testpage");
1252                 }
1253                 else {
1254                         return IkiWiki::FailReason->new("$page not created before $testpage");
1255                 }
1256         }
1257         else {
1258                 return IkiWiki::FailReason->new("$testpage has no ctime");
1259         }
1260 } #}}}
1261
1262 sub match_created_after ($$;@) { #{{{
1263         my $page=shift;
1264         my $testpage=shift;
1265
1266         if (exists $IkiWiki::pagectime{$testpage}) {
1267                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
1268                         return IkiWiki::SuccessReason->new("$page created after $testpage");
1269                 }
1270                 else {
1271                         return IkiWiki::FailReason->new("$page not created after $testpage");
1272                 }
1273         }
1274         else {
1275                 return IkiWiki::FailReason->new("$testpage has no ctime");
1276         }
1277 } #}}}
1278
1279 sub match_creation_day ($$;@) { #{{{
1280         if ((gmtime($IkiWiki::pagectime{shift()}))[3] == shift) {
1281                 return IkiWiki::SuccessReason->new('creation_day matched');
1282         }
1283         else {
1284                 return IkiWiki::FailReason->new('creation_day did not match');
1285         }
1286 } #}}}
1287
1288 sub match_creation_month ($$;@) { #{{{
1289         if ((gmtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
1290                 return IkiWiki::SuccessReason->new('creation_month matched');
1291         }
1292         else {
1293                 return IkiWiki::FailReason->new('creation_month did not match');
1294         }
1295 } #}}}
1296
1297 sub match_creation_year ($$;@) { #{{{
1298         if ((gmtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
1299                 return IkiWiki::SuccessReason->new('creation_year matched');
1300         }
1301         else {
1302                 return IkiWiki::FailReason->new('creation_year did not match');
1303         }
1304 } #}}}
1305
1306 sub match_user ($$;@) { #{{{
1307         shift;
1308         my $user=shift;
1309         my %params=@_;
1310
1311         return IkiWiki::FailReason->new('cannot match user')
1312                 unless exists $params{user};
1313         if ($user eq $params{user}) {
1314                 return IkiWiki::SuccessReason->new("user is $user")
1315         }
1316         else {
1317                 return IkiWiki::FailReason->new("user is not $user");
1318         }
1319 } #}}}
1320
1321 1