ikiwiki.in

   1 #!/usr/bin/perl -T
   2 $ENV{PATH}="/usr/local/bin:/usr/bin:/bin";
   3 delete @ENV{qw{IFS CDPATH ENV BASH_ENV}};
   4
   5 package IkiWiki;
   6
   7 use warnings;
   8 use strict;
   9 use lib '.'; # For use in nonstandard directory, munged by Makefile.
  10 use IkiWiki;
  11
  12 sub usage () { #{{{
  13         die gettext("usage: ikiwiki [options] source dest"), "\n",
  14             gettext("       ikiwiki --setup configfile"), "\n";
  15 } #}}}
  16
  17 sub getconfig () { #{{{
  18         if (! exists $ENV{WRAPPED_OPTIONS}) {
  19                 %config=defaultconfig();
  20                 eval q{use Getopt::Long};
  21                 Getopt::Long::Configure('pass_through');
  22                 GetOptions(
  23                         "setup|s=s" => sub {
  24                                 require IkiWiki::Setup;
  25                                 my $verbose=$config{verbose};
  26                                 my $syslog=$config{syslog};
  27                                 IkiWiki::Setup::load($_[1]);
  28                                 $config{setupverbose}=$config{verbose};
  29                                 $config{setupsyslog}=$config{syslog};
  30                                 $config{verbose}=$verbose || $config{setupverbose};
  31                                 $config{syslog}=$syslog;
  32                                 $config{setup}=1;
  33                         },
  34                         "dumpsetup|s=s" => \$config{dumpsetup},
  35                         "wikiname=s" => \$config{wikiname},
  36                         "verbose|v!" => \$config{verbose},
  37                         "syslog!" => \$config{syslog},
  38                         "rebuild!" => \$config{rebuild},
  39                         "refresh!" => \$config{refresh},
  40                         "post-commit" => \$config{post_commit},
  41                         "render=s" => \$config{render},
  42                         "wrappers!" => \$config{genwrappers},
  43                         "usedirs!" => \$config{usedirs},
  44                         "prefix-directives!" => \$config{prefix_directives},
  45                         "getctime" => \$config{getctime},
  46                         "numbacklinks=i" => \$config{numbacklinks},
  47                         "rcs=s" => \$config{rcs},
  48                         "no-rcs" => sub { $config{rcs}="" },
  49                         "cgi!" => \$config{cgi},
  50                         "discussion!" => \$config{discussion},
  51                         "w3mmode!" => \$config{w3mmode},
  52                         "url=s" => \$config{url},
  53                         "cgiurl=s" => \$config{cgiurl},
  54                         "historyurl=s" => \$config{historyurl},
  55                         "diffurl=s" => \$config{diffurl},
  56                         "svnpath" => \$config{svnpath},
  57                         "adminemail=s" => \$config{adminemail},
  58                         "timeformat=s" => \$config{timeformat},
  59                         "sslcookie!" => \$config{sslcookie},
  60                         "userdir=s" => \$config{userdir},
  61                         "htmlext=s" => \$config{htmlext},
  62                         "libdir=s" => \$config{libdir},
  63                         "exclude=s@" => sub {
  64                                 push @{$config{wiki_file_prune_regexps}}, $_[1];
  65                         },
  66                         "adminuser=s@" => sub {
  67                                 push @{$config{adminuser}}, $_[1]
  68                         },
  69                         "templatedir=s" => sub {
  70                                 $config{templatedir}=possibly_foolish_untaint($_[1])
  71                         },
  72                         "underlaydir=s" => sub {
  73                                 $config{underlaydir}=possibly_foolish_untaint($_[1])
  74                         },
  75                         "wrapper:s" => sub {
  76                                 $config{wrapper}=$_[1] ? possibly_foolish_untaint($_[1]) : "ikiwiki-wrap"
  77                         },
  78                         "wrappermode=i" => sub {
  79                                 $config{wrappermode}=possibly_foolish_untaint($_[1])
  80                         },
  81                         "plugin=s@" => sub {
  82                                 push @{$config{add_plugins}}, $_[1];
  83                         },
  84                         "disable-plugin=s@" => sub {
  85                                 push @{$config{disable_plugins}}, $_[1];
  86                         },
  87                         "set=s" => sub {
  88                                 my ($var, $val)=split('=', $_[1], 2);
  89                                 if (! defined $var || ! defined $val) {
  90                                         die gettext("usage: --set var=value"), "\n";
  91                                 }
  92                                 $config{$var}=$val;
  93                         },
  94                         "version" => sub {
  95                                 print "ikiwiki version $IkiWiki::version\n";
  96                                 exit;
  97                         },
  98                         "help|h" => sub { $SIG{__WARN__}=sub {}; die },
  99                 ) || usage();
 100
 101                 if (! $config{setup} && ! $config{render}) {
 102                         loadplugins();
 103                         if (@ARGV == 2) {
 104                                 $config{srcdir} = possibly_foolish_untaint(shift @ARGV);
 105                                 $config{destdir} = possibly_foolish_untaint(shift @ARGV);
 106                                 checkconfig();
 107                         }
 108                         else {
 109                                 usage() unless $config{dumpsetup};
 110                         }
 111                 }
 112         }
 113         else {
 114                 # wrapper passes a full config structure in the environment
 115                 # variable
 116                 eval possibly_foolish_untaint($ENV{WRAPPED_OPTIONS});
 117                 if ($@) {
 118                         error("WRAPPED_OPTIONS: $@");
 119                 }
 120                 delete $ENV{WRAPPED_OPTIONS};
 121
 122                 # optimisation for no-op post_commit
 123                 if ($config{post_commit} && ! commit_hook_enabled()) {
 124                         exit 0;
 125                 }
 126
 127                 loadplugins();
 128                 checkconfig();
 129         }
 130 } #}}}
 131
 132 sub main () { #{{{
 133         getconfig();
 134
 135         if ($config{setup}) {
 136                 delete $config{setup};
 137                 loadplugins();
 138                 checkconfig();
 139
 140                 if (@{$config{wrappers}} &&
 141                     ! $config{render} && ! $config{dumpsetup} &&
 142                     (! $config{refresh} || $config{genwrappers})) {
 143                         debug(gettext("generating wrappers.."));
 144                         require IkiWiki::Wrapper;
 145                         my %origconfig=(%config);
 146                         foreach my $wrapper (@{$config{wrappers}}) {
 147                                 %config=(%origconfig, %{$wrapper});
 148                                 $config{verbose}=$config{setupverbose}
 149                                         if exists $config{setupverbose};
 150                                 $config{syslog}=$config{setupsyslog}
 151                                         if exists $config{setupsyslog};
 152                                 delete @config{qw(setupsyslog setupverbose wrappers genwrappers rebuild)};
 153                                 checkconfig();
 154                                 if (! $config{cgi} && ! $config{post_commit}) {
 155                                         $config{post_commit}=1;
 156                                 }
 157                                 gen_wrapper();
 158                         }
 159                         %config=(%origconfig);
 160                 }
 161
 162                 # setup implies a wiki rebuild by default
 163                 if (! $config{refresh}) {
 164                         $config{rebuild}=1;
 165                 }
 166         }
 167
 168         if ($config{dumpsetup}) {
 169                 $config{srdir}=$config{destdir}="";
 170                 require IkiWiki::Setup;
 171                 IkiWiki::Setup::dump($config{dumpsetup});
 172         }
 173         elsif ($config{wrapper}) {
 174                 lockwiki();
 175                 require IkiWiki::Wrapper;
 176                 gen_wrapper();
 177         }
 178         elsif ($config{cgi}) {
 179                 require IkiWiki::CGI;
 180                 eval {cgi()};
 181                 if ($@) {
 182                         cgierror($@);
 183                 }
 184         }
 185         elsif ($config{render}) {
 186                 require IkiWiki::Render;
 187                 commandline_render();
 188         }
 189         elsif ($config{post_commit} && ! commit_hook_enabled()) {
 190                 # do nothing
 191         }
 192         else {
 193                 if ($config{rebuild}) {
 194                         debug(gettext("rebuilding wiki.."));
 195                 }
 196                 else {
 197                         debug(gettext("refreshing wiki.."));
 198                 }
 199                 lockwiki();
 200                 loadindex();
 201                 require IkiWiki::Render;
 202                 rcs_update();
 203                 refresh();
 204                 saveindex();
 205                 debug(gettext("done"));
 206         }
 207 } #}}}
 208
 209 main;