IkiWiki/Plugin/inline.pm

   1 #!/usr/bin/perl
   2 # Page inlining and blogging.
   3 package IkiWiki::Plugin::inline;
   4
   5 use warnings;
   6 use strict;
   7 use Encode;
   8 use IkiWiki 3.00;
   9 use URI;
  10
  11 my %knownfeeds;
  12 my %page_numfeeds;
  13 my @inline;
  14 my $nested=0;
  15
  16 sub import {
  17         hook(type => "getopt", id => "inline", call => \&getopt);
  18         hook(type => "getsetup", id => "inline", call => \&getsetup);
  19         hook(type => "checkconfig", id => "inline", call => \&checkconfig);
  20         hook(type => "sessioncgi", id => "inline", call => \&sessioncgi);
  21         hook(type => "preprocess", id => "inline",
  22                 call => \&IkiWiki::preprocess_inline);
  23         hook(type => "pagetemplate", id => "inline",
  24                 call => \&IkiWiki::pagetemplate_inline);
  25         hook(type => "format", id => "inline", call => \&format, first => 1);
  26         # Hook to change to do pinging since it's called late.
  27         # This ensures each page only pings once and prevents slow
  28         # pings interrupting page builds.
  29         hook(type => "change", id => "inline", call => \&IkiWiki::pingurl);
  30 }
  31
  32 sub getopt () {
  33         eval q{use Getopt::Long};
  34         error($@) if $@;
  35         Getopt::Long::Configure('pass_through');
  36         GetOptions(
  37                 "rss!" => \$config{rss},
  38                 "atom!" => \$config{atom},
  39                 "allowrss!" => \$config{allowrss},
  40                 "allowatom!" => \$config{allowatom},
  41                 "pingurl=s" => sub {
  42                         push @{$config{pingurl}}, $_[1];
  43                 },
  44         );
  45 }
  46
  47 sub getsetup () {
  48         return
  49                 plugin => {
  50                         safe => 1,
  51                         rebuild => undef,
  52                 },
  53                 rss => {
  54                         type => "boolean",
  55                         example => 0,
  56                         description => "enable rss feeds by default?",
  57                         safe => 1,
  58                         rebuild => 1,
  59                 },
  60                 atom => {
  61                         type => "boolean",
  62                         example => 0,
  63                         description => "enable atom feeds by default?",
  64                         safe => 1,
  65                         rebuild => 1,
  66                 },
  67                 allowrss => {
  68                         type => "boolean",
  69                         example => 0,
  70                         description => "allow rss feeds to be used?",
  71                         safe => 1,
  72                         rebuild => 1,
  73                 },
  74                 allowatom => {
  75                         type => "boolean",
  76                         example => 0,
  77                         description => "allow atom feeds to be used?",
  78                         safe => 1,
  79                         rebuild => 1,
  80                 },
  81                 pingurl => {
  82                         type => "string",
  83                         example => "http://rpc.technorati.com/rpc/ping",
  84                         description => "urls to ping (using XML-RPC) on feed update",
  85                         safe => 1,
  86                         rebuild => 0,
  87                 },
  88 }
  89
  90 sub checkconfig () {
  91         if (($config{rss} || $config{atom}) && ! length $config{url}) {
  92                 error(gettext("Must specify url to wiki with --url when using --rss or --atom"));
  93         }
  94         if ($config{rss}) {
  95                 push @{$config{wiki_file_prune_regexps}}, qr/\.rss$/;
  96         }
  97         if ($config{atom}) {
  98                 push @{$config{wiki_file_prune_regexps}}, qr/\.atom$/;
  99         }
 100         if (! exists $config{pingurl}) {
 101                 $config{pingurl}=[];
 102         }
 103 }
 104
 105 sub format (@) {
 106         my %params=@_;
 107
 108         # Fill in the inline content generated earlier. This is actually an
 109         # optimisation.
 110         $params{content}=~s{<div class="inline" id="([^"]+)"></div>}{
 111                 delete @inline[$1,]
 112         }eg;
 113         return $params{content};
 114 }
 115
 116 sub sessioncgi ($$) {
 117         my $q=shift;
 118         my $session=shift;
 119
 120         if ($q->param('do') eq 'blog') {
 121                 my $page=titlepage(decode_utf8($q->param('title')));
 122                 $page=~s/(\/)/"__".ord($1)."__"/eg; # don't create subdirs
 123                 # if the page already exists, munge it to be unique
 124                 my $from=$q->param('from');
 125                 my $add="";
 126                 while (exists $IkiWiki::pagecase{lc($from."/".$page.$add)}) {
 127                         $add=1 unless length $add;
 128                         $add++;
 129                 }
 130                 $q->param('page', $page.$add);
 131                 # now go create the page
 132                 $q->param('do', 'create');
 133                 # make sure the editpage plugin in loaded
 134                 if (IkiWiki->can("cgi_editpage")) {
 135                         IkiWiki::cgi_editpage($q, $session);
 136                 }
 137                 else {
 138                         error(gettext("page editing not allowed"));
 139                 }
 140                 exit;
 141         }
 142 }
 143
 144 # Back to ikiwiki namespace for the rest, this code is very much
 145 # internal to ikiwiki even though it's separated into a plugin.
 146 package IkiWiki;
 147
 148 my %toping;
 149 my %feedlinks;
 150
 151 sub preprocess_inline (@) {
 152         my %params=@_;
 153
 154         if (! exists $params{pages} && ! exists $params{pagenames}) {
 155                 error gettext("missing pages parameter");
 156         }
 157         my $raw=yesno($params{raw});
 158         my $archive=yesno($params{archive});
 159         my $rss=(($config{rss} || $config{allowrss}) && exists $params{rss}) ? yesno($params{rss}) : $config{rss};
 160         my $atom=(($config{atom} || $config{allowatom}) && exists $params{atom}) ? yesno($params{atom}) : $config{atom};
 161         my $quick=exists $params{quick} ? yesno($params{quick}) : 0;
 162         my $feeds=exists $params{feeds} ? yesno($params{feeds}) : !$quick;
 163         my $emptyfeeds=exists $params{emptyfeeds} ? yesno($params{emptyfeeds}) : 1;
 164         my $feedonly=yesno($params{feedonly});
 165         if (! exists $params{show} && ! $archive) {
 166                 $params{show}=10;
 167         }
 168         if (! exists $params{feedshow} && exists $params{show}) {
 169                 $params{feedshow}=$params{show};
 170         }
 171         my $desc;
 172         if (exists $params{description}) {
 173                 $desc = $params{description}
 174         }
 175         else {
 176                 $desc = $config{wikiname};
 177         }
 178         my $actions=yesno($params{actions});
 179         if (exists $params{template}) {
 180                 $params{template}=~s/[^-_a-zA-Z0-9]+//g;
 181         }
 182         else {
 183                 $params{template} = $archive ? "archivepage" : "inlinepage";
 184         }
 185
 186         my @list;
 187
 188         if (exists $params{pagenames}) {
 189                 foreach my $p (qw(sort pages)) {
 190                         if (exists $params{$p}) {
 191                                 error sprintf(gettext("the %s and %s parameters cannot be used together"),
 192                                         "pagenames", $p);
 193                         }
 194                 }
 195
 196                 @list = map { bestlink($params{page}, $_) }
 197                         split ' ', $params{pagenames};
 198         }
 199         else {
 200                 add_depends($params{page}, $params{pages});
 201
 202                 @list = pagespec_match_list(
 203                         [ grep { $_ ne $params{page} } keys %pagesources ],
 204                         $params{pages}, location => $params{page});
 205
 206                 if (exists $params{sort} && $params{sort} eq 'title') {
 207                         @list=sort { pagetitle(basename($a)) cmp pagetitle(basename($b)) } @list;
 208                 }
 209                 elsif (exists $params{sort} && $params{sort} eq 'title_natural') {
 210                         eval q{use Sort::Naturally};
 211                         if ($@) {
 212                                 error(gettext("Sort::Naturally needed for title_natural sort"));
 213                         }
 214                         @list=sort { Sort::Naturally::ncmp(pagetitle(basename($a)), pagetitle(basename($b))) } @list;
 215                 }
 216                 elsif (exists $params{sort} && $params{sort} eq 'mtime') {
 217                         @list=sort { $pagemtime{$b} <=> $pagemtime{$a} } @list;
 218                 }
 219                 elsif (! exists $params{sort} || $params{sort} eq 'age') {
 220                         @list=sort { $pagectime{$b} <=> $pagectime{$a} } @list;
 221                 }
 222                 else {
 223                         error sprintf(gettext("unknown sort type %s"), $params{sort});
 224                 }
 225         }
 226
 227         if (yesno($params{reverse})) {
 228                 @list=reverse(@list);
 229         }
 230
 231         if (exists $params{skip}) {
 232                 @list=@list[$params{skip} .. scalar @list - 1];
 233         }
 234
 235         my @feedlist;
 236         if ($feeds) {
 237                 if (exists $params{feedshow} &&
 238                     $params{feedshow} && @list > $params{feedshow}) {
 239                         @feedlist=@list[0..$params{feedshow} - 1];
 240                 }
 241                 else {
 242                         @feedlist=@list;
 243                 }
 244         }
 245
 246         if ($params{show} && @list > $params{show}) {
 247                 @list=@list[0..$params{show} - 1];
 248         }
 249
 250         # Explicitly add all currently displayed pages as dependencies, so
 251         # that if they are removed or otherwise changed, the inline will be
 252         # sure to be updated.
 253         foreach my $p ($#list >= $#feedlist ? @list : @feedlist) {
 254                 add_depends($params{page}, $p);
 255         }
 256
 257         if ($feeds && exists $params{feedpages}) {
 258                 @feedlist=pagespec_match_list(\@feedlist, $params{feedpages}, location => $params{page});
 259         }
 260
 261         my ($feedbase, $feednum);
 262         if ($feeds) {
 263                 # Ensure that multiple feeds on a page go to unique files.
 264
 265                 # Feedfile can lead to conflicts if usedirs is not enabled,
 266                 # so avoid supporting it in that case.
 267                 delete $params{feedfile} if ! $config{usedirs};
 268                 # Tight limits on legal feedfiles, to avoid security issues
 269                 # and conflicts.
 270                 if (defined $params{feedfile}) {
 271                         if ($params{feedfile} =~ /\// ||
 272                             $params{feedfile} !~ /$config{wiki_file_regexp}/) {
 273                                 error("illegal feedfile");
 274                         }
 275                         $params{feedfile}=possibly_foolish_untaint($params{feedfile});
 276                 }
 277                 $feedbase=targetpage($params{destpage}, "", $params{feedfile});
 278
 279                 my $feedid=join("\0", $feedbase, map { $_."\0".$params{$_} } sort keys %params);
 280                 if (exists $knownfeeds{$feedid}) {
 281                         $feednum=$knownfeeds{$feedid};
 282                 }
 283                 else {
 284                         if (exists $page_numfeeds{$params{destpage}}{$feedbase}) {
 285                                 if ($feeds) {
 286                                         $feednum=$knownfeeds{$feedid}=++$page_numfeeds{$params{destpage}}{$feedbase};
 287                                 }
 288                         }
 289                         else {
 290                                 $feednum=$knownfeeds{$feedid}="";
 291                                 if ($feeds) {
 292                                         $page_numfeeds{$params{destpage}}{$feedbase}=1;
 293                                 }
 294                         }
 295                 }
 296         }
 297
 298         my $rssurl=abs2rel($feedbase."rss".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $rss;
 299         my $atomurl=abs2rel($feedbase."atom".$feednum, dirname(htmlpage($params{destpage}))) if $feeds && $atom;
 300
 301         my $ret="";
 302
 303         if (length $config{cgiurl} && ! $params{preview} && (exists $params{rootpage} ||
 304             (exists $params{postform} && yesno($params{postform}))) &&
 305             IkiWiki->can("cgi_editpage")) {
 306                 # Add a blog post form, with feed buttons.
 307                 my $formtemplate=template("blogpost.tmpl", blind_cache => 1);
 308                 $formtemplate->param(cgiurl => $config{cgiurl});
 309                 $formtemplate->param(rootpage => rootpage(%params));
 310                 $formtemplate->param(rssurl => $rssurl) if $feeds && $rss;
 311                 $formtemplate->param(atomurl => $atomurl) if $feeds && $atom;
 312                 if (exists $params{postformtext}) {
 313                         $formtemplate->param(postformtext =>
 314                                 $params{postformtext});
 315                 }
 316                 else {
 317                         $formtemplate->param(postformtext =>
 318                                 gettext("Add a new post titled:"));
 319                 }
 320                 $ret.=$formtemplate->output;
 321
 322                 # The post form includes the feed buttons, so
 323                 # emptyfeeds cannot be hidden.
 324                 $emptyfeeds=1;
 325         }
 326         elsif ($feeds && !$params{preview} && ($emptyfeeds || @feedlist)) {
 327                 # Add feed buttons.
 328                 my $linktemplate=template("feedlink.tmpl", blind_cache => 1);
 329                 $linktemplate->param(rssurl => $rssurl) if $rss;
 330                 $linktemplate->param(atomurl => $atomurl) if $atom;
 331                 $ret.=$linktemplate->output;
 332         }
 333
 334         if (! $feedonly) {
 335                 require HTML::Template;
 336                 my @params=IkiWiki::template_params($params{template}.".tmpl", blind_cache => 1);
 337                 if (! @params) {
 338                         error sprintf(gettext("nonexistant template %s"), $params{template});
 339                 }
 340                 my $template=HTML::Template->new(@params) unless $raw;
 341
 342                 foreach my $page (@list) {
 343                         my $file = $pagesources{$page};
 344                         my $type = pagetype($file);
 345                         if (! $raw || ($raw && ! defined $type)) {
 346                                 unless ($archive && $quick) {
 347                                         # Get the content before populating the
 348                                         # template, since getting the content uses
 349                                         # the same template if inlines are nested.
 350                                         my $content=get_inline_content($page, $params{destpage});
 351                                         $template->param(content => $content);
 352                                 }
 353                                 $template->param(pageurl => urlto($page, $params{destpage}));
 354                                 $template->param(inlinepage => $page);
 355                                 $template->param(title => pagetitle(basename($page)));
 356                                 $template->param(ctime => displaytime($pagectime{$page}, $params{timeformat}));
 357                                 $template->param(mtime => displaytime($pagemtime{$page}, $params{timeformat}));
 358                                 $template->param(first => 1) if $page eq $list[0];
 359                                 $template->param(last => 1) if $page eq $list[$#list];
 360
 361                                 if ($actions) {
 362                                         my $file = $pagesources{$page};
 363                                         my $type = pagetype($file);
 364                                         if ($config{discussion}) {
 365                                                 if ($page !~ /.*\/\Q$config{discussionpage}\E$/ &&
 366                                                     (length $config{cgiurl} ||
 367                                                      exists $links{$page."/".$config{discussionpage}})) {
 368                                                         $template->param(have_actions => 1);
 369                                                         $template->param(discussionlink =>
 370                                                                 htmllink($page,
 371                                                                         $params{destpage},
 372                                                                         $config{discussionpage},
 373                                                                         noimageinline => 1,
 374                                                                         forcesubpage => 1));
 375                                                 }
 376                                         }
 377                                         if (length $config{cgiurl} && defined $type) {
 378                                                 $template->param(have_actions => 1);
 379                                                 $template->param(editurl => cgiurl(do => "edit", page => $page));
 380                                         }
 381                                 }
 382
 383                                 run_hooks(pagetemplate => sub {
 384                                         shift->(page => $page, destpage => $params{destpage},
 385                                                 template => $template,);
 386                                 });
 387
 388                                 $ret.=$template->output;
 389                                 $template->clear_params;
 390                         }
 391                         else {
 392                                 if (defined $type) {
 393                                         $ret.="\n".
 394                                               linkify($page, $params{destpage},
 395                                               preprocess($page, $params{destpage},
 396                                               filter($page, $params{destpage},
 397                                               readfile(srcfile($file)))));
 398                                 }
 399                         }
 400                 }
 401         }
 402
 403         if ($feeds && ($emptyfeeds || @feedlist)) {
 404                 if ($rss) {
 405                         my $rssp=$feedbase."rss".$feednum;
 406                         will_render($params{destpage}, $rssp);
 407                         if (! $params{preview}) {
 408                                 writefile($rssp, $config{destdir},
 409                                         genfeed("rss",
 410                                                 $config{url}."/".$rssp, $desc, $params{guid}, $params{destpage}, @feedlist));
 411                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 412                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/rss+xml" title="$desc (RSS)" href="$rssurl" />};
 413                         }
 414                 }
 415                 if ($atom) {
 416                         my $atomp=$feedbase."atom".$feednum;
 417                         will_render($params{destpage}, $atomp);
 418                         if (! $params{preview}) {
 419                                 writefile($atomp, $config{destdir},
 420                                         genfeed("atom", $config{url}."/".$atomp, $desc, $params{guid}, $params{destpage}, @feedlist));
 421                                 $toping{$params{destpage}}=1 unless $config{rebuild};
 422                                 $feedlinks{$params{destpage}}.=qq{<link rel="alternate" type="application/atom+xml" title="$desc (Atom)" href="$atomurl" />};
 423                         }
 424                 }
 425         }
 426
 427         return $ret if $raw || $nested;
 428         push @inline, $ret;
 429         return "<div class=\"inline\" id=\"$#inline\"></div>\n\n";
 430 }
 431
 432 sub pagetemplate_inline (@) {
 433         my %params=@_;
 434         my $page=$params{page};
 435         my $template=$params{template};
 436
 437         $template->param(feedlinks => $feedlinks{$page})
 438                 if exists $feedlinks{$page} && $template->query(name => "feedlinks");
 439 }
 440
 441 sub get_inline_content ($$) {
 442         my $page=shift;
 443         my $destpage=shift;
 444
 445         my $file=$pagesources{$page};
 446         my $type=pagetype($file);
 447         if (defined $type) {
 448                 $nested++;
 449                 my $ret=htmlize($page, $destpage, $type,
 450                        linkify($page, $destpage,
 451                        preprocess($page, $destpage,
 452                        filter($page, $destpage,
 453                        readfile(srcfile($file))))));
 454                 $nested--;
 455                 return $ret;
 456         }
 457         else {
 458                 return "";
 459         }
 460 }
 461
 462 sub date_822 ($) {
 463         my $time=shift;
 464
 465         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 466         POSIX::setlocale(&POSIX::LC_TIME, "C");
 467         my $ret=POSIX::strftime("%a, %d %b %Y %H:%M:%S %z", localtime($time));
 468         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 469         return $ret;
 470 }
 471
 472 sub date_3339 ($) {
 473         my $time=shift;
 474
 475         my $lc_time=POSIX::setlocale(&POSIX::LC_TIME);
 476         POSIX::setlocale(&POSIX::LC_TIME, "C");
 477         my $ret=POSIX::strftime("%Y-%m-%dT%H:%M:%SZ", gmtime($time));
 478         POSIX::setlocale(&POSIX::LC_TIME, $lc_time);
 479         return $ret;
 480 }
 481
 482 sub absolute_urls ($$) {
 483         # sucky sub because rss sucks
 484         my $content=shift;
 485         my $baseurl=shift;
 486
 487         my $url=$baseurl;
 488         $url=~s/[^\/]+$//;
 489
 490         # what is the non path part of the url?
 491         my $top_uri = URI->new($url);
 492         $top_uri->path_query(""); # reset the path
 493         my $urltop = $top_uri->as_string;
 494
 495         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(#[^"]+)"/$1 href="$baseurl$2"/mig;
 496         # relative to another wiki page
 497         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)([^\/][^"]*)"/$1 href="$url$2"/mig;
 498         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)([^\/][^"]*)"/$1 src="$url$2"/mig;
 499         # relative to the top of the site
 500         $content=~s/(<a(?:\s+(?:class|id)\s*="?\w+"?)?)\s+href=\s*"(?!\w+:)(\/[^"]*)"/$1 href="$urltop$2"/mig;
 501         $content=~s/(<img(?:\s+(?:class|id|width|height)\s*="?\w+"?)*)\s+src=\s*"(?!\w+:)(\/[^"]*)"/$1 src="$urltop$2"/mig;
 502         return $content;
 503 }
 504
 505 sub genfeed ($$$$$@) {
 506         my $feedtype=shift;
 507         my $feedurl=shift;
 508         my $feeddesc=shift;
 509         my $guid=shift;
 510         my $page=shift;
 511         my @pages=@_;
 512
 513         my $url=URI->new(encode_utf8(urlto($page,"",1)));
 514
 515         my $itemtemplate=template($feedtype."item.tmpl", blind_cache => 1);
 516         my $content="";
 517         my $lasttime = 0;
 518         foreach my $p (@pages) {
 519                 my $u=URI->new(encode_utf8(urlto($p, "", 1)));
 520                 my $pcontent = absolute_urls(get_inline_content($p, $page), $url);
 521
 522                 $itemtemplate->param(
 523                         title => pagetitle(basename($p)),
 524                         url => $u,
 525                         permalink => $u,
 526                         cdate_822 => date_822($pagectime{$p}),
 527                         mdate_822 => date_822($pagemtime{$p}),
 528                         cdate_3339 => date_3339($pagectime{$p}),
 529                         mdate_3339 => date_3339($pagemtime{$p}),
 530                 );
 531
 532                 if (exists $pagestate{$p}) {
 533                         if (exists $pagestate{$p}{meta}{guid}) {
 534                                 $itemtemplate->param(guid => $pagestate{$p}{meta}{guid});
 535                         }
 536
 537                         if (exists $pagestate{$p}{meta}{updated}) {
 538                                 $itemtemplate->param(mdate_822 => date_822($pagestate{$p}{meta}{updated}));
 539                                 $itemtemplate->param(mdate_3339 => date_3339($pagestate{$p}{meta}{updated}));
 540                         }
 541                 }
 542
 543                 if ($itemtemplate->query(name => "enclosure")) {
 544                         my $file=$pagesources{$p};
 545                         my $type=pagetype($file);
 546                         if (defined $type) {
 547                                 $itemtemplate->param(content => $pcontent);
 548                         }
 549                         else {
 550                                 my $size=(srcfile_stat($file))[8];
 551                                 my $mime="unknown";
 552                                 eval q{use File::MimeInfo};
 553                                 if (! $@) {
 554                                         $mime = mimetype($file);
 555                                 }
 556                                 $itemtemplate->param(
 557                                         enclosure => $u,
 558                                         type => $mime,
 559                                         length => $size,
 560                                 );
 561                         }
 562                 }
 563                 else {
 564                         $itemtemplate->param(content => $pcontent);
 565                 }
 566
 567                 run_hooks(pagetemplate => sub {
 568                         shift->(page => $p, destpage => $page,
 569                                 template => $itemtemplate);
 570                 });
 571
 572                 $content.=$itemtemplate->output;
 573                 $itemtemplate->clear_params;
 574
 575                 $lasttime = $pagemtime{$p} if $pagemtime{$p} > $lasttime;
 576         }
 577
 578         my $template=template($feedtype."page.tmpl", blind_cache => 1);
 579         $template->param(
 580                 title => $page ne "index" ? pagetitle($page) : $config{wikiname},
 581                 wikiname => $config{wikiname},
 582                 pageurl => $url,
 583                 content => $content,
 584                 feeddesc => $feeddesc,
 585                 guid => $guid,
 586                 feeddate => date_3339($lasttime),
 587                 feedurl => $feedurl,
 588                 version => $IkiWiki::version,
 589         );
 590         run_hooks(pagetemplate => sub {
 591                 shift->(page => $page, destpage => $page,
 592                         template => $template);
 593         });
 594
 595         return $template->output;
 596 }
 597
 598 sub pingurl (@) {
 599         return unless @{$config{pingurl}} && %toping;
 600
 601         eval q{require RPC::XML::Client};
 602         if ($@) {
 603                 debug(gettext("RPC::XML::Client not found, not pinging"));
 604                 return;
 605         }
 606
 607         # daemonize here so slow pings don't slow down wiki updates
 608         defined(my $pid = fork) or error("Can't fork: $!");
 609         return if $pid;
 610         chdir '/';
 611         POSIX::setsid() or error("Can't start a new session: $!");
 612         open STDIN, '/dev/null';
 613         open STDOUT, '>/dev/null';
 614         open STDERR, '>&STDOUT' or error("Can't dup stdout: $!");
 615
 616         # Don't need to keep a lock on the wiki as a daemon.
 617         IkiWiki::unlockwiki();
 618
 619         foreach my $page (keys %toping) {
 620                 my $title=pagetitle(basename($page), 0);
 621                 my $url=urlto($page, "", 1);
 622                 foreach my $pingurl (@{$config{pingurl}}) {
 623                         debug("Pinging $pingurl for $page");
 624                         eval {
 625                                 my $client = RPC::XML::Client->new($pingurl);
 626                                 my $req = RPC::XML::request->new('weblogUpdates.ping',
 627                                         $title, $url);
 628                                 my $res = $client->send_request($req);
 629                                 if (! ref $res) {
 630                                         error("Did not receive response to ping");
 631                                 }
 632                                 my $r=$res->value;
 633                                 if (! exists $r->{flerror} || $r->{flerror}) {
 634                                         error("Ping rejected: ".(exists $r->{message} ? $r->{message} : "[unknown reason]"));
 635                                 }
 636                         };
 637                         if ($@) {
 638                                 error "Ping failed: $@";
 639                         }
 640                 }
 641         }
 642
 643         exit 0; # daemon done
 644 }
 645
 646
 647 sub rootpage (@) {
 648         my %params=@_;
 649
 650         my $rootpage;
 651         if (exists $params{rootpage}) {
 652                 $rootpage=bestlink($params{page}, $params{rootpage});
 653                 if (!length $rootpage) {
 654                         $rootpage=$params{rootpage};
 655                 }
 656         }
 657         else {
 658                 $rootpage=$params{page};
 659         }
 660         return $rootpage;
 661 }
 662
 663 1