IkiWiki.pm

   1 #!/usr/bin/perl
   2
   3 package IkiWiki;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use URI::Escape q{uri_escape_utf8};
   9 use POSIX ();
  10 use Storable;
  11 use open qw{:utf8 :std};
  12
  13 use vars qw{%config %links %oldlinks %pagemtime %pagectime %pagecase
  14         %pagestate %wikistate %renderedfiles %oldrenderedfiles
  15         %pagesources %delpagesources %destsources %depends %depends_simple
  16         @mass_depends %hooks %forcerebuild %loaded_plugins %typedlinks
  17         %oldtypedlinks %autofiles};
  18
  19 use Exporter q{import};
  20 our @EXPORT = qw(hook debug error htmlpage template template_depends
  21         deptype add_depends pagespec_match pagespec_match_list bestlink
  22         htmllink readfile writefile pagetype srcfile pagename
  23         displaytime will_render gettext ngettext urlto targetpage
  24         add_underlay pagetitle titlepage linkpage newpagefile
  25         inject add_link add_autofile
  26         %config %links %pagestate %wikistate %renderedfiles
  27         %pagesources %destsources %typedlinks);
  28 our $VERSION = 3.00; # plugin interface version, next is ikiwiki version
  29 our $version='unknown'; # VERSION_AUTOREPLACE done by Makefile, DNE
  30 our $installdir='/usr'; # INSTALLDIR_AUTOREPLACE done by Makefile, DNE
  31
  32 # Page dependency types.
  33 our $DEPEND_CONTENT=1;
  34 our $DEPEND_PRESENCE=2;
  35 our $DEPEND_LINKS=4;
  36
  37 # Optimisation.
  38 use Memoize;
  39 memoize("abs2rel");
  40 memoize("sortspec_translate");
  41 memoize("pagespec_translate");
  42 memoize("template_file");
  43
  44 sub getsetup () {
  45         wikiname => {
  46                 type => "string",
  47                 default => "wiki",
  48                 description => "name of the wiki",
  49                 safe => 1,
  50                 rebuild => 1,
  51         },
  52         adminemail => {
  53                 type => "string",
  54                 default => undef,
  55                 example => 'me@example.com',
  56                 description => "contact email for wiki",
  57                 safe => 1,
  58                 rebuild => 0,
  59         },
  60         adminuser => {
  61                 type => "string",
  62                 default => [],
  63                 description => "users who are wiki admins",
  64                 safe => 1,
  65                 rebuild => 0,
  66         },
  67         banned_users => {
  68                 type => "string",
  69                 default => [],
  70                 description => "users who are banned from the wiki",
  71                 safe => 1,
  72                 rebuild => 0,
  73         },
  74         srcdir => {
  75                 type => "string",
  76                 default => undef,
  77                 example => "$ENV{HOME}/wiki",
  78                 description => "where the source of the wiki is located",
  79                 safe => 0, # path
  80                 rebuild => 1,
  81         },
  82         destdir => {
  83                 type => "string",
  84                 default => undef,
  85                 example => "/var/www/wiki",
  86                 description => "where to build the wiki",
  87                 safe => 0, # path
  88                 rebuild => 1,
  89         },
  90         url => {
  91                 type => "string",
  92                 default => '',
  93                 example => "http://example.com/wiki",
  94                 description => "base url to the wiki",
  95                 safe => 1,
  96                 rebuild => 1,
  97         },
  98         cgiurl => {
  99                 type => "string",
 100                 default => '',
 101                 example => "http://example.com/wiki/ikiwiki.cgi",
 102                 description => "url to the ikiwiki.cgi",
 103                 safe => 1,
 104                 rebuild => 1,
 105         },
 106         cgi_wrapper => {
 107                 type => "string",
 108                 default => '',
 109                 example => "/var/www/wiki/ikiwiki.cgi",
 110                 description => "filename of cgi wrapper to generate",
 111                 safe => 0, # file
 112                 rebuild => 0,
 113         },
 114         cgi_wrappermode => {
 115                 type => "string",
 116                 default => '06755',
 117                 description => "mode for cgi_wrapper (can safely be made suid)",
 118                 safe => 0,
 119                 rebuild => 0,
 120         },
 121         rcs => {
 122                 type => "string",
 123                 default => '',
 124                 description => "rcs backend to use",
 125                 safe => 0, # don't allow overriding
 126                 rebuild => 0,
 127         },
 128         default_plugins => {
 129                 type => "internal",
 130                 default => [qw{mdwn link inline meta htmlscrubber passwordauth
 131                                 openid signinedit lockedit conditional
 132                                 recentchanges parentlinks editpage}],
 133                 description => "plugins to enable by default",
 134                 safe => 0,
 135                 rebuild => 1,
 136         },
 137         add_plugins => {
 138                 type => "string",
 139                 default => [],
 140                 description => "plugins to add to the default configuration",
 141                 safe => 1,
 142                 rebuild => 1,
 143         },
 144         disable_plugins => {
 145                 type => "string",
 146                 default => [],
 147                 description => "plugins to disable",
 148                 safe => 1,
 149                 rebuild => 1,
 150         },
 151         templatedir => {
 152                 type => "string",
 153                 default => "$installdir/share/ikiwiki/templates",
 154                 description => "additional directory to search for template files",
 155                 advanced => 1,
 156                 safe => 0, # path
 157                 rebuild => 1,
 158         },
 159         underlaydir => {
 160                 type => "string",
 161                 default => "$installdir/share/ikiwiki/basewiki",
 162                 description => "base wiki source location",
 163                 advanced => 1,
 164                 safe => 0, # path
 165                 rebuild => 0,
 166         },
 167         underlaydirbase => {
 168                 type => "internal",
 169                 default => "$installdir/share/ikiwiki",
 170                 description => "parent directory containing additional underlays",
 171                 safe => 0,
 172                 rebuild => 0,
 173         },
 174         wrappers => {
 175                 type => "internal",
 176                 default => [],
 177                 description => "wrappers to generate",
 178                 safe => 0,
 179                 rebuild => 0,
 180         },
 181         underlaydirs => {
 182                 type => "internal",
 183                 default => [],
 184                 description => "additional underlays to use",
 185                 safe => 0,
 186                 rebuild => 0,
 187         },
 188         verbose => {
 189                 type => "boolean",
 190                 example => 1,
 191                 description => "display verbose messages?",
 192                 safe => 1,
 193                 rebuild => 0,
 194         },
 195         syslog => {
 196                 type => "boolean",
 197                 example => 1,
 198                 description => "log to syslog?",
 199                 safe => 1,
 200                 rebuild => 0,
 201         },
 202         usedirs => {
 203                 type => "boolean",
 204                 default => 1,
 205                 description => "create output files named page/index.html?",
 206                 safe => 0, # changing requires manual transition
 207                 rebuild => 1,
 208         },
 209         prefix_directives => {
 210                 type => "boolean",
 211                 default => 1,
 212                 description => "use '!'-prefixed preprocessor directives?",
 213                 safe => 0, # changing requires manual transition
 214                 rebuild => 1,
 215         },
 216         indexpages => {
 217                 type => "boolean",
 218                 default => 0,
 219                 description => "use page/index.mdwn source files",
 220                 safe => 1,
 221                 rebuild => 1,
 222         },
 223         discussion => {
 224                 type => "boolean",
 225                 default => 1,
 226                 description => "enable Discussion pages?",
 227                 safe => 1,
 228                 rebuild => 1,
 229         },
 230         discussionpage => {
 231                 type => "string",
 232                 default => gettext("Discussion"),
 233                 description => "name of Discussion pages",
 234                 safe => 1,
 235                 rebuild => 1,
 236         },
 237         html5 => {
 238                 type => "boolean",
 239                 default => 0,
 240                 description => "generate HTML5? (experimental)",
 241                 advanced => 1,
 242                 safe => 1,
 243                 rebuild => 1,
 244         },
 245         sslcookie => {
 246                 type => "boolean",
 247                 default => 0,
 248                 description => "only send cookies over SSL connections?",
 249                 advanced => 1,
 250                 safe => 1,
 251                 rebuild => 0,
 252         },
 253         default_pageext => {
 254                 type => "string",
 255                 default => "mdwn",
 256                 description => "extension to use for new pages",
 257                 safe => 0, # not sanitized
 258                 rebuild => 0,
 259         },
 260         htmlext => {
 261                 type => "string",
 262                 default => "html",
 263                 description => "extension to use for html files",
 264                 safe => 0, # not sanitized
 265                 rebuild => 1,
 266         },
 267         timeformat => {
 268                 type => "string",
 269                 default => '%c',
 270                 description => "strftime format string to display date",
 271                 advanced => 1,
 272                 safe => 1,
 273                 rebuild => 1,
 274         },
 275         locale => {
 276                 type => "string",
 277                 default => undef,
 278                 example => "en_US.UTF-8",
 279                 description => "UTF-8 locale to use",
 280                 advanced => 1,
 281                 safe => 0,
 282                 rebuild => 1,
 283         },
 284         userdir => {
 285                 type => "string",
 286                 default => "",
 287                 example => "users",
 288                 description => "put user pages below specified page",
 289                 safe => 1,
 290                 rebuild => 1,
 291         },
 292         numbacklinks => {
 293                 type => "integer",
 294                 default => 10,
 295                 description => "how many backlinks to show before hiding excess (0 to show all)",
 296                 safe => 1,
 297                 rebuild => 1,
 298         },
 299         hardlink => {
 300                 type => "boolean",
 301                 default => 0,
 302                 description => "attempt to hardlink source files? (optimisation for large files)",
 303                 advanced => 1,
 304                 safe => 0, # paranoia
 305                 rebuild => 0,
 306         },
 307         umask => {
 308                 type => "integer",
 309                 example => "022",
 310                 description => "force ikiwiki to use a particular umask",
 311                 advanced => 1,
 312                 safe => 0, # paranoia
 313                 rebuild => 0,
 314         },
 315         wrappergroup => {
 316                 type => "string",
 317                 example => "ikiwiki",
 318                 description => "group for wrappers to run in",
 319                 advanced => 1,
 320                 safe => 0, # paranoia
 321                 rebuild => 0,
 322         },
 323         libdir => {
 324                 type => "string",
 325                 default => "",
 326                 example => "$ENV{HOME}/.ikiwiki/",
 327                 description => "extra library and plugin directory",
 328                 advanced => 1,
 329                 safe => 0, # directory
 330                 rebuild => 0,
 331         },
 332         ENV => {
 333                 type => "string",
 334                 default => {},
 335                 description => "environment variables",
 336                 safe => 0, # paranoia
 337                 rebuild => 0,
 338         },
 339         include => {
 340                 type => "string",
 341                 default => undef,
 342                 example => '^\.htaccess$',
 343                 description => "regexp of normally excluded files to include",
 344                 advanced => 1,
 345                 safe => 0, # regexp
 346                 rebuild => 1,
 347         },
 348         exclude => {
 349                 type => "string",
 350                 default => undef,
 351                 example => '^(*\.private|Makefile)$',
 352                 description => "regexp of files that should be skipped",
 353                 advanced => 1,
 354                 safe => 0, # regexp
 355                 rebuild => 1,
 356         },
 357         wiki_file_prune_regexps => {
 358                 type => "internal",
 359                 default => [qr/(^|\/)\.\.(\/|$)/, qr/^\//, qr/^\./, qr/\/\./,
 360                         qr/\.x?html?$/, qr/\.ikiwiki-new$/,
 361                         qr/(^|\/).svn\//, qr/.arch-ids\//, qr/{arch}\//,
 362                         qr/(^|\/)_MTN\//, qr/(^|\/)_darcs\//,
 363                         qr/(^|\/)CVS\//, qr/\.dpkg-tmp$/],
 364                 description => "regexps of source files to ignore",
 365                 safe => 0,
 366                 rebuild => 1,
 367         },
 368         wiki_file_chars => {
 369                 type => "string",
 370                 description => "specifies the characters that are allowed in source filenames",
 371                 default => "-[:alnum:]+/.:_",
 372                 safe => 0,
 373                 rebuild => 1,
 374         },
 375         wiki_file_regexp => {
 376                 type => "internal",
 377                 description => "regexp of legal source files",
 378                 safe => 0,
 379                 rebuild => 1,
 380         },
 381         web_commit_regexp => {
 382                 type => "internal",
 383                 default => qr/^web commit (by (.*?(?=: |$))|from ([0-9a-fA-F:.]+[0-9a-fA-F])):?(.*)/,
 384                 description => "regexp to parse web commits from logs",
 385                 safe => 0,
 386                 rebuild => 0,
 387         },
 388         cgi => {
 389                 type => "internal",
 390                 default => 0,
 391                 description => "run as a cgi",
 392                 safe => 0,
 393                 rebuild => 0,
 394         },
 395         cgi_disable_uploads => {
 396                 type => "internal",
 397                 default => 1,
 398                 description => "whether CGI should accept file uploads",
 399                 safe => 0,
 400                 rebuild => 0,
 401         },
 402         post_commit => {
 403                 type => "internal",
 404                 default => 0,
 405                 description => "run as a post-commit hook",
 406                 safe => 0,
 407                 rebuild => 0,
 408         },
 409         rebuild => {
 410                 type => "internal",
 411                 default => 0,
 412                 description => "running in rebuild mode",
 413                 safe => 0,
 414                 rebuild => 0,
 415         },
 416         setup => {
 417                 type => "internal",
 418                 default => undef,
 419                 description => "running in setup mode",
 420                 safe => 0,
 421                 rebuild => 0,
 422         },
 423         clean => {
 424                 type => "internal",
 425                 default => 0,
 426                 description => "running in clean mode",
 427                 safe => 0,
 428                 rebuild => 0,
 429         },
 430         refresh => {
 431                 type => "internal",
 432                 default => 0,
 433                 description => "running in refresh mode",
 434                 safe => 0,
 435                 rebuild => 0,
 436         },
 437         test_receive => {
 438                 type => "internal",
 439                 default => 0,
 440                 description => "running in receive test mode",
 441                 safe => 0,
 442                 rebuild => 0,
 443         },
 444         wrapper_background_command => {
 445                 type => "internal",
 446                 default => '',
 447                 description => "background shell command to run",
 448                 safe => 0,
 449                 rebuild => 0,
 450         },
 451         gettime => {
 452                 type => "internal",
 453                 description => "running in gettime mode",
 454                 safe => 0,
 455                 rebuild => 0,
 456         },
 457         w3mmode => {
 458                 type => "internal",
 459                 default => 0,
 460                 description => "running in w3mmode",
 461                 safe => 0,
 462                 rebuild => 0,
 463         },
 464         wikistatedir => {
 465                 type => "internal",
 466                 default => undef,
 467                 description => "path to the .ikiwiki directory holding ikiwiki state",
 468                 safe => 0,
 469                 rebuild => 0,
 470         },
 471         setupfile => {
 472                 type => "internal",
 473                 default => undef,
 474                 description => "path to setup file",
 475                 safe => 0,
 476                 rebuild => 0,
 477         },
 478         setuptype => {
 479                 type => "internal",
 480                 default => "Standard",
 481                 description => "perl class to use to dump setup file",
 482                 safe => 0,
 483                 rebuild => 0,
 484         },
 485         allow_symlinks_before_srcdir => {
 486                 type => "boolean",
 487                 default => 0,
 488                 description => "allow symlinks in the path leading to the srcdir (potentially insecure)",
 489                 safe => 0,
 490                 rebuild => 0,
 491         },
 492 }
 493
 494 sub defaultconfig () {
 495         my %s=getsetup();
 496         my @ret;
 497         foreach my $key (keys %s) {
 498                 push @ret, $key, $s{$key}->{default};
 499         }
 500         use Data::Dumper;
 501         return @ret;
 502 }
 503
 504 sub checkconfig () {
 505         # locale stuff; avoid LC_ALL since it overrides everything
 506         if (defined $ENV{LC_ALL}) {
 507                 $ENV{LANG} = $ENV{LC_ALL};
 508                 delete $ENV{LC_ALL};
 509         }
 510         if (defined $config{locale}) {
 511                 if (POSIX::setlocale(&POSIX::LC_ALL, $config{locale})) {
 512                         $ENV{LANG}=$config{locale};
 513                         define_gettext();
 514                 }
 515         }
 516
 517         if (! defined $config{wiki_file_regexp}) {
 518                 $config{wiki_file_regexp}=qr/(^[$config{wiki_file_chars}]+$)/;
 519         }
 520
 521         if (ref $config{ENV} eq 'HASH') {
 522                 foreach my $val (keys %{$config{ENV}}) {
 523                         $ENV{$val}=$config{ENV}{$val};
 524                 }
 525         }
 526
 527         if ($config{w3mmode}) {
 528                 eval q{use Cwd q{abs_path}};
 529                 error($@) if $@;
 530                 $config{srcdir}=possibly_foolish_untaint(abs_path($config{srcdir}));
 531                 $config{destdir}=possibly_foolish_untaint(abs_path($config{destdir}));
 532                 $config{cgiurl}="file:///\$LIB/ikiwiki-w3m.cgi/".$config{cgiurl}
 533                         unless $config{cgiurl} =~ m!file:///!;
 534                 $config{url}="file://".$config{destdir};
 535         }
 536
 537         if ($config{cgi} && ! length $config{url}) {
 538                 error(gettext("Must specify url to wiki with --url when using --cgi"));
 539         }
 540
 541         $config{wikistatedir}="$config{srcdir}/.ikiwiki"
 542                 unless exists $config{wikistatedir} && defined $config{wikistatedir};
 543
 544         if (defined $config{umask}) {
 545                 umask(possibly_foolish_untaint($config{umask}));
 546         }
 547
 548         run_hooks(checkconfig => sub { shift->() });
 549
 550         return 1;
 551 }
 552
 553 sub listplugins () {
 554         my %ret;
 555
 556         foreach my $dir (@INC, $config{libdir}) {
 557                 next unless defined $dir && length $dir;
 558                 foreach my $file (glob("$dir/IkiWiki/Plugin/*.pm")) {
 559                         my ($plugin)=$file=~/.*\/(.*)\.pm$/;
 560                         $ret{$plugin}=1;
 561                 }
 562         }
 563         foreach my $dir ($config{libdir}, "$installdir/lib/ikiwiki") {
 564                 next unless defined $dir && length $dir;
 565                 foreach my $file (glob("$dir/plugins/*")) {
 566                         $ret{basename($file)}=1 if -x $file;
 567                 }
 568         }
 569
 570         return keys %ret;
 571 }
 572
 573 sub loadplugins () {
 574         if (defined $config{libdir} && length $config{libdir}) {
 575                 unshift @INC, possibly_foolish_untaint($config{libdir});
 576         }
 577
 578         foreach my $plugin (@{$config{default_plugins}}, @{$config{add_plugins}}) {
 579                 loadplugin($plugin);
 580         }
 581
 582         if ($config{rcs}) {
 583                 if (exists $hooks{rcs}) {
 584                         error(gettext("cannot use multiple rcs plugins"));
 585                 }
 586                 loadplugin($config{rcs});
 587         }
 588         if (! exists $hooks{rcs}) {
 589                 loadplugin("norcs");
 590         }
 591
 592         run_hooks(getopt => sub { shift->() });
 593         if (grep /^-/, @ARGV) {
 594                 print STDERR "Unknown option (or missing parameter): $_\n"
 595                         foreach grep /^-/, @ARGV;
 596                 usage();
 597         }
 598
 599         return 1;
 600 }
 601
 602 sub loadplugin ($;$) {
 603         my $plugin=shift;
 604         my $force=shift;
 605
 606         return if ! $force && grep { $_ eq $plugin} @{$config{disable_plugins}};
 607
 608         foreach my $dir (defined $config{libdir} ? possibly_foolish_untaint($config{libdir}) : undef,
 609                          "$installdir/lib/ikiwiki") {
 610                 if (defined $dir && -x "$dir/plugins/$plugin") {
 611                         eval { require IkiWiki::Plugin::external };
 612                         if ($@) {
 613                                 my $reason=$@;
 614                                 error(sprintf(gettext("failed to load external plugin needed for %s plugin: %s"), $plugin, $reason));
 615                         }
 616                         import IkiWiki::Plugin::external "$dir/plugins/$plugin";
 617                         $loaded_plugins{$plugin}=1;
 618                         return 1;
 619                 }
 620         }
 621
 622         my $mod="IkiWiki::Plugin::".possibly_foolish_untaint($plugin);
 623         eval qq{use $mod};
 624         if ($@) {
 625                 error("Failed to load plugin $mod: $@");
 626         }
 627         $loaded_plugins{$plugin}=1;
 628         return 1;
 629 }
 630
 631 sub error ($;$) {
 632         my $message=shift;
 633         my $cleaner=shift;
 634         log_message('err' => $message) if $config{syslog};
 635         if (defined $cleaner) {
 636                 $cleaner->();
 637         }
 638         die $message."\n";
 639 }
 640
 641 sub debug ($) {
 642         return unless $config{verbose};
 643         return log_message(debug => @_);
 644 }
 645
 646 my $log_open=0;
 647 sub log_message ($$) {
 648         my $type=shift;
 649
 650         if ($config{syslog}) {
 651                 require Sys::Syslog;
 652                 if (! $log_open) {
 653                         Sys::Syslog::setlogsock('unix');
 654                         Sys::Syslog::openlog('ikiwiki', '', 'user');
 655                         $log_open=1;
 656                 }
 657                 return eval {
 658                         Sys::Syslog::syslog($type, "[$config{wikiname}] %s", join(" ", @_));
 659                 };
 660         }
 661         elsif (! $config{cgi}) {
 662                 return print "@_\n";
 663         }
 664         else {
 665                 return print STDERR "@_\n";
 666         }
 667 }
 668
 669 sub possibly_foolish_untaint ($) {
 670         my $tainted=shift;
 671         my ($untainted)=$tainted=~/(.*)/s;
 672         return $untainted;
 673 }
 674
 675 sub basename ($) {
 676         my $file=shift;
 677
 678         $file=~s!.*/+!!;
 679         return $file;
 680 }
 681
 682 sub dirname ($) {
 683         my $file=shift;
 684
 685         $file=~s!/*[^/]+$!!;
 686         return $file;
 687 }
 688
 689 sub isinternal ($) {
 690         my $page=shift;
 691         return exists $pagesources{$page} &&
 692                 $pagesources{$page} =~ /\._([^.]+)$/;
 693 }
 694
 695 sub pagetype ($) {
 696         my $file=shift;
 697
 698         if ($file =~ /\.([^.]+)$/) {
 699                 return $1 if exists $hooks{htmlize}{$1};
 700         }
 701         my $base=basename($file);
 702         if (exists $hooks{htmlize}{$base} &&
 703             $hooks{htmlize}{$base}{noextension}) {
 704                 return $base;
 705         }
 706         return;
 707 }
 708
 709 my %pagename_cache;
 710
 711 sub pagename ($) {
 712         my $file=shift;
 713
 714         if (exists $pagename_cache{$file}) {
 715                 return $pagename_cache{$file};
 716         }
 717
 718         my $type=pagetype($file);
 719         my $page=$file;
 720         $page=~s/\Q.$type\E*$//
 721                 if defined $type && !$hooks{htmlize}{$type}{keepextension}
 722                         && !$hooks{htmlize}{$type}{noextension};
 723         if ($config{indexpages} && $page=~/(.*)\/index$/) {
 724                 $page=$1;
 725         }
 726
 727         $pagename_cache{$file} = $page;
 728         return $page;
 729 }
 730
 731 sub newpagefile ($$) {
 732         my $page=shift;
 733         my $type=shift;
 734
 735         if (! $config{indexpages} || $page eq 'index') {
 736                 return $page.".".$type;
 737         }
 738         else {
 739                 return $page."/index.".$type;
 740         }
 741 }
 742
 743 sub targetpage ($$;$) {
 744         my $page=shift;
 745         my $ext=shift;
 746         my $filename=shift;
 747
 748         if (defined $filename) {
 749                 return $page."/".$filename.".".$ext;
 750         }
 751         elsif (! $config{usedirs} || $page eq 'index') {
 752                 return $page.".".$ext;
 753         }
 754         else {
 755                 return $page."/index.".$ext;
 756         }
 757 }
 758
 759 sub htmlpage ($) {
 760         my $page=shift;
 761
 762         return targetpage($page, $config{htmlext});
 763 }
 764
 765 sub srcfile_stat {
 766         my $file=shift;
 767         my $nothrow=shift;
 768
 769         return "$config{srcdir}/$file", stat(_) if -e "$config{srcdir}/$file";
 770         foreach my $dir (@{$config{underlaydirs}}, $config{underlaydir}) {
 771                 return "$dir/$file", stat(_) if -e "$dir/$file";
 772         }
 773         error("internal error: $file cannot be found in $config{srcdir} or underlay") unless $nothrow;
 774         return;
 775 }
 776
 777 sub srcfile ($;$) {
 778         return (srcfile_stat(@_))[0];
 779 }
 780
 781 sub add_underlay ($) {
 782         my $dir=shift;
 783
 784         if ($dir !~ /^\//) {
 785                 $dir="$config{underlaydirbase}/$dir";
 786         }
 787
 788         if (! grep { $_ eq $dir } @{$config{underlaydirs}}) {
 789                 unshift @{$config{underlaydirs}}, $dir;
 790         }
 791
 792         return 1;
 793 }
 794
 795 sub readfile ($;$$) {
 796         my $file=shift;
 797         my $binary=shift;
 798         my $wantfd=shift;
 799
 800         if (-l $file) {
 801                 error("cannot read a symlink ($file)");
 802         }
 803
 804         local $/=undef;
 805         open (my $in, "<", $file) || error("failed to read $file: $!");
 806         binmode($in) if ($binary);
 807         return \*$in if $wantfd;
 808         my $ret=<$in>;
 809         # check for invalid utf-8, and toss it back to avoid crashes
 810         if (! utf8::valid($ret)) {
 811                 $ret=encode_utf8($ret);
 812         }
 813         close $in || error("failed to read $file: $!");
 814         return $ret;
 815 }
 816
 817 sub prep_writefile ($$) {
 818         my $file=shift;
 819         my $destdir=shift;
 820
 821         my $test=$file;
 822         while (length $test) {
 823                 if (-l "$destdir/$test") {
 824                         error("cannot write to a symlink ($test)");
 825                 }
 826                 if (-f _ && $test ne $file) {
 827                         # Remove conflicting file.
 828                         foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 829                                 foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 830                                         if ($f eq $test) {
 831                                                 unlink("$destdir/$test");
 832                                                 last;
 833                                         }
 834                                 }
 835                         }
 836                 }
 837                 $test=dirname($test);
 838         }
 839
 840         my $dir=dirname("$destdir/$file");
 841         if (! -d $dir) {
 842                 my $d="";
 843                 foreach my $s (split(m!/+!, $dir)) {
 844                         $d.="$s/";
 845                         if (! -d $d) {
 846                                 mkdir($d) || error("failed to create directory $d: $!");
 847                         }
 848                 }
 849         }
 850
 851         return 1;
 852 }
 853
 854 sub writefile ($$$;$$) {
 855         my $file=shift; # can include subdirs
 856         my $destdir=shift; # directory to put file in
 857         my $content=shift;
 858         my $binary=shift;
 859         my $writer=shift;
 860
 861         prep_writefile($file, $destdir);
 862
 863         my $newfile="$destdir/$file.ikiwiki-new";
 864         if (-l $newfile) {
 865                 error("cannot write to a symlink ($newfile)");
 866         }
 867
 868         my $cleanup = sub { unlink($newfile) };
 869         open (my $out, '>', $newfile) || error("failed to write $newfile: $!", $cleanup);
 870         binmode($out) if ($binary);
 871         if ($writer) {
 872                 $writer->(\*$out, $cleanup);
 873         }
 874         else {
 875                 print $out $content or error("failed writing to $newfile: $!", $cleanup);
 876         }
 877         close $out || error("failed saving $newfile: $!", $cleanup);
 878         rename($newfile, "$destdir/$file") ||
 879                 error("failed renaming $newfile to $destdir/$file: $!", $cleanup);
 880
 881         return 1;
 882 }
 883
 884 my %cleared;
 885 sub will_render ($$;$) {
 886         my $page=shift;
 887         my $dest=shift;
 888         my $clear=shift;
 889
 890         # Important security check for independently created files.
 891         if (-e "$config{destdir}/$dest" && ! $config{rebuild} &&
 892             ! grep { $_ eq $dest } (@{$renderedfiles{$page}}, @{$oldrenderedfiles{$page}}, @{$wikistate{editpage}{previews}})) {
 893                 my $from_other_page=0;
 894                 # Expensive, but rarely runs.
 895                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 896                         if (grep {
 897                                 $_ eq $dest ||
 898                                 dirname($_) eq $dest
 899                             } @{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 900                                 $from_other_page=1;
 901                                 last;
 902                         }
 903                 }
 904
 905                 error("$config{destdir}/$dest independently created, not overwriting with version from $page")
 906                         unless $from_other_page;
 907         }
 908
 909         # If $dest exists as a directory, remove conflicting files in it
 910         # rendered from other pages.
 911         if (-d _) {
 912                 foreach my $p (keys %renderedfiles, keys %oldrenderedfiles) {
 913                         foreach my $f (@{$renderedfiles{$p}}, @{$oldrenderedfiles{$p}}) {
 914                                 if (dirname($f) eq $dest) {
 915                                         unlink("$config{destdir}/$f");
 916                                         rmdir(dirname("$config{destdir}/$f"));
 917                                 }
 918                         }
 919                 }
 920         }
 921
 922         if (! $clear || $cleared{$page}) {
 923                 $renderedfiles{$page}=[$dest, grep { $_ ne $dest } @{$renderedfiles{$page}}];
 924         }
 925         else {
 926                 foreach my $old (@{$renderedfiles{$page}}) {
 927                         delete $destsources{$old};
 928                 }
 929                 $renderedfiles{$page}=[$dest];
 930                 $cleared{$page}=1;
 931         }
 932         $destsources{$dest}=$page;
 933
 934         return 1;
 935 }
 936
 937 sub bestlink ($$) {
 938         my $page=shift;
 939         my $link=shift;
 940
 941         my $cwd=$page;
 942         if ($link=~s/^\/+//) {
 943                 # absolute links
 944                 $cwd="";
 945         }
 946         $link=~s/\/$//;
 947
 948         do {
 949                 my $l=$cwd;
 950                 $l.="/" if length $l;
 951                 $l.=$link;
 952
 953                 if (exists $pagesources{$l}) {
 954                         return $l;
 955                 }
 956                 elsif (exists $pagecase{lc $l}) {
 957                         return $pagecase{lc $l};
 958                 }
 959         } while $cwd=~s{/?[^/]+$}{};
 960
 961         if (length $config{userdir}) {
 962                 my $l = "$config{userdir}/".lc($link);
 963                 if (exists $pagesources{$l}) {
 964                         return $l;
 965                 }
 966                 elsif (exists $pagecase{lc $l}) {
 967                         return $pagecase{lc $l};
 968                 }
 969         }
 970
 971         #print STDERR "warning: page $page, broken link: $link\n";
 972         return "";
 973 }
 974
 975 sub isinlinableimage ($) {
 976         my $file=shift;
 977
 978         return $file =~ /\.(png|gif|jpg|jpeg)$/i;
 979 }
 980
 981 sub pagetitle ($;$) {
 982         my $page=shift;
 983         my $unescaped=shift;
 984
 985         if ($unescaped) {
 986                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : chr($2)/eg;
 987         }
 988         else {
 989                 $page=~s/(__(\d+)__|_)/$1 eq '_' ? ' ' : "&#$2;"/eg;
 990         }
 991
 992         return $page;
 993 }
 994
 995 sub titlepage ($) {
 996         my $title=shift;
 997         # support use w/o %config set
 998         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
 999         $title=~s/([^$chars]|_)/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1000         return $title;
1001 }
1002
1003 sub linkpage ($) {
1004         my $link=shift;
1005         my $chars = defined $config{wiki_file_chars} ? $config{wiki_file_chars} : "-[:alnum:]+/.:_";
1006         $link=~s/([^$chars])/$1 eq ' ' ? '_' : "__".ord($1)."__"/eg;
1007         return $link;
1008 }
1009
1010 sub cgiurl (@) {
1011         my %params=@_;
1012
1013         my $cgiurl=$config{cgiurl};
1014         if (exists $params{cgiurl}) {
1015                 $cgiurl=$params{cgiurl};
1016                 delete $params{cgiurl};
1017         }
1018         return $cgiurl."?".
1019                 join("&amp;", map $_."=".uri_escape_utf8($params{$_}), keys %params);
1020 }
1021
1022 sub baseurl (;$) {
1023         my $page=shift;
1024
1025         return "$config{url}/" if ! defined $page;
1026
1027         $page=htmlpage($page);
1028         $page=~s/[^\/]+$//;
1029         $page=~s/[^\/]+\//..\//g;
1030         return $page;
1031 }
1032
1033 sub abs2rel ($$) {
1034         # Work around very innefficient behavior in File::Spec if abs2rel
1035         # is passed two relative paths. It's much faster if paths are
1036         # absolute! (Debian bug #376658; fixed in debian unstable now)
1037         my $path="/".shift;
1038         my $base="/".shift;
1039
1040         require File::Spec;
1041         my $ret=File::Spec->abs2rel($path, $base);
1042         $ret=~s/^// if defined $ret;
1043         return $ret;
1044 }
1045
1046 sub displaytime ($;$$) {
1047         # Plugins can override this function to mark up the time to
1048         # display.
1049         my $time=formattime($_[0], $_[1]);
1050         if ($config{html5}) {
1051                 return '<time datetime="'.date_3339($_[0]).'"'.
1052                         ($_[2] ? ' pubdate="pubdate"' : '').
1053                         '>'.$time.'</time>';
1054         }
1055         else {
1056                 return '<span class="date">'.$time.'</span>';
1057         }
1058 }
1059
1060 sub formattime ($;$) {
1061         # Plugins can override this function to format the time.
1062         my $time=shift;
1063         my $format=shift;
1064         if (! defined $format) {
1065                 $format=$config{timeformat};
1066         }
1067
1068         # strftime doesn't know about encodings, so make sure
1069         # its output is properly treated as utf8
1070         return decode_utf8(POSIX::strftime($format, localtime($time)));
1071 }
1072
1073 sub date_3339 ($) {
1074         my $time=shift;
1075
1076         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
1077         POSIX::setlocale(&POSIX::LC_TIME, "C");
1078         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
1079         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
1080         return $ret;
1081 }
1082
1083 sub beautify_urlpath ($) {
1084         my $url=shift;
1085
1086         # Ensure url is not an empty link, and if necessary,
1087         # add ./ to avoid colon confusion.
1088         if ($url !~ /^\// && $url !~ /^\.\.?\//) {
1089                 $url="./$url";
1090         }
1091
1092         if ($config{usedirs}) {
1093                 $url =~ s!/index.$config{htmlext}$!/!;
1094         }
1095
1096         return $url;
1097 }
1098
1099 sub urlto ($$;$) {
1100         my $to=shift;
1101         my $from=shift;
1102         my $absolute=shift;
1103
1104         if (! length $to) {
1105                 return beautify_urlpath(baseurl($from)."index.$config{htmlext}");
1106         }
1107
1108         if (! $destsources{$to}) {
1109                 $to=htmlpage($to);
1110         }
1111
1112         if ($absolute) {
1113                 return $config{url}.beautify_urlpath("/".$to);
1114         }
1115
1116         my $link = abs2rel($to, dirname(htmlpage($from)));
1117
1118         return beautify_urlpath($link);
1119 }
1120
1121 sub isselflink ($$) {
1122         # Plugins can override this function to support special types
1123         # of selflinks.
1124         my $page=shift;
1125         my $link=shift;
1126
1127         return $page eq $link;
1128 }
1129
1130 sub htmllink ($$$;@) {
1131         my $lpage=shift; # the page doing the linking
1132         my $page=shift; # the page that will contain the link (different for inline)
1133         my $link=shift;
1134         my %opts=@_;
1135
1136         $link=~s/\/$//;
1137
1138         my $bestlink;
1139         if (! $opts{forcesubpage}) {
1140                 $bestlink=bestlink($lpage, $link);
1141         }
1142         else {
1143                 $bestlink="$lpage/".lc($link);
1144         }
1145
1146         my $linktext;
1147         if (defined $opts{linktext}) {
1148                 $linktext=$opts{linktext};
1149         }
1150         else {
1151                 $linktext=pagetitle(basename($link));
1152         }
1153
1154         return "<span class=\"selflink\">$linktext</span>"
1155                 if length $bestlink && isselflink($page, $bestlink) &&
1156                    ! defined $opts{anchor};
1157
1158         if (! $destsources{$bestlink}) {
1159                 $bestlink=htmlpage($bestlink);
1160
1161                 if (! $destsources{$bestlink}) {
1162                         my $cgilink = "";
1163                         if (length $config{cgiurl}) {
1164                                 $cgilink = "<a href=\"".
1165                                         cgiurl(
1166                                                 do => "create",
1167                                                 page => lc($link),
1168                                                 from => $lpage
1169                                         )."\" rel=\"nofollow\">?</a>";
1170                         }
1171                         return "<span class=\"createlink\">$cgilink$linktext</span>"
1172                 }
1173         }
1174
1175         $bestlink=abs2rel($bestlink, dirname(htmlpage($page)));
1176         $bestlink=beautify_urlpath($bestlink);
1177
1178         if (! $opts{noimageinline} && isinlinableimage($bestlink)) {
1179                 return "<img src=\"$bestlink\" alt=\"$linktext\" />";
1180         }
1181
1182         if (defined $opts{anchor}) {
1183                 $bestlink.="#".$opts{anchor};
1184         }
1185
1186         my @attrs;
1187         foreach my $attr (qw{rel class title}) {
1188                 if (defined $opts{$attr}) {
1189                         push @attrs, " $attr=\"$opts{$attr}\"";
1190                 }
1191         }
1192
1193         return "<a href=\"$bestlink\"@attrs>$linktext</a>";
1194 }
1195
1196 sub userpage ($) {
1197         my $user=shift;
1198         return length $config{userdir} ? "$config{userdir}/$user" : $user;
1199 }
1200
1201 sub openiduser ($) {
1202         my $user=shift;
1203
1204         if ($user =~ m!^https?://! &&
1205             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
1206                 my $display;
1207
1208                 if (Net::OpenID::VerifiedIdentity->can("DisplayOfURL")) {
1209                         $display = Net::OpenID::VerifiedIdentity::DisplayOfURL($user);
1210                 }
1211                 else {
1212                         # backcompat with old version
1213                         my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
1214                         $display=$oid->display;
1215                 }
1216
1217                 # Convert "user.somehost.com" to "user [somehost.com]"
1218                 # (also "user.somehost.co.uk")
1219                 if ($display !~ /\[/) {
1220                         $display=~s/^([-a-zA-Z0-9]+?)\.([-.a-zA-Z0-9]+\.[a-z]+)$/$1 [$2]/;
1221                 }
1222                 # Convert "http://somehost.com/user" to "user [somehost.com]".
1223                 # (also "https://somehost.com/user/")
1224                 if ($display !~ /\[/) {
1225                         $display=~s/^https?:\/\/(.+)\/([^\/#?]+)\/?(?:[#?].*)?$/$2 [$1]/;
1226                 }
1227                 $display=~s!^https?://!!; # make sure this is removed
1228                 eval q{use CGI 'escapeHTML'};
1229                 error($@) if $@;
1230                 return escapeHTML($display);
1231         }
1232         return;
1233 }
1234
1235 sub htmlize ($$$$) {
1236         my $page=shift;
1237         my $destpage=shift;
1238         my $type=shift;
1239         my $content=shift;
1240
1241         my $oneline = $content !~ /\n/;
1242
1243         if (exists $hooks{htmlize}{$type}) {
1244                 $content=$hooks{htmlize}{$type}{call}->(
1245                         page => $page,
1246                         content => $content,
1247                 );
1248         }
1249         else {
1250                 error("htmlization of $type not supported");
1251         }
1252
1253         run_hooks(sanitize => sub {
1254                 $content=shift->(
1255                         page => $page,
1256                         destpage => $destpage,
1257                         content => $content,
1258                 );
1259         });
1260
1261         if ($oneline) {
1262                 # hack to get rid of enclosing junk added by markdown
1263                 # and other htmlizers/sanitizers
1264                 $content=~s/^<p>//i;
1265                 $content=~s/<\/p>\n*$//i;
1266         }
1267
1268         return $content;
1269 }
1270
1271 sub linkify ($$$) {
1272         my $page=shift;
1273         my $destpage=shift;
1274         my $content=shift;
1275
1276         run_hooks(linkify => sub {
1277                 $content=shift->(
1278                         page => $page,
1279                         destpage => $destpage,
1280                         content => $content,
1281                 );
1282         });
1283
1284         return $content;
1285 }
1286
1287 our %preprocessing;
1288 our $preprocess_preview=0;
1289 sub preprocess ($$$;$$) {
1290         my $page=shift; # the page the data comes from
1291         my $destpage=shift; # the page the data will appear in (different for inline)
1292         my $content=shift;
1293         my $scan=shift;
1294         my $preview=shift;
1295
1296         # Using local because it needs to be set within any nested calls
1297         # of this function.
1298         local $preprocess_preview=$preview if defined $preview;
1299
1300         my $handle=sub {
1301                 my $escape=shift;
1302                 my $prefix=shift;
1303                 my $command=shift;
1304                 my $params=shift;
1305                 $params="" if ! defined $params;
1306
1307                 if (length $escape) {
1308                         return "[[$prefix$command $params]]";
1309                 }
1310                 elsif (exists $hooks{preprocess}{$command}) {
1311                         return "" if $scan && ! $hooks{preprocess}{$command}{scan};
1312                         # Note: preserve order of params, some plugins may
1313                         # consider it significant.
1314                         my @params;
1315                         while ($params =~ m{
1316                                 (?:([-\w]+)=)?          # 1: named parameter key?
1317                                 (?:
1318                                         """(.*?)"""     # 2: triple-quoted value
1319                                 |
1320                                         "([^"]*?)"      # 3: single-quoted value
1321                                 |
1322                                         (\S+)           # 4: unquoted value
1323                                 )
1324                                 (?:\s+|$)               # delimiter to next param
1325                         }sgx) {
1326                                 my $key=$1;
1327                                 my $val;
1328                                 if (defined $2) {
1329                                         $val=$2;
1330                                         $val=~s/\r\n/\n/mg;
1331                                         $val=~s/^\n+//g;
1332                                         $val=~s/\n+$//g;
1333                                 }
1334                                 elsif (defined $3) {
1335                                         $val=$3;
1336                                 }
1337                                 elsif (defined $4) {
1338                                         $val=$4;
1339                                 }
1340
1341                                 if (defined $key) {
1342                                         push @params, $key, $val;
1343                                 }
1344                                 else {
1345                                         push @params, $val, '';
1346                                 }
1347                         }
1348                         if ($preprocessing{$page}++ > 3) {
1349                                 # Avoid loops of preprocessed pages preprocessing
1350                                 # other pages that preprocess them, etc.
1351                                 return "[[!$command <span class=\"error\">".
1352                                         sprintf(gettext("preprocessing loop detected on %s at depth %i"),
1353                                                 $page, $preprocessing{$page}).
1354                                         "</span>]]";
1355                         }
1356                         my $ret;
1357                         if (! $scan) {
1358                                 $ret=eval {
1359                                         $hooks{preprocess}{$command}{call}->(
1360                                                 @params,
1361                                                 page => $page,
1362                                                 destpage => $destpage,
1363                                                 preview => $preprocess_preview,
1364                                         );
1365                                 };
1366                                 if ($@) {
1367                                         my $error=$@;
1368                                         chomp $error;
1369                                         $ret="[[!$command <span class=\"error\">".
1370                                                 gettext("Error").": $error"."</span>]]";
1371                                 }
1372                         }
1373                         else {
1374                                 # use void context during scan pass
1375                                 eval {
1376                                         $hooks{preprocess}{$command}{call}->(
1377                                                 @params,
1378                                                 page => $page,
1379                                                 destpage => $destpage,
1380                                                 preview => $preprocess_preview,
1381                                         );
1382                                 };
1383                                 $ret="";
1384                         }
1385                         $preprocessing{$page}--;
1386                         return $ret;
1387                 }
1388                 else {
1389                         return "[[$prefix$command $params]]";
1390                 }
1391         };
1392
1393         my $regex;
1394         if ($config{prefix_directives}) {
1395                 $regex = qr{
1396                         (\\?)           # 1: escape?
1397                         \[\[(!)         # directive open; 2: prefix
1398                         ([-\w]+)        # 3: command
1399                         (               # 4: the parameters..
1400                                 \s+     # Must have space if parameters present
1401                                 (?:
1402                                         (?:[-\w]+=)?            # named parameter key?
1403                                         (?:
1404                                                 """.*?"""       # triple-quoted value
1405                                                 |
1406                                                 "[^"]*?"        # single-quoted value
1407                                                 |
1408                                                 [^"\s\]]+       # unquoted value
1409                                         )
1410                                         \s*                     # whitespace or end
1411                                                                 # of directive
1412                                 )
1413                         *)?             # 0 or more parameters
1414                         \]\]            # directive closed
1415                 }sx;
1416         }
1417         else {
1418                 $regex = qr{
1419                         (\\?)           # 1: escape?
1420                         \[\[(!?)        # directive open; 2: optional prefix
1421                         ([-\w]+)        # 3: command
1422                         \s+
1423                         (               # 4: the parameters..
1424                                 (?:
1425                                         (?:[-\w]+=)?            # named parameter key?
1426                                         (?:
1427                                                 """.*?"""       # triple-quoted value
1428                                                 |
1429                                                 "[^"]*?"        # single-quoted value
1430                                                 |
1431                                                 [^"\s\]]+       # unquoted value
1432                                         )
1433                                         \s*                     # whitespace or end
1434                                                                 # of directive
1435                                 )
1436                         *)              # 0 or more parameters
1437                         \]\]            # directive closed
1438                 }sx;
1439         }
1440
1441         $content =~ s{$regex}{$handle->($1, $2, $3, $4)}eg;
1442         return $content;
1443 }
1444
1445 sub filter ($$$) {
1446         my $page=shift;
1447         my $destpage=shift;
1448         my $content=shift;
1449
1450         run_hooks(filter => sub {
1451                 $content=shift->(page => $page, destpage => $destpage,
1452                         content => $content);
1453         });
1454
1455         return $content;
1456 }
1457
1458 sub check_canedit ($$$;$) {
1459         my $page=shift;
1460         my $q=shift;
1461         my $session=shift;
1462         my $nonfatal=shift;
1463
1464         my $canedit;
1465         run_hooks(canedit => sub {
1466                 return if defined $canedit;
1467                 my $ret=shift->($page, $q, $session);
1468                 if (defined $ret) {
1469                         if ($ret eq "") {
1470                                 $canedit=1;
1471                         }
1472                         elsif (ref $ret eq 'CODE') {
1473                                 $ret->() unless $nonfatal;
1474                                 $canedit=0;
1475                         }
1476                         elsif (defined $ret) {
1477                                 error($ret) unless $nonfatal;
1478                                 $canedit=0;
1479                         }
1480                 }
1481         });
1482         return defined $canedit ? $canedit : 1;
1483 }
1484
1485 sub check_content (@) {
1486         my %params=@_;
1487
1488         return 1 if ! exists $hooks{checkcontent}; # optimisation
1489
1490         if (exists $pagesources{$params{page}}) {
1491                 my @diff;
1492                 my %old=map { $_ => 1 }
1493                         split("\n", readfile(srcfile($pagesources{$params{page}})));
1494                 foreach my $line (split("\n", $params{content})) {
1495                         push @diff, $line if ! exists $old{$line};
1496                 }
1497                 $params{diff}=join("\n", @diff);
1498         }
1499
1500         my $ok;
1501         run_hooks(checkcontent => sub {
1502                 return if defined $ok;
1503                 my $ret=shift->(%params);
1504                 if (defined $ret) {
1505                         if ($ret eq "") {
1506                                 $ok=1;
1507                         }
1508                         elsif (ref $ret eq 'CODE') {
1509                                 $ret->() unless $params{nonfatal};
1510                                 $ok=0;
1511                         }
1512                         elsif (defined $ret) {
1513                                 error($ret) unless $params{nonfatal};
1514                                 $ok=0;
1515                         }
1516                 }
1517
1518         });
1519         return defined $ok ? $ok : 1;
1520 }
1521
1522 my $wikilock;
1523
1524 sub lockwiki () {
1525         # Take an exclusive lock on the wiki to prevent multiple concurrent
1526         # run issues. The lock will be dropped on program exit.
1527         if (! -d $config{wikistatedir}) {
1528                 mkdir($config{wikistatedir});
1529         }
1530         open($wikilock, '>', "$config{wikistatedir}/lockfile") ||
1531                 error ("cannot write to $config{wikistatedir}/lockfile: $!");
1532         if (! flock($wikilock, 2)) { # LOCK_EX
1533                 error("failed to get lock");
1534         }
1535         return 1;
1536 }
1537
1538 sub unlockwiki () {
1539         POSIX::close($ENV{IKIWIKI_CGILOCK_FD}) if exists $ENV{IKIWIKI_CGILOCK_FD};
1540         return close($wikilock) if $wikilock;
1541         return;
1542 }
1543
1544 my $commitlock;
1545
1546 sub commit_hook_enabled () {
1547         open($commitlock, '+>', "$config{wikistatedir}/commitlock") ||
1548                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1549         if (! flock($commitlock, 1 | 4)) { # LOCK_SH | LOCK_NB to test
1550                 close($commitlock) || error("failed closing commitlock: $!");
1551                 return 0;
1552         }
1553         close($commitlock) || error("failed closing commitlock: $!");
1554         return 1;
1555 }
1556
1557 sub disable_commit_hook () {
1558         open($commitlock, '>', "$config{wikistatedir}/commitlock") ||
1559                 error("cannot write to $config{wikistatedir}/commitlock: $!");
1560         if (! flock($commitlock, 2)) { # LOCK_EX
1561                 error("failed to get commit lock");
1562         }
1563         return 1;
1564 }
1565
1566 sub enable_commit_hook () {
1567         return close($commitlock) if $commitlock;
1568         return;
1569 }
1570
1571 sub loadindex () {
1572         %oldrenderedfiles=%pagectime=();
1573         if (! $config{rebuild}) {
1574                 %pagesources=%pagemtime=%oldlinks=%links=%depends=
1575                 %destsources=%renderedfiles=%pagecase=%pagestate=
1576                 %depends_simple=%typedlinks=%oldtypedlinks=();
1577         }
1578         my $in;
1579         if (! open ($in, "<", "$config{wikistatedir}/indexdb")) {
1580                 if (-e "$config{wikistatedir}/index") {
1581                         system("ikiwiki-transition", "indexdb", $config{srcdir});
1582                         open ($in, "<", "$config{wikistatedir}/indexdb") || return;
1583                 }
1584                 else {
1585                         $config{gettime}=1; # first build
1586                         return;
1587                 }
1588         }
1589
1590         my $index=Storable::fd_retrieve($in);
1591         if (! defined $index) {
1592                 return 0;
1593         }
1594
1595         my $pages;
1596         if (exists $index->{version} && ! ref $index->{version}) {
1597                 $pages=$index->{page};
1598                 %wikistate=%{$index->{state}};
1599                 # Handle plugins that got disabled by loading a new setup.
1600                 if (exists $config{setupfile}) {
1601                         require IkiWiki::Setup;
1602                         IkiWiki::Setup::disabled_plugins(
1603                                 grep { ! $loaded_plugins{$_} } keys %wikistate);
1604                 }
1605         }
1606         else {
1607                 $pages=$index;
1608                 %wikistate=();
1609         }
1610
1611         foreach my $src (keys %$pages) {
1612                 my $d=$pages->{$src};
1613                 my $page=pagename($src);
1614                 $pagectime{$page}=$d->{ctime};
1615                 $pagesources{$page}=$src;
1616                 if (! $config{rebuild}) {
1617                         $pagemtime{$page}=$d->{mtime};
1618                         $renderedfiles{$page}=$d->{dest};
1619                         if (exists $d->{links} && ref $d->{links}) {
1620                                 $links{$page}=$d->{links};
1621                                 $oldlinks{$page}=[@{$d->{links}}];
1622                         }
1623                         if (ref $d->{depends_simple} eq 'ARRAY') {
1624                                 # old format
1625                                 $depends_simple{$page}={
1626                                         map { $_ => 1 } @{$d->{depends_simple}}
1627                                 };
1628                         }
1629                         elsif (exists $d->{depends_simple}) {
1630                                 $depends_simple{$page}=$d->{depends_simple};
1631                         }
1632                         if (exists $d->{dependslist}) {
1633                                 # old format
1634                                 $depends{$page}={
1635                                         map { $_ => $DEPEND_CONTENT }
1636                                                 @{$d->{dependslist}}
1637                                 };
1638                         }
1639                         elsif (exists $d->{depends} && ! ref $d->{depends}) {
1640                                 # old format
1641                                 $depends{$page}={$d->{depends} => $DEPEND_CONTENT };
1642                         }
1643                         elsif (exists $d->{depends}) {
1644                                 $depends{$page}=$d->{depends};
1645                         }
1646                         if (exists $d->{state}) {
1647                                 $pagestate{$page}=$d->{state};
1648                         }
1649                         if (exists $d->{typedlinks}) {
1650                                 $typedlinks{$page}=$d->{typedlinks};
1651
1652                                 while (my ($type, $links) = each %{$typedlinks{$page}}) {
1653                                         next unless %$links;
1654                                         $oldtypedlinks{$page}{$type} = {%$links};
1655                                 }
1656                         }
1657                 }
1658                 $oldrenderedfiles{$page}=[@{$d->{dest}}];
1659         }
1660         foreach my $page (keys %pagesources) {
1661                 $pagecase{lc $page}=$page;
1662         }
1663         foreach my $page (keys %renderedfiles) {
1664                 $destsources{$_}=$page foreach @{$renderedfiles{$page}};
1665         }
1666         return close($in);
1667 }
1668
1669 sub saveindex () {
1670         run_hooks(savestate => sub { shift->() });
1671
1672         my @plugins=keys %loaded_plugins;
1673
1674         if (! -d $config{wikistatedir}) {
1675                 mkdir($config{wikistatedir});
1676         }
1677         my $newfile="$config{wikistatedir}/indexdb.new";
1678         my $cleanup = sub { unlink($newfile) };
1679         open (my $out, '>', $newfile) || error("cannot write to $newfile: $!", $cleanup);
1680
1681         my %index;
1682         foreach my $page (keys %pagemtime) {
1683                 next unless $pagemtime{$page};
1684                 my $src=$pagesources{$page};
1685
1686                 $index{page}{$src}={
1687                         ctime => $pagectime{$page},
1688                         mtime => $pagemtime{$page},
1689                         dest => $renderedfiles{$page},
1690                         links => $links{$page},
1691                 };
1692
1693                 if (exists $depends{$page}) {
1694                         $index{page}{$src}{depends} = $depends{$page};
1695                 }
1696
1697                 if (exists $depends_simple{$page}) {
1698                         $index{page}{$src}{depends_simple} = $depends_simple{$page};
1699                 }
1700
1701                 if (exists $typedlinks{$page} && %{$typedlinks{$page}}) {
1702                         $index{page}{$src}{typedlinks} = $typedlinks{$page};
1703                 }
1704
1705                 if (exists $pagestate{$page}) {
1706                         foreach my $id (@plugins) {
1707                                 foreach my $key (keys %{$pagestate{$page}{$id}}) {
1708                                         $index{page}{$src}{state}{$id}{$key}=$pagestate{$page}{$id}{$key};
1709                                 }
1710                         }
1711                 }
1712         }
1713
1714         $index{state}={};
1715         foreach my $id (@plugins) {
1716                 $index{state}{$id}={}; # used to detect disabled plugins
1717                 foreach my $key (keys %{$wikistate{$id}}) {
1718                         $index{state}{$id}{$key}=$wikistate{$id}{$key};
1719                 }
1720         }
1721
1722         $index{version}="3";
1723         my $ret=Storable::nstore_fd(\%index, $out);
1724         return if ! defined $ret || ! $ret;
1725         close $out || error("failed saving to $newfile: $!", $cleanup);
1726         rename($newfile, "$config{wikistatedir}/indexdb") ||
1727                 error("failed renaming $newfile to $config{wikistatedir}/indexdb", $cleanup);
1728
1729         return 1;
1730 }
1731
1732 sub template_file ($) {
1733         my $name=shift;
1734
1735         my $tpage=($name =~ s/^\///) ? $name : "templates/$name";
1736         my $template;
1737         if ($name !~ /\.tmpl$/ && exists $pagesources{$tpage}) {
1738                 $template=srcfile($pagesources{$tpage}, 1);
1739                 $name.=".tmpl";
1740         }
1741         else {
1742                 $template=srcfile($tpage, 1);
1743         }
1744
1745         if (defined $template) {
1746                 return $template, $tpage, 1 if wantarray;
1747                 return $template;
1748         }
1749         else {
1750                 $name=~s:/::; # avoid path traversal
1751                 foreach my $dir ($config{templatedir},
1752                                  "$installdir/share/ikiwiki/templates") {
1753                         if (-e "$dir/$name") {
1754                                 $template="$dir/$name";
1755                                 last;
1756                         }
1757                 }
1758                 if (defined $template) {
1759                         return $template, $tpage if wantarray;
1760                         return $template;
1761                 }
1762         }
1763
1764         return;
1765 }
1766
1767 sub template_depends ($$;@) {
1768         my $name=shift;
1769         my $page=shift;
1770
1771         my ($filename, $tpage, $untrusted)=template_file($name);
1772         if (defined $page && defined $tpage) {
1773                 add_depends($page, $tpage);
1774         }
1775
1776         return unless defined $filename;
1777
1778         my @opts=(
1779                 filter => sub {
1780                         my $text_ref = shift;
1781                         ${$text_ref} = decode_utf8(${$text_ref});
1782                 },
1783                 loop_context_vars => 1,
1784                 die_on_bad_params => 0,
1785                 filename => $filename,
1786                 @_,
1787                 ($untrusted ? (no_includes => 1) : ()),
1788         );
1789         return @opts if wantarray;
1790
1791         require HTML::Template;
1792         return HTML::Template->new(@opts);
1793 }
1794
1795 sub template ($;@) {
1796         template_depends(shift, undef, @_);
1797 }
1798
1799 sub misctemplate ($$;@) {
1800         my $title=shift;
1801         my $content=shift;
1802         my %params=@_;
1803
1804         my $template=template("page.tmpl");
1805
1806         my $page="";
1807         if (exists $params{page}) {
1808                 $page=delete $params{page};
1809         }
1810         run_hooks(pagetemplate => sub {
1811                 shift->(
1812                         page => $page,
1813                         destpage => $page,
1814                         template => $template,
1815                 );
1816         });
1817         templateactions($template, "");
1818
1819         $template->param(
1820                 dynamic => 1,
1821                 title => $title,
1822                 wikiname => $config{wikiname},
1823                 content => $content,
1824                 baseurl => baseurl(),
1825                 html5 => $config{html5},
1826                 %params,
1827         );
1828
1829         return $template->output;
1830 }
1831
1832 sub templateactions ($$) {
1833         my $template=shift;
1834         my $page=shift;
1835
1836         my $have_actions=0;
1837         my @actions;
1838         run_hooks(pageactions => sub {
1839                 push @actions, map { { action => $_ } }
1840                         grep { defined } shift->(page => $page);
1841         });
1842         $template->param(actions => \@actions);
1843
1844         if ($config{cgiurl} && exists $hooks{auth}) {
1845                 $template->param(prefsurl => cgiurl(do => "prefs"));
1846                 $have_actions=1;
1847         }
1848
1849         if ($have_actions || @actions) {
1850                 $template->param(have_actions => 1);
1851         }
1852 }
1853
1854 sub hook (@) {
1855         my %param=@_;
1856
1857         if (! exists $param{type} || ! ref $param{call} || ! exists $param{id}) {
1858                 error 'hook requires type, call, and id parameters';
1859         }
1860
1861         return if $param{no_override} && exists $hooks{$param{type}}{$param{id}};
1862
1863         $hooks{$param{type}}{$param{id}}=\%param;
1864         return 1;
1865 }
1866
1867 sub run_hooks ($$) {
1868         # Calls the given sub for each hook of the given type,
1869         # passing it the hook function to call.
1870         my $type=shift;
1871         my $sub=shift;
1872
1873         if (exists $hooks{$type}) {
1874                 my (@first, @middle, @last);
1875                 foreach my $id (keys %{$hooks{$type}}) {
1876                         if ($hooks{$type}{$id}{first}) {
1877                                 push @first, $id;
1878                         }
1879                         elsif ($hooks{$type}{$id}{last}) {
1880                                 push @last, $id;
1881                         }
1882                         else {
1883                                 push @middle, $id;
1884                         }
1885                 }
1886                 foreach my $id (@first, @middle, @last) {
1887                         $sub->($hooks{$type}{$id}{call});
1888                 }
1889         }
1890
1891         return 1;
1892 }
1893
1894 sub rcs_update () {
1895         $hooks{rcs}{rcs_update}{call}->(@_);
1896 }
1897
1898 sub rcs_prepedit ($) {
1899         $hooks{rcs}{rcs_prepedit}{call}->(@_);
1900 }
1901
1902 sub rcs_commit (@) {
1903         $hooks{rcs}{rcs_commit}{call}->(@_);
1904 }
1905
1906 sub rcs_commit_staged (@) {
1907         $hooks{rcs}{rcs_commit_staged}{call}->(@_);
1908 }
1909
1910 sub rcs_add ($) {
1911         $hooks{rcs}{rcs_add}{call}->(@_);
1912 }
1913
1914 sub rcs_remove ($) {
1915         $hooks{rcs}{rcs_remove}{call}->(@_);
1916 }
1917
1918 sub rcs_rename ($$) {
1919         $hooks{rcs}{rcs_rename}{call}->(@_);
1920 }
1921
1922 sub rcs_recentchanges ($) {
1923         $hooks{rcs}{rcs_recentchanges}{call}->(@_);
1924 }
1925
1926 sub rcs_diff ($) {
1927         $hooks{rcs}{rcs_diff}{call}->(@_);
1928 }
1929
1930 sub rcs_getctime ($) {
1931         $hooks{rcs}{rcs_getctime}{call}->(@_);
1932 }
1933
1934 sub rcs_getmtime ($) {
1935         $hooks{rcs}{rcs_getmtime}{call}->(@_);
1936 }
1937
1938 sub rcs_receive () {
1939         $hooks{rcs}{rcs_receive}{call}->();
1940 }
1941
1942 sub add_depends ($$;$) {
1943         my $page=shift;
1944         my $pagespec=shift;
1945         my $deptype=shift || $DEPEND_CONTENT;
1946
1947         # Is the pagespec a simple page name?
1948         if ($pagespec =~ /$config{wiki_file_regexp}/ &&
1949             $pagespec !~ /[\s*?()!]/) {
1950                 $depends_simple{$page}{lc $pagespec} |= $deptype;
1951                 return 1;
1952         }
1953
1954         # Add explicit dependencies for influences.
1955         my $sub=pagespec_translate($pagespec);
1956         return unless defined $sub;
1957         foreach my $p (keys %pagesources) {
1958                 my $r=$sub->($p, location => $page);
1959                 my $i=$r->influences;
1960                 my $static=$r->influences_static;
1961                 foreach my $k (keys %$i) {
1962                         next unless $r || $static || $k eq $page;
1963                         $depends_simple{$page}{lc $k} |= $i->{$k};
1964                 }
1965                 last if $static;
1966         }
1967
1968         $depends{$page}{$pagespec} |= $deptype;
1969         return 1;
1970 }
1971
1972 sub deptype (@) {
1973         my $deptype=0;
1974         foreach my $type (@_) {
1975                 if ($type eq 'presence') {
1976                         $deptype |= $DEPEND_PRESENCE;
1977                 }
1978                 elsif ($type eq 'links') {
1979                         $deptype |= $DEPEND_LINKS;
1980                 }
1981                 elsif ($type eq 'content') {
1982                         $deptype |= $DEPEND_CONTENT;
1983                 }
1984         }
1985         return $deptype;
1986 }
1987
1988 my $file_prune_regexp;
1989 sub file_pruned ($) {
1990         my $file=shift;
1991
1992         if (defined $config{include} && length $config{include}) {
1993                 return 0 if $file =~ m/$config{include}/;
1994         }
1995
1996         if (! defined $file_prune_regexp) {
1997                 $file_prune_regexp='('.join('|', @{$config{wiki_file_prune_regexps}}).')';
1998                 $file_prune_regexp=qr/$file_prune_regexp/;
1999         }
2000         return $file =~ m/$file_prune_regexp/;
2001 }
2002
2003 sub define_gettext () {
2004         # If translation is needed, redefine the gettext function to do it.
2005         # Otherwise, it becomes a quick no-op.
2006         my $gettext_obj;
2007         my $getobj;
2008         if ((exists $ENV{LANG} && length $ENV{LANG}) ||
2009             (exists $ENV{LC_ALL} && length $ENV{LC_ALL}) ||
2010             (exists $ENV{LC_MESSAGES} && length $ENV{LC_MESSAGES})) {
2011                 $getobj=sub {
2012                         $gettext_obj=eval q{
2013                                 use Locale::gettext q{textdomain};
2014                                 Locale::gettext->domain('ikiwiki')
2015                         };
2016                 };
2017         }
2018
2019         no warnings 'redefine';
2020         *gettext=sub {
2021                 $getobj->() if $getobj;
2022                 if ($gettext_obj) {
2023                         $gettext_obj->get(shift);
2024                 }
2025                 else {
2026                         return shift;
2027                 }
2028         };
2029         *ngettext=sub {
2030                 $getobj->() if $getobj;
2031                 if ($gettext_obj) {
2032                         $gettext_obj->nget(@_);
2033                 }
2034                 else {
2035                         return ($_[2] == 1 ? $_[0] : $_[1])
2036                 }
2037         };
2038 }
2039
2040 sub gettext {
2041         define_gettext();
2042         gettext(@_);
2043 }
2044
2045 sub ngettext {
2046         define_gettext();
2047         ngettext(@_);
2048 }
2049
2050 sub yesno ($) {
2051         my $val=shift;
2052
2053         return (defined $val && (lc($val) eq gettext("yes") || lc($val) eq "yes" || $val eq "1"));
2054 }
2055
2056 sub inject {
2057         # Injects a new function into the symbol table to replace an
2058         # exported function.
2059         my %params=@_;
2060
2061         # This is deep ugly perl foo, beware.
2062         no strict;
2063         no warnings;
2064         if (! defined $params{parent}) {
2065                 $params{parent}='::';
2066                 $params{old}=\&{$params{name}};
2067                 $params{name}=~s/.*:://;
2068         }
2069         my $parent=$params{parent};
2070         foreach my $ns (grep /^\w+::/, keys %{$parent}) {
2071                 $ns = $params{parent} . $ns;
2072                 inject(%params, parent => $ns) unless $ns eq '::main::';
2073                 *{$ns . $params{name}} = $params{call}
2074                         if exists ${$ns}{$params{name}} &&
2075                            \&{${$ns}{$params{name}}} == $params{old};
2076         }
2077         use strict;
2078         use warnings;
2079 }
2080
2081 sub add_link ($$;$) {
2082         my $page=shift;
2083         my $link=shift;
2084         my $type=shift;
2085
2086         push @{$links{$page}}, $link
2087                 unless grep { $_ eq $link } @{$links{$page}};
2088
2089         if (defined $type) {
2090                 $typedlinks{$page}{$type}{$link} = 1;
2091         }
2092 }
2093
2094 sub add_autofile ($$$) {
2095         my $file=shift;
2096         my $plugin=shift;
2097         my $generator=shift;
2098
2099         $autofiles{$file}{plugin}=$plugin;
2100         $autofiles{$file}{generator}=$generator;
2101 }
2102
2103 sub sortspec_translate ($$) {
2104         my $spec = shift;
2105         my $reverse = shift;
2106
2107         my $code = "";
2108         my @data;
2109         while ($spec =~ m{
2110                 \s*
2111                 (-?)            # group 1: perhaps negated
2112                 \s*
2113                 (               # group 2: a word
2114                         \w+\([^\)]*\)   # command(params)
2115                         |
2116                         [^\s]+          # or anything else
2117                 )
2118                 \s*
2119         }gx) {
2120                 my $negated = $1;
2121                 my $word = $2;
2122                 my $params = undef;
2123
2124                 if ($word =~ m/^(\w+)\((.*)\)$/) {
2125                         # command with parameters
2126                         $params = $2;
2127                         $word = $1;
2128                 }
2129                 elsif ($word !~ m/^\w+$/) {
2130                         error(sprintf(gettext("invalid sort type %s"), $word));
2131                 }
2132
2133                 if (length $code) {
2134                         $code .= " || ";
2135                 }
2136
2137                 if ($negated) {
2138                         $code .= "-";
2139                 }
2140
2141                 if (exists $IkiWiki::SortSpec::{"cmp_$word"}) {
2142                         if (defined $params) {
2143                                 push @data, $params;
2144                                 $code .= "IkiWiki::SortSpec::cmp_$word(\$data[$#data])";
2145                         }
2146                         else {
2147                                 $code .= "IkiWiki::SortSpec::cmp_$word(undef)";
2148                         }
2149                 }
2150                 else {
2151                         error(sprintf(gettext("unknown sort type %s"), $word));
2152                 }
2153         }
2154
2155         if (! length $code) {
2156                 # undefined sorting method... sort arbitrarily
2157                 return sub { 0 };
2158         }
2159
2160         if ($reverse) {
2161                 $code="-($code)";
2162         }
2163
2164         no warnings;
2165         return eval 'sub { '.$code.' }';
2166 }
2167
2168 sub pagespec_translate ($) {
2169         my $spec=shift;
2170
2171         # Convert spec to perl code.
2172         my $code="";
2173         my @data;
2174         while ($spec=~m{
2175                 \s*             # ignore whitespace
2176                 (               # 1: match a single word
2177                         \!              # !
2178                 |
2179                         \(              # (
2180                 |
2181                         \)              # )
2182                 |
2183                         \w+\([^\)]*\)   # command(params)
2184                 |
2185                         [^\s()]+        # any other text
2186                 )
2187                 \s*             # ignore whitespace
2188         }gx) {
2189                 my $word=$1;
2190                 if (lc $word eq 'and') {
2191                         $code.=' &';
2192                 }
2193                 elsif (lc $word eq 'or') {
2194                         $code.=' |';
2195                 }
2196                 elsif ($word eq "(" || $word eq ")" || $word eq "!") {
2197                         $code.=' '.$word;
2198                 }
2199                 elsif ($word =~ /^(\w+)\((.*)\)$/) {
2200                         if (exists $IkiWiki::PageSpec::{"match_$1"}) {
2201                                 push @data, $2;
2202                                 $code.="IkiWiki::PageSpec::match_$1(\$page, \$data[$#data], \@_)";
2203                         }
2204                         else {
2205                                 push @data, qq{unknown function in pagespec "$word"};
2206                                 $code.="IkiWiki::ErrorReason->new(\$data[$#data])";
2207                         }
2208                 }
2209                 else {
2210                         push @data, $word;
2211                         $code.=" IkiWiki::PageSpec::match_glob(\$page, \$data[$#data], \@_)";
2212                 }
2213         }
2214
2215         if (! length $code) {
2216                 $code="IkiWiki::FailReason->new('empty pagespec')";
2217         }
2218
2219         no warnings;
2220         return eval 'sub { my $page=shift; '.$code.' }';
2221 }
2222
2223 sub pagespec_match ($$;@) {
2224         my $page=shift;
2225         my $spec=shift;
2226         my @params=@_;
2227
2228         # Backwards compatability with old calling convention.
2229         if (@params == 1) {
2230                 unshift @params, 'location';
2231         }
2232
2233         my $sub=pagespec_translate($spec);
2234         return IkiWiki::ErrorReason->new("syntax error in pagespec \"$spec\"")
2235                 if ! defined $sub;
2236         return $sub->($page, @params);
2237 }
2238
2239 sub pagespec_match_list ($$;@) {
2240         my $page=shift;
2241         my $pagespec=shift;
2242         my %params=@_;
2243
2244         # Backwards compatability with old calling convention.
2245         if (ref $page) {
2246                 print STDERR "warning: a plugin (".caller().") is using pagespec_match_list in an obsolete way, and needs to be updated\n";
2247                 $params{list}=$page;
2248                 $page=$params{location}; # ugh!
2249         }
2250
2251         my $sub=pagespec_translate($pagespec);
2252         error "syntax error in pagespec \"$pagespec\""
2253                 if ! defined $sub;
2254         my $sort=sortspec_translate($params{sort}, $params{reverse})
2255                 if defined $params{sort};
2256
2257         my @candidates;
2258         if (exists $params{list}) {
2259                 @candidates=exists $params{filter}
2260                         ? grep { ! $params{filter}->($_) } @{$params{list}}
2261                         : @{$params{list}};
2262         }
2263         else {
2264                 @candidates=exists $params{filter}
2265                         ? grep { ! $params{filter}->($_) } keys %pagesources
2266                         : keys %pagesources;
2267         }
2268
2269         # clear params, remainder is passed to pagespec
2270         $depends{$page}{$pagespec} |= ($params{deptype} || $DEPEND_CONTENT);
2271         my $num=$params{num};
2272         delete @params{qw{num deptype reverse sort filter list}};
2273
2274         # when only the top matches will be returned, it's efficient to
2275         # sort before matching to pagespec,
2276         if (defined $num && defined $sort) {
2277                 @candidates=IkiWiki::SortSpec::sort_pages(
2278                         $sort, @candidates);
2279         }
2280
2281         my @matches;
2282         my $firstfail;
2283         my $count=0;
2284         my $accum=IkiWiki::SuccessReason->new();
2285         foreach my $p (@candidates) {
2286                 my $r=$sub->($p, %params, location => $page);
2287                 error(sprintf(gettext("cannot match pages: %s"), $r))
2288                         if $r->isa("IkiWiki::ErrorReason");
2289                 unless ($r || $r->influences_static) {
2290                         $r->remove_influence($p);
2291                 }
2292                 $accum |= $r;
2293                 if ($r) {
2294                         push @matches, $p;
2295                         last if defined $num && ++$count == $num;
2296                 }
2297         }
2298
2299         # Add simple dependencies for accumulated influences.
2300         my $i=$accum->influences;
2301         foreach my $k (keys %$i) {
2302                 $depends_simple{$page}{lc $k} |= $i->{$k};
2303         }
2304
2305         # when all matches will be returned, it's efficient to
2306         # sort after matching
2307         if (! defined $num && defined $sort) {
2308                 return IkiWiki::SortSpec::sort_pages(
2309                         $sort, @matches);
2310         }
2311         else {
2312                 return @matches;
2313         }
2314 }
2315
2316 sub pagespec_valid ($) {
2317         my $spec=shift;
2318
2319         return defined pagespec_translate($spec);
2320 }
2321
2322 sub glob2re ($) {
2323         my $re=quotemeta(shift);
2324         $re=~s/\\\*/.*/g;
2325         $re=~s/\\\?/./g;
2326         return $re;
2327 }
2328
2329 package IkiWiki::FailReason;
2330
2331 use overload (
2332         '""'    => sub { $_[0][0] },
2333         '0+'    => sub { 0 },
2334         '!'     => sub { bless $_[0], 'IkiWiki::SuccessReason'},
2335         '&'     => sub { $_[0]->merge_influences($_[1], 1); $_[0] },
2336         '|'     => sub { $_[1]->merge_influences($_[0]); $_[1] },
2337         fallback => 1,
2338 );
2339
2340 our @ISA = 'IkiWiki::SuccessReason';
2341
2342 package IkiWiki::SuccessReason;
2343
2344 use overload (
2345         '""'    => sub { $_[0][0] },
2346         '0+'    => sub { 1 },
2347         '!'     => sub { bless $_[0], 'IkiWiki::FailReason'},
2348         '&'     => sub { $_[1]->merge_influences($_[0], 1); $_[1] },
2349         '|'     => sub { $_[0]->merge_influences($_[1]); $_[0] },
2350         fallback => 1,
2351 );
2352
2353 sub new {
2354         my $class = shift;
2355         my $value = shift;
2356         return bless [$value, {@_}], $class;
2357 }
2358
2359 sub influences {
2360         my $this=shift;
2361         $this->[1]={@_} if @_;
2362         my %i=%{$this->[1]};
2363         delete $i{""};
2364         return \%i;
2365 }
2366
2367 sub influences_static {
2368         return ! $_[0][1]->{""};
2369 }
2370
2371 sub merge_influences {
2372         my $this=shift;
2373         my $other=shift;
2374         my $anded=shift;
2375
2376         if (! $anded || (($this || %{$this->[1]}) &&
2377                          ($other || %{$other->[1]}))) {
2378                 foreach my $influence (keys %{$other->[1]}) {
2379                         $this->[1]{$influence} |= $other->[1]{$influence};
2380                 }
2381         }
2382         else {
2383                 # influence blocker
2384                 $this->[1]={};
2385         }
2386 }
2387
2388 sub remove_influence {
2389         my $this=shift;
2390         my $torm=shift;
2391
2392         delete $this->[1]{$torm};
2393 }
2394
2395 package IkiWiki::ErrorReason;
2396
2397 our @ISA = 'IkiWiki::FailReason';
2398
2399 package IkiWiki::PageSpec;
2400
2401 sub derel ($$) {
2402         my $path=shift;
2403         my $from=shift;
2404
2405         if ($path =~ m!^\./!) {
2406                 $from=~s#/?[^/]+$## if defined $from;
2407                 $path=~s#^\./##;
2408                 $path="$from/$path" if defined $from && length $from;
2409         }
2410
2411         return $path;
2412 }
2413
2414 sub match_glob ($$;@) {
2415         my $page=shift;
2416         my $glob=shift;
2417         my %params=@_;
2418
2419         $glob=derel($glob, $params{location});
2420
2421         my $regexp=IkiWiki::glob2re($glob);
2422         if ($page=~/^$regexp$/i) {
2423                 if (! IkiWiki::isinternal($page) || $params{internal}) {
2424                         return IkiWiki::SuccessReason->new("$glob matches $page");
2425                 }
2426                 else {
2427                         return IkiWiki::FailReason->new("$glob matches $page, but the page is an internal page");
2428                 }
2429         }
2430         else {
2431                 return IkiWiki::FailReason->new("$glob does not match $page");
2432         }
2433 }
2434
2435 sub match_internal ($$;@) {
2436         return match_glob(shift, shift, @_, internal => 1)
2437 }
2438
2439 sub match_page ($$;@) {
2440         my $page=shift;
2441         my $match=match_glob($page, shift, @_);
2442         if ($match) {
2443                 my $source=exists $IkiWiki::pagesources{$page} ?
2444                         $IkiWiki::pagesources{$page} :
2445                         $IkiWiki::delpagesources{$page};
2446                 my $type=defined $source ? IkiWiki::pagetype($source) : undef;
2447                 if (! defined $type) {
2448                         return IkiWiki::FailReason->new("$page is not a page");
2449                 }
2450         }
2451         return $match;
2452 }
2453
2454 sub match_link ($$;@) {
2455         my $page=shift;
2456         my $link=lc(shift);
2457         my %params=@_;
2458
2459         $link=derel($link, $params{location});
2460         my $from=exists $params{location} ? $params{location} : '';
2461         my $linktype=$params{linktype};
2462         my $qualifier='';
2463         if (defined $linktype) {
2464                 $qualifier=" with type $linktype";
2465         }
2466
2467         my $links = $IkiWiki::links{$page};
2468         return IkiWiki::FailReason->new("$page has no links", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2469                 unless $links && @{$links};
2470         my $bestlink = IkiWiki::bestlink($from, $link);
2471         foreach my $p (@{$links}) {
2472                 next unless (! defined $linktype || exists $IkiWiki::typedlinks{$page}{$linktype}{$p});
2473
2474                 if (length $bestlink) {
2475                         if ($bestlink eq IkiWiki::bestlink($page, $p)) {
2476                                 return IkiWiki::SuccessReason->new("$page links to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2477                         }
2478                 }
2479                 else {
2480                         if (match_glob($p, $link, %params)) {
2481                                 return IkiWiki::SuccessReason->new("$page links to page $p$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2482                         }
2483                         my ($p_rel)=$p=~/^\/?(.*)/;
2484                         $link=~s/^\///;
2485                         if (match_glob($p_rel, $link, %params)) {
2486                                 return IkiWiki::SuccessReason->new("$page links to page $p_rel$qualifier, matching $link", $page => $IkiWiki::DEPEND_LINKS, "" => 1)
2487                         }
2488                 }
2489         }
2490         return IkiWiki::FailReason->new("$page does not link to $link$qualifier", $page => $IkiWiki::DEPEND_LINKS, "" => 1);
2491 }
2492
2493 sub match_backlink ($$;@) {
2494         my $ret=match_link($_[1], $_[0], @_);
2495         $ret->influences($_[1] => $IkiWiki::DEPEND_LINKS);
2496         return $ret;
2497 }
2498
2499 sub match_created_before ($$;@) {
2500         my $page=shift;
2501         my $testpage=shift;
2502         my %params=@_;
2503
2504         $testpage=derel($testpage, $params{location});
2505
2506         if (exists $IkiWiki::pagectime{$testpage}) {
2507                 if ($IkiWiki::pagectime{$page} < $IkiWiki::pagectime{$testpage}) {
2508                         return IkiWiki::SuccessReason->new("$page created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2509                 }
2510                 else {
2511                         return IkiWiki::FailReason->new("$page not created before $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2512                 }
2513         }
2514         else {
2515                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2516         }
2517 }
2518
2519 sub match_created_after ($$;@) {
2520         my $page=shift;
2521         my $testpage=shift;
2522         my %params=@_;
2523
2524         $testpage=derel($testpage, $params{location});
2525
2526         if (exists $IkiWiki::pagectime{$testpage}) {
2527                 if ($IkiWiki::pagectime{$page} > $IkiWiki::pagectime{$testpage}) {
2528                         return IkiWiki::SuccessReason->new("$page created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2529                 }
2530                 else {
2531                         return IkiWiki::FailReason->new("$page not created after $testpage", $testpage => $IkiWiki::DEPEND_PRESENCE);
2532                 }
2533         }
2534         else {
2535                 return IkiWiki::ErrorReason->new("$testpage does not exist", $testpage => $IkiWiki::DEPEND_PRESENCE);
2536         }
2537 }
2538
2539 sub match_creation_day ($$;@) {
2540         if ((localtime($IkiWiki::pagectime{shift()}))[3] == shift) {
2541                 return IkiWiki::SuccessReason->new('creation_day matched');
2542         }
2543         else {
2544                 return IkiWiki::FailReason->new('creation_day did not match');
2545         }
2546 }
2547
2548 sub match_creation_month ($$;@) {
2549         if ((localtime($IkiWiki::pagectime{shift()}))[4] + 1 == shift) {
2550                 return IkiWiki::SuccessReason->new('creation_month matched');
2551         }
2552         else {
2553                 return IkiWiki::FailReason->new('creation_month did not match');
2554         }
2555 }
2556
2557 sub match_creation_year ($$;@) {
2558         if ((localtime($IkiWiki::pagectime{shift()}))[5] + 1900 == shift) {
2559                 return IkiWiki::SuccessReason->new('creation_year matched');
2560         }
2561         else {
2562                 return IkiWiki::FailReason->new('creation_year did not match');
2563         }
2564 }
2565
2566 sub match_user ($$;@) {
2567         shift;
2568         my $user=shift;
2569         my %params=@_;
2570
2571         my $regexp=IkiWiki::glob2re($user);
2572
2573         if (! exists $params{user}) {
2574                 return IkiWiki::ErrorReason->new("no user specified");
2575         }
2576
2577         if (defined $params{user} && $params{user}=~/^$regexp$/i) {
2578                 return IkiWiki::SuccessReason->new("user is $user");
2579         }
2580         elsif (! defined $params{user}) {
2581                 return IkiWiki::FailReason->new("not logged in");
2582         }
2583         else {
2584                 return IkiWiki::FailReason->new("user is $params{user}, not $user");
2585         }
2586 }
2587
2588 sub match_admin ($$;@) {
2589         shift;
2590         shift;
2591         my %params=@_;
2592
2593         if (! exists $params{user}) {
2594                 return IkiWiki::ErrorReason->new("no user specified");
2595         }
2596
2597         if (defined $params{user} && IkiWiki::is_admin($params{user})) {
2598                 return IkiWiki::SuccessReason->new("user is an admin");
2599         }
2600         elsif (! defined $params{user}) {
2601                 return IkiWiki::FailReason->new("not logged in");
2602         }
2603         else {
2604                 return IkiWiki::FailReason->new("user is not an admin");
2605         }
2606 }
2607
2608 sub match_ip ($$;@) {
2609         shift;
2610         my $ip=shift;
2611         my %params=@_;
2612
2613         if (! exists $params{ip}) {
2614                 return IkiWiki::ErrorReason->new("no IP specified");
2615         }
2616
2617         if (defined $params{ip} && lc $params{ip} eq lc $ip) {
2618                 return IkiWiki::SuccessReason->new("IP is $ip");
2619         }
2620         else {
2621                 return IkiWiki::FailReason->new("IP is $params{ip}, not $ip");
2622         }
2623 }
2624
2625 package IkiWiki::SortSpec;
2626
2627 # This is in the SortSpec namespace so that the $a and $b that sort() uses
2628 # are easily available in this namespace, for cmp functions to use them.
2629 sub sort_pages {
2630         my $f=shift;
2631         sort $f @_
2632 }
2633
2634 sub cmp_title {
2635         IkiWiki::pagetitle(IkiWiki::basename($a))
2636         cmp
2637         IkiWiki::pagetitle(IkiWiki::basename($b))
2638 }
2639
2640 sub cmp_mtime { $IkiWiki::pagemtime{$b} <=> $IkiWiki::pagemtime{$a} }
2641 sub cmp_age { $IkiWiki::pagectime{$b} <=> $IkiWiki::pagectime{$a} }
2642
2643 1