IkiWiki/CGI.pm

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5 use IkiWiki;
   6 use IkiWiki::UserInfo;
   7 use open qw{:utf8 :std};
   8 use Encode;
   9
  10 package IkiWiki;
  11
  12 sub printheader ($) { #{{{
  13         my $session=shift;
  14
  15         if ($config{sslcookie}) {
  16                 print $session->header(-charset => 'utf-8',
  17                         -cookie => $session->cookie(-secure => 1));
  18         } else {
  19                 print $session->header(-charset => 'utf-8');
  20         }
  21
  22 } #}}}
  23
  24 sub redirect ($$) { #{{{
  25         my $q=shift;
  26         my $url=shift;
  27         if (! $config{w3mmode}) {
  28                 print $q->redirect($url);
  29         }
  30         else {
  31                 print "Content-type: text/plain\n";
  32                 print "W3m-control: GOTO $url\n\n";
  33         }
  34 } #}}}
  35
  36 sub check_canedit ($$$;$) { #{{{
  37         my $page=shift;
  38         my $q=shift;
  39         my $session=shift;
  40         my $nonfatal=shift;
  41
  42         my $canedit;
  43         run_hooks(canedit => sub {
  44                 return if defined $canedit;
  45                 my $ret=shift->($page, $q, $session);
  46                 if (defined $ret && $ret eq "") {
  47                         $canedit=1;
  48                 }
  49                 elsif (defined $ret) {
  50                         $canedit=0;
  51                         error($ret) unless $nonfatal;
  52                 }
  53         });
  54         return $canedit;
  55 } #}}}
  56
  57 sub decode_form_utf8 ($) { #{{{
  58         my $form = shift;
  59         foreach my $f ($form->field) {
  60                 next if Encode::is_utf8(scalar $form->field($f));
  61                 $form->field(name  => $f,
  62                              value => decode_utf8($form->field($f)),
  63                              force => 1,
  64                             );
  65         }
  66 } #}}}
  67
  68 sub cgi_recentchanges ($) { #{{{
  69         my $q=shift;
  70
  71         # Optimisation: building recentchanges means calculating lots of
  72         # links. Memoizing htmllink speeds it up a lot (can't be memoized
  73         # during page builds as the return values may change, but they
  74         # won't here.)
  75         eval q{use Memoize};
  76         error($@) if $@;
  77         memoize("htmllink");
  78
  79         eval q{use Time::Duration};
  80         error($@) if $@;
  81
  82         my $changelog=[rcs_recentchanges(100)];
  83         foreach my $change (@$changelog) {
  84                 $change->{when} = concise(ago($change->{when}));
  85
  86                 $change->{user} = userlink($change->{user});
  87
  88                 my $is_excess = exists $change->{pages}[10]; # limit pages to first 10
  89                 delete @{$change->{pages}}[10 .. @{$change->{pages}}] if $is_excess;
  90                 $change->{pages} = [
  91                         map {
  92                                 $_->{link} = htmllink("", "", $_->{page},
  93                                         noimageinline => 1,
  94                                         linktext => pagetitle($_->{page}));
  95                                 $_;
  96                         } @{$change->{pages}}
  97                 ];
  98                 push @{$change->{pages}}, { link => '...' } if $is_excess;
  99         }
 100
 101         my $template=template("recentchanges.tmpl");
 102         $template->param(
 103                 title => "RecentChanges",
 104                 indexlink => indexlink(),
 105                 wikiname => $config{wikiname},
 106                 changelog => $changelog,
 107                 baseurl => baseurl(),
 108         );
 109         run_hooks(pagetemplate => sub {
 110                 shift->(page => "", destpage => "", template => $template);
 111         });
 112         print $q->header(-charset => 'utf-8'), $template->output;
 113 } #}}}
 114
 115 # Check if the user is signed in. If not, redirect to the signin form and
 116 # save their place to return to later.
 117 sub needsignin ($$) { #{{{
 118         my $q=shift;
 119         my $session=shift;
 120
 121         if (! defined $session->param("name") ||
 122             ! userinfo_get($session->param("name"), "regdate")) {
 123                 if (! defined $session->param("postsignin")) {
 124                         $session->param(postsignin => $ENV{QUERY_STRING});
 125                 }
 126                 cgi_signin($q, $session);
 127                 cgi_savesession($session);
 128                 exit;
 129         }
 130 } #}}}
 131
 132 sub cgi_signin ($$) { #{{{
 133         my $q=shift;
 134         my $session=shift;
 135
 136         eval q{use CGI::FormBuilder};
 137         error($@) if $@;
 138         my $form = CGI::FormBuilder->new(
 139                 title => "signin",
 140                 header => 1,
 141                 charset => "utf-8",
 142                 method => 'POST',
 143                 required => 'NONE',
 144                 javascript => 0,
 145                 params => $q,
 146                 action => $config{cgiurl},
 147                 header => 0,
 148                 template => scalar template_params("signin.tmpl"),
 149                 stylesheet => baseurl()."style.css",
 150         );
 151         my $buttons=["Login"];
 152
 153         if ($q->param("do") ne "signin" && !$form->submitted) {
 154                 $form->text(gettext("You need to log in first."));
 155         }
 156         $form->field(name => "do", type => "hidden", value => "signin",
 157                 force => 1);
 158
 159         run_hooks(formbuilder_setup => sub {
 160                 shift->(form => $form, cgi => $q, session => $session);
 161         });
 162
 163         decode_form_utf8($form);
 164
 165         if (exists $hooks{formbuilder}) {
 166                 run_hooks(formbuilder => sub {
 167                         shift->(form => $form, cgi => $q, session => $session,
 168                                 buttons => $buttons);
 169                 });
 170         }
 171         else {
 172                 if ($form->submitted) {
 173                         $form->validate;
 174                 }
 175                 printheader($session);
 176                 print misctemplate($form->title, $form->render(submit => $buttons));
 177         }
 178 } #}}}
 179
 180 sub cgi_postsignin ($$) { #{{{
 181         my $q=shift;
 182         my $session=shift;
 183
 184         # Continue with whatever was being done before the signin process.
 185         if (defined $session->param("postsignin")) {
 186                 my $postsignin=CGI->new($session->param("postsignin"));
 187                 $session->clear("postsignin");
 188                 cgi($postsignin, $session);
 189                 cgi_savesession($session);
 190                 exit;
 191         }
 192         else {
 193                 # This can occur, for example, if a user went to the signin
 194                 # url via a bookmark.
 195                 redirect($q, $config{url});
 196         }
 197 } #}}}
 198
 199 sub cgi_prefs ($$) { #{{{
 200         my $q=shift;
 201         my $session=shift;
 202
 203         needsignin($q, $session);
 204
 205         eval q{use CGI::FormBuilder};
 206         error($@) if $@;
 207         my $form = CGI::FormBuilder->new(
 208                 title => "preferences",
 209                 header => 0,
 210                 charset => "utf-8",
 211                 method => 'POST',
 212                 validate => {
 213                         email => 'EMAIL',
 214                 },
 215                 required => 'NONE',
 216                 javascript => 0,
 217                 params => $q,
 218                 action => $config{cgiurl},
 219                 template => scalar template_params("prefs.tmpl"),
 220                 stylesheet => baseurl()."style.css",
 221         );
 222         my $buttons=["Save Preferences", "Logout", "Cancel"];
 223
 224         run_hooks(formbuilder_setup => sub {
 225                 shift->(form => $form, cgi => $q, session => $session);
 226         });
 227
 228         $form->field(name => "do", type => "hidden");
 229         $form->field(name => "email", size => 50);
 230         $form->field(name => "subscriptions", size => 50,
 231                 comment => "(".htmllink("", "", "PageSpec", noimageinline => 1).")");
 232         $form->field(name => "banned_users", size => 50);
 233
 234         my $user_name=$session->param("name");
 235         if (! is_admin($user_name)) {
 236                 $form->field(name => "banned_users", type => "hidden");
 237         }
 238
 239         if (! $form->submitted) {
 240                 $form->field(name => "email", force => 1,
 241                         value => userinfo_get($user_name, "email"));
 242                 $form->field(name => "subscriptions", force => 1,
 243                         value => userinfo_get($user_name, "subscriptions"));
 244                 if (is_admin($user_name)) {
 245                         $form->field(name => "banned_users", force => 1,
 246                                 value => join(" ", get_banned_users()));
 247                 }
 248         }
 249
 250         decode_form_utf8($form);
 251
 252         if ($form->submitted eq 'Logout') {
 253                 $session->delete();
 254                 redirect($q, $config{url});
 255                 return;
 256         }
 257         elsif ($form->submitted eq 'Cancel') {
 258                 redirect($q, $config{url});
 259                 return;
 260         }
 261         elsif ($form->submitted eq 'Save Preferences' && $form->validate) {
 262                 foreach my $field (qw(email subscriptions)) {
 263                         if (defined $form->field($field) && length $form->field($field)) {
 264                                 userinfo_set($user_name, $field, $form->field($field)) ||
 265                                         error("failed to set $field");
 266                         }
 267                 }
 268                 if (is_admin($user_name)) {
 269                         set_banned_users(grep { ! is_admin($_) }
 270                                         split(' ',
 271                                                 $form->field("banned_users"))) ||
 272                                 error("failed saving changes");
 273                 }
 274                 $form->text(gettext("Preferences saved."));
 275         }
 276
 277         if (exists $hooks{formbuilder}) {
 278                 run_hooks(formbuilder => sub {
 279                         shift->(form => $form, cgi => $q, session => $session,
 280                                 buttons => $buttons);
 281                 });
 282         }
 283         else {
 284                 printheader($session);
 285                 print misctemplate($form->title, $form->render(submit => $buttons));
 286         }
 287 } #}}}
 288
 289 sub cgi_editpage ($$) { #{{{
 290         my $q=shift;
 291         my $session=shift;
 292
 293         my @fields=qw(do rcsinfo subpage from page type editcontent comments
 294                       newfile);
 295         my @buttons=("Save Page", "Preview", "Cancel");
 296
 297         eval q{use CGI::FormBuilder};
 298         error($@) if $@;
 299         my $form = CGI::FormBuilder->new(
 300                 fields => \@fields,
 301                 header => 1,
 302                 charset => "utf-8",
 303                 method => 'POST',
 304                 validate => {
 305                         editcontent => '/.+/',
 306                 },
 307                 required => [qw{editcontent}],
 308                 javascript => 0,
 309                 params => $q,
 310                 action => $config{cgiurl},
 311                 table => 0,
 312                 template => scalar template_params("editpage.tmpl"),
 313         );
 314
 315         run_hooks(formbuilder_setup => sub {
 316                 shift->(form => $form, cgi => $q, session => $session);
 317         });
 318
 319         decode_form_utf8($form);
 320
 321         # This untaint is safe because titlepage removes any problematic
 322         # characters.
 323         my ($page)=$form->field('page');
 324         $page=titlepage(possibly_foolish_untaint($page));
 325         if (! defined $page || ! length $page || file_pruned($page, $config{srcdir}) || $page=~/^\//) {
 326                 error("bad page name");
 327         }
 328
 329         my $from;
 330         if (defined $form->field('from')) {
 331                 ($from)=$form->field('from')=~/$config{wiki_file_regexp}/;
 332         }
 333
 334         my $file;
 335         my $type;
 336         if (exists $pagesources{$page}) {
 337                 $file=$pagesources{$page};
 338                 $type=pagetype($file);
 339                 if (! defined $type) {
 340                         error(sprintf(gettext("%s is not an editable page"), $page));
 341                 }
 342         }
 343         else {
 344                 $type=$form->param('type');
 345                 if (defined $type && length $type && $hooks{htmlize}{$type}) {
 346                         $type=possibly_foolish_untaint($type);
 347                 }
 348                 elsif (defined $from) {
 349                         # favor the type of linking page
 350                         $type=pagetype($pagesources{$from});
 351                 }
 352                 $type=$config{default_pageext} unless defined $type;
 353                 $file=$page.".".$type;
 354         }
 355
 356
 357         $form->field(name => "do", type => 'hidden');
 358         $form->field(name => "from", type => 'hidden');
 359         $form->field(name => "rcsinfo", type => 'hidden');
 360         $form->field(name => "subpage", type => 'hidden');
 361         $form->field(name => "page", value => pagetitle($page, 1), force => 1);
 362         $form->field(name => "type", value => $type, force => 1);
 363         $form->field(name => "comments", type => "text", size => 80);
 364         $form->field(name => "editcontent", type => "textarea", rows => 20,
 365                 cols => 80);
 366         $form->field(name => "newfile", type => 'hidden');
 367         $form->tmpl_param("can_commit", $config{rcs});
 368         $form->tmpl_param("indexlink", indexlink());
 369         $form->tmpl_param("helponformattinglink",
 370                 htmllink("", "", "HelpOnFormatting", noimageinline => 1));
 371         $form->tmpl_param("baseurl", baseurl());
 372         if (! $form->submitted) {
 373                 $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 374                         force => 1);
 375                 $form->field(name => "newfile",
 376                         value => ! -e "$config{srcdir}/$file",
 377                         force => 1);
 378         }
 379
 380         if ($form->submitted eq "Cancel") {
 381                 if ($form->field(name => "newfile") && defined $from) {
 382                         redirect($q, "$config{url}/".htmlpage($from));
 383                 }
 384                 elsif ($form->field(name => "newfile")) {
 385                         redirect($q, $config{url});
 386                 }
 387                 else {
 388                         redirect($q, "$config{url}/".htmlpage($page));
 389                 }
 390                 return;
 391         }
 392         elsif ($form->submitted eq "Preview") {
 393                 my $content=$form->field('editcontent');
 394                 my $comments=$form->field('comments');
 395                 $form->field(name => "editcontent",
 396                                 value => $content, force => 1);
 397                 $form->field(name => "comments",
 398                                 value => $comments, force => 1);
 399                 $form->tmpl_param("page_preview",
 400                         htmlize($page, $type,
 401                         linkify($page, "",
 402                         preprocess($page, $page,
 403                         filter($page, $content), 0, 1))));
 404         }
 405         else {
 406                 $form->tmpl_param("page_preview", "");
 407         }
 408         $form->tmpl_param("page_conflict", "");
 409
 410         if (! $form->submitted || $form->submitted eq "Preview" ||
 411             ! $form->validate) {
 412                 if ($form->field("do") eq "create") {
 413                         my @page_locs;
 414                         my $best_loc;
 415                         if (! defined $from || ! length $from ||
 416                             $from ne $form->field('from') ||
 417                             file_pruned($from, $config{srcdir}) ||
 418                             $from=~/^\// ||
 419                             $form->submitted eq "Preview") {
 420                                 @page_locs=$best_loc=$page;
 421                         }
 422                         else {
 423                                 my $dir=$from."/";
 424                                 $dir=~s![^/]+/+$!!;
 425
 426                                 if ((defined $form->field('subpage') && length $form->field('subpage')) ||
 427                                     $page eq gettext('discussion')) {
 428                                         $best_loc="$from/$page";
 429                                 }
 430                                 else {
 431                                         $best_loc=$dir.$page;
 432                                 }
 433
 434                                 push @page_locs, $dir.$page;
 435                                 push @page_locs, "$from/$page";
 436                                 while (length $dir) {
 437                                         $dir=~s![^/]+/+$!!;
 438                                         push @page_locs, $dir.$page;
 439                                 }
 440                         }
 441                         push @page_locs, "$config{userdir}/$page"
 442                                 if length $config{userdir};
 443
 444                         @page_locs = grep {
 445                                 ! exists $pagecase{lc $_}
 446                         } @page_locs;
 447                         if (! @page_locs) {
 448                                 # hmm, someone else made the page in the
 449                                 # meantime?
 450                                 redirect($q, "$config{url}/".htmlpage($page));
 451                                 return;
 452                         }
 453
 454                         my @editable_locs = grep {
 455                                 check_canedit($_, $q, $session, 1)
 456                         } @page_locs;
 457                         if (! @editable_locs) {
 458                                 # let it throw an error this time
 459                                 map { check_canedit($_, $q, $session) } @page_locs;
 460                         }
 461
 462                         my @page_types;
 463                         if (exists $hooks{htmlize}) {
 464                                 @page_types=keys %{$hooks{htmlize}};
 465                         }
 466
 467                         $form->tmpl_param("page_select", 1);
 468                         $form->field(name => "page", type => 'select',
 469                                 options => [ map { pagetitle($_, 1) } @editable_locs ],
 470                                 value => pagetitle($best_loc, 1));
 471                         $form->field(name => "type", type => 'select',
 472                                 options => \@page_types);
 473                         $form->title(sprintf(gettext("creating %s"), pagetitle($page)));
 474                 }
 475                 elsif ($form->field("do") eq "edit") {
 476                         check_canedit($page, $q, $session);
 477                         if (! defined $form->field('editcontent') ||
 478                             ! length $form->field('editcontent')) {
 479                                 my $content="";
 480                                 if (exists $pagesources{$page}) {
 481                                         $content=readfile(srcfile($pagesources{$page}));
 482                                         $content=~s/\n/\r\n/g;
 483                                 }
 484                                 $form->field(name => "editcontent", value => $content,
 485                                         force => 1);
 486                         }
 487                         $form->tmpl_param("page_select", 0);
 488                         $form->field(name => "page", type => 'hidden');
 489                         $form->field(name => "type", type => 'hidden');
 490                         $form->title(sprintf(gettext("editing %s"), pagetitle($page)));
 491                 }
 492
 493                 print $form->render(submit => \@buttons);
 494         }
 495         else {
 496                 # save page
 497                 check_canedit($page, $q, $session);
 498                 if (! -e "$config{srcdir}/$file" && ! $form->field(name => 'newfile')){
 499                         $form->tmpl_param("page_gone", 1);
 500                         $form->field(name => "newfile",
 501                                      value => 1, force => 1);
 502                         $form->tmpl_param("page_select", 0);
 503                         $form->field(name => "page", type => 'hidden');
 504                         $form->field(name => "type", type => 'hidden');
 505                         print $form->render(submit => \@buttons);
 506                         return;
 507                 }
 508
 509                 my $content=$form->field('editcontent');
 510
 511                 $content=~s/\r\n/\n/g;
 512                 $content=~s/\r/\n/g;
 513
 514                 $config{cgi}=0; # avoid cgi error message
 515                 eval { writefile($file, $config{srcdir}, $content) };
 516                 $config{cgi}=1;
 517                 if ($@) {
 518                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 519                                 force => 1);
 520                         $form->tmpl_param("failed_save", 1);
 521                         $form->tmpl_param("error_message", $@);
 522                         $form->field("editcontent", value => $content, force => 1);
 523                         $form->tmpl_param("page_select", 0);
 524                         $form->field(name => "page", type => 'hidden');
 525                         $form->field(name => "type", type => 'hidden');
 526                         $form->title(sprintf(gettext("editing %s"), $page));
 527                         print $form->render(submit => \@buttons);
 528                         return;
 529                 }
 530
 531                 my $conflict;
 532                 if ($config{rcs}) {
 533                         my $message="";
 534                         if (defined $form->field('comments') &&
 535                             length $form->field('comments')) {
 536                                 $message=$form->field('comments');
 537                         }
 538
 539                         if ($form->field(name => "newfile")) {
 540                                 rcs_add($file);
 541                         }
 542
 543                         # Prevent deadlock with post-commit hook by
 544                         # signaling to it that it should not try to
 545                         # do anything (except send commit mails).
 546                         disable_commit_hook();
 547                         $conflict=rcs_commit($file, $message,
 548                                 $form->field("rcsinfo"),
 549                                 $session->param("name"), $ENV{REMOTE_ADDR});
 550                         enable_commit_hook();
 551                         rcs_update();
 552                 }
 553
 554                 # Refresh even if there was a conflict, since other changes
 555                 # may have been committed while the post-commit hook was
 556                 # disabled.
 557                 require IkiWiki::Render;
 558                 refresh();
 559                 saveindex();
 560
 561                 if (defined $conflict) {
 562                         $form->field(name => "rcsinfo", value => rcs_prepedit($file),
 563                                 force => 1);
 564                         $form->tmpl_param("page_conflict", 1);
 565                         $form->field("editcontent", value => $conflict, force => 1);
 566                         $form->field("do", "edit", force => 1);
 567                         $form->tmpl_param("page_select", 0);
 568                         $form->field(name => "page", type => 'hidden');
 569                         $form->field(name => "type", type => 'hidden');
 570                         $form->title(sprintf(gettext("editing %s"), $page));
 571                         print $form->render(submit => \@buttons);
 572                         return;
 573                 }
 574                 else {
 575                         # The trailing question mark tries to avoid broken
 576                         # caches and get the most recent version of the page.
 577                         redirect($q, "$config{url}/".htmlpage($page)."?updated");
 578                 }
 579         }
 580 } #}}}
 581
 582 sub cgi_getsession ($) { #{{{
 583         my $q=shift;
 584
 585         eval q{use CGI::Session};
 586         CGI::Session->name("ikiwiki_session_".encode_utf8($config{wikiname}));
 587
 588         my $oldmask=umask(077);
 589         my $session = CGI::Session->new("driver:DB_File", $q,
 590                 { FileName => "$config{wikistatedir}/sessions.db" });
 591         umask($oldmask);
 592
 593         return $session;
 594 } #}}}
 595
 596 sub cgi_savesession ($) { #{{{
 597         my $session=shift;
 598
 599         # Force session flush with safe umask.
 600         my $oldmask=umask(077);
 601         $session->flush;
 602         umask($oldmask);
 603 } #}}}
 604
 605 sub cgi (;$$) { #{{{
 606         my $q=shift;
 607         my $session=shift;
 608
 609         if (! $q) {
 610                 eval q{use CGI};
 611                 error($@) if $@;
 612
 613                 $q=CGI->new;
 614
 615                 run_hooks(cgi => sub { shift->($q) });
 616         }
 617
 618         my $do=$q->param('do');
 619         if (! defined $do || ! length $do) {
 620                 my $error = $q->cgi_error;
 621                 if ($error) {
 622                         error("Request not processed: $error");
 623                 }
 624                 else {
 625                         error("\"do\" parameter missing");
 626                 }
 627         }
 628
 629         # Things that do not need a session.
 630         if ($do eq 'recentchanges') {
 631                 cgi_recentchanges($q);
 632                 return;
 633         }
 634         elsif ($do eq 'hyperestraier') {
 635                 cgi_hyperestraier();
 636         }
 637
 638         # Need to lock the wiki before getting a session.
 639         lockwiki();
 640
 641         if (! $session) {
 642                 $session=cgi_getsession($q);
 643         }
 644
 645         # Auth hooks can sign a user in.
 646         if ($do ne 'signin' && ! defined $session->param("name")) {
 647                 run_hooks(auth => sub {
 648                         shift->($q, $session)
 649                 });
 650                 if (defined $session->param("name")) {
 651                         # Make sure whatever user was authed is in the
 652                         # userinfo db.
 653                         if (! userinfo_get($session->param("name"), "regdate")) {
 654                                 userinfo_setall($session->param("name"), {
 655                                         email => "",
 656                                         password => "",
 657                                         regdate => time,
 658                                 }) || error("failed adding user");
 659                         }
 660                 }
 661         }
 662
 663         if (defined $session->param("name") &&
 664             userinfo_get($session->param("name"), "banned")) {
 665                 print $q->header(-status => "403 Forbidden");
 666                 $session->delete();
 667                 print gettext("You are banned.");
 668                 cgi_savesession($session);
 669         }
 670         elsif ($do eq 'signin') {
 671                 cgi_signin($q, $session);
 672                 cgi_savesession($session);
 673         }
 674         elsif (defined $session->param("postsignin")) {
 675                 cgi_postsignin($q, $session);
 676         }
 677         elsif ($do eq 'prefs') {
 678                 cgi_prefs($q, $session);
 679         }
 680         elsif ($do eq 'create' || $do eq 'edit') {
 681                 cgi_editpage($q, $session);
 682         }
 683         elsif ($do eq 'blog') {
 684                 my $page=decode_utf8($q->param('title'));
 685                 $page=~s/\///g; # no slashes in blog posts
 686                 # if the page already exists, munge it to be unique
 687                 my $from=$q->param('from');
 688                 my $add="";
 689                 while (exists $pagecase{lc($from."/".titlepage($page).$add)}) {
 690                         $add=1 unless length $add;
 691                         $add++;
 692                 }
 693                 $q->param('page', $page.$add);
 694                 # now run same as create
 695                 $q->param('do', 'create');
 696                 cgi_editpage($q, $session);
 697         }
 698         elsif ($do eq 'postsignin') {
 699                 error(gettext("login failed, perhaps you need to turn on cookies?"));
 700         }
 701         else {
 702                 error("unknown do parameter");
 703         }
 704 } #}}}
 705
 706 sub userlink ($) { #{{{
 707         my $user=shift;
 708
 709         eval q{use CGI 'escapeHTML'};
 710         error($@) if $@;
 711         if ($user =~ m!^https?://! &&
 712             eval q{use Net::OpenID::VerifiedIdentity; 1} && !$@) {
 713                 # Munge user-urls, as used by eg, OpenID.
 714                 my $oid=Net::OpenID::VerifiedIdentity->new(identity => $user);
 715                 my $display=$oid->display;
 716                 # Convert "user.somehost.com" to "user [somehost.com]".
 717                 if ($display !~ /\[/) {
 718                         $display=~s/^(.*?)\.([^.]+\.[a-z]+)$/$1 [$2]/;
 719                 }
 720                 # Convert "http://somehost.com/user" to "user [somehost.com]".
 721                 if ($display !~ /\[/) {
 722                         $display=~s/^https?:\/\/(.+)\/([^\/]+)$/$2 [$1]/;
 723                 }
 724                 $display=~s!^https?://!!; # make sure this is removed
 725                 return "<a href=\"$user\">".escapeHTML($display)."</a>";
 726         }
 727         else {
 728                 return htmllink("", "", escapeHTML(
 729                         length $config{userdir} ? $config{userdir}."/".$user : $user
 730                 ), noimageinline => 1);
 731         }
 732 } #}}}
 733
 734 1