IkiWiki/Wrapper.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use File::Spec;
   8 use Data::Dumper;
   9 use IkiWiki;
  10
  11 sub gen_wrappers () {
  12         debug(gettext("generating wrappers.."));
  13         my %origconfig=(%config);
  14         foreach my $wrapper (@{$config{wrappers}}) {
  15                 %config=(%origconfig, %{$wrapper});
  16                 $config{verbose}=$config{setupverbose}
  17                         if exists $config{setupverbose};
  18                 $config{syslog}=$config{setupsyslog}
  19                         if exists $config{setupsyslog};
  20                 delete @config{qw(setupsyslog setupverbose wrappers genwrappers rebuild)};
  21                 checkconfig();
  22                 if (! $config{cgi} && ! $config{post_commit} &&
  23                     ! $config{test_receive}) {
  24                         $config{post_commit}=1;
  25                 }
  26                 gen_wrapper();
  27         }
  28         %config=(%origconfig);
  29 }
  30
  31 our $program_to_wrap = $0;
  32 sub gen_wrapper () {
  33         $config{srcdir}=File::Spec->rel2abs($config{srcdir});
  34         $config{destdir}=File::Spec->rel2abs($config{destdir});
  35         my $this=File::Spec->rel2abs($program_to_wrap);
  36         if (! -x $this) {
  37                 error(sprintf(gettext("%s doesn't seem to be executable"), $this));
  38         }
  39
  40         if ($config{setup}) {
  41                 error(gettext("cannot create a wrapper that uses a setup file"));
  42         }
  43         my $wrapper=possibly_foolish_untaint($config{wrapper});
  44         if (! defined $wrapper || ! length $wrapper) {
  45                 error(gettext("wrapper filename not specified"));
  46         }
  47         delete $config{wrapper};
  48
  49         my @envsave;
  50         push @envsave, qw{REMOTE_ADDR QUERY_STRING REQUEST_METHOD REQUEST_URI
  51                        CONTENT_TYPE CONTENT_LENGTH GATEWAY_INTERFACE
  52                        HTTP_COOKIE REMOTE_USER HTTPS REDIRECT_STATUS
  53                        HTTP_HOST SERVER_PORT HTTPS HTTP_ACCEPT
  54                        REDIRECT_URL} if $config{cgi};
  55         my $envsize=$#envsave;
  56         my $envsave="";
  57         foreach my $var (@envsave) {
  58                 $envsave.=<<"EOF";
  59         if ((s=getenv("$var")))
  60                 addenv("$var", s);
  61 EOF
  62         }
  63         if (ref $config{ENV} eq 'HASH') {
  64                 foreach my $key (keys %{$config{ENV}}) {
  65                         my $val=$config{ENV}{$key};
  66                         utf8::encode($val) if utf8::is_utf8($val);
  67                         $val =~ s/([^A-Za-z0-9])/sprintf '""\\x%02x""', ord($1)/ge;
  68                         $envsize += 1;
  69                         $envsave.=<<"EOF";
  70         addenv("$key", "$val");
  71 EOF
  72                 }
  73                 delete $config{ENV};
  74         }
  75
  76         my @wrapper_hooks;
  77         run_hooks(genwrapper => sub { push @wrapper_hooks, shift->() });
  78
  79         my $check_commit_hook="";
  80         my $pre_exec="";
  81         if ($config{post_commit}) {
  82                 # Optimise checking !commit_hook_enabled() ,
  83                 # so that ikiwiki does not have to be started if the
  84                 # hook is disabled.
  85                 #
  86                 # Note that perl's flock may be implemented using fcntl
  87                 # or lockf on some systems. If so, and if there is no
  88                 # interop between the locking systems, the true C flock will
  89                 # always succeed, and this optimisation won't work.
  90                 # The perl code will later correctly check the lock,
  91                 # so the right thing will still happen, though without
  92                 # the benefit of this optimisation.
  93                 $check_commit_hook=<<"EOF";
  94         {
  95                 int fd=open("$config{wikistatedir}/commitlock", O_CREAT | O_RDWR, 0666);
  96                 if (fd != -1) {
  97                         if (flock(fd, LOCK_SH | LOCK_NB) != 0)
  98                                 exit(0);
  99                         close(fd);
 100                 }
 101         }
 102 EOF
 103         }
 104         elsif ($config{cgi}) {
 105                 # Avoid more than one ikiwiki cgi running at a time by
 106                 # taking a cgi lock. Since ikiwiki uses several MB of
 107                 # memory, a pile up of processes could cause thrashing
 108                 # otherwise. The fd of the lock is stored in
 109                 # IKIWIKI_CGILOCK_FD so unlockwiki can close it.
 110                 #
 111                 # A lot of cgi wrapper processes can potentially build
 112                 # up and clog an otherwise unloaded web server. To
 113                 # partially avoid this, when a GET comes in and the lock
 114                 # is already held, rather than blocking a html page is
 115                 # constructed that retries. This is enabled by setting
 116                 # cgi_overload_delay.
 117                 if (defined $config{cgi_overload_delay} &&
 118                     $config{cgi_overload_delay} =~/^[0-9]+/) {
 119                         my $i=int($config{cgi_overload_delay});
 120                         $pre_exec.="#define CGI_OVERLOAD_DELAY $i\n"
 121                                 if $i > 0;
 122                         my $msg=gettext("Please wait");
 123                         $msg=~s/"/\\"/g;
 124                         $pre_exec.='#define CGI_PLEASE_WAIT_TITLE "'.$msg."\"\n";
 125                         if (defined $config{cgi_overload_message} && length $config{cgi_overload_message}) {
 126                                 $msg=$config{cgi_overload_message};
 127                                 $msg=~s/"/\\"/g;
 128                         }
 129                         $pre_exec.='#define CGI_PLEASE_WAIT_BODY "'.$msg."\"\n";
 130                 }
 131                 $pre_exec.=<<"EOF";
 132         lockfd=open("$config{wikistatedir}/cgilock", O_CREAT | O_RDWR, 0666);
 133         if (lockfd != -1) {
 134 #ifdef CGI_OVERLOAD_DELAY
 135                 char *request_method = getenv("REQUEST_METHOD");
 136                 if (request_method && strcmp(request_method, "GET") == 0) {
 137                         if (lockf(lockfd, F_TLOCK, 0) == 0) {
 138                                 set_cgilock_fd(lockfd);
 139                         }
 140                         else {
 141                                 printf("Content-Type: text/html\\nRefresh: %i; URL=%s\\n\\n<html><head><title>%s</title><head><body><p>%s</p></body></html>",
 142                                         CGI_OVERLOAD_DELAY,
 143                                         getenv("REQUEST_URI"),
 144                                         CGI_PLEASE_WAIT_TITLE,
 145                                         CGI_PLEASE_WAIT_BODY);
 146                                 exit(0);
 147                         }
 148                 }
 149                 else if (lockf(lockfd, F_LOCK, 0) == 0) {
 150                         set_cgilock_fd(lockfd);
 151                 }
 152 #else
 153                 if (lockf(lockfd, F_LOCK, 0) == 0) {
 154                         set_cgilock_fd(lockfd);
 155                 }
 156 #endif
 157         }
 158 EOF
 159         }
 160
 161         my $set_background_command='';
 162         if (defined $config{wrapper_background_command} &&
 163             length $config{wrapper_background_command}) {
 164                 my $background_command=delete $config{wrapper_background_command};
 165                 $set_background_command=~s/"/\\"/g;
 166                 $set_background_command='#define BACKGROUND_COMMAND "'.$background_command.'"';
 167         }
 168
 169         $Data::Dumper::Indent=0; # no newlines
 170         my $configstring=Data::Dumper->Dump([\%config], ['*config']);
 171         $configstring=~s/\\/\\\\/g;
 172         $configstring=~s/"/\\"/g;
 173         $configstring=~s/\n/\\n/g;
 174
 175         writefile(basename("$wrapper.c"), dirname($wrapper), <<"EOF");
 176 /* A wrapper for ikiwiki, can be safely made suid. */
 177 #include <stdio.h>
 178 #include <sys/types.h>
 179 #include <sys/stat.h>
 180 #include <fcntl.h>
 181 #include <unistd.h>
 182 #include <stdlib.h>
 183 #include <string.h>
 184 #include <sys/file.h>
 185
 186 extern char **environ;
 187 char *newenviron[$envsize+7];
 188 int i=0;
 189
 190 void addenv(char *var, char *val) {
 191         char *s=malloc(strlen(var)+1+strlen(val)+1);
 192         if (!s) {
 193                 perror("malloc");
 194                 exit(1);
 195         }
 196         else {
 197                 sprintf(s, "%s=%s", var, val);
 198                 newenviron[i++]=s;
 199         }
 200 }
 201
 202 void set_cgilock_fd (int lockfd) {
 203         char fd_s[12];
 204         sprintf(fd_s, "%i", lockfd);
 205         if (setenv("IKIWIKI_CGILOCK_FD", fd_s, 1) != 0) {
 206                 perror("setenv");
 207                 exit(1);
 208         }
 209 }
 210
 211 int main (int argc, char **argv) {
 212         int lockfd=-1;
 213         char *s;
 214
 215 $check_commit_hook
 216 @wrapper_hooks
 217 $envsave
 218         newenviron[i++]="HOME=$ENV{HOME}";
 219         newenviron[i++]="PATH=$ENV{PATH}";
 220         newenviron[i++]="WRAPPED_OPTIONS=$configstring";
 221
 222 #ifdef __TINYC__
 223         /* old tcc versions do not support modifying environ directly */
 224         if (clearenv() != 0) {
 225                 perror("clearenv");
 226                 exit(1);
 227         }
 228         for (; i>0; i--)
 229                 putenv(newenviron[i-1]);
 230 #else
 231         newenviron[i]=NULL;
 232         environ=newenviron;
 233 #endif
 234
 235         if (setregid(getegid(), -1) != 0 &&
 236             setregid(getegid(), -1) != 0) {
 237                 perror("failed to drop real gid");
 238                 exit(1);
 239         }
 240         if (setreuid(geteuid(), -1) != 0 &&
 241             setreuid(geteuid(), -1) != 0) {
 242                 perror("failed to drop real uid");
 243                 exit(1);
 244         }
 245
 246 $pre_exec
 247
 248 $set_background_command
 249 #ifdef BACKGROUND_COMMAND
 250         if (lockfd != -1) {
 251                 close(lockfd);
 252         }
 253
 254         pid_t pid=fork();
 255         if (pid == -1) {
 256                 perror("fork");
 257                 exit(1);
 258         }
 259         else if (pid == 0) {
 260                 execl("$this", "$this", NULL);
 261                 perror("exec $this");
 262                 exit(1);
 263         }
 264         else {
 265                 waitpid(pid, NULL, 0);
 266
 267                 if (daemon(1, 0) == 0) {
 268                         system(BACKGROUND_COMMAND);
 269                         exit(0);
 270                 }
 271                 else {
 272                         perror("daemon");
 273                         exit(1);
 274                 }
 275         }
 276 #else
 277         execl("$this", "$this", NULL);
 278         perror("exec $this");
 279         exit(1);
 280 #endif
 281 }
 282 EOF
 283
 284         my @cc=exists $ENV{CC} ? possibly_foolish_untaint($ENV{CC}) : 'cc';
 285         push @cc, split(' ', possibly_foolish_untaint($ENV{CFLAGS})) if exists $ENV{CFLAGS};
 286         if (system(@cc, "$wrapper.c", "-o", "$wrapper.new") != 0) {
 287                 #translators: The parameter is a C filename.
 288                 error(sprintf(gettext("failed to compile %s"), "$wrapper.c"));
 289         }
 290         unlink("$wrapper.c");
 291         if (defined $config{wrappergroup}) {
 292                 my $gid=(getgrnam($config{wrappergroup}))[2];
 293                 if (! defined $gid) {
 294                         error(sprintf("bad wrappergroup"));
 295                 }
 296                 if (! chown(-1, $gid, "$wrapper.new")) {
 297                         error("chown $wrapper.new: $!");
 298                 }
 299         }
 300         if (defined $config{wrappermode} &&
 301             ! chmod(oct($config{wrappermode}), "$wrapper.new")) {
 302                 error("chmod $wrapper.new: $!");
 303         }
 304         if (! rename("$wrapper.new", $wrapper)) {
 305                 error("rename $wrapper.new $wrapper: $!");
 306         }
 307         #translators: The parameter is a filename.
 308         debug(sprintf(gettext("successfully generated %s"), $wrapper));
 309 }
 310
 311 1