IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 my %metaheaders;
  10
  11 sub import {
  12         hook(type => "getsetup", id => "meta", call => \&getsetup);
  13         hook(type => "needsbuild", id => "meta", call => \&needsbuild);
  14         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  15         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  16 }
  17
  18 sub getsetup () {
  19         return
  20                 plugin => {
  21                         safe => 1,
  22                         rebuild => undef,
  23                         section => "core",
  24                 },
  25 }
  26
  27 sub needsbuild (@) {
  28         my $needsbuild=shift;
  29         foreach my $page (keys %pagestate) {
  30                 if (exists $pagestate{$page}{meta}) {
  31                         if (exists $pagesources{$page} &&
  32                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  33                                 # remove state, it will be re-added
  34                                 # if the preprocessor directive is still
  35                                 # there during the rebuild
  36                                 delete $pagestate{$page}{meta};
  37                         }
  38                 }
  39         }
  40         return $needsbuild;
  41 }
  42
  43 sub scrub ($$$) {
  44         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  45                 return IkiWiki::Plugin::htmlscrubber::sanitize(
  46                         content => shift, page => shift, destpage => shift);
  47         }
  48         else {
  49                 return shift;
  50         }
  51 }
  52
  53 sub safeurl ($) {
  54         my $url=shift;
  55         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
  56             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
  57                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
  58         }
  59         else {
  60                 return 1;
  61         }
  62 }
  63
  64 sub htmlize ($$$) {
  65         my $page = shift;
  66         my $destpage = shift;
  67
  68         return IkiWiki::htmlize($page, $destpage, pagetype($pagesources{$page}),
  69                 IkiWiki::linkify($page, $destpage,
  70                 IkiWiki::preprocess($page, $destpage, shift)));
  71 }
  72
  73 sub preprocess (@) {
  74         return "" unless @_;
  75         my %params=@_;
  76         my $key=shift;
  77         my $value=$params{$key};
  78         delete $params{$key};
  79         my $page=$params{page};
  80         delete $params{page};
  81         my $destpage=$params{destpage};
  82         delete $params{destpage};
  83         delete $params{preview};
  84
  85         eval q{use HTML::Entities};
  86         # Always decode, even if encoding later, since it might not be
  87         # fully encoded.
  88         $value=decode_entities($value);
  89
  90         # Metadata collection that needs to happen during the scan pass.
  91         if ($key eq 'title') {
  92                 $pagestate{$page}{meta}{title}=$value;
  93                 if (exists $params{sortas}) {
  94                         $pagestate{$page}{meta}{titlesort}=$params{sortas};
  95                 }
  96                 else {
  97                         delete $pagestate{$page}{meta}{titlesort};
  98                 }
  99                 return "";
 100         }
 101         elsif ($key eq 'description') {
 102                 $pagestate{$page}{meta}{description}=$value;
 103                 # fallthrough
 104         }
 105         elsif ($key eq 'guid') {
 106                 $pagestate{$page}{meta}{guid}=$value;
 107                 # fallthrough
 108         }
 109         elsif ($key eq 'license') {
 110                 push @{$metaheaders{$page}}, '<link rel="license" href="#page_license" />';
 111                 $pagestate{$page}{meta}{license}=$value;
 112                 return "";
 113         }
 114         elsif ($key eq 'copyright') {
 115                 push @{$metaheaders{$page}}, '<link rel="copyright" href="#page_copyright" />';
 116                 $pagestate{$page}{meta}{copyright}=$value;
 117                 return "";
 118         }
 119         elsif ($key eq 'link' && ! %params) {
 120                 # hidden WikiLink
 121                 add_link($page, $value);
 122                 return "";
 123         }
 124         elsif ($key eq 'author') {
 125                 $pagestate{$page}{meta}{author}=$value;
 126                 if (exists $params{sortas}) {
 127                         $pagestate{$page}{meta}{authorsort}=$params{sortas};
 128                 }
 129                 else {
 130                         delete $pagestate{$page}{meta}{authorsort};
 131                 }
 132                 # fallthorough
 133         }
 134         elsif ($key eq 'authorurl') {
 135                 $pagestate{$page}{meta}{authorurl}=$value if safeurl($value);
 136                 # fallthrough
 137         }
 138         elsif ($key eq 'permalink') {
 139                 $pagestate{$page}{meta}{permalink}=$value if safeurl($value);
 140                 # fallthrough
 141         }
 142         elsif ($key eq 'date') {
 143                 eval q{use Date::Parse};
 144                 if (! $@) {
 145                         my $time = str2time($value);
 146                         $IkiWiki::pagectime{$page}=$time if defined $time;
 147                 }
 148         }
 149         elsif ($key eq 'updated') {
 150                 eval q{use Date::Parse};
 151                 if (! $@) {
 152                         my $time = str2time($value);
 153                         $pagestate{$page}{meta}{updated}=$time if defined $time;
 154                 }
 155         }
 156
 157         if (! defined wantarray) {
 158                 # avoid collecting duplicate data during scan pass
 159                 return;
 160         }
 161
 162         # Metadata handling that happens only during preprocessing pass.
 163         if ($key eq 'permalink') {
 164                 if (safeurl($value)) {
 165                         push @{$metaheaders{$page}}, scrub('<link rel="bookmark" href="'.encode_entities($value).'" />', $page, $destpage);
 166                 }
 167         }
 168         elsif ($key eq 'stylesheet') {
 169                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
 170                 my $title=exists $params{title} ? $params{title} : $value;
 171                 # adding .css to the value prevents using any old web
 172                 # editable page as a stylesheet
 173                 my $stylesheet=bestlink($page, $value.".css");
 174                 if (! length $stylesheet) {
 175                         error gettext("stylesheet not found")
 176                 }
 177                 push @{$metaheaders{$page}}, scrub('<link href="'.urlto($stylesheet, $page).
 178                         '" rel="'.encode_entities($rel).
 179                         '" title="'.encode_entities($title).
 180                         "\" type=\"text/css\" />", $page, $destpage);
 181         }
 182         elsif ($key eq 'script') {
 183                 my $defer=exists $params{defer} ? ' defer="defer"' : '';
 184                 my $async=exists $params{async} ? ' async="async"' : '';
 185                 my $js=bestlink($page, $value.".js");
 186                 if (! length $js) {
 187                         error gettext("script not found");
 188                 }
 189                 push @{$metaheaders{$page}}, scrub('<script src="'.urlto($js, $page).
 190                         '"' . $defer . $async . ' type="text/javascript"></script>',
 191                         $page, $destpage);
 192         }
 193         elsif ($key eq 'openid') {
 194                 my $delegate=0; # both by default
 195                 if (exists $params{delegate}) {
 196                         $delegate = 1 if lc $params{delegate} eq 'openid';
 197                         $delegate = 2 if lc $params{delegate} eq 'openid2';
 198                 }
 199                 if (exists $params{server} && safeurl($params{server})) {
 200                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 201                                 '" rel="openid.server" />' if $delegate ne 2;
 202                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 203                                 '" rel="openid2.provider" />' if $delegate ne 1;
 204                 }
 205                 if (safeurl($value)) {
 206                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 207                                 '" rel="openid.delegate" />' if $delegate ne 2;
 208                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 209                                 '" rel="openid2.local_id" />' if $delegate ne 1;
 210                 }
 211                 if (exists $params{"xrds-location"} && safeurl($params{"xrds-location"})) {
 212                         # force url absolute
 213                         eval q{use URI};
 214                         error($@) if $@;
 215                         my $url=URI->new_abs($params{"xrds-location"}, $config{url});
 216                         push @{$metaheaders{$page}}, '<meta http-equiv="X-XRDS-Location" '.
 217                                 'content="'.encode_entities($url).'" />';
 218                 }
 219         }
 220         elsif ($key eq 'foaf') {
 221                 if (safeurl($value)) {
 222                         push @{$metaheaders{$page}}, '<link rel="meta" '.
 223                                 'type="application/rdf+xml" title="FOAF" '.
 224                                 'href="'.encode_entities($value).'" />';
 225                 }
 226         }
 227         elsif ($key eq 'redir') {
 228                 return "" if $page ne $destpage;
 229                 my $safe=0;
 230                 if ($value !~ /^\w+:\/\//) {
 231                         my ($redir_page, $redir_anchor) = split /\#/, $value;
 232
 233                         my $link=bestlink($page, $redir_page);
 234                         if (! length $link) {
 235                                 error gettext("redir page not found")
 236                         }
 237                         add_depends($page, $link, deptype("presence"));
 238
 239                         $value=urlto($link, $page);
 240                         $value.='#'.$redir_anchor if defined $redir_anchor;
 241                         $safe=1;
 242
 243                         # redir cycle detection
 244                         $pagestate{$page}{meta}{redir}=$link;
 245                         my $at=$page;
 246                         my %seen;
 247                         while (exists $pagestate{$at}{meta}{redir}) {
 248                                 if ($seen{$at}) {
 249                                         error gettext("redir cycle is not allowed")
 250                                 }
 251                                 $seen{$at}=1;
 252                                 $at=$pagestate{$at}{meta}{redir};
 253                         }
 254                 }
 255                 else {
 256                         $value=encode_entities($value);
 257                 }
 258                 my $delay=int(exists $params{delay} ? $params{delay} : 0);
 259                 my $redir="<meta http-equiv=\"refresh\" content=\"$delay; URL=$value\" />";
 260                 if (! $safe) {
 261                         $redir=scrub($redir, $page, $destpage);
 262                 }
 263                 push @{$metaheaders{$page}}, $redir;
 264         }
 265         elsif ($key eq 'link') {
 266                 if (%params) {
 267                         push @{$metaheaders{$page}}, scrub("<link href=\"".encode_entities($value)."\" ".
 268                                 join(" ", map {
 269                                         encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\""
 270                                 } keys %params).
 271                                 " />\n", $page, $destpage);
 272                 }
 273         }
 274         elsif ($key eq 'robots') {
 275                 push @{$metaheaders{$page}}, '<meta name="robots"'.
 276                         ' content="'.encode_entities($value).'" />';
 277         }
 278         elsif ($key eq 'description' || $key eq 'author') {
 279                 push @{$metaheaders{$page}}, '<meta name="'.$key.
 280                         '" content="'.encode_entities($value).'" />';
 281         }
 282         elsif ($key eq 'name') {
 283                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 284                         encode_entities($value).
 285                         join(' ', map { "$_=\"$params{$_}\"" } keys %params).
 286                         ' />', $page, $destpage);
 287         }
 288         else {
 289                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 290                         encode_entities($key).'" content="'.
 291                         encode_entities($value).'" />', $page, $destpage);
 292         }
 293
 294         return "";
 295 }
 296
 297 sub pagetemplate (@) {
 298         my %params=@_;
 299         my $page=$params{page};
 300         my $destpage=$params{destpage};
 301         my $template=$params{template};
 302
 303         if (exists $metaheaders{$page} && $template->query(name => "meta")) {
 304                 # avoid duplicate meta lines
 305                 my %seen;
 306                 $template->param(meta => join("\n", grep { (! $seen{$_}) && ($seen{$_}=1) } @{$metaheaders{$page}}));
 307         }
 308         if (exists $pagestate{$page}{meta}{title} && $template->query(name => "title")) {
 309                 eval q{use HTML::Entities};
 310                 $template->param(title => HTML::Entities::encode_numeric($pagestate{$page}{meta}{title}));
 311                 $template->param(title_overridden => 1);
 312         }
 313
 314         foreach my $field (qw{author authorurl}) {
 315                 $template->param($field => $pagestate{$page}{meta}{$field})
 316                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 317         }
 318
 319         foreach my $field (qw{permalink}) {
 320                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field)) {
 321                         eval q{use HTML::Entities};
 322                         $template->param($field => HTML::Entities::encode_entities(IkiWiki::urlabs($pagestate{$page}{meta}{$field}, $config{url})));
 323                 }
 324         }
 325
 326         foreach my $field (qw{description}) {
 327                 eval q{use HTML::Entities};
 328                 $template->param($field => HTML::Entities::encode_numeric($pagestate{$page}{meta}{$field}))
 329                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 330         }
 331
 332         foreach my $field (qw{license copyright}) {
 333                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field) &&
 334                     ($page eq $destpage || ! exists $pagestate{$destpage}{meta}{$field} ||
 335                      $pagestate{$page}{meta}{$field} ne $pagestate{$destpage}{meta}{$field})) {
 336                         $template->param($field => htmlize($page, $destpage, $pagestate{$page}{meta}{$field}));
 337                 }
 338         }
 339 }
 340
 341 sub get_sort_key {
 342         my $page = shift;
 343         my $meta = shift;
 344
 345         # e.g. titlesort (also makes sense for author)
 346         my $key = $pagestate{$page}{meta}{$meta . "sort"};
 347         return $key if defined $key;
 348
 349         # e.g. title
 350         $key = $pagestate{$page}{meta}{$meta};
 351         return $key if defined $key;
 352
 353         # fall back to closer-to-core things
 354         if ($meta eq 'title') {
 355                 return pagetitle(IkiWiki::basename($page));
 356         }
 357         elsif ($meta eq 'date') {
 358                 return $IkiWiki::pagectime{$page};
 359         }
 360         elsif ($meta eq 'updated') {
 361                 return $IkiWiki::pagemtime{$page};
 362         }
 363         else {
 364                 return '';
 365         }
 366 }
 367
 368 sub match {
 369         my $field=shift;
 370         my $page=shift;
 371
 372         # turn glob into a safe regexp
 373         my $re=IkiWiki::glob2re(shift);
 374
 375         my $val;
 376         if (exists $pagestate{$page}{meta}{$field}) {
 377                 $val=$pagestate{$page}{meta}{$field};
 378         }
 379         elsif ($field eq 'title') {
 380                 $val = pagetitle($page);
 381         }
 382
 383         if (defined $val) {
 384                 if ($val=~$re) {
 385                         return IkiWiki::SuccessReason->new("$re matches $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 386                 }
 387                 else {
 388                         return IkiWiki::FailReason->new("$re does not match $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 389                 }
 390         }
 391         else {
 392                 return IkiWiki::FailReason->new("$page does not have a $field", $page => $IkiWiki::DEPEND_CONTENT);
 393         }
 394 }
 395
 396 package IkiWiki::PageSpec;
 397
 398 sub match_title ($$;@) {
 399         IkiWiki::Plugin::meta::match("title", @_);
 400 }
 401
 402 sub match_author ($$;@) {
 403         IkiWiki::Plugin::meta::match("author", @_);
 404 }
 405
 406 sub match_authorurl ($$;@) {
 407         IkiWiki::Plugin::meta::match("authorurl", @_);
 408 }
 409
 410 sub match_license ($$;@) {
 411         IkiWiki::Plugin::meta::match("license", @_);
 412 }
 413
 414 sub match_copyright ($$;@) {
 415         IkiWiki::Plugin::meta::match("copyright", @_);
 416 }
 417
 418 sub match_guid ($$;@) {
 419         IkiWiki::Plugin::meta::match("guid", @_);
 420 }
 421
 422 package IkiWiki::SortSpec;
 423
 424 sub cmp_meta {
 425         my $meta = shift;
 426         error(gettext("sort=meta requires a parameter")) unless defined $meta;
 427
 428         if ($meta eq 'updated' || $meta eq 'date') {
 429                 return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 430                         <=>
 431                         IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 432         }
 433
 434         return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 435                 cmp
 436                 IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 437 }
 438
 439 # A prototype of how sort=title could behave in 4.0 or something
 440 sub cmp_meta_title {
 441         $_[0] = 'title';
 442         return cmp_meta(@_);
 443 }
 444
 445 1