IkiWiki/Plugin/meta.pm

   1 #!/usr/bin/perl
   2 # Ikiwiki metadata plugin.
   3 package IkiWiki::Plugin::meta;
   4
   5 use warnings;
   6 use strict;
   7 use IkiWiki 3.00;
   8
   9 my %metaheaders;
  10
  11 sub import {
  12         hook(type => "getsetup", id => "meta", call => \&getsetup);
  13         hook(type => "needsbuild", id => "meta", call => \&needsbuild);
  14         hook(type => "preprocess", id => "meta", call => \&preprocess, scan => 1);
  15         hook(type => "pagetemplate", id => "meta", call => \&pagetemplate);
  16 }
  17
  18 sub getsetup () {
  19         return
  20                 plugin => {
  21                         safe => 1,
  22                         rebuild => undef,
  23                         section => "core",
  24                 },
  25 }
  26
  27 sub needsbuild (@) {
  28         my $needsbuild=shift;
  29         foreach my $page (keys %pagestate) {
  30                 if (exists $pagestate{$page}{meta}) {
  31                         if (exists $pagesources{$page} &&
  32                             grep { $_ eq $pagesources{$page} } @$needsbuild) {
  33                                 # remove state, it will be re-added
  34                                 # if the preprocessor directive is still
  35                                 # there during the rebuild
  36                                 delete $pagestate{$page}{meta};
  37                         }
  38                 }
  39         }
  40         return $needsbuild;
  41 }
  42
  43 sub scrub ($$$) {
  44         if (IkiWiki::Plugin::htmlscrubber->can("sanitize")) {
  45                 return IkiWiki::Plugin::htmlscrubber::sanitize(
  46                         content => shift, page => shift, destpage => shift);
  47         }
  48         else {
  49                 return shift;
  50         }
  51 }
  52
  53 sub safeurl ($) {
  54         my $url=shift;
  55         if (exists $IkiWiki::Plugin::htmlscrubber::{safe_url_regexp} &&
  56             defined $IkiWiki::Plugin::htmlscrubber::safe_url_regexp) {
  57                 return $url=~/$IkiWiki::Plugin::htmlscrubber::safe_url_regexp/;
  58         }
  59         else {
  60                 return 1;
  61         }
  62 }
  63
  64 sub htmlize ($$$) {
  65         my $page = shift;
  66         my $destpage = shift;
  67
  68         return IkiWiki::htmlize($page, $destpage, pagetype($pagesources{$page}),
  69                 IkiWiki::linkify($page, $destpage,
  70                 IkiWiki::preprocess($page, $destpage, shift)));
  71 }
  72
  73 sub preprocess (@) {
  74         return "" unless @_;
  75         my %params=@_;
  76         my $key=shift;
  77         my $value=$params{$key};
  78         delete $params{$key};
  79         my $page=$params{page};
  80         delete $params{page};
  81         my $destpage=$params{destpage};
  82         delete $params{destpage};
  83         delete $params{preview};
  84
  85         eval q{use HTML::Entities};
  86         # Always decode, even if encoding later, since it might not be
  87         # fully encoded.
  88         $value=decode_entities($value);
  89
  90         # Metadata collection that needs to happen during the scan pass.
  91         if ($key eq 'title') {
  92                 $pagestate{$page}{meta}{title}=$value;
  93                 if (exists $params{sortas}) {
  94                         $pagestate{$page}{meta}{titlesort}=$params{sortas};
  95                 }
  96                 else {
  97                         delete $pagestate{$page}{meta}{titlesort};
  98                 }
  99                 return "";
 100         }
 101         elsif ($key eq 'description') {
 102                 $pagestate{$page}{meta}{description}=$value;
 103                 # fallthrough
 104         }
 105         elsif ($key eq 'guid') {
 106                 $pagestate{$page}{meta}{guid}=$value;
 107                 # fallthrough
 108         }
 109         elsif ($key eq 'license') {
 110                 push @{$metaheaders{$page}}, '<link rel="license" href="#pagelicense" />';
 111                 $pagestate{$page}{meta}{license}=$value;
 112                 return "";
 113         }
 114         elsif ($key eq 'copyright') {
 115                 push @{$metaheaders{$page}}, '<link rel="copyright" href="#pagecopyright" />';
 116                 $pagestate{$page}{meta}{copyright}=$value;
 117                 return "";
 118         }
 119         elsif ($key eq 'link' && ! %params) {
 120                 # hidden WikiLink
 121                 add_link($page, $value);
 122                 return "";
 123         }
 124         elsif ($key eq 'enclosure') {
 125                 my $link=bestlink($page, $value);
 126                 if (! length $link) {
 127                         error gettext("enclosure not found")
 128                 }
 129                 add_depends($page, $link, deptype("presence"));
 130
 131                 $value=urlto($link, $page, 1);
 132                 $pagestate{$page}{meta}{enclosure}=$value;
 133                 $pagestate{$page}{meta}{enclosurefile}=$link;
 134                 # fallthrough
 135         }
 136         elsif ($key eq 'author') {
 137                 $pagestate{$page}{meta}{author}=$value;
 138                 if (exists $params{sortas}) {
 139                         $pagestate{$page}{meta}{authorsort}=$params{sortas};
 140                 }
 141                 else {
 142                         delete $pagestate{$page}{meta}{authorsort};
 143                 }
 144                 # fallthorough
 145         }
 146         elsif ($key eq 'authorurl') {
 147                 $pagestate{$page}{meta}{authorurl}=$value if safeurl($value);
 148                 # fallthrough
 149         }
 150         elsif ($key eq 'permalink') {
 151                 $pagestate{$page}{meta}{permalink}=$value if safeurl($value);
 152                 # fallthrough
 153         }
 154         elsif ($key eq 'date') {
 155                 eval q{use Date::Parse};
 156                 if (! $@) {
 157                         my $time = str2time($value);
 158                         if (defined $time) {
 159                                 $IkiWiki::pagectime{$page}=$time;
 160                         }
 161                         else {
 162                                 error(sprintf(gettext('cannot parse date/time: %s'), $value));
 163                         }
 164                 }
 165         }
 166         elsif ($key eq 'updated') {
 167                 eval q{use Date::Parse};
 168                 if (! $@) {
 169                         my $time = str2time($value);
 170                         if (defined $time) {
 171                                 $pagestate{$page}{meta}{updated}=$time;
 172                         }
 173                         else {
 174                                 error(sprintf(gettext('cannot parse date/time: %s'), $value));
 175                         }
 176                 }
 177         }
 178
 179         if (! defined wantarray) {
 180                 # avoid collecting duplicate data during scan pass
 181                 return;
 182         }
 183
 184         # Metadata handling that happens only during preprocessing pass.
 185         if ($key eq 'permalink') {
 186                 if (safeurl($value)) {
 187                         push @{$metaheaders{$page}}, scrub('<link rel="bookmark" href="'.encode_entities($value).'" />', $page, $destpage);
 188                 }
 189         }
 190         elsif ($key eq 'stylesheet') {
 191                 my $rel=exists $params{rel} ? $params{rel} : "alternate stylesheet";
 192                 my $title=exists $params{title} ? $params{title} : $value;
 193                 # adding .css to the value prevents using any old web
 194                 # editable page as a stylesheet
 195                 my $stylesheet=bestlink($page, $value.".css");
 196                 if (! length $stylesheet) {
 197                         error gettext("stylesheet not found")
 198                 }
 199                 push @{$metaheaders{$page}}, scrub('<link href="'.urlto($stylesheet, $page).
 200                         '" rel="'.encode_entities($rel).
 201                         '" title="'.encode_entities($title).
 202                         "\" type=\"text/css\" />", $page, $destpage);
 203         }
 204         elsif ($key eq 'script') {
 205                 my $defer=exists $params{defer} ? ' defer="defer"' : '';
 206                 my $async=exists $params{async} ? ' async="async"' : '';
 207                 my $js=bestlink($page, $value.".js");
 208                 if (! length $js) {
 209                         error gettext("script not found");
 210                 }
 211                 push @{$metaheaders{$page}}, scrub('<script src="'.urlto($js, $page).
 212                         '"' . $defer . $async . ' type="text/javascript"></script>',
 213                         $page, $destpage);
 214         }
 215         elsif ($key eq 'openid') {
 216                 my $delegate=0; # both by default
 217                 if (exists $params{delegate}) {
 218                         $delegate = 1 if lc $params{delegate} eq 'openid';
 219                         $delegate = 2 if lc $params{delegate} eq 'openid2';
 220                 }
 221                 if (exists $params{server} && safeurl($params{server})) {
 222                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 223                                 '" rel="openid.server" />' if $delegate ne 2;
 224                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($params{server}).
 225                                 '" rel="openid2.provider" />' if $delegate ne 1;
 226                 }
 227                 if (safeurl($value)) {
 228                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 229                                 '" rel="openid.delegate" />' if $delegate ne 2;
 230                         push @{$metaheaders{$page}}, '<link href="'.encode_entities($value).
 231                                 '" rel="openid2.local_id" />' if $delegate ne 1;
 232                 }
 233                 if (exists $params{"xrds-location"} && safeurl($params{"xrds-location"})) {
 234                         # force url absolute
 235                         eval q{use URI};
 236                         error($@) if $@;
 237                         my $url=URI->new_abs($params{"xrds-location"}, $config{url});
 238                         push @{$metaheaders{$page}}, '<meta http-equiv="X-XRDS-Location" '.
 239                                 'content="'.encode_entities($url).'" />';
 240                 }
 241         }
 242         elsif ($key eq 'foaf') {
 243                 if (safeurl($value)) {
 244                         push @{$metaheaders{$page}}, '<link rel="meta" '.
 245                                 'type="application/rdf+xml" title="FOAF" '.
 246                                 'href="'.encode_entities($value).'" />';
 247                 }
 248         }
 249         elsif ($key eq 'redir') {
 250                 return "" if $page ne $destpage;
 251                 my $safe=0;
 252                 if ($value !~ /^\w+:\/\//) {
 253                         my ($redir_page, $redir_anchor) = split /\#/, $value;
 254
 255                         my $link=bestlink($page, $redir_page);
 256                         if (! length $link) {
 257                                 error gettext("redir page not found")
 258                         }
 259                         add_depends($page, $link, deptype("presence"));
 260
 261                         $value=urlto($link, $page);
 262                         $value.='#'.$redir_anchor if defined $redir_anchor;
 263                         $safe=1;
 264
 265                         # redir cycle detection
 266                         $pagestate{$page}{meta}{redir}=$link;
 267                         my $at=$page;
 268                         my %seen;
 269                         while (exists $pagestate{$at}{meta}{redir}) {
 270                                 if ($seen{$at}) {
 271                                         error gettext("redir cycle is not allowed")
 272                                 }
 273                                 $seen{$at}=1;
 274                                 $at=$pagestate{$at}{meta}{redir};
 275                         }
 276                 }
 277                 else {
 278                         $value=encode_entities($value);
 279                 }
 280                 my $delay=int(exists $params{delay} ? $params{delay} : 0);
 281                 my $redir="<meta http-equiv=\"refresh\" content=\"$delay; URL=$value\" />";
 282                 if (! $safe) {
 283                         $redir=scrub($redir, $page, $destpage);
 284                 }
 285                 push @{$metaheaders{$page}}, $redir;
 286         }
 287         elsif ($key eq 'link') {
 288                 if (%params) {
 289                         push @{$metaheaders{$page}}, scrub("<link href=\"".encode_entities($value)."\" ".
 290                                 join(" ", map {
 291                                         encode_entities($_)."=\"".encode_entities(decode_entities($params{$_}))."\""
 292                                 } keys %params).
 293                                 " />\n", $page, $destpage);
 294                 }
 295         }
 296         elsif ($key eq 'robots') {
 297                 push @{$metaheaders{$page}}, '<meta name="robots"'.
 298                         ' content="'.encode_entities($value).'" />';
 299         }
 300         elsif ($key eq 'description' || $key eq 'author') {
 301                 push @{$metaheaders{$page}}, '<meta name="'.$key.
 302                         '" content="'.encode_entities($value).'" />';
 303         }
 304         elsif ($key eq 'name') {
 305                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 306                         encode_entities($value).
 307                         '" '.
 308                         join(' ', map { "$_=\"$params{$_}\"" } keys %params).
 309                         ' />', $page, $destpage);
 310         }
 311         elsif ($key eq 'keywords') {
 312                 # Make sure the keyword string is safe: only allow alphanumeric
 313                 # characters, space and comma and strip the rest.
 314                 $value =~ s/[^[:alnum:], ]+//g;
 315                 push @{$metaheaders{$page}}, '<meta name="keywords"'.
 316                         ' content="'.encode_entities($value).'" />';
 317         }
 318         else {
 319                 push @{$metaheaders{$page}}, scrub('<meta name="'.
 320                         encode_entities($key).'" content="'.
 321                         encode_entities($value).'" />', $page, $destpage);
 322         }
 323
 324         return "";
 325 }
 326
 327 sub pagetemplate (@) {
 328         my %params=@_;
 329         my $page=$params{page};
 330         my $destpage=$params{destpage};
 331         my $template=$params{template};
 332
 333         if (exists $metaheaders{$page} && $template->query(name => "meta")) {
 334                 # avoid duplicate meta lines
 335                 my %seen;
 336                 $template->param(meta => join("\n", grep { (! $seen{$_}) && ($seen{$_}=1) } @{$metaheaders{$page}}));
 337         }
 338         if (exists $pagestate{$page}{meta}{title} && $template->query(name => "title")) {
 339                 eval q{use HTML::Entities};
 340                 $template->param(title => HTML::Entities::encode_numeric($pagestate{$page}{meta}{title}));
 341                 $template->param(title_overridden => 1);
 342         }
 343
 344         if (exists $pagestate{$page}{meta}{enclosure}) {
 345                 $template->param(enclosure => HTML::Entities::encode_entities(IkiWiki::urlabs($pagestate{$page}{meta}{enclosure}, $config{url})));
 346         }
 347
 348         foreach my $field (qw{authorurl}) {
 349                 eval q{use HTML::Entities};
 350                 $template->param($field => HTML::Entities::encode_entities($pagestate{$page}{meta}{$field}))
 351                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 352         }
 353
 354         foreach my $field (qw{permalink}) {
 355                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field)) {
 356                         eval q{use HTML::Entities};
 357                         $template->param($field => HTML::Entities::encode_entities(IkiWiki::urlabs($pagestate{$page}{meta}{$field}, $config{url})));
 358                 }
 359         }
 360
 361         foreach my $field (qw{description author}) {
 362                 eval q{use HTML::Entities};
 363                 $template->param($field => HTML::Entities::encode_numeric($pagestate{$page}{meta}{$field}))
 364                         if exists $pagestate{$page}{meta}{$field} && $template->query(name => $field);
 365         }
 366
 367         foreach my $field (qw{license copyright}) {
 368                 if (exists $pagestate{$page}{meta}{$field} && $template->query(name => $field) &&
 369                     ($page eq $destpage || ! exists $pagestate{$destpage}{meta}{$field} ||
 370                      $pagestate{$page}{meta}{$field} ne $pagestate{$destpage}{meta}{$field})) {
 371                         $template->param($field => htmlize($page, $destpage, $pagestate{$page}{meta}{$field}));
 372                 }
 373         }
 374 }
 375
 376 sub get_sort_key {
 377         my $page = shift;
 378         my $meta = shift;
 379
 380         # e.g. titlesort (also makes sense for author)
 381         my $key = $pagestate{$page}{meta}{$meta . "sort"};
 382         return $key if defined $key;
 383
 384         # e.g. title
 385         $key = $pagestate{$page}{meta}{$meta};
 386         return $key if defined $key;
 387
 388         # fall back to closer-to-core things
 389         if ($meta eq 'title') {
 390                 return pagetitle(IkiWiki::basename($page));
 391         }
 392         elsif ($meta eq 'date') {
 393                 return $IkiWiki::pagectime{$page};
 394         }
 395         elsif ($meta eq 'updated') {
 396                 return $IkiWiki::pagemtime{$page};
 397         }
 398         else {
 399                 return '';
 400         }
 401 }
 402
 403 sub match {
 404         my $field=shift;
 405         my $page=shift;
 406
 407         # turn glob into a safe regexp
 408         my $re=IkiWiki::glob2re(shift);
 409
 410         my $val;
 411         if (exists $pagestate{$page}{meta}{$field}) {
 412                 $val=$pagestate{$page}{meta}{$field};
 413         }
 414         elsif ($field eq 'title') {
 415                 $val = pagetitle($page);
 416         }
 417
 418         if (defined $val) {
 419                 if ($val=~$re) {
 420                         return IkiWiki::SuccessReason->new("$re matches $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 421                 }
 422                 else {
 423                         return IkiWiki::FailReason->new("$re does not match $field of $page", $page => $IkiWiki::DEPEND_CONTENT, "" => 1);
 424                 }
 425         }
 426         else {
 427                 return IkiWiki::FailReason->new("$page does not have a $field", $page => $IkiWiki::DEPEND_CONTENT);
 428         }
 429 }
 430
 431 package IkiWiki::PageSpec;
 432
 433 sub match_title ($$;@) {
 434         IkiWiki::Plugin::meta::match("title", @_);
 435 }
 436
 437 sub match_author ($$;@) {
 438         IkiWiki::Plugin::meta::match("author", @_);
 439 }
 440
 441 sub match_authorurl ($$;@) {
 442         IkiWiki::Plugin::meta::match("authorurl", @_);
 443 }
 444
 445 sub match_license ($$;@) {
 446         IkiWiki::Plugin::meta::match("license", @_);
 447 }
 448
 449 sub match_copyright ($$;@) {
 450         IkiWiki::Plugin::meta::match("copyright", @_);
 451 }
 452
 453 sub match_guid ($$;@) {
 454         IkiWiki::Plugin::meta::match("guid", @_);
 455 }
 456
 457 package IkiWiki::SortSpec;
 458
 459 sub cmp_meta {
 460         my $meta = shift;
 461         error(gettext("sort=meta requires a parameter")) unless defined $meta;
 462
 463         if ($meta eq 'updated' || $meta eq 'date') {
 464                 return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 465                         <=>
 466                         IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 467         }
 468
 469         return IkiWiki::Plugin::meta::get_sort_key($a, $meta)
 470                 cmp
 471                 IkiWiki::Plugin::meta::get_sort_key($b, $meta);
 472 }
 473
 474 # A prototype of how sort=title could behave in 4.0 or something
 475 sub cmp_meta_title {
 476         $_[0] = 'title';
 477         return cmp_meta(@_);
 478 }
 479
 480 1